lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mid_mime mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 our $BATCH_BYTES = defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000;
  27 use constant DEBUG => !!$ENV{DEBUG};
  28
  29 my $xapianlevels = qr/\A(?:full|medium)\z/;
  30
  31 sub new {
  32         my ($class, $ibx, $creat, $shard) = @_;
  33         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  34         my $levels = qr/\A(?:full|medium|basic)\z/;
  35         my $inboxdir = $ibx->{inboxdir};
  36         my $version = $ibx->version;
  37         my $indexlevel = 'full';
  38         my $altid = $ibx->{altid};
  39         if ($altid) {
  40                 require PublicInbox::AltId;
  41                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  42         }
  43         if ($ibx->{indexlevel}) {
  44                 if ($ibx->{indexlevel} =~ $levels) {
  45                         $indexlevel = $ibx->{indexlevel};
  46                 } else {
  47                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  48                 }
  49         }
  50         $ibx = PublicInbox::InboxWritable->new($ibx);
  51         my $self = bless {
  52                 inboxdir => $inboxdir,
  53                 ibx => $ibx,
  54                 -altid => $altid,
  55                 ibx_ver => $version,
  56                 indexlevel => $indexlevel,
  57         }, $class;
  58         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  59         $ibx->umask_prepare;
  60         if ($version == 1) {
  61                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  62                 my $dir = $self->xdir;
  63                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  64                 $self->{index_max_size} = $ibx->{index_max_size};
  65         } elsif ($version == 2) {
  66                 defined $shard or die "shard is required for v2\n";
  67                 # shard is a number
  68                 $self->{shard} = $shard;
  69                 $self->{lock_path} = undef;
  70         } else {
  71                 die "unsupported inbox version=$version\n";
  72         }
  73         $self->{creat} = ($creat || 0) == 1;
  74         $self;
  75 }
  76
  77 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  78
  79 sub _xdb_release {
  80         my ($self, $wake) = @_;
  81         if (need_xapian($self)) {
  82                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  83                 $xdb->close;
  84         }
  85         $self->lock_release($wake) if $self->{creat};
  86         undef;
  87 }
  88
  89 sub load_xapian_writable () {
  90         return 1 if $X->{WritableDatabase};
  91         PublicInbox::Search::load_xapian() or return;
  92         my $xap = $PublicInbox::Search::Xap;
  93         for (qw(Document TermGenerator WritableDatabase)) {
  94                 $X->{$_} = $xap.'::'.$_;
  95         }
  96         eval 'require '.$X->{WritableDatabase} or die;
  97         *sortable_serialise = $xap.'::sortable_serialise';
  98         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
  99         $DB_OPEN = eval($xap.'::DB_OPEN()');
 100         1;
 101 }
 102
 103 sub _xdb_acquire {
 104         my ($self) = @_;
 105         my $flag;
 106         my $dir = $self->xdir;
 107         if (need_xapian($self)) {
 108                 croak 'already acquired' if $self->{xdb};
 109                 load_xapian_writable();
 110                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 111         }
 112         if ($self->{creat}) {
 113                 require File::Path;
 114                 $self->lock_acquire;
 115
 116                 # don't create empty Xapian directories if we don't need Xapian
 117                 my $is_shard = defined($self->{shard});
 118                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 119                         File::Path::mkpath($dir);
 120                 }
 121         }
 122         return unless defined $flag;
 123         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 124         if ($@) {
 125                 die "Failed opening $dir: ", $@;
 126         }
 127         $self->{xdb} = $xdb;
 128 }
 129
 130 sub add_val ($$$) {
 131         my ($doc, $col, $num) = @_;
 132         $num = sortable_serialise($num);
 133         $doc->add_value($col, $num);
 134 }
 135
 136 sub term_generator ($) { # write-only
 137         my ($self) = @_;
 138
 139         $self->{term_generator} //= do {
 140                 my $tg = $X->{TermGenerator}->new;
 141                 $tg->set_stemmer($self->stemmer);
 142                 $tg;
 143         }
 144 }
 145
 146 sub index_text ($$$$) {
 147         my ($self, $text, $wdf_inc, $prefix) = @_;
 148         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 149
 150         if ($self->{indexlevel} eq 'full') {
 151                 $tg->index_text($text, $wdf_inc, $prefix);
 152                 $tg->increase_termpos;
 153         } else {
 154                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 155         }
 156 }
 157
 158 sub index_headers ($$) {
 159         my ($self, $smsg) = @_;
 160         my @x = (from => 'A', # Author
 161                 subject => 'S', to => 'XTO', cc => 'XCC');
 162         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 163                 my $val = $smsg->{$field};
 164                 index_text($self, $val, 1, $pfx) if $val ne '';
 165         }
 166 }
 167
 168 sub index_diff_inc ($$$$) {
 169         my ($self, $text, $pfx, $xnq) = @_;
 170         if (@$xnq) {
 171                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 172                 @$xnq = ();
 173         }
 174         index_text($self, $text, 1, $pfx);
 175 }
 176
 177 sub index_old_diff_fn {
 178         my ($self, $seen, $fa, $fb, $xnq) = @_;
 179
 180         # no renames or space support for traditional diffs,
 181         # find the number of leading common paths to strip:
 182         my @fa = split('/', $fa);
 183         my @fb = split('/', $fb);
 184         while (scalar(@fa) && scalar(@fb)) {
 185                 $fa = join('/', @fa);
 186                 $fb = join('/', @fb);
 187                 if ($fa eq $fb) {
 188                         unless ($seen->{$fa}++) {
 189                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 190                         }
 191                         return 1;
 192                 }
 193                 shift @fa;
 194                 shift @fb;
 195         }
 196         0;
 197 }
 198
 199 sub index_diff ($$$) {
 200         my ($self, $txt, $doc) = @_;
 201         my %seen;
 202         my $in_diff;
 203         my @xnq;
 204         my $xnq = \@xnq;
 205         foreach (split(/\n/, $txt)) {
 206                 if ($in_diff && s/^ //) { # diff context
 207                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 208                 } elsif (/^-- $/) { # email signature begins
 209                         $in_diff = undef;
 210                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 211                         # wait until "---" and "+++" to capture filenames
 212                         $in_diff = 1;
 213                 # traditional diff:
 214                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 215                         my ($opt, $fa, $fb) = ($1, $2, $3);
 216                         push @xnq, $_;
 217                         # only support unified:
 218                         next unless $opt =~ /[uU]/;
 219                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 220                                                         $xnq);
 221                 } elsif (m!^--- ("?[^/]+/.+)!) {
 222                         my $fn = $1;
 223                         $fn = (split('/', git_unquote($fn), 2))[1];
 224                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 225                         $in_diff = 1;
 226                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 227                         my $fn = $1;
 228                         $fn = (split('/', git_unquote($fn), 2))[1];
 229                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 230                         $in_diff = 1;
 231                 } elsif (/^--- (\S+)/) {
 232                         $in_diff = $1;
 233                         push @xnq, $_;
 234                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 235                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 236                                                         $1, $xnq);
 237                 } elsif ($in_diff && s/^\+//) { # diff added
 238                         index_diff_inc($self, $_, 'XDFB', $xnq);
 239                 } elsif ($in_diff && s/^-//) { # diff removed
 240                         index_diff_inc($self, $_, 'XDFA', $xnq);
 241                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 242                         my ($ba, $bb) = ($1, $2);
 243                         index_git_blob_id($doc, 'XDFPRE', $ba);
 244                         index_git_blob_id($doc, 'XDFPOST', $bb);
 245                         $in_diff = 1;
 246                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 247                         # traditional diff w/o -p
 248                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 249                         # hunk header context
 250                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 251                 # ignore the following lines:
 252                 } elsif (/^(?:dis)similarity index/ ||
 253                                 /^(?:old|new) mode/ ||
 254                                 /^(?:deleted|new) file mode/ ||
 255                                 /^(?:copy|rename) (?:from|to) / ||
 256                                 /^(?:dis)?similarity index / ||
 257                                 /^\\ No newline at end of file/ ||
 258                                 /^Binary files .* differ/) {
 259                         push @xnq, $_;
 260                 } elsif ($_ eq '') {
 261                         # possible to be in diff context, some mail may be
 262                         # stripped by MUA or even GNU diff(1).  "git apply"
 263                         # treats a bare "\n" as diff context, too
 264                 } else {
 265                         push @xnq, $_;
 266                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 267                         $in_diff = undef;
 268                 }
 269         }
 270
 271         index_text($self, join("\n", @xnq), 1, 'XNQ');
 272 }
 273
 274 sub index_xapian { # msg_iter callback
 275         my $part = $_[0]->[0]; # ignore $depth and $idx
 276         my ($self, $doc) = @{$_[1]};
 277         my $ct = $part->content_type || 'text/plain';
 278         my $fn = $part->filename;
 279         if (defined $fn && $fn ne '') {
 280                 index_text($self, $fn, 1, 'XFN');
 281         }
 282         if ($part->{is_submsg}) {
 283                 my $mids = mids_for_index($part);
 284                 index_ids($self, $doc, $part, $mids);
 285                 my $smsg = bless {}, 'PublicInbox::Smsg';
 286                 $smsg->populate($part);
 287                 index_headers($self, $smsg);
 288         }
 289
 290         my ($s, undef) = msg_part_text($part, $ct);
 291         defined $s or return;
 292         $_[0]->[0] = $part = undef; # free memory
 293
 294         # split off quoted and unquoted blocks:
 295         my @sections = PublicInbox::MsgIter::split_quotes($s);
 296         undef $s; # free memory
 297         for my $txt (@sections) {
 298                 if ($txt =~ /\A>/) {
 299                         index_text($self, $txt, 0, 'XQUOT');
 300                 } else {
 301                         # does it look like a diff?
 302                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 303                                 index_diff($self, $txt, $doc);
 304                         } else {
 305                                 index_text($self, $txt, 1, 'XNQ');
 306                         }
 307                 }
 308                 undef $txt; # free memory
 309         }
 310 }
 311
 312 sub index_ids ($$$$) {
 313         my ($self, $doc, $hdr, $mids) = @_;
 314         for my $mid (@$mids) {
 315                 index_text($self, $mid, 1, 'XM');
 316
 317                 # because too many Message-IDs are prefixed with
 318                 # "Pine.LNX."...
 319                 if ($mid =~ /\w{12,}/) {
 320                         my @long = ($mid =~ /(\w{3,}+)/g);
 321                         index_text($self, join(' ', @long), 1, 'XM');
 322                 }
 323         }
 324         $doc->add_boolean_term('Q' . $_) for @$mids;
 325         for my $l ($hdr->header_raw('List-Id')) {
 326                 $l =~ /<([^>]+)>/ or next;
 327                 my $lid = $1;
 328                 $doc->add_boolean_term('G' . $lid);
 329                 index_text($self, $lid, 1, 'XL'); # probabilistic
 330         }
 331 }
 332
 333 sub add_xapian ($$$$) {
 334         my ($self, $mime, $smsg, $mids) = @_;
 335         my $hdr = $mime->header_obj;
 336         my $doc = $X->{Document}->new;
 337         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 338         my @ds = gmtime($smsg->{ds});
 339         my $yyyymmdd = strftime('%Y%m%d', @ds);
 340         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 341         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 342         add_val($doc, PublicInbox::Search::DT(), $dt);
 343         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 344         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 345
 346         my $tg = term_generator($self);
 347         $tg->set_document($doc);
 348         index_headers($self, $smsg);
 349
 350         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 351         index_ids($self, $doc, $hdr, $mids);
 352         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 353         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 354         my $data = $smsg->to_doc_data;
 355         $doc->set_data($data);
 356         if (my $altid = $self->{-altid}) {
 357                 foreach my $alt (@$altid) {
 358                         my $pfx = $alt->{xprefix};
 359                         foreach my $mid (@$mids) {
 360                                 my $id = $alt->mid2alt($mid);
 361                                 next unless defined $id;
 362                                 $doc->add_boolean_term($pfx . $id);
 363                         }
 364                 }
 365         }
 366         $self->{xdb}->replace_document($smsg->{num}, $doc);
 367 }
 368
 369 sub _msgmap_init ($) {
 370         my ($self) = @_;
 371         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 372         $self->{mm} //= eval {
 373                 require PublicInbox::Msgmap;
 374                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 375         };
 376 }
 377
 378 sub add_message {
 379         # mime = PublicInbox::Eml or Email::MIME object
 380         my ($self, $mime, $smsg, $sync) = @_;
 381         my $hdr = $mime->header_obj;
 382         my $mids = mids_for_index($hdr);
 383         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 384         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 385         $smsg->{num} //= do { # v1
 386                 _msgmap_init($self);
 387                 index_mm($self, $mime);
 388         };
 389
 390         # v1 and tests only:
 391         $smsg->populate($hdr, $sync);
 392         $smsg->{bytes} //= length($mime->as_string);
 393
 394         eval {
 395                 # order matters, overview stores every possible piece of
 396                 # data in doc_data (deflated).  Xapian only stores a subset
 397                 # of the fields which exist in over.sqlite3.  We may stop
 398                 # storing doc_data in Xapian sometime after we get multi-inbox
 399                 # search working.
 400                 if (my $over = $self->{over}) { # v1 only
 401                         $over->add_overview($mime, $smsg);
 402                 }
 403                 if (need_xapian($self)) {
 404                         add_xapian($self, $mime, $smsg, $mids);
 405                 }
 406         };
 407
 408         if ($@) {
 409                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 410                 return undef;
 411         }
 412         $smsg->{num};
 413 }
 414
 415 sub xdb_remove {
 416         my ($self, $oid, @removed) = @_;
 417         my $xdb = $self->{xdb} or return;
 418         for my $num (@removed) {
 419                 my $doc = eval { $xdb->get_document($num) };
 420                 unless ($doc) {
 421                         warn "E: $@\n" if $@;
 422                         warn "E: #$num $oid missing in Xapian\n";
 423                         next;
 424                 }
 425                 my $smsg = bless {}, 'PublicInbox::Smsg';
 426                 $smsg->load_expand($doc);
 427                 my $blob = $smsg->{blob} // '(unset)';
 428                 if ($blob eq $oid) {
 429                         $xdb->delete_document($num);
 430                 } else {
 431                         warn "E: #$num $oid != $blob in Xapian\n";
 432                 }
 433         }
 434 }
 435
 436 sub remove_by_oid {
 437         my ($self, $oid, $num) = @_;
 438         die "BUG: remove_by_oid is v2-only\n" if $self->{over};
 439         $self->begin_txn_lazy;
 440         xdb_remove($self, $oid, $num) if need_xapian($self);
 441 }
 442
 443 sub index_git_blob_id {
 444         my ($doc, $pfx, $objid) = @_;
 445
 446         my $len = length($objid);
 447         for (my $len = length($objid); $len >= 7; ) {
 448                 $doc->add_term($pfx.$objid);
 449                 $objid = substr($objid, 0, --$len);
 450         }
 451 }
 452
 453 # v1 only
 454 sub unindex_eml {
 455         my ($self, $oid, $eml) = @_;
 456         my $mids = mids($eml);
 457         my $nr = 0;
 458         my %tmp;
 459         for my $mid (@$mids) {
 460                 my @removed = eval { $self->{over}->remove_oid($oid, $mid) };
 461                 if ($@) {
 462                         warn "E: failed to remove <$mid> from overview: $@\n";
 463                 } else {
 464                         $nr += scalar @removed;
 465                         $tmp{$_}++ for @removed;
 466                 }
 467         }
 468         if (!$nr) {
 469                 $mids = join('> <', @$mids);
 470                 warn "W: <$mids> missing for removal from overview\n";
 471         }
 472         while (my ($num, $nr) = each %tmp) {
 473                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 474         }
 475         xdb_remove($self, $oid, keys %tmp) if need_xapian($self);
 476 }
 477
 478 sub index_mm {
 479         my ($self, $mime) = @_;
 480         my $mid = mid_mime($mime);
 481         my $mm = $self->{mm};
 482         my $num;
 483
 484         if (defined $self->{regen_down}) {
 485                 $num = $mm->num_for($mid) and return $num;
 486
 487                 while (($num = $self->{regen_down}--) > 0) {
 488                         if ($mm->mid_set($num, $mid) != 0) {
 489                                 return $num;
 490                         }
 491                 }
 492         } elsif (defined $self->{regen_up}) {
 493                 $num = $mm->num_for($mid) and return $num;
 494
 495                 # this is to fixup old bugs due to add-remove-add
 496                 while (($num = ++$self->{regen_up})) {
 497                         if ($mm->mid_set($num, $mid) != 0) {
 498                                 return $num;
 499                         }
 500                 }
 501         }
 502
 503         $num = $mm->mid_insert($mid) and return $num;
 504
 505         # fallback to num_for since filters like RubyLang set the number
 506         $mm->num_for($mid);
 507 }
 508
 509 sub unindex_mm {
 510         my ($self, $mime) = @_;
 511         $self->{mm}->mid_delete(mid_mime($mime));
 512 }
 513
 514 # returns the number of bytes to add if given a non-CRLF arg
 515 sub crlf_adjust ($) {
 516         if (index($_[0], "\r\n") < 0) {
 517                 # common case is LF-only, every \n needs an \r;
 518                 # so favor a cheap tr// over an expensive m//g
 519                 $_[0] =~ tr/\n/\n/;
 520         } else { # count number of '\n' w/o '\r', expensive:
 521                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 522         }
 523 }
 524
 525 sub index_both { # git->cat_async callback
 526         my ($bref, $oid, $type, $size, $sync) = @_;
 527         my ($nr, $max) = @$sync{qw(nr max)};
 528         ++$$nr;
 529         $$max -= $size;
 530         $size += crlf_adjust($$bref);
 531         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 532         my $self = $sync->{sidx};
 533         my $eml = PublicInbox::Eml->new($bref);
 534         my $num = index_mm($self, $eml);
 535         $smsg->{num} = $num;
 536         add_message($self, $eml, $smsg, $sync);
 537 }
 538
 539 sub unindex_both { # git->cat_async callback
 540         my ($bref, $oid, $type, $size, $self) = @_;
 541         my $eml = PublicInbox::Eml->new($bref);
 542         unindex_eml($self, $oid, $eml);
 543         unindex_mm($self, $eml);
 544 }
 545
 546 # called by public-inbox-index
 547 sub index_sync {
 548         my ($self, $opts) = @_;
 549         delete $self->{lock_path} if $opts->{-skip_lock};
 550         $self->{ibx}->with_umask(\&_index_sync, $self, $opts);
 551 }
 552
 553 sub too_big ($$) {
 554         my ($self, $oid) = @_;
 555         my $max_size = $self->{index_max_size} or return;
 556         my (undef, undef, $size) = $self->{ibx}->git->check($oid);
 557         die "E: bad $oid in $self->{ibx}->{inboxdir}\n" if !defined($size);
 558         return if $size <= $max_size;
 559         warn "W: skipping $oid ($size > $max_size)\n";
 560         1;
 561 }
 562
 563 # only for v1
 564 sub read_log {
 565         my ($self, $log, $batch_cb) = @_;
 566         my $hex = '[a-f0-9]';
 567         my $h40 = $hex .'{40}';
 568         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 569         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 570         my $git = $self->{ibx}->git;
 571         my $latest;
 572         my $max = $BATCH_BYTES;
 573         local $/ = "\n";
 574         my %D;
 575         my $line;
 576         my $newest;
 577         my $nr = 0;
 578         my $sync = { sidx => $self, nr => \$nr, max => \$max };
 579         while (defined($line = <$log>)) {
 580                 if ($line =~ /$addmsg/o) {
 581                         my $blob = $1;
 582                         if (delete $D{$blob}) {
 583                                 # make sure pending index writes are done
 584                                 # before writing to ->mm
 585                                 $git->cat_async_wait;
 586
 587                                 if (defined $self->{regen_down}) {
 588                                         my $num = $self->{regen_down}--;
 589                                         $self->{mm}->num_highwater($num);
 590                                 }
 591                                 next;
 592                         }
 593                         next if too_big($self, $blob);
 594                         $git->cat_async($blob, \&index_both, { %$sync });
 595                         if ($max <= 0) {
 596                                 $git->cat_async_wait;
 597                                 $max = $BATCH_BYTES;
 598                                 $batch_cb->($nr, $latest);
 599                         }
 600                 } elsif ($line =~ /$delmsg/o) {
 601                         my $blob = $1;
 602                         $D{$blob} = 1 unless too_big($self, $blob);
 603                 } elsif ($line =~ /^commit ($h40)/o) {
 604                         $latest = $1;
 605                         $newest ||= $latest;
 606                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 607                         $sync->{autime} = $1;
 608                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 609                         $sync->{cotime} = $1;
 610                 }
 611         }
 612         close($log) or die "git log failed: \$?=$?";
 613         # get the leftovers
 614         foreach my $blob (keys %D) {
 615                 $git->cat_async($blob, \&unindex_both, $self);
 616         }
 617         $git->cat_async_wait;
 618         $batch_cb->($nr, $latest, $newest);
 619 }
 620
 621 sub _git_log {
 622         my ($self, $opts, $range) = @_;
 623         my $git = $self->{ibx}->git;
 624
 625         if (index($range, '..') < 0) {
 626                 # don't show annoying git errors to users who run -index
 627                 # on empty inboxes
 628                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 629                 if ($?) {
 630                         open my $fh, '<', '/dev/null' or
 631                                 die "failed to open /dev/null: $!\n";
 632                         return $fh;
 633                 }
 634         }
 635
 636         # Count the new files so they can be added newest to oldest
 637         # and still have numbers increasing from oldest to newest
 638         my $fcount = 0;
 639         my $pr = $opts->{-progress};
 640         $pr->("counting changes\n\t$range ... ") if $pr;
 641         # can't use 'rev-list --count' if we use --diff-filter
 642         my $fh = $git->popen(qw(log --pretty=tformat:%h
 643                              --no-notes --no-color --no-renames
 644                              --diff-filter=AM), $range);
 645         ++$fcount while <$fh>;
 646         close $fh or die "git log failed: \$?=$?";
 647         my $high = $self->{mm}->num_highwater;
 648         $pr->("$fcount\n") if $pr; # continue previous line
 649         $self->{ntodo} = $fcount;
 650
 651         if (index($range, '..') < 0) {
 652                 if ($high && $high == $fcount) {
 653                         # fix up old bugs in full indexes which caused messages to
 654                         # not appear in Msgmap
 655                         $self->{regen_up} = $high;
 656                 } else {
 657                         # normal regen is for for fresh data
 658                         $self->{regen_down} = $fcount;
 659                         $self->{regen_down} += $high unless $opts->{reindex};
 660                 }
 661         } else {
 662                 # Give oldest messages the smallest numbers
 663                 $self->{regen_down} = $high + $fcount;
 664         }
 665
 666         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 667                                 --raw -r --no-abbrev/, $range);
 668 }
 669
 670 # --is-ancestor requires git 1.8.0+
 671 sub is_ancestor ($$$) {
 672         my ($git, $cur, $tip) = @_;
 673         return 0 unless $git->check($cur);
 674         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 675                 qw(merge-base --is-ancestor), $cur, $tip ];
 676         my $pid = spawn($cmd);
 677         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 678         $? == 0;
 679 }
 680
 681 sub need_update ($$$) {
 682         my ($self, $cur, $new) = @_;
 683         my $git = $self->{ibx}->git;
 684         return 1 if $cur && !is_ancestor($git, $cur, $new);
 685         my $range = $cur eq '' ? $new : "$cur..$new";
 686         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 687         ($n eq '' || $n > 0);
 688 }
 689
 690 # The last git commit we indexed with Xapian or SQLite (msgmap)
 691 # This needs to account for cases where Xapian or SQLite is
 692 # out-of-date with respect to the other.
 693 sub _last_x_commit {
 694         my ($self, $mm) = @_;
 695         my $lm = $mm->last_commit || '';
 696         my $lx = '';
 697         if (need_xapian($self)) {
 698                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 699         } else {
 700                 $lx = $lm;
 701         }
 702         # Use last_commit from msgmap if it is older or unset
 703         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 704                 $lx = $lm;
 705         }
 706         $lx;
 707 }
 708
 709 sub reindex_from ($$) {
 710         my ($reindex, $last_commit) = @_;
 711         return $last_commit unless $reindex;
 712         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 713 }
 714
 715 # indexes all unindexed messages (v1 only)
 716 sub _index_sync {
 717         my ($self, $opts) = @_;
 718         my $tip = $opts->{ref} || 'HEAD';
 719         my ($last_commit, $lx, $xlog);
 720         my $git = $self->{ibx}->git;
 721         $git->batch_prepare;
 722         my $pr = $opts->{-progress};
 723
 724         my $xdb = $self->begin_txn_lazy;
 725         $self->{over}->rethread_prepare($opts);
 726         my $mm = _msgmap_init($self);
 727         do {
 728                 $xlog = undef; # stop previous git-log via SIGPIPE
 729                 $last_commit = _last_x_commit($self, $mm);
 730                 $lx = reindex_from($opts->{reindex}, $last_commit);
 731
 732                 $self->{over}->rollback_lazy;
 733                 $self->{over}->disconnect;
 734                 $git->cleanup;
 735                 delete $self->{txn};
 736                 $xdb->cancel_transaction if $xdb;
 737                 $xdb = _xdb_release($self);
 738
 739                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 740                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 741                 $xlog = _git_log($self, $opts, $range);
 742
 743                 $xdb = $self->begin_txn_lazy;
 744         } while (_last_x_commit($self, $mm) ne $last_commit);
 745
 746         my $dbh = $mm->{dbh} if $mm;
 747         my $batch_cb = sub {
 748                 my ($nr, $commit, $newest) = @_;
 749                 if ($dbh) {
 750                         if ($newest) {
 751                                 my $cur = $mm->last_commit || '';
 752                                 if (need_update($self, $cur, $newest)) {
 753                                         $mm->last_commit($newest);
 754                                 }
 755                         }
 756                         $dbh->commit;
 757                 }
 758                 if ($newest && need_xapian($self)) {
 759                         my $cur = $xdb->get_metadata('last_commit');
 760                         if (need_update($self, $cur, $newest)) {
 761                                 $xdb->set_metadata('last_commit', $newest);
 762                         }
 763                 }
 764
 765                 $self->{over}->rethread_done($opts) if $newest; # all done
 766                 $self->commit_txn_lazy;
 767                 $git->cleanup;
 768                 $xdb = _xdb_release($self, $nr);
 769                 # let another process do some work...
 770                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 771                 if (!$newest) { # more to come
 772                         $xdb = $self->begin_txn_lazy;
 773                         $dbh->begin_work if $dbh;
 774                 }
 775         };
 776
 777         $dbh->begin_work;
 778         read_log($self, $xlog, $batch_cb);
 779 }
 780
 781 sub DESTROY {
 782         # order matters for unlocking
 783         $_[0]->{xdb} = undef;
 784         $_[0]->{lockfh} = undef;
 785 }
 786
 787 # remote_* subs are only used by SearchIdxPart
 788 sub remote_commit {
 789         my ($self) = @_;
 790         if (my $w = $self->{w}) {
 791                 print $w "commit\n" or die "failed to write commit: $!";
 792         } else {
 793                 $self->commit_txn_lazy;
 794         }
 795 }
 796
 797 sub remote_close {
 798         my ($self) = @_;
 799         if (my $w = delete $self->{w}) {
 800                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 801                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 802                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 803                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 804                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 805         } else {
 806                 die "transaction in progress $self\n" if $self->{txn};
 807                 $self->_xdb_release if $self->{xdb};
 808         }
 809 }
 810
 811 sub remote_remove {
 812         my ($self, $oid, $num) = @_;
 813         if (my $w = $self->{w}) {
 814                 # triggers remove_by_oid in a shard
 815                 print $w "D $oid $num\n" or die "failed to write remove $!";
 816         } else {
 817                 $self->remove_by_oid($oid, $num);
 818         }
 819 }
 820
 821 sub _begin_txn {
 822         my ($self) = @_;
 823         my $xdb = $self->{xdb} || $self->_xdb_acquire;
 824         $self->{over}->begin_lazy if $self->{over};
 825         $xdb->begin_transaction if $xdb;
 826         $self->{txn} = 1;
 827         $xdb;
 828 }
 829
 830 sub begin_txn_lazy {
 831         my ($self) = @_;
 832         $self->{ibx}->with_umask(\&_begin_txn, $self) if !$self->{txn};
 833 }
 834
 835 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 836 # This metadata is read by Admin::detect_indexlevel:
 837 sub set_indexlevel {
 838         my ($self) = @_;
 839
 840         if (!$self->{shard} && # undef or 0, not >0
 841                         delete($self->{-set_indexlevel_once})) {
 842                 my $xdb = $self->{xdb};
 843                 my $level = $xdb->get_metadata('indexlevel');
 844                 if (!$level || $level ne 'medium') {
 845                         $xdb->set_metadata('indexlevel', 'medium');
 846                 }
 847         }
 848 }
 849
 850 sub _commit_txn {
 851         my ($self) = @_;
 852         if (my $xdb = $self->{xdb}) {
 853                 set_indexlevel($self);
 854                 $xdb->commit_transaction;
 855         }
 856         $self->{over}->commit_lazy if $self->{over};
 857 }
 858
 859 sub commit_txn_lazy {
 860         my ($self) = @_;
 861         delete($self->{txn}) and
 862                 $self->{ibx}->with_umask(\&_commit_txn, $self);
 863 }
 864
 865 sub worker_done {
 866         my ($self) = @_;
 867         if (need_xapian($self)) {
 868                 die "$$ $0 xdb not released\n" if $self->{xdb};
 869         }
 870         die "$$ $0 still in transaction\n" if $self->{txn};
 871 }
 872
 873 1;