lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 use constant {
  26         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  27                         0x7fffffff : 1_000_000,
  28         DEBUG => !!$ENV{DEBUG},
  29 };
  30
  31 my $xapianlevels = qr/\A(?:full|medium)\z/;
  32
  33 sub new {
  34         my ($class, $ibx, $creat, $shard) = @_;
  35         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  36         my $levels = qr/\A(?:full|medium|basic)\z/;
  37         my $inboxdir = $ibx->{inboxdir};
  38         my $version = $ibx->version;
  39         my $indexlevel = 'full';
  40         my $altid = $ibx->{altid};
  41         if ($altid) {
  42                 require PublicInbox::AltId;
  43                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  44         }
  45         if ($ibx->{indexlevel}) {
  46                 if ($ibx->{indexlevel} =~ $levels) {
  47                         $indexlevel = $ibx->{indexlevel};
  48                 } else {
  49                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  50                 }
  51         }
  52         $ibx = PublicInbox::InboxWritable->new($ibx);
  53         my $self = bless {
  54                 inboxdir => $inboxdir,
  55                 -inbox => $ibx,
  56                 git => $ibx->git,
  57                 -altid => $altid,
  58                 ibx_ver => $version,
  59                 indexlevel => $indexlevel,
  60         }, $class;
  61         $ibx->umask_prepare;
  62         if ($version == 1) {
  63                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  64                 my $dir = $self->xdir;
  65                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  66         } elsif ($version == 2) {
  67                 defined $shard or die "shard is required for v2\n";
  68                 # shard is a number
  69                 $self->{shard} = $shard;
  70                 $self->{lock_path} = undef;
  71         } else {
  72                 die "unsupported inbox version=$version\n";
  73         }
  74         $self->{creat} = ($creat || 0) == 1;
  75         $self;
  76 }
  77
  78 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  79
  80 sub _xdb_release {
  81         my ($self) = @_;
  82         if (need_xapian($self)) {
  83                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  84                 $xdb->close;
  85         }
  86         $self->lock_release if $self->{creat};
  87         undef;
  88 }
  89
  90 sub load_xapian_writable () {
  91         return 1 if $X->{WritableDatabase};
  92         PublicInbox::Search::load_xapian() or return;
  93         my $xap = $PublicInbox::Search::Xap;
  94         for (qw(Document TermGenerator WritableDatabase)) {
  95                 $X->{$_} = $xap.'::'.$_;
  96         }
  97         eval 'require '.$X->{WritableDatabase} or die;
  98         *sortable_serialise = $xap.'::sortable_serialise';
  99         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 100         $DB_OPEN = eval($xap.'::DB_OPEN()');
 101         1;
 102 }
 103
 104 sub _xdb_acquire {
 105         my ($self) = @_;
 106         my $flag;
 107         my $dir = $self->xdir;
 108         if (need_xapian($self)) {
 109                 croak 'already acquired' if $self->{xdb};
 110                 load_xapian_writable();
 111                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 112         }
 113         if ($self->{creat}) {
 114                 require File::Path;
 115                 $self->lock_acquire;
 116
 117                 # don't create empty Xapian directories if we don't need Xapian
 118                 my $is_shard = defined($self->{shard});
 119                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 120                         File::Path::mkpath($dir);
 121                 }
 122         }
 123         return unless defined $flag;
 124         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 125         if ($@) {
 126                 die "Failed opening $dir: ", $@;
 127         }
 128         $self->{xdb} = $xdb;
 129 }
 130
 131 sub add_val ($$$) {
 132         my ($doc, $col, $num) = @_;
 133         $num = sortable_serialise($num);
 134         $doc->add_value($col, $num);
 135 }
 136
 137 sub term_generator ($) { # write-only
 138         my ($self) = @_;
 139
 140         $self->{term_generator} //= do {
 141                 my $tg = $X->{TermGenerator}->new;
 142                 $tg->set_stemmer($self->stemmer);
 143                 $tg;
 144         }
 145 }
 146
 147 sub index_text ($$$$) {
 148         my ($self, $text, $wdf_inc, $prefix) = @_;
 149         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 150
 151         if ($self->{indexlevel} eq 'full') {
 152                 $tg->index_text($text, $wdf_inc, $prefix);
 153                 $tg->increase_termpos;
 154         } else {
 155                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 156         }
 157 }
 158
 159 sub index_users ($$) {
 160         my ($self, $smsg) = @_;
 161
 162         my $from = $smsg->from;
 163         my $to = $smsg->to;
 164         my $cc = $smsg->cc;
 165
 166         index_text($self, $from, 1, 'A'); # A - author
 167         index_text($self, $to, 1, 'XTO') if $to ne '';
 168         index_text($self, $cc, 1, 'XCC') if $cc ne '';
 169 }
 170
 171 sub index_diff_inc ($$$$) {
 172         my ($self, $text, $pfx, $xnq) = @_;
 173         if (@$xnq) {
 174                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 175                 @$xnq = ();
 176         }
 177         index_text($self, $text, 1, $pfx);
 178 }
 179
 180 sub index_old_diff_fn {
 181         my ($self, $seen, $fa, $fb, $xnq) = @_;
 182
 183         # no renames or space support for traditional diffs,
 184         # find the number of leading common paths to strip:
 185         my @fa = split('/', $fa);
 186         my @fb = split('/', $fb);
 187         while (scalar(@fa) && scalar(@fb)) {
 188                 $fa = join('/', @fa);
 189                 $fb = join('/', @fb);
 190                 if ($fa eq $fb) {
 191                         unless ($seen->{$fa}++) {
 192                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 193                         }
 194                         return 1;
 195                 }
 196                 shift @fa;
 197                 shift @fb;
 198         }
 199         0;
 200 }
 201
 202 sub index_diff ($$$) {
 203         my ($self, $txt, $doc) = @_;
 204         my %seen;
 205         my $in_diff;
 206         my @xnq;
 207         my $xnq = \@xnq;
 208         foreach (split(/\n/, $txt)) {
 209                 if ($in_diff && s/^ //) { # diff context
 210                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 211                 } elsif (/^-- $/) { # email signature begins
 212                         $in_diff = undef;
 213                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 214                         # wait until "---" and "+++" to capture filenames
 215                         $in_diff = 1;
 216                 # traditional diff:
 217                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 218                         my ($opt, $fa, $fb) = ($1, $2, $3);
 219                         push @xnq, $_;
 220                         # only support unified:
 221                         next unless $opt =~ /[uU]/;
 222                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 223                                                         $xnq);
 224                 } elsif (m!^--- ("?[^/]+/.+)!) {
 225                         my $fn = $1;
 226                         $fn = (split('/', git_unquote($fn), 2))[1];
 227                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 228                         $in_diff = 1;
 229                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 230                         my $fn = $1;
 231                         $fn = (split('/', git_unquote($fn), 2))[1];
 232                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 233                         $in_diff = 1;
 234                 } elsif (/^--- (\S+)/) {
 235                         $in_diff = $1;
 236                         push @xnq, $_;
 237                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 238                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 239                                                         $1, $xnq);
 240                 } elsif ($in_diff && s/^\+//) { # diff added
 241                         index_diff_inc($self, $_, 'XDFB', $xnq);
 242                 } elsif ($in_diff && s/^-//) { # diff removed
 243                         index_diff_inc($self, $_, 'XDFA', $xnq);
 244                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 245                         my ($ba, $bb) = ($1, $2);
 246                         index_git_blob_id($doc, 'XDFPRE', $ba);
 247                         index_git_blob_id($doc, 'XDFPOST', $bb);
 248                         $in_diff = 1;
 249                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 250                         # traditional diff w/o -p
 251                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 252                         # hunk header context
 253                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 254                 # ignore the following lines:
 255                 } elsif (/^(?:dis)similarity index/ ||
 256                                 /^(?:old|new) mode/ ||
 257                                 /^(?:deleted|new) file mode/ ||
 258                                 /^(?:copy|rename) (?:from|to) / ||
 259                                 /^(?:dis)?similarity index / ||
 260                                 /^\\ No newline at end of file/ ||
 261                                 /^Binary files .* differ/) {
 262                         push @xnq, $_;
 263                 } elsif ($_ eq '') {
 264                         # possible to be in diff context, some mail may be
 265                         # stripped by MUA or even GNU diff(1).  "git apply"
 266                         # treats a bare "\n" as diff context, too
 267                 } else {
 268                         push @xnq, $_;
 269                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 270                         $in_diff = undef;
 271                 }
 272         }
 273
 274         index_text($self, join("\n", @xnq), 1, 'XNQ');
 275 }
 276
 277 sub index_body ($$$) {
 278         my ($self, $txt, $doc) = @_;
 279         if ($doc) {
 280                 # does it look like a diff?
 281                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 282                         index_diff($self, $txt, $doc);
 283                 } else {
 284                         index_text($self, $txt, 1, 'XNQ');
 285                 }
 286         } else {
 287                 index_text($self, $txt, 0, 'XQUOT');
 288         }
 289 }
 290
 291 sub index_xapian { # msg_iter callback
 292         my ($part, $depth, @idx) = @{$_[0]};
 293         my ($self, $doc) = @{$_[1]};
 294         my $ct = $part->content_type || 'text/plain';
 295         my $fn = $part->filename;
 296         if (defined $fn && $fn ne '') {
 297                 index_text($self, $fn, 1, 'XFN');
 298         }
 299
 300         my ($s, undef) = msg_part_text($part, $ct);
 301         defined $s or return;
 302
 303         # split off quoted and unquoted blocks:
 304         my @sections = split(/((?:^>[^\n]*\n)+)/sm, $s);
 305         $part = $s = undef;
 306         index_body($self, $_, /\A>/ ? 0 : $doc) for @sections;
 307 }
 308
 309 sub add_xapian ($$$$) {
 310         my ($self, $mime, $smsg, $mids) = @_;
 311         $smsg->{mime} = $mime; # XXX dangerous
 312         my $hdr = $mime->header_obj;
 313         my $doc = $X->{Document}->new;
 314         my $subj = $smsg->subject;
 315         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 316         my @ds = gmtime($smsg->{ds});
 317         my $yyyymmdd = strftime('%Y%m%d', @ds);
 318         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 319         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 320         add_val($doc, PublicInbox::Search::DT(), $dt);
 321
 322         my $tg = term_generator($self);
 323
 324         $tg->set_document($doc);
 325         index_text($self, $subj, 1, 'S') if $subj;
 326         index_users($self, $smsg);
 327
 328         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 329         foreach my $mid (@$mids) {
 330                 index_text($self, $mid, 1, 'XM');
 331
 332                 # because too many Message-IDs are prefixed with
 333                 # "Pine.LNX."...
 334                 if ($mid =~ /\w{12,}/) {
 335                         my @long = ($mid =~ /(\w{3,}+)/g);
 336                         index_text($self, join(' ', @long), 1, 'XM');
 337                 }
 338         }
 339         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 340         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 341         my $data = $smsg->to_doc_data;
 342         $doc->set_data($data);
 343         if (my $altid = $self->{-altid}) {
 344                 foreach my $alt (@$altid) {
 345                         my $pfx = $alt->{xprefix};
 346                         foreach my $mid (@$mids) {
 347                                 my $id = $alt->mid2alt($mid);
 348                                 next unless defined $id;
 349                                 $doc->add_boolean_term($pfx . $id);
 350                         }
 351                 }
 352         }
 353         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 354         $self->{xdb}->replace_document($smsg->{num}, $doc);
 355 }
 356
 357 sub _msgmap_init ($) {
 358         my ($self) = @_;
 359         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 360         $self->{mm} //= eval {
 361                 require PublicInbox::Msgmap;
 362                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 363         };
 364 }
 365
 366 sub add_message {
 367         # mime = Email::MIME object
 368         my ($self, $mime, $smsg) = @_;
 369         my $hdr = $mime->header_obj;
 370         my $mids = mids_for_index($hdr);
 371         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 372         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 373         $smsg->{num} //= do { # v1
 374                 _msgmap_init($self);
 375                 index_mm($self, $mime);
 376         };
 377
 378         # v1 and tests only:
 379         $smsg->{ds} //= msg_datestamp($hdr, $self->{autime});
 380         $smsg->{ts} //= msg_timestamp($hdr, $self->{cotime});
 381
 382         eval {
 383                 # order matters, overview stores every possible piece of
 384                 # data in doc_data (deflated).  Xapian only stores a subset
 385                 # of the fields which exist in over.sqlite3.  We may stop
 386                 # storing doc_data in Xapian sometime after we get multi-inbox
 387                 # search working.
 388                 if (my $over = $self->{over}) { # v1 only
 389                         $over->add_overview($mime, $smsg);
 390                 }
 391                 if (need_xapian($self)) {
 392                         add_xapian($self, $mime, $smsg, $mids);
 393                 }
 394         };
 395
 396         if ($@) {
 397                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 398                 return undef;
 399         }
 400         $smsg->{num};
 401 }
 402
 403 # returns begin and end PostingIterator
 404 sub find_doc_ids {
 405         my ($self, $termval) = @_;
 406         my $db = $self->{xdb};
 407
 408         ($db->postlist_begin($termval), $db->postlist_end($termval));
 409 }
 410
 411 # v1 only
 412 sub batch_do {
 413         my ($self, $termval, $cb) = @_;
 414         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 415         while (1) {
 416                 my ($head, $tail) = $self->find_doc_ids($termval);
 417                 return if $head == $tail;
 418                 my @ids;
 419                 for (; $head != $tail && @ids < $batch_size; $head++) {
 420                         push @ids, $head->get_docid;
 421                 }
 422                 $cb->(\@ids);
 423         }
 424 }
 425
 426 # v1 only, where $mid is unique
 427 sub remove_message {
 428         my ($self, $mid) = @_;
 429         $mid = mid_clean($mid);
 430
 431         if (my $over = $self->{over}) {
 432                 my $nr = eval { $over->remove_oid(undef, $mid) };
 433                 if ($@) {
 434                         warn "failed to remove <$mid> from overview: $@\n";
 435                 } elsif ($nr == 0) {
 436                         warn "<$mid> missing for removal from overview\n";
 437                 }
 438         }
 439         return unless need_xapian($self);
 440         my $db = $self->{xdb};
 441         my $nr = 0;
 442         eval {
 443                 batch_do($self, 'Q' . $mid, sub {
 444                         my ($ids) = @_;
 445                         $db->delete_document($_) for @$ids;
 446                         $nr += scalar @$ids;
 447                 });
 448         };
 449         if ($@) {
 450                 warn "failed to remove <$mid> from Xapian: $@\n";
 451         } elsif ($nr == 0) {
 452                 warn "<$mid> missing for removal from Xapian\n";
 453         }
 454 }
 455
 456 # MID is a hint in V2
 457 sub remove_by_oid {
 458         my ($self, $oid, $mid) = @_;
 459
 460         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 461
 462         return unless need_xapian($self);
 463         my $db = $self->{xdb};
 464
 465         # XXX careful, we cannot use batch_do here since we conditionally
 466         # delete documents based on other factors, so we cannot call
 467         # find_doc_ids twice.
 468         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 469         return if $head == $tail;
 470
 471         # there is only ONE element in @delete unless we
 472         # have bugs in our v2writable deduplication check
 473         my @delete;
 474         for (; $head != $tail; $head++) {
 475                 my $docid = $head->get_docid;
 476                 my $doc = $db->get_document($docid);
 477                 my $smsg = PublicInbox::Smsg->wrap($mid);
 478                 $smsg->load_expand($doc);
 479                 if ($smsg->{blob} eq $oid) {
 480                         push(@delete, $docid);
 481                 }
 482         }
 483         $db->delete_document($_) foreach @delete;
 484         scalar(@delete);
 485 }
 486
 487 sub index_git_blob_id {
 488         my ($doc, $pfx, $objid) = @_;
 489
 490         my $len = length($objid);
 491         for (my $len = length($objid); $len >= 7; ) {
 492                 $doc->add_term($pfx.$objid);
 493                 $objid = substr($objid, 0, --$len);
 494         }
 495 }
 496
 497 sub unindex_blob {
 498         my ($self, $mime) = @_;
 499         my $mid = eval { mid_clean(mid_mime($mime)) };
 500         $self->remove_message($mid) if defined $mid;
 501 }
 502
 503 sub index_mm {
 504         my ($self, $mime) = @_;
 505         my $mid = mid_clean(mid_mime($mime));
 506         my $mm = $self->{mm};
 507         my $num;
 508
 509         if (defined $self->{regen_down}) {
 510                 $num = $mm->num_for($mid) and return $num;
 511
 512                 while (($num = $self->{regen_down}--) > 0) {
 513                         if ($mm->mid_set($num, $mid) != 0) {
 514                                 return $num;
 515                         }
 516                 }
 517         } elsif (defined $self->{regen_up}) {
 518                 $num = $mm->num_for($mid) and return $num;
 519
 520                 # this is to fixup old bugs due to add-remove-add
 521                 while (($num = ++$self->{regen_up})) {
 522                         if ($mm->mid_set($num, $mid) != 0) {
 523                                 return $num;
 524                         }
 525                 }
 526         }
 527
 528         $num = $mm->mid_insert($mid) and return $num;
 529
 530         # fallback to num_for since filters like RubyLang set the number
 531         $mm->num_for($mid);
 532 }
 533
 534 sub unindex_mm {
 535         my ($self, $mime) = @_;
 536         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 537 }
 538
 539 sub index_both {
 540         my ($self, $mime, $smsg) = @_;
 541         my $num = index_mm($self, $mime);
 542         $smsg->{num} = $num;
 543         add_message($self, $mime, $smsg);
 544 }
 545
 546 sub unindex_both {
 547         my ($self, $mime) = @_;
 548         unindex_blob($self, $mime);
 549         unindex_mm($self, $mime);
 550 }
 551
 552 sub do_cat_mail {
 553         my ($git, $blob, $sizeref) = @_;
 554         my $mime = eval {
 555                 my $str = $git->cat_file($blob, $sizeref);
 556                 # fixup bugs from import:
 557                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 558                 PublicInbox::MIME->new($str);
 559         };
 560         $@ ? undef : $mime;
 561 }
 562
 563 # called by public-inbox-index
 564 sub index_sync {
 565         my ($self, $opts) = @_;
 566         delete $self->{lock_path} if $opts->{-skip_lock};
 567         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 568 }
 569
 570 sub batch_adjust ($$$$$) {
 571         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 572         $$max -= $bytes;
 573         if ($$max <= 0) {
 574                 $$max = BATCH_BYTES;
 575                 $batch_cb->($nr, $latest);
 576         }
 577 }
 578
 579 # only for v1
 580 sub read_log {
 581         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 582         my $hex = '[a-f0-9]';
 583         my $h40 = $hex .'{40}';
 584         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 585         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 586         my $git = $self->{git};
 587         my $latest;
 588         my $bytes;
 589         my $max = BATCH_BYTES;
 590         local $/ = "\n";
 591         my %D;
 592         my $line;
 593         my $newest;
 594         my $nr = 0;
 595         while (defined($line = <$log>)) {
 596                 if ($line =~ /$addmsg/o) {
 597                         my $blob = $1;
 598                         if (delete $D{$blob}) {
 599                                 if (defined $self->{regen_down}) {
 600                                         my $num = $self->{regen_down}--;
 601                                         $self->{mm}->num_highwater($num);
 602                                 }
 603                                 next;
 604                         }
 605                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 606                         my $smsg = bless {}, 'PublicInbox::Smsg';
 607                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 608                         $smsg->{blob} = $blob;
 609                         $smsg->{bytes} = $bytes;
 610                         $add_cb->($self, $mime, $smsg);
 611                 } elsif ($line =~ /$delmsg/o) {
 612                         my $blob = $1;
 613                         $D{$blob} = 1;
 614                 } elsif ($line =~ /^commit ($h40)/o) {
 615                         $latest = $1;
 616                         $newest ||= $latest;
 617                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 618                         $self->{autime} = $1;
 619                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 620                         $self->{cotime} = $1;
 621                 }
 622         }
 623         close($log) or die "git log failed: \$?=$?";
 624         # get the leftovers
 625         foreach my $blob (keys %D) {
 626                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 627                 $del_cb->($self, $mime);
 628         }
 629         $batch_cb->($nr, $latest, $newest);
 630 }
 631
 632 sub _git_log {
 633         my ($self, $opts, $range) = @_;
 634         my $git = $self->{git};
 635
 636         if (index($range, '..') < 0) {
 637                 # don't show annoying git errrors to users who run -index
 638                 # on empty inboxes
 639                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 640                 if ($?) {
 641                         open my $fh, '<', '/dev/null' or
 642                                 die "failed to open /dev/null: $!\n";
 643                         return $fh;
 644                 }
 645         }
 646
 647         # Count the new files so they can be added newest to oldest
 648         # and still have numbers increasing from oldest to newest
 649         my $fcount = 0;
 650         my $pr = $opts->{-progress};
 651         $pr->("counting changes\n\t$range ... ") if $pr;
 652         # can't use 'rev-list --count' if we use --diff-filter
 653         my $fh = $git->popen(qw(log --pretty=tformat:%h
 654                              --no-notes --no-color --no-renames
 655                              --diff-filter=AM), $range);
 656         ++$fcount while <$fh>;
 657         close $fh or die "git log failed: \$?=$?";
 658         my $high = $self->{mm}->num_highwater;
 659         $pr->("$fcount\n") if $pr; # continue previous line
 660         $self->{ntodo} = $fcount;
 661
 662         if (index($range, '..') < 0) {
 663                 if ($high && $high == $fcount) {
 664                         # fix up old bugs in full indexes which caused messages to
 665                         # not appear in Msgmap
 666                         $self->{regen_up} = $high;
 667                 } else {
 668                         # normal regen is for for fresh data
 669                         $self->{regen_down} = $fcount;
 670                 }
 671         } else {
 672                 # Give oldest messages the smallest numbers
 673                 $self->{regen_down} = $high + $fcount;
 674         }
 675
 676         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 677                                 --raw -r --no-abbrev/, $range);
 678 }
 679
 680 # --is-ancestor requires git 1.8.0+
 681 sub is_ancestor ($$$) {
 682         my ($git, $cur, $tip) = @_;
 683         return 0 unless $git->check($cur);
 684         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 685                 qw(merge-base --is-ancestor), $cur, $tip ];
 686         my $pid = spawn($cmd);
 687         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 688         $? == 0;
 689 }
 690
 691 sub need_update ($$$) {
 692         my ($self, $cur, $new) = @_;
 693         my $git = $self->{git};
 694         return 1 if $cur && !is_ancestor($git, $cur, $new);
 695         my $range = $cur eq '' ? $new : "$cur..$new";
 696         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 697         ($n eq '' || $n > 0);
 698 }
 699
 700 # The last git commit we indexed with Xapian or SQLite (msgmap)
 701 # This needs to account for cases where Xapian or SQLite is
 702 # out-of-date with respect to the other.
 703 sub _last_x_commit {
 704         my ($self, $mm) = @_;
 705         my $lm = $mm->last_commit || '';
 706         my $lx = '';
 707         if (need_xapian($self)) {
 708                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 709         } else {
 710                 $lx = $lm;
 711         }
 712         # Use last_commit from msgmap if it is older or unset
 713         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 714                 $lx = $lm;
 715         }
 716         $lx;
 717 }
 718
 719 sub reindex_from ($$) {
 720         my ($reindex, $last_commit) = @_;
 721         return $last_commit unless $reindex;
 722         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 723 }
 724
 725 # indexes all unindexed messages (v1 only)
 726 sub _index_sync {
 727         my ($self, $opts) = @_;
 728         my $tip = $opts->{ref} || 'HEAD';
 729         my ($last_commit, $lx, $xlog);
 730         my $git = $self->{git};
 731         $git->batch_prepare;
 732         my $pr = $opts->{-progress};
 733
 734         my $xdb = $self->begin_txn_lazy;
 735         my $mm = _msgmap_init($self);
 736         do {
 737                 if ($xlog) {
 738                         close($xlog) or die "git log failed: \$?=$?";
 739                         $xlog = undef;
 740                 }
 741                 $last_commit = _last_x_commit($self, $mm);
 742                 $lx = reindex_from($opts->{reindex}, $last_commit);
 743
 744                 $self->{over}->rollback_lazy;
 745                 $self->{over}->disconnect;
 746                 $git->cleanup;
 747                 delete $self->{txn};
 748                 $xdb->cancel_transaction if $xdb;
 749                 $xdb = _xdb_release($self);
 750
 751                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 752                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 753                 $xlog = _git_log($self, $opts, $range);
 754
 755                 $xdb = $self->begin_txn_lazy;
 756         } while (_last_x_commit($self, $mm) ne $last_commit);
 757
 758         my $dbh = $mm->{dbh} if $mm;
 759         my $cb = sub {
 760                 my ($nr, $commit, $newest) = @_;
 761                 if ($dbh) {
 762                         if ($newest) {
 763                                 my $cur = $mm->last_commit || '';
 764                                 if (need_update($self, $cur, $newest)) {
 765                                         $mm->last_commit($newest);
 766                                 }
 767                         }
 768                         $dbh->commit;
 769                 }
 770                 if ($newest && need_xapian($self)) {
 771                         my $cur = $xdb->get_metadata('last_commit');
 772                         if (need_update($self, $cur, $newest)) {
 773                                 $xdb->set_metadata('last_commit', $newest);
 774                         }
 775                 }
 776                 $self->commit_txn_lazy;
 777                 $git->cleanup;
 778                 $xdb = _xdb_release($self);
 779                 # let another process do some work... <
 780                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 781                 if (!$newest) {
 782                         $xdb = $self->begin_txn_lazy;
 783                         $dbh->begin_work if $dbh;
 784                 }
 785         };
 786
 787         $dbh->begin_work;
 788         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 789 }
 790
 791 sub DESTROY {
 792         # order matters for unlocking
 793         $_[0]->{xdb} = undef;
 794         $_[0]->{lockfh} = undef;
 795 }
 796
 797 # remote_* subs are only used by SearchIdxPart
 798 sub remote_commit {
 799         my ($self) = @_;
 800         if (my $w = $self->{w}) {
 801                 print $w "commit\n" or die "failed to write commit: $!";
 802         } else {
 803                 $self->commit_txn_lazy;
 804         }
 805 }
 806
 807 sub remote_close {
 808         my ($self) = @_;
 809         if (my $w = delete $self->{w}) {
 810                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 811                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 812                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 813                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 814                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 815         } else {
 816                 die "transaction in progress $self\n" if $self->{txn};
 817                 $self->_xdb_release if $self->{xdb};
 818         }
 819 }
 820
 821 sub remote_remove {
 822         my ($self, $oid, $mid) = @_;
 823         if (my $w = $self->{w}) {
 824                 # triggers remove_by_oid in a shard
 825                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 826         } else {
 827                 $self->begin_txn_lazy;
 828                 $self->remove_by_oid($oid, $mid);
 829         }
 830 }
 831
 832 sub begin_txn_lazy {
 833         my ($self) = @_;
 834         return if $self->{txn};
 835
 836         $self->{-inbox}->with_umask(sub {
 837                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 838                 $self->{over}->begin_lazy if $self->{over};
 839                 $xdb->begin_transaction if $xdb;
 840                 $self->{txn} = 1;
 841                 $xdb;
 842         });
 843 }
 844
 845 sub commit_txn_lazy {
 846         my ($self) = @_;
 847         delete $self->{txn} or return;
 848         $self->{-inbox}->with_umask(sub {
 849                 if (my $xdb = $self->{xdb}) {
 850
 851                         # store 'indexlevel=medium' in v2 shard=0 and
 852                         # v1 (only one shard)
 853                         # This metadata is read by Admin::detect_indexlevel:
 854                         if (!$self->{shard} # undef or 0, not >0
 855                             && $self->{indexlevel} eq 'medium') {
 856                                 $xdb->set_metadata('indexlevel', 'medium');
 857                         }
 858
 859                         $xdb->commit_transaction;
 860                 }
 861                 $self->{over}->commit_lazy if $self->{over};
 862         });
 863 }
 864
 865 sub worker_done {
 866         my ($self) = @_;
 867         if (need_xapian($self)) {
 868                 die "$$ $0 xdb not released\n" if $self->{xdb};
 869         }
 870         die "$$ $0 still in transaction\n" if $self->{txn};
 871 }
 872
 873 1;