lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 use constant {
  26         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  27                         0x7fffffff : 1_000_000,
  28         DEBUG => !!$ENV{DEBUG},
  29 };
  30
  31 my $xapianlevels = qr/\A(?:full|medium)\z/;
  32
  33 sub new {
  34         my ($class, $ibx, $creat, $shard) = @_;
  35         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  36         my $levels = qr/\A(?:full|medium|basic)\z/;
  37         my $inboxdir = $ibx->{inboxdir};
  38         my $version = $ibx->version;
  39         my $indexlevel = 'full';
  40         my $altid = $ibx->{altid};
  41         if ($altid) {
  42                 require PublicInbox::AltId;
  43                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  44         }
  45         if ($ibx->{indexlevel}) {
  46                 if ($ibx->{indexlevel} =~ $levels) {
  47                         $indexlevel = $ibx->{indexlevel};
  48                 } else {
  49                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  50                 }
  51         }
  52         $ibx = PublicInbox::InboxWritable->new($ibx);
  53         my $self = bless {
  54                 inboxdir => $inboxdir,
  55                 -inbox => $ibx,
  56                 git => $ibx->git,
  57                 -altid => $altid,
  58                 ibx_ver => $version,
  59                 indexlevel => $indexlevel,
  60         }, $class;
  61         $ibx->umask_prepare;
  62         if ($version == 1) {
  63                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  64                 my $dir = $self->xdir;
  65                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  66         } elsif ($version == 2) {
  67                 defined $shard or die "shard is required for v2\n";
  68                 # shard is a number
  69                 $self->{shard} = $shard;
  70                 $self->{lock_path} = undef;
  71         } else {
  72                 die "unsupported inbox version=$version\n";
  73         }
  74         $self->{creat} = ($creat || 0) == 1;
  75         $self;
  76 }
  77
  78 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  79
  80 sub _xdb_release {
  81         my ($self) = @_;
  82         if (need_xapian($self)) {
  83                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  84                 $xdb->close;
  85         }
  86         $self->lock_release if $self->{creat};
  87         undef;
  88 }
  89
  90 sub load_xapian_writable () {
  91         return 1 if $X->{WritableDatabase};
  92         PublicInbox::Search::load_xapian() or return;
  93         my $xap = $PublicInbox::Search::Xap;
  94         for (qw(Document TermGenerator WritableDatabase)) {
  95                 $X->{$_} = $xap.'::'.$_;
  96         }
  97         eval 'require '.$X->{WritableDatabase} or die;
  98         *sortable_serialise = $xap.'::sortable_serialise';
  99         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 100         $DB_OPEN = eval($xap.'::DB_OPEN()');
 101         1;
 102 }
 103
 104 sub _xdb_acquire {
 105         my ($self) = @_;
 106         my $flag;
 107         my $dir = $self->xdir;
 108         if (need_xapian($self)) {
 109                 croak 'already acquired' if $self->{xdb};
 110                 load_xapian_writable();
 111                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 112         }
 113         if ($self->{creat}) {
 114                 require File::Path;
 115                 $self->lock_acquire;
 116
 117                 # don't create empty Xapian directories if we don't need Xapian
 118                 my $is_shard = defined($self->{shard});
 119                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 120                         File::Path::mkpath($dir);
 121                 }
 122         }
 123         return unless defined $flag;
 124         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 125         if ($@) {
 126                 die "Failed opening $dir: ", $@;
 127         }
 128         $self->{xdb} = $xdb;
 129 }
 130
 131 sub add_val ($$$) {
 132         my ($doc, $col, $num) = @_;
 133         $num = sortable_serialise($num);
 134         $doc->add_value($col, $num);
 135 }
 136
 137 sub term_generator ($) { # write-only
 138         my ($self) = @_;
 139
 140         $self->{term_generator} //= do {
 141                 my $tg = $X->{TermGenerator}->new;
 142                 $tg->set_stemmer($self->stemmer);
 143                 $tg;
 144         }
 145 }
 146
 147 sub index_text ($$$$) {
 148         my ($self, $text, $wdf_inc, $prefix) = @_;
 149         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 150
 151         if ($self->{indexlevel} eq 'full') {
 152                 $tg->index_text($text, $wdf_inc, $prefix);
 153                 $tg->increase_termpos;
 154         } else {
 155                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 156         }
 157 }
 158
 159 sub index_users ($$) {
 160         my ($self, $smsg) = @_;
 161
 162         my $from = $smsg->from;
 163         my $to = $smsg->to;
 164         my $cc = $smsg->cc;
 165
 166         index_text($self, $from, 1, 'A'); # A - author
 167         index_text($self, $to, 1, 'XTO') if $to ne '';
 168         index_text($self, $cc, 1, 'XCC') if $cc ne '';
 169 }
 170
 171 sub index_diff_inc ($$$$) {
 172         my ($self, $text, $pfx, $xnq) = @_;
 173         if (@$xnq) {
 174                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 175                 @$xnq = ();
 176         }
 177         index_text($self, $text, 1, $pfx);
 178 }
 179
 180 sub index_old_diff_fn {
 181         my ($self, $seen, $fa, $fb, $xnq) = @_;
 182
 183         # no renames or space support for traditional diffs,
 184         # find the number of leading common paths to strip:
 185         my @fa = split('/', $fa);
 186         my @fb = split('/', $fb);
 187         while (scalar(@fa) && scalar(@fb)) {
 188                 $fa = join('/', @fa);
 189                 $fb = join('/', @fb);
 190                 if ($fa eq $fb) {
 191                         unless ($seen->{$fa}++) {
 192                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 193                         }
 194                         return 1;
 195                 }
 196                 shift @fa;
 197                 shift @fb;
 198         }
 199         0;
 200 }
 201
 202 sub index_diff ($$$) {
 203         my ($self, $txt, $doc) = @_;
 204         my %seen;
 205         my $in_diff;
 206         my @xnq;
 207         my $xnq = \@xnq;
 208         foreach (split(/\n/, $txt)) {
 209                 if ($in_diff && s/^ //) { # diff context
 210                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 211                 } elsif (/^-- $/) { # email signature begins
 212                         $in_diff = undef;
 213                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 214                         # wait until "---" and "+++" to capture filenames
 215                         $in_diff = 1;
 216                 # traditional diff:
 217                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 218                         my ($opt, $fa, $fb) = ($1, $2, $3);
 219                         push @xnq, $_;
 220                         # only support unified:
 221                         next unless $opt =~ /[uU]/;
 222                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 223                                                         $xnq);
 224                 } elsif (m!^--- ("?[^/]+/.+)!) {
 225                         my $fn = $1;
 226                         $fn = (split('/', git_unquote($fn), 2))[1];
 227                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 228                         $in_diff = 1;
 229                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 230                         my $fn = $1;
 231                         $fn = (split('/', git_unquote($fn), 2))[1];
 232                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 233                         $in_diff = 1;
 234                 } elsif (/^--- (\S+)/) {
 235                         $in_diff = $1;
 236                         push @xnq, $_;
 237                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 238                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 239                                                         $1, $xnq);
 240                 } elsif ($in_diff && s/^\+//) { # diff added
 241                         index_diff_inc($self, $_, 'XDFB', $xnq);
 242                 } elsif ($in_diff && s/^-//) { # diff removed
 243                         index_diff_inc($self, $_, 'XDFA', $xnq);
 244                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 245                         my ($ba, $bb) = ($1, $2);
 246                         index_git_blob_id($doc, 'XDFPRE', $ba);
 247                         index_git_blob_id($doc, 'XDFPOST', $bb);
 248                         $in_diff = 1;
 249                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 250                         # traditional diff w/o -p
 251                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 252                         # hunk header context
 253                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 254                 # ignore the following lines:
 255                 } elsif (/^(?:dis)similarity index/ ||
 256                                 /^(?:old|new) mode/ ||
 257                                 /^(?:deleted|new) file mode/ ||
 258                                 /^(?:copy|rename) (?:from|to) / ||
 259                                 /^(?:dis)?similarity index / ||
 260                                 /^\\ No newline at end of file/ ||
 261                                 /^Binary files .* differ/) {
 262                         push @xnq, $_;
 263                 } elsif ($_ eq '') {
 264                         # possible to be in diff context, some mail may be
 265                         # stripped by MUA or even GNU diff(1).  "git apply"
 266                         # treats a bare "\n" as diff context, too
 267                 } else {
 268                         push @xnq, $_;
 269                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 270                         $in_diff = undef;
 271                 }
 272         }
 273
 274         index_text($self, join("\n", @xnq), 1, 'XNQ');
 275 }
 276
 277 sub index_body ($$$) {
 278         my ($self, $txt, $doc) = @_;
 279         if ($doc) {
 280                 # does it look like a diff?
 281                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 282                         index_diff($self, $txt, $doc);
 283                 } else {
 284                         index_text($self, $txt, 1, 'XNQ');
 285                 }
 286         } else {
 287                 index_text($self, $txt, 0, 'XQUOT');
 288         }
 289 }
 290
 291 sub index_xapian { # msg_iter callback
 292         my ($part, $depth, @idx) = @{$_[0]};
 293         my ($self, $doc) = @{$_[1]};
 294         my $ct = $part->content_type || 'text/plain';
 295         my $fn = $part->filename;
 296         if (defined $fn && $fn ne '') {
 297                 index_text($self, $fn, 1, 'XFN');
 298         }
 299
 300         my ($s, undef) = msg_part_text($part, $ct);
 301         defined $s or return;
 302
 303         # split off quoted and unquoted blocks:
 304         my @sections = split(/((?:^>[^\n]*\n)+)/sm, $s);
 305         $part = $s = undef;
 306         index_body($self, $_, /\A>/ ? 0 : $doc) for @sections;
 307 }
 308
 309 sub add_xapian ($$$$) {
 310         my ($self, $mime, $smsg, $mids) = @_;
 311         $smsg->{mime} = $mime; # XXX dangerous
 312         my $hdr = $mime->header_obj;
 313         $smsg->{ds} = msg_datestamp($hdr, $self->{autime});
 314         $smsg->{ts} = msg_timestamp($hdr, $self->{cotime});
 315         my $doc = $X->{Document}->new;
 316         my $subj = $smsg->subject;
 317         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 318         my @ds = gmtime($smsg->{ds});
 319         my $yyyymmdd = strftime('%Y%m%d', @ds);
 320         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 321         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 322         add_val($doc, PublicInbox::Search::DT(), $dt);
 323
 324         my $tg = term_generator($self);
 325
 326         $tg->set_document($doc);
 327         index_text($self, $subj, 1, 'S') if $subj;
 328         index_users($self, $smsg);
 329
 330         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 331         foreach my $mid (@$mids) {
 332                 index_text($self, $mid, 1, 'XM');
 333
 334                 # because too many Message-IDs are prefixed with
 335                 # "Pine.LNX."...
 336                 if ($mid =~ /\w{12,}/) {
 337                         my @long = ($mid =~ /(\w{3,}+)/g);
 338                         index_text($self, join(' ', @long), 1, 'XM');
 339                 }
 340         }
 341         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 342         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 343         my $data = $smsg->to_doc_data;
 344         $doc->set_data($data);
 345         if (my $altid = $self->{-altid}) {
 346                 foreach my $alt (@$altid) {
 347                         my $pfx = $alt->{xprefix};
 348                         foreach my $mid (@$mids) {
 349                                 my $id = $alt->mid2alt($mid);
 350                                 next unless defined $id;
 351                                 $doc->add_boolean_term($pfx . $id);
 352                         }
 353                 }
 354         }
 355         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 356         $self->{xdb}->replace_document($smsg->{num}, $doc);
 357 }
 358
 359 sub _msgmap_init ($) {
 360         my ($self) = @_;
 361         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 362         $self->{mm} //= eval {
 363                 require PublicInbox::Msgmap;
 364                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 365         };
 366 }
 367
 368 sub add_message {
 369         # mime = Email::MIME object
 370         my ($self, $mime, $smsg) = @_;
 371         my $mids = mids_for_index($mime->header_obj);
 372         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 373         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 374         $smsg->{num} //= do { # v1
 375                 _msgmap_init($self);
 376                 index_mm($self, $mime);
 377         };
 378         eval {
 379                 # order matters, overview stores every possible piece of
 380                 # data in doc_data (deflated).  Xapian only stores a subset
 381                 # of the fields which exist in over.sqlite3.  We may stop
 382                 # storing doc_data in Xapian sometime after we get multi-inbox
 383                 # search working.
 384                 if (my $over = $self->{over}) { # v1 only
 385                         $over->add_overview($mime, $smsg, $self);
 386                 }
 387                 if (need_xapian($self)) {
 388                         add_xapian($self, $mime, $smsg, $mids);
 389                 }
 390         };
 391
 392         if ($@) {
 393                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 394                 return undef;
 395         }
 396         $smsg->{num};
 397 }
 398
 399 # returns begin and end PostingIterator
 400 sub find_doc_ids {
 401         my ($self, $termval) = @_;
 402         my $db = $self->{xdb};
 403
 404         ($db->postlist_begin($termval), $db->postlist_end($termval));
 405 }
 406
 407 # v1 only
 408 sub batch_do {
 409         my ($self, $termval, $cb) = @_;
 410         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 411         while (1) {
 412                 my ($head, $tail) = $self->find_doc_ids($termval);
 413                 return if $head == $tail;
 414                 my @ids;
 415                 for (; $head != $tail && @ids < $batch_size; $head++) {
 416                         push @ids, $head->get_docid;
 417                 }
 418                 $cb->(\@ids);
 419         }
 420 }
 421
 422 # v1 only, where $mid is unique
 423 sub remove_message {
 424         my ($self, $mid) = @_;
 425         $mid = mid_clean($mid);
 426
 427         if (my $over = $self->{over}) {
 428                 my $nr = eval { $over->remove_oid(undef, $mid) };
 429                 if ($@) {
 430                         warn "failed to remove <$mid> from overview: $@\n";
 431                 } elsif ($nr == 0) {
 432                         warn "<$mid> missing for removal from overview\n";
 433                 }
 434         }
 435         return unless need_xapian($self);
 436         my $db = $self->{xdb};
 437         my $nr = 0;
 438         eval {
 439                 batch_do($self, 'Q' . $mid, sub {
 440                         my ($ids) = @_;
 441                         $db->delete_document($_) for @$ids;
 442                         $nr += scalar @$ids;
 443                 });
 444         };
 445         if ($@) {
 446                 warn "failed to remove <$mid> from Xapian: $@\n";
 447         } elsif ($nr == 0) {
 448                 warn "<$mid> missing for removal from Xapian\n";
 449         }
 450 }
 451
 452 # MID is a hint in V2
 453 sub remove_by_oid {
 454         my ($self, $oid, $mid) = @_;
 455
 456         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 457
 458         return unless need_xapian($self);
 459         my $db = $self->{xdb};
 460
 461         # XXX careful, we cannot use batch_do here since we conditionally
 462         # delete documents based on other factors, so we cannot call
 463         # find_doc_ids twice.
 464         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 465         return if $head == $tail;
 466
 467         # there is only ONE element in @delete unless we
 468         # have bugs in our v2writable deduplication check
 469         my @delete;
 470         for (; $head != $tail; $head++) {
 471                 my $docid = $head->get_docid;
 472                 my $doc = $db->get_document($docid);
 473                 my $smsg = PublicInbox::Smsg->wrap($mid);
 474                 $smsg->load_expand($doc);
 475                 if ($smsg->{blob} eq $oid) {
 476                         push(@delete, $docid);
 477                 }
 478         }
 479         $db->delete_document($_) foreach @delete;
 480         scalar(@delete);
 481 }
 482
 483 sub index_git_blob_id {
 484         my ($doc, $pfx, $objid) = @_;
 485
 486         my $len = length($objid);
 487         for (my $len = length($objid); $len >= 7; ) {
 488                 $doc->add_term($pfx.$objid);
 489                 $objid = substr($objid, 0, --$len);
 490         }
 491 }
 492
 493 sub unindex_blob {
 494         my ($self, $mime) = @_;
 495         my $mid = eval { mid_clean(mid_mime($mime)) };
 496         $self->remove_message($mid) if defined $mid;
 497 }
 498
 499 sub index_mm {
 500         my ($self, $mime) = @_;
 501         my $mid = mid_clean(mid_mime($mime));
 502         my $mm = $self->{mm};
 503         my $num;
 504
 505         if (defined $self->{regen_down}) {
 506                 $num = $mm->num_for($mid) and return $num;
 507
 508                 while (($num = $self->{regen_down}--) > 0) {
 509                         if ($mm->mid_set($num, $mid) != 0) {
 510                                 return $num;
 511                         }
 512                 }
 513         } elsif (defined $self->{regen_up}) {
 514                 $num = $mm->num_for($mid) and return $num;
 515
 516                 # this is to fixup old bugs due to add-remove-add
 517                 while (($num = ++$self->{regen_up})) {
 518                         if ($mm->mid_set($num, $mid) != 0) {
 519                                 return $num;
 520                         }
 521                 }
 522         }
 523
 524         $num = $mm->mid_insert($mid) and return $num;
 525
 526         # fallback to num_for since filters like RubyLang set the number
 527         $mm->num_for($mid);
 528 }
 529
 530 sub unindex_mm {
 531         my ($self, $mime) = @_;
 532         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 533 }
 534
 535 sub index_both {
 536         my ($self, $mime, $smsg) = @_;
 537         my $num = index_mm($self, $mime);
 538         $smsg->{num} = $num;
 539         add_message($self, $mime, $smsg);
 540 }
 541
 542 sub unindex_both {
 543         my ($self, $mime) = @_;
 544         unindex_blob($self, $mime);
 545         unindex_mm($self, $mime);
 546 }
 547
 548 sub do_cat_mail {
 549         my ($git, $blob, $sizeref) = @_;
 550         my $mime = eval {
 551                 my $str = $git->cat_file($blob, $sizeref);
 552                 # fixup bugs from import:
 553                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 554                 PublicInbox::MIME->new($str);
 555         };
 556         $@ ? undef : $mime;
 557 }
 558
 559 # called by public-inbox-index
 560 sub index_sync {
 561         my ($self, $opts) = @_;
 562         delete $self->{lock_path} if $opts->{-skip_lock};
 563         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 564 }
 565
 566 sub batch_adjust ($$$$$) {
 567         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 568         $$max -= $bytes;
 569         if ($$max <= 0) {
 570                 $$max = BATCH_BYTES;
 571                 $batch_cb->($nr, $latest);
 572         }
 573 }
 574
 575 # only for v1
 576 sub read_log {
 577         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 578         my $hex = '[a-f0-9]';
 579         my $h40 = $hex .'{40}';
 580         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 581         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 582         my $git = $self->{git};
 583         my $latest;
 584         my $bytes;
 585         my $max = BATCH_BYTES;
 586         local $/ = "\n";
 587         my %D;
 588         my $line;
 589         my $newest;
 590         my $nr = 0;
 591         while (defined($line = <$log>)) {
 592                 if ($line =~ /$addmsg/o) {
 593                         my $blob = $1;
 594                         if (delete $D{$blob}) {
 595                                 if (defined $self->{regen_down}) {
 596                                         my $num = $self->{regen_down}--;
 597                                         $self->{mm}->num_highwater($num);
 598                                 }
 599                                 next;
 600                         }
 601                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 602                         my $smsg = bless {}, 'PublicInbox::Smsg';
 603                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 604                         $smsg->{blob} = $blob;
 605                         $smsg->{bytes} = $bytes;
 606                         $add_cb->($self, $mime, $smsg);
 607                 } elsif ($line =~ /$delmsg/o) {
 608                         my $blob = $1;
 609                         $D{$blob} = 1;
 610                 } elsif ($line =~ /^commit ($h40)/o) {
 611                         $latest = $1;
 612                         $newest ||= $latest;
 613                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 614                         $self->{over}->{autime} = $self->{autime} = $1;
 615                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 616                         $self->{over}->{cotime} = $self->{cotime} = $1;
 617                 }
 618         }
 619         close($log) or die "git log failed: \$?=$?";
 620         # get the leftovers
 621         foreach my $blob (keys %D) {
 622                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 623                 $del_cb->($self, $mime);
 624         }
 625         $batch_cb->($nr, $latest, $newest);
 626 }
 627
 628 sub _git_log {
 629         my ($self, $opts, $range) = @_;
 630         my $git = $self->{git};
 631
 632         if (index($range, '..') < 0) {
 633                 # don't show annoying git errrors to users who run -index
 634                 # on empty inboxes
 635                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 636                 if ($?) {
 637                         open my $fh, '<', '/dev/null' or
 638                                 die "failed to open /dev/null: $!\n";
 639                         return $fh;
 640                 }
 641         }
 642
 643         # Count the new files so they can be added newest to oldest
 644         # and still have numbers increasing from oldest to newest
 645         my $fcount = 0;
 646         my $pr = $opts->{-progress};
 647         $pr->("counting changes\n\t$range ... ") if $pr;
 648         # can't use 'rev-list --count' if we use --diff-filter
 649         my $fh = $git->popen(qw(log --pretty=tformat:%h
 650                              --no-notes --no-color --no-renames
 651                              --diff-filter=AM), $range);
 652         ++$fcount while <$fh>;
 653         close $fh or die "git log failed: \$?=$?";
 654         my $high = $self->{mm}->num_highwater;
 655         $pr->("$fcount\n") if $pr; # continue previous line
 656         $self->{ntodo} = $fcount;
 657
 658         if (index($range, '..') < 0) {
 659                 if ($high && $high == $fcount) {
 660                         # fix up old bugs in full indexes which caused messages to
 661                         # not appear in Msgmap
 662                         $self->{regen_up} = $high;
 663                 } else {
 664                         # normal regen is for for fresh data
 665                         $self->{regen_down} = $fcount;
 666                 }
 667         } else {
 668                 # Give oldest messages the smallest numbers
 669                 $self->{regen_down} = $high + $fcount;
 670         }
 671
 672         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 673                                 --raw -r --no-abbrev/, $range);
 674 }
 675
 676 # --is-ancestor requires git 1.8.0+
 677 sub is_ancestor ($$$) {
 678         my ($git, $cur, $tip) = @_;
 679         return 0 unless $git->check($cur);
 680         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 681                 qw(merge-base --is-ancestor), $cur, $tip ];
 682         my $pid = spawn($cmd);
 683         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 684         $? == 0;
 685 }
 686
 687 sub need_update ($$$) {
 688         my ($self, $cur, $new) = @_;
 689         my $git = $self->{git};
 690         return 1 if $cur && !is_ancestor($git, $cur, $new);
 691         my $range = $cur eq '' ? $new : "$cur..$new";
 692         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 693         ($n eq '' || $n > 0);
 694 }
 695
 696 # The last git commit we indexed with Xapian or SQLite (msgmap)
 697 # This needs to account for cases where Xapian or SQLite is
 698 # out-of-date with respect to the other.
 699 sub _last_x_commit {
 700         my ($self, $mm) = @_;
 701         my $lm = $mm->last_commit || '';
 702         my $lx = '';
 703         if (need_xapian($self)) {
 704                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 705         } else {
 706                 $lx = $lm;
 707         }
 708         # Use last_commit from msgmap if it is older or unset
 709         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 710                 $lx = $lm;
 711         }
 712         $lx;
 713 }
 714
 715 sub reindex_from ($$) {
 716         my ($reindex, $last_commit) = @_;
 717         return $last_commit unless $reindex;
 718         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 719 }
 720
 721 # indexes all unindexed messages (v1 only)
 722 sub _index_sync {
 723         my ($self, $opts) = @_;
 724         my $tip = $opts->{ref} || 'HEAD';
 725         my ($last_commit, $lx, $xlog);
 726         my $git = $self->{git};
 727         $git->batch_prepare;
 728         my $pr = $opts->{-progress};
 729
 730         my $xdb = $self->begin_txn_lazy;
 731         my $mm = _msgmap_init($self);
 732         do {
 733                 if ($xlog) {
 734                         close($xlog) or die "git log failed: \$?=$?";
 735                         $xlog = undef;
 736                 }
 737                 $last_commit = _last_x_commit($self, $mm);
 738                 $lx = reindex_from($opts->{reindex}, $last_commit);
 739
 740                 $self->{over}->rollback_lazy;
 741                 $self->{over}->disconnect;
 742                 $git->cleanup;
 743                 delete $self->{txn};
 744                 $xdb->cancel_transaction if $xdb;
 745                 $xdb = _xdb_release($self);
 746
 747                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 748                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 749                 $xlog = _git_log($self, $opts, $range);
 750
 751                 $xdb = $self->begin_txn_lazy;
 752         } while (_last_x_commit($self, $mm) ne $last_commit);
 753
 754         my $dbh = $mm->{dbh} if $mm;
 755         my $cb = sub {
 756                 my ($nr, $commit, $newest) = @_;
 757                 if ($dbh) {
 758                         if ($newest) {
 759                                 my $cur = $mm->last_commit || '';
 760                                 if (need_update($self, $cur, $newest)) {
 761                                         $mm->last_commit($newest);
 762                                 }
 763                         }
 764                         $dbh->commit;
 765                 }
 766                 if ($newest && need_xapian($self)) {
 767                         my $cur = $xdb->get_metadata('last_commit');
 768                         if (need_update($self, $cur, $newest)) {
 769                                 $xdb->set_metadata('last_commit', $newest);
 770                         }
 771                 }
 772                 $self->commit_txn_lazy;
 773                 $git->cleanup;
 774                 $xdb = _xdb_release($self);
 775                 # let another process do some work... <
 776                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 777                 if (!$newest) {
 778                         $xdb = $self->begin_txn_lazy;
 779                         $dbh->begin_work if $dbh;
 780                 }
 781         };
 782
 783         $dbh->begin_work;
 784         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 785 }
 786
 787 sub DESTROY {
 788         # order matters for unlocking
 789         $_[0]->{xdb} = undef;
 790         $_[0]->{lockfh} = undef;
 791 }
 792
 793 # remote_* subs are only used by SearchIdxPart
 794 sub remote_commit {
 795         my ($self) = @_;
 796         if (my $w = $self->{w}) {
 797                 print $w "commit\n" or die "failed to write commit: $!";
 798         } else {
 799                 $self->commit_txn_lazy;
 800         }
 801 }
 802
 803 sub remote_close {
 804         my ($self) = @_;
 805         if (my $w = delete $self->{w}) {
 806                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 807                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 808                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 809                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 810                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 811         } else {
 812                 die "transaction in progress $self\n" if $self->{txn};
 813                 $self->_xdb_release if $self->{xdb};
 814         }
 815 }
 816
 817 sub remote_remove {
 818         my ($self, $oid, $mid) = @_;
 819         if (my $w = $self->{w}) {
 820                 # triggers remove_by_oid in a shard
 821                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 822         } else {
 823                 $self->begin_txn_lazy;
 824                 $self->remove_by_oid($oid, $mid);
 825         }
 826 }
 827
 828 sub begin_txn_lazy {
 829         my ($self) = @_;
 830         return if $self->{txn};
 831
 832         $self->{-inbox}->with_umask(sub {
 833                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 834                 $self->{over}->begin_lazy if $self->{over};
 835                 $xdb->begin_transaction if $xdb;
 836                 $self->{txn} = 1;
 837                 $xdb;
 838         });
 839 }
 840
 841 sub commit_txn_lazy {
 842         my ($self) = @_;
 843         delete $self->{txn} or return;
 844         $self->{-inbox}->with_umask(sub {
 845                 if (my $xdb = $self->{xdb}) {
 846
 847                         # store 'indexlevel=medium' in v2 shard=0 and
 848                         # v1 (only one shard)
 849                         # This metadata is read by Admin::detect_indexlevel:
 850                         if (!$self->{shard} # undef or 0, not >0
 851                             && $self->{indexlevel} eq 'medium') {
 852                                 $xdb->set_metadata('indexlevel', 'medium');
 853                         }
 854
 855                         $xdb->commit_transaction;
 856                 }
 857                 $self->{over}->commit_lazy if $self->{over};
 858         });
 859 }
 860
 861 sub worker_done {
 862         my ($self) = @_;
 863         if (need_xapian($self)) {
 864                 die "$$ $0 xdb not released\n" if $self->{xdb};
 865         }
 866         die "$$ $0 still in transaction\n" if $self->{txn};
 867 }
 868
 869 1;