lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 my $X = \%PublicInbox::Search::X;
  23 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  24 use constant {
  25         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000,
  27         DEBUG => !!$ENV{DEBUG},
  28 };
  29
  30 my $xapianlevels = qr/\A(?:full|medium)\z/;
  31
  32 sub new {
  33         my ($class, $ibx, $creat, $shard) = @_;
  34         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  35         my $levels = qr/\A(?:full|medium|basic)\z/;
  36         my $inboxdir = $ibx->{inboxdir};
  37         my $version = $ibx->{version} || 1;
  38         my $indexlevel = 'full';
  39         my $altid = $ibx->{altid};
  40         if ($altid) {
  41                 require PublicInbox::AltId;
  42                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  43         }
  44         if ($ibx->{indexlevel}) {
  45                 if ($ibx->{indexlevel} =~ $levels) {
  46                         $indexlevel = $ibx->{indexlevel};
  47                 } else {
  48                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  49                 }
  50         }
  51         $ibx = PublicInbox::InboxWritable->new($ibx);
  52         my $self = bless {
  53                 inboxdir => $inboxdir,
  54                 -inbox => $ibx,
  55                 git => $ibx->git,
  56                 -altid => $altid,
  57                 version => $version,
  58                 indexlevel => $indexlevel,
  59         }, $class;
  60         $ibx->umask_prepare;
  61         if ($version == 1) {
  62                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  63                 my $dir = $self->xdir;
  64                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  65         } elsif ($version == 2) {
  66                 defined $shard or die "shard is required for v2\n";
  67                 # shard is a number
  68                 $self->{shard} = $shard;
  69                 $self->{lock_path} = undef;
  70         } else {
  71                 die "unsupported inbox version=$version\n";
  72         }
  73         $self->{creat} = ($creat || 0) == 1;
  74         $self;
  75 }
  76
  77 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  78
  79 sub _xdb_release {
  80         my ($self) = @_;
  81         if (need_xapian($self)) {
  82                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  83                 $xdb->close;
  84         }
  85         $self->lock_release if $self->{creat};
  86         undef;
  87 }
  88
  89 sub load_xapian_writable () {
  90         return 1 if $X->{WritableDatabase};
  91         PublicInbox::Search::load_xapian() or return;
  92         my $xap = $PublicInbox::Search::Xap;
  93         for (qw(Document TermGenerator WritableDatabase)) {
  94                 $X->{$_} = $xap.'::'.$_;
  95         }
  96         eval 'require '.$X->{WritableDatabase} or die;
  97         *sortable_serialise = $xap.'::sortable_serialise';
  98         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
  99         $DB_OPEN = eval($xap.'::DB_OPEN()');
 100         1;
 101 }
 102
 103 sub _xdb_acquire {
 104         my ($self) = @_;
 105         my $flag;
 106         my $dir = $self->xdir;
 107         if (need_xapian($self)) {
 108                 croak 'already acquired' if $self->{xdb};
 109                 load_xapian_writable();
 110                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 111         }
 112         if ($self->{creat}) {
 113                 require File::Path;
 114                 $self->lock_acquire;
 115
 116                 # don't create empty Xapian directories if we don't need Xapian
 117                 my $is_shard = defined($self->{shard});
 118                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 119                         File::Path::mkpath($dir);
 120                 }
 121         }
 122         return unless defined $flag;
 123         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 124         if ($@) {
 125                 die "Failed opening $dir: ", $@;
 126         }
 127         $self->{xdb} = $xdb;
 128 }
 129
 130 sub add_val ($$$) {
 131         my ($doc, $col, $num) = @_;
 132         $num = sortable_serialise($num);
 133         $doc->add_value($col, $num);
 134 }
 135
 136 sub term_generator ($) { # write-only
 137         my ($self) = @_;
 138
 139         $self->{term_generator} //= do {
 140                 my $tg = $X->{TermGenerator}->new;
 141                 $tg->set_stemmer($self->stemmer);
 142                 $tg;
 143         }
 144 }
 145
 146 sub index_text ($$$$) {
 147         my ($self, $field, $n, $text) = @_;
 148         my $tg = term_generator($self);
 149
 150         if ($self->{indexlevel} eq 'full') {
 151                 $tg->index_text($field, $n, $text);
 152                 $tg->increase_termpos;
 153         } else {
 154                 $tg->index_text_without_positions($field, $n, $text);
 155         }
 156 }
 157
 158 sub index_users ($$) {
 159         my ($self, $smsg) = @_;
 160
 161         my $from = $smsg->from;
 162         my $to = $smsg->to;
 163         my $cc = $smsg->cc;
 164
 165         index_text($self, $from, 1, 'A'); # A - author
 166         index_text($self, $to, 1, 'XTO') if $to ne '';
 167         index_text($self, $cc, 1, 'XCC') if $cc ne '';
 168 }
 169
 170 sub index_diff_inc ($$$$) {
 171         my ($self, $text, $pfx, $xnq) = @_;
 172         if (@$xnq) {
 173                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 174                 @$xnq = ();
 175         }
 176         index_text($self, $text, 1, $pfx);
 177 }
 178
 179 sub index_old_diff_fn {
 180         my ($self, $seen, $fa, $fb, $xnq) = @_;
 181
 182         # no renames or space support for traditional diffs,
 183         # find the number of leading common paths to strip:
 184         my @fa = split('/', $fa);
 185         my @fb = split('/', $fb);
 186         while (scalar(@fa) && scalar(@fb)) {
 187                 $fa = join('/', @fa);
 188                 $fb = join('/', @fb);
 189                 if ($fa eq $fb) {
 190                         unless ($seen->{$fa}++) {
 191                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 192                         }
 193                         return 1;
 194                 }
 195                 shift @fa;
 196                 shift @fb;
 197         }
 198         0;
 199 }
 200
 201 sub index_diff ($$$) {
 202         my ($self, $lines, $doc) = @_;
 203         my %seen;
 204         my $in_diff;
 205         my @xnq;
 206         my $xnq = \@xnq;
 207         foreach (@$lines) {
 208                 if ($in_diff && s/^ //) { # diff context
 209                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 210                 } elsif (/^-- $/) { # email signature begins
 211                         $in_diff = undef;
 212                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 213                         my ($fa, $fb) = ($1, $2);
 214                         my $fn = (split('/', git_unquote($fa), 2))[1];
 215                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 216                         $fn = (split('/', git_unquote($fb), 2))[1];
 217                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 218                         $in_diff = 1;
 219                 # traditional diff:
 220                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 221                         my ($opt, $fa, $fb) = ($1, $2, $3);
 222                         push @xnq, $_;
 223                         # only support unified:
 224                         next unless $opt =~ /[uU]/;
 225                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 226                                                         $xnq);
 227                 } elsif (m!^--- ("?a/.+)!) {
 228                         my $fn = $1;
 229                         $fn = (split('/', git_unquote($fn), 2))[1];
 230                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 231                         $in_diff = 1;
 232                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 233                         my $fn = $1;
 234                         $fn = (split('/', git_unquote($fn), 2))[1];
 235                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 236                         $in_diff = 1;
 237                 } elsif (/^--- (\S+)/) {
 238                         $in_diff = $1;
 239                         push @xnq, $_;
 240                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 241                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 242                                                         $1, $xnq);
 243                 } elsif ($in_diff && s/^\+//) { # diff added
 244                         index_diff_inc($self, $_, 'XDFB', $xnq);
 245                 } elsif ($in_diff && s/^-//) { # diff removed
 246                         index_diff_inc($self, $_, 'XDFA', $xnq);
 247                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 248                         my ($ba, $bb) = ($1, $2);
 249                         index_git_blob_id($doc, 'XDFPRE', $ba);
 250                         index_git_blob_id($doc, 'XDFPOST', $bb);
 251                         $in_diff = 1;
 252                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 253                         # traditional diff w/o -p
 254                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 255                         # hunk header context
 256                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 257                 # ignore the following lines:
 258                 } elsif (/^(?:dis)similarity index/ ||
 259                                 /^(?:old|new) mode/ ||
 260                                 /^(?:deleted|new) file mode/ ||
 261                                 /^(?:copy|rename) (?:from|to) / ||
 262                                 /^(?:dis)?similarity index / ||
 263                                 /^\\ No newline at end of file/ ||
 264                                 /^Binary files .* differ/) {
 265                         push @xnq, $_;
 266                 } elsif ($_ eq '') {
 267                         # possible to be in diff context, some mail may be
 268                         # stripped by MUA or even GNU diff(1).  "git apply"
 269                         # treats a bare "\n" as diff context, too
 270                 } else {
 271                         push @xnq, $_;
 272                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 273                         $in_diff = undef;
 274                 }
 275         }
 276
 277         index_text($self, join("\n", @xnq), 1, 'XNQ');
 278 }
 279
 280 sub index_body ($$$) {
 281         my ($self, $lines, $doc) = @_;
 282         my $txt = join("\n", @$lines);
 283         if ($doc) {
 284                 # does it look like a diff?
 285                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 286                         $txt = undef;
 287                         index_diff($self, $lines, $doc);
 288                 } else {
 289                         index_text($self, $txt, 1, 'XNQ');
 290                 }
 291         } else {
 292                 index_text($self, $txt, 0, 'XQUOT');
 293         }
 294         @$lines = ();
 295 }
 296
 297 sub index_xapian { # msg_iter callback
 298         my ($part, $depth, @idx) = @{$_[0]};
 299         my ($self, $doc) = @{$_[1]};
 300         my $ct = $part->content_type || 'text/plain';
 301         my $fn = $part->filename;
 302         if (defined $fn && $fn ne '') {
 303                 index_text($self, $fn, 1, 'XFN');
 304         }
 305
 306         my ($s, undef) = msg_part_text($part, $ct);
 307         defined $s or return;
 308
 309         my (@orig, @quot);
 310         my @lines = split(/\n/, $s);
 311         while (defined(my $l = shift @lines)) {
 312                 if ($l =~ /^>/) {
 313                         index_body($self, \@orig, $doc) if @orig;
 314                         push @quot, $l;
 315                 } else {
 316                         index_body($self, \@quot, 0) if @quot;
 317                         push @orig, $l;
 318                 }
 319         }
 320         index_body($self, \@quot, 0) if @quot;
 321         index_body($self, \@orig, $doc) if @orig;
 322 }
 323
 324 sub add_xapian ($$$$$$) {
 325         my ($self, $mime, $num, $oid, $mids, $mid0) = @_;
 326         my $smsg = PublicInbox::SearchMsg->new($mime);
 327         my $doc = $X->{Document}->new;
 328         my $subj = $smsg->subject;
 329         add_val($doc, PublicInbox::Search::TS(), $smsg->ts);
 330         my @ds = gmtime($smsg->ds);
 331         my $yyyymmdd = strftime('%Y%m%d', @ds);
 332         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 333         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 334         add_val($doc, PublicInbox::Search::DT(), $dt);
 335
 336         my $tg = term_generator($self);
 337
 338         $tg->set_document($doc);
 339         index_text($self, $subj, 1, 'S') if $subj;
 340         index_users($self, $smsg);
 341
 342         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 343         foreach my $mid (@$mids) {
 344                 index_text($self, $mid, 1, 'XM');
 345
 346                 # because too many Message-IDs are prefixed with
 347                 # "Pine.LNX."...
 348                 if ($mid =~ /\w{12,}/) {
 349                         my @long = ($mid =~ /(\w{3,}+)/g);
 350                         index_text($self, join(' ', @long), 1, 'XM');
 351                 }
 352         }
 353         $smsg->{to} = $smsg->{cc} = '';
 354         PublicInbox::OverIdx::parse_references($smsg, $mid0, $mids);
 355         my $data = $smsg->to_doc_data($oid, $mid0);
 356         $doc->set_data($data);
 357         if (my $altid = $self->{-altid}) {
 358                 foreach my $alt (@$altid) {
 359                         my $pfx = $alt->{xprefix};
 360                         foreach my $mid (@$mids) {
 361                                 my $id = $alt->mid2alt($mid);
 362                                 next unless defined $id;
 363                                 $doc->add_boolean_term($pfx . $id);
 364                         }
 365                 }
 366         }
 367         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 368         $self->{xdb}->replace_document($num, $doc);
 369 }
 370
 371 sub _msgmap_init ($) {
 372         my ($self) = @_;
 373         die "BUG: _msgmap_init is only for v1\n" if $self->{version} != 1;
 374         $self->{mm} //= eval {
 375                 require PublicInbox::Msgmap;
 376                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 377         };
 378 }
 379
 380 sub add_message {
 381         # mime = Email::MIME object
 382         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 383         my $mids = mids_for_index($mime->header_obj);
 384         $mid0 //= $mids->[0]; # v1 compatibility
 385         $num //= do { # v1
 386                 _msgmap_init($self);
 387                 index_mm($self, $mime);
 388         };
 389         eval {
 390                 if (need_xapian($self)) {
 391                         add_xapian($self, $mime, $num, $oid, $mids, $mid0);
 392                 }
 393                 if (my $over = $self->{over}) {
 394                         $over->add_overview($mime, $bytes, $num, $oid, $mid0);
 395                 }
 396         };
 397
 398         if ($@) {
 399                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 400                 return undef;
 401         }
 402         $num;
 403 }
 404
 405 # returns begin and end PostingIterator
 406 sub find_doc_ids {
 407         my ($self, $termval) = @_;
 408         my $db = $self->{xdb};
 409
 410         ($db->postlist_begin($termval), $db->postlist_end($termval));
 411 }
 412
 413 # v1 only
 414 sub batch_do {
 415         my ($self, $termval, $cb) = @_;
 416         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 417         while (1) {
 418                 my ($head, $tail) = $self->find_doc_ids($termval);
 419                 return if $head == $tail;
 420                 my @ids;
 421                 for (; $head != $tail && @ids < $batch_size; $head++) {
 422                         push @ids, $head->get_docid;
 423                 }
 424                 $cb->(\@ids);
 425         }
 426 }
 427
 428 # v1 only, where $mid is unique
 429 sub remove_message {
 430         my ($self, $mid) = @_;
 431         $mid = mid_clean($mid);
 432
 433         if (my $over = $self->{over}) {
 434                 my $nr = eval { $over->remove_oid(undef, $mid) };
 435                 if ($@) {
 436                         warn "failed to remove <$mid> from overview: $@\n";
 437                 } elsif ($nr == 0) {
 438                         warn "<$mid> missing for removal from overview\n";
 439                 }
 440         }
 441         return unless need_xapian($self);
 442         my $db = $self->{xdb};
 443         my $nr = 0;
 444         eval {
 445                 batch_do($self, 'Q' . $mid, sub {
 446                         my ($ids) = @_;
 447                         $db->delete_document($_) for @$ids;
 448                         $nr = scalar @$ids;
 449                 });
 450         };
 451         if ($@) {
 452                 warn "failed to remove <$mid> from Xapian: $@\n";
 453         } elsif ($nr == 0) {
 454                 warn "<$mid> missing for removal from Xapian\n";
 455         }
 456 }
 457
 458 # MID is a hint in V2
 459 sub remove_by_oid {
 460         my ($self, $oid, $mid) = @_;
 461
 462         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 463
 464         return unless need_xapian($self);
 465         my $db = $self->{xdb};
 466
 467         # XXX careful, we cannot use batch_do here since we conditionally
 468         # delete documents based on other factors, so we cannot call
 469         # find_doc_ids twice.
 470         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 471         return if $head == $tail;
 472
 473         # there is only ONE element in @delete unless we
 474         # have bugs in our v2writable deduplication check
 475         my @delete;
 476         for (; $head != $tail; $head++) {
 477                 my $docid = $head->get_docid;
 478                 my $doc = $db->get_document($docid);
 479                 my $smsg = PublicInbox::SearchMsg->wrap($mid);
 480                 $smsg->load_expand($doc);
 481                 if ($smsg->{blob} eq $oid) {
 482                         push(@delete, $docid);
 483                 }
 484         }
 485         $db->delete_document($_) foreach @delete;
 486         scalar(@delete);
 487 }
 488
 489 sub index_git_blob_id {
 490         my ($doc, $pfx, $objid) = @_;
 491
 492         my $len = length($objid);
 493         for (my $len = length($objid); $len >= 7; ) {
 494                 $doc->add_term($pfx.$objid);
 495                 $objid = substr($objid, 0, --$len);
 496         }
 497 }
 498
 499 sub unindex_blob {
 500         my ($self, $mime) = @_;
 501         my $mid = eval { mid_clean(mid_mime($mime)) };
 502         $self->remove_message($mid) if defined $mid;
 503 }
 504
 505 sub index_mm {
 506         my ($self, $mime) = @_;
 507         my $mid = mid_clean(mid_mime($mime));
 508         my $mm = $self->{mm};
 509         my $num;
 510
 511         if (defined $self->{regen_down}) {
 512                 $num = $mm->num_for($mid) and return $num;
 513
 514                 while (($num = $self->{regen_down}--) > 0) {
 515                         if ($mm->mid_set($num, $mid) != 0) {
 516                                 return $num;
 517                         }
 518                 }
 519         } elsif (defined $self->{regen_up}) {
 520                 $num = $mm->num_for($mid) and return $num;
 521
 522                 # this is to fixup old bugs due to add-remove-add
 523                 while (($num = ++$self->{regen_up})) {
 524                         if ($mm->mid_set($num, $mid) != 0) {
 525                                 return $num;
 526                         }
 527                 }
 528         }
 529
 530         $num = $mm->mid_insert($mid) and return $num;
 531
 532         # fallback to num_for since filters like RubyLang set the number
 533         $mm->num_for($mid);
 534 }
 535
 536 sub unindex_mm {
 537         my ($self, $mime) = @_;
 538         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 539 }
 540
 541 sub index_both {
 542         my ($self, $mime, $bytes, $blob) = @_;
 543         my $num = index_mm($self, $mime);
 544         add_message($self, $mime, $bytes, $num, $blob);
 545 }
 546
 547 sub unindex_both {
 548         my ($self, $mime) = @_;
 549         unindex_blob($self, $mime);
 550         unindex_mm($self, $mime);
 551 }
 552
 553 sub do_cat_mail {
 554         my ($git, $blob, $sizeref) = @_;
 555         my $mime = eval {
 556                 my $str = $git->cat_file($blob, $sizeref);
 557                 # fixup bugs from import:
 558                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 559                 PublicInbox::MIME->new($str);
 560         };
 561         $@ ? undef : $mime;
 562 }
 563
 564 # called by public-inbox-index
 565 sub index_sync {
 566         my ($self, $opts) = @_;
 567         delete $self->{lock_path} if $opts->{-skip_lock};
 568         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 569 }
 570
 571 sub batch_adjust ($$$$$) {
 572         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 573         $$max -= $bytes;
 574         if ($$max <= 0) {
 575                 $$max = BATCH_BYTES;
 576                 $batch_cb->($nr, $latest);
 577         }
 578 }
 579
 580 # only for v1
 581 sub read_log {
 582         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 583         my $hex = '[a-f0-9]';
 584         my $h40 = $hex .'{40}';
 585         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 586         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 587         my $git = $self->{git};
 588         my $latest;
 589         my $bytes;
 590         my $max = BATCH_BYTES;
 591         local $/ = "\n";
 592         my %D;
 593         my $line;
 594         my $newest;
 595         my $nr = 0;
 596         while (defined($line = <$log>)) {
 597                 if ($line =~ /$addmsg/o) {
 598                         my $blob = $1;
 599                         if (delete $D{$blob}) {
 600                                 if (defined $self->{regen_down}) {
 601                                         my $num = $self->{regen_down}--;
 602                                         $self->{mm}->num_highwater($num);
 603                                 }
 604                                 next;
 605                         }
 606                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 607                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 608                         $add_cb->($self, $mime, $bytes, $blob);
 609                 } elsif ($line =~ /$delmsg/o) {
 610                         my $blob = $1;
 611                         $D{$blob} = 1;
 612                 } elsif ($line =~ /^commit ($h40)/o) {
 613                         $latest = $1;
 614                         $newest ||= $latest;
 615                 }
 616         }
 617         close($log) or die "git log failed: \$?=$?";
 618         # get the leftovers
 619         foreach my $blob (keys %D) {
 620                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 621                 $del_cb->($self, $mime);
 622         }
 623         $batch_cb->($nr, $latest, $newest);
 624 }
 625
 626 sub _git_log {
 627         my ($self, $opts, $range) = @_;
 628         my $git = $self->{git};
 629
 630         if (index($range, '..') < 0) {
 631                 # don't show annoying git errrors to users who run -index
 632                 # on empty inboxes
 633                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 634                 if ($?) {
 635                         open my $fh, '<', '/dev/null' or
 636                                 die "failed to open /dev/null: $!\n";
 637                         return $fh;
 638                 }
 639         }
 640
 641         # Count the new files so they can be added newest to oldest
 642         # and still have numbers increasing from oldest to newest
 643         my $fcount = 0;
 644         my $pr = $opts->{-progress};
 645         $pr->("counting changes\n\t$range ... ") if $pr;
 646         # can't use 'rev-list --count' if we use --diff-filter
 647         my $fh = $git->popen(qw(log --pretty=tformat:%h
 648                              --no-notes --no-color --no-renames
 649                              --diff-filter=AM), $range);
 650         ++$fcount while <$fh>;
 651         close $fh or die "git log failed: \$?=$?";
 652         my $high = $self->{mm}->num_highwater;
 653         $pr->("$fcount\n") if $pr; # continue previous line
 654         $self->{ntodo} = $fcount;
 655
 656         if (index($range, '..') < 0) {
 657                 if ($high && $high == $fcount) {
 658                         # fix up old bugs in full indexes which caused messages to
 659                         # not appear in Msgmap
 660                         $self->{regen_up} = $high;
 661                 } else {
 662                         # normal regen is for for fresh data
 663                         $self->{regen_down} = $fcount;
 664                 }
 665         } else {
 666                 # Give oldest messages the smallest numbers
 667                 $self->{regen_down} = $high + $fcount;
 668         }
 669
 670         $git->popen(qw/log --no-notes --no-color --no-renames
 671                                 --raw -r --no-abbrev/, $range);
 672 }
 673
 674 # --is-ancestor requires git 1.8.0+
 675 sub is_ancestor ($$$) {
 676         my ($git, $cur, $tip) = @_;
 677         return 0 unless $git->check($cur);
 678         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 679                 qw(merge-base --is-ancestor), $cur, $tip ];
 680         my $pid = spawn($cmd);
 681         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 682         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 683         $? == 0;
 684 }
 685
 686 sub need_update ($$$) {
 687         my ($self, $cur, $new) = @_;
 688         my $git = $self->{git};
 689         return 1 if $cur && !is_ancestor($git, $cur, $new);
 690         my $range = $cur eq '' ? $new : "$cur..$new";
 691         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 692         ($n eq '' || $n > 0);
 693 }
 694
 695 # The last git commit we indexed with Xapian or SQLite (msgmap)
 696 # This needs to account for cases where Xapian or SQLite is
 697 # out-of-date with respect to the other.
 698 sub _last_x_commit {
 699         my ($self, $mm) = @_;
 700         my $lm = $mm->last_commit || '';
 701         my $lx = '';
 702         if (need_xapian($self)) {
 703                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 704         } else {
 705                 $lx = $lm;
 706         }
 707         # Use last_commit from msgmap if it is older or unset
 708         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 709                 $lx = $lm;
 710         }
 711         $lx;
 712 }
 713
 714 sub reindex_from ($$) {
 715         my ($reindex, $last_commit) = @_;
 716         return $last_commit unless $reindex;
 717         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 718 }
 719
 720 # indexes all unindexed messages (v1 only)
 721 sub _index_sync {
 722         my ($self, $opts) = @_;
 723         my $tip = $opts->{ref} || 'HEAD';
 724         my ($last_commit, $lx, $xlog);
 725         my $git = $self->{git};
 726         $git->batch_prepare;
 727         my $pr = $opts->{-progress};
 728
 729         my $xdb = $self->begin_txn_lazy;
 730         my $mm = _msgmap_init($self);
 731         do {
 732                 if ($xlog) {
 733                         close($xlog) or die "git log failed: \$?=$?";
 734                         $xlog = undef;
 735                 }
 736                 $last_commit = _last_x_commit($self, $mm);
 737                 $lx = reindex_from($opts->{reindex}, $last_commit);
 738
 739                 $self->{over}->rollback_lazy;
 740                 $self->{over}->disconnect;
 741                 $git->cleanup;
 742                 delete $self->{txn};
 743                 $xdb->cancel_transaction if $xdb;
 744                 $xdb = _xdb_release($self);
 745
 746                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 747                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 748                 $xlog = _git_log($self, $opts, $range);
 749
 750                 $xdb = $self->begin_txn_lazy;
 751         } while (_last_x_commit($self, $mm) ne $last_commit);
 752
 753         my $dbh = $mm->{dbh} if $mm;
 754         my $cb = sub {
 755                 my ($nr, $commit, $newest) = @_;
 756                 if ($dbh) {
 757                         if ($newest) {
 758                                 my $cur = $mm->last_commit || '';
 759                                 if (need_update($self, $cur, $newest)) {
 760                                         $mm->last_commit($newest);
 761                                 }
 762                         }
 763                         $dbh->commit;
 764                 }
 765                 if ($newest && need_xapian($self)) {
 766                         my $cur = $xdb->get_metadata('last_commit');
 767                         if (need_update($self, $cur, $newest)) {
 768                                 $xdb->set_metadata('last_commit', $newest);
 769                         }
 770                 }
 771                 $self->commit_txn_lazy;
 772                 $git->cleanup;
 773                 $xdb = _xdb_release($self);
 774                 # let another process do some work... <
 775                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 776                 if (!$newest) {
 777                         $xdb = $self->begin_txn_lazy;
 778                         $dbh->begin_work if $dbh;
 779                 }
 780         };
 781
 782         $dbh->begin_work;
 783         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 784 }
 785
 786 sub DESTROY {
 787         # order matters for unlocking
 788         $_[0]->{xdb} = undef;
 789         $_[0]->{lockfh} = undef;
 790 }
 791
 792 # remote_* subs are only used by SearchIdxPart
 793 sub remote_commit {
 794         my ($self) = @_;
 795         if (my $w = $self->{w}) {
 796                 print $w "commit\n" or die "failed to write commit: $!";
 797         } else {
 798                 $self->commit_txn_lazy;
 799         }
 800 }
 801
 802 sub remote_close {
 803         my ($self) = @_;
 804         if (my $w = delete $self->{w}) {
 805                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 806                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 807                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 808                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 809                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 810         } else {
 811                 die "transaction in progress $self\n" if $self->{txn};
 812                 $self->_xdb_release if $self->{xdb};
 813         }
 814 }
 815
 816 sub remote_remove {
 817         my ($self, $oid, $mid) = @_;
 818         if (my $w = $self->{w}) {
 819                 # triggers remove_by_oid in a shard
 820                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 821         } else {
 822                 $self->begin_txn_lazy;
 823                 $self->remove_by_oid($oid, $mid);
 824         }
 825 }
 826
 827 sub begin_txn_lazy {
 828         my ($self) = @_;
 829         return if $self->{txn};
 830
 831         $self->{-inbox}->with_umask(sub {
 832                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 833                 $self->{over}->begin_lazy if $self->{over};
 834                 $xdb->begin_transaction if $xdb;
 835                 $self->{txn} = 1;
 836                 $xdb;
 837         });
 838 }
 839
 840 sub commit_txn_lazy {
 841         my ($self) = @_;
 842         delete $self->{txn} or return;
 843         $self->{-inbox}->with_umask(sub {
 844                 if (my $xdb = $self->{xdb}) {
 845
 846                         # store 'indexlevel=medium' in v2 shard=0 and
 847                         # v1 (only one shard)
 848                         # This metadata is read by Admin::detect_indexlevel:
 849                         if (!$self->{shard} # undef or 0, not >0
 850                             && $self->{indexlevel} eq 'medium') {
 851                                 $xdb->set_metadata('indexlevel', 'medium');
 852                         }
 853
 854                         $xdb->commit_transaction;
 855                 }
 856                 $self->{over}->commit_lazy if $self->{over};
 857         });
 858 }
 859
 860 sub worker_done {
 861         my ($self) = @_;
 862         if (need_xapian($self)) {
 863                 die "$$ $0 xdb not released\n" if $self->{xdb};
 864         }
 865         die "$$ $0 still in transaction\n" if $self->{txn};
 866 }
 867
 868 1;