lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::Search qw(xap_terms);
  15 use PublicInbox::InboxWritable;
  16 use PublicInbox::MID qw(mids_for_index mids);
  17 use PublicInbox::MsgIter;
  18 use PublicInbox::IdxStack;
  19 use Carp qw(croak carp);
  20 use POSIX qw(strftime);
  21 use Time::Local qw(timegm);
  22 use PublicInbox::OverIdx;
  23 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  24 use PublicInbox::Git qw(git_unquote);
  25 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  26 use PublicInbox::Address;
  27 use Config;
  28 our @EXPORT_OK = qw(log2stack is_ancestor check_size prepare_stack
  29         index_text term_generator add_val is_bad_blob);
  30 my $X = \%PublicInbox::Search::X;
  31 our ($DB_CREATE_OR_OPEN, $DB_OPEN);
  32 our $DB_NO_SYNC = 0;
  33 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff :
  34         # assume a typical 64-bit system has 8x more RAM than a
  35         # typical 32-bit system:
  36         (($Config{ptrsize} >= 8 ? 8192 : 1024) * 1024);
  37
  38 use constant DEBUG => !!$ENV{DEBUG};
  39
  40 my $xapianlevels = qr/\A(?:full|medium)\z/;
  41 my $hex = '[a-f0-9]';
  42 my $OID = $hex .'{40,}';
  43 my @VMD_MAP = (kw => 'K', L => 'L');
  44 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  45
  46 sub new {
  47         my ($class, $ibx, $creat, $shard) = @_;
  48         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  49         my $inboxdir = $ibx->{inboxdir};
  50         my $version = $ibx->version;
  51         my $indexlevel = 'full';
  52         my $altid = $ibx->{altid};
  53         if ($altid) {
  54                 require PublicInbox::AltId;
  55                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  56         }
  57         if ($ibx->{indexlevel}) {
  58                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  59                         $indexlevel = $ibx->{indexlevel};
  60                 } else {
  61                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  62                 }
  63         }
  64         $ibx = PublicInbox::InboxWritable->new($ibx);
  65         my $self = PublicInbox::Search->new($ibx);
  66         bless $self, $class;
  67         $self->{ibx} = $ibx;
  68         $self->{-altid} = $altid;
  69         $self->{indexlevel} = $indexlevel;
  70         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  71         if ($ibx->{-skip_docdata}) {
  72                 $self->{-set_skip_docdata_once} = 1;
  73                 $self->{-skip_docdata} = 1;
  74         }
  75         if ($version == 1) {
  76                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  77                 my $dir = $self->xdir;
  78                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  79                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  80         } elsif ($version == 2) {
  81                 defined $shard or die "shard is required for v2\n";
  82                 # shard is a number
  83                 $self->{shard} = $shard;
  84                 $self->{lock_path} = undef;
  85         } else {
  86                 die "unsupported inbox version=$version\n";
  87         }
  88         $self->{creat} = ($creat || 0) == 1;
  89         $self;
  90 }
  91
  92 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  93
  94 sub idx_release {
  95         my ($self, $wake) = @_;
  96         if (need_xapian($self)) {
  97                 my $xdb = delete $self->{xdb} or croak '{xdb} not acquired';
  98                 $xdb->close;
  99         }
 100         $self->lock_release($wake) if $self->{creat};
 101         undef;
 102 }
 103
 104 sub load_xapian_writable () {
 105         return 1 if $X->{WritableDatabase};
 106         PublicInbox::Search::load_xapian() or die "failed to load Xapian: $@\n";
 107         my $xap = $PublicInbox::Search::Xap;
 108         for (qw(Document TermGenerator WritableDatabase)) {
 109                 $X->{$_} = $xap.'::'.$_;
 110         }
 111         eval 'require '.$X->{WritableDatabase} or die;
 112         *sortable_serialise = $xap.'::sortable_serialise';
 113         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 114         $DB_OPEN = eval($xap.'::DB_OPEN()');
 115         my $ver = (eval($xap.'::major_version()') << 16) |
 116                 (eval($xap.'::minor_version()') << 8) |
 117                 eval($xap.'::revision()');
 118         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 119         # Xapian v1.2.21..v1.2.24 were missing close-on-exec on OFD locks
 120         $X->{CLOEXEC_UNSET} = 1 if $ver >= 0x010215 && $ver <= 0x010218;
 121         1;
 122 }
 123
 124 sub idx_acquire {
 125         my ($self) = @_;
 126         my $flag;
 127         my $dir = $self->xdir;
 128         if (need_xapian($self)) {
 129                 croak 'already acquired' if $self->{xdb};
 130                 load_xapian_writable();
 131                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 132         }
 133         if ($self->{creat}) {
 134                 require File::Path;
 135                 $self->lock_acquire;
 136
 137                 # don't create empty Xapian directories if we don't need Xapian
 138                 my $is_shard = defined($self->{shard});
 139                 if (!-d $dir && (!$is_shard ||
 140                                 ($is_shard && need_xapian($self)))) {
 141                         File::Path::mkpath($dir);
 142                         nodatacow_dir($dir);
 143                         $self->{-set_has_threadid_once} = 1;
 144                 }
 145         }
 146         return unless defined $flag;
 147         $flag |= $DB_NO_SYNC if ($self->{ibx} // $self->{eidx})->{-no_fsync};
 148         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 149         croak "Failed opening $dir: $@" if $@;
 150         $self->{xdb} = $xdb;
 151 }
 152
 153 sub add_val ($$$) {
 154         my ($doc, $col, $num) = @_;
 155         $num = sortable_serialise($num);
 156         $doc->add_value($col, $num);
 157 }
 158
 159 sub term_generator ($) { # write-only
 160         my ($self) = @_;
 161
 162         $self->{term_generator} //= do {
 163                 my $tg = $X->{TermGenerator}->new;
 164                 $tg->set_stemmer(PublicInbox::Search::stemmer($self));
 165                 $tg;
 166         }
 167 }
 168
 169 sub index_phrase ($$$$) {
 170         my ($self, $text, $wdf_inc, $prefix) = @_;
 171
 172         my $tg = term_generator($self);
 173         $tg->index_text($text, $wdf_inc, $prefix);
 174         $tg->increase_termpos;
 175 }
 176
 177 sub index_text ($$$$) {
 178         my ($self, $text, $wdf_inc, $prefix) = @_;
 179
 180         if ($self->{indexlevel} eq 'full') {
 181                 index_phrase($self, $text, $wdf_inc, $prefix);
 182         } else {
 183                 my $tg = term_generator($self);
 184                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 185         }
 186 }
 187
 188 sub index_headers ($$) {
 189         my ($self, $smsg) = @_;
 190         my @x = (from => 'A', to => 'XTO', cc => 'XCC'); # A: Author
 191         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 192                 my $val = $smsg->{$field};
 193                 next if $val eq '';
 194                 # include "(comments)" after the address, too, so not using
 195                 # PublicInbox::Address::names or pairs
 196                 index_text($self, $val, 1, $pfx);
 197
 198                 # we need positional info for email addresses since they
 199                 # can be considered phrases
 200                 if ($self->{indexlevel} eq 'medium') {
 201                         for my $addr (PublicInbox::Address::emails($val)) {
 202                                 index_phrase($self, $addr, 1, $pfx);
 203                         }
 204                 }
 205         }
 206         @x = (subject => 'S');
 207         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 208                 my $val = $smsg->{$field};
 209                 index_text($self, $val, 1, $pfx) if $val ne '';
 210         }
 211 }
 212
 213 sub index_diff_inc ($$$$) {
 214         my ($self, $text, $pfx, $xnq) = @_;
 215         if (@$xnq) {
 216                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 217                 @$xnq = ();
 218         }
 219         if ($pfx eq 'XDFN') {
 220                 index_phrase($self, $text, 1, $pfx);
 221         } else {
 222                 index_text($self, $text, 1, $pfx);
 223         }
 224 }
 225
 226 sub index_old_diff_fn {
 227         my ($self, $seen, $fa, $fb, $xnq) = @_;
 228
 229         # no renames or space support for traditional diffs,
 230         # find the number of leading common paths to strip:
 231         my @fa = split('/', $fa);
 232         my @fb = split('/', $fb);
 233         while (scalar(@fa) && scalar(@fb)) {
 234                 $fa = join('/', @fa);
 235                 $fb = join('/', @fb);
 236                 if ($fa eq $fb) {
 237                         unless ($seen->{$fa}++) {
 238                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 239                         }
 240                         return 1;
 241                 }
 242                 shift @fa;
 243                 shift @fb;
 244         }
 245         0;
 246 }
 247
 248 sub index_diff ($$$) {
 249         my ($self, $txt, $doc) = @_;
 250         my %seen;
 251         my $in_diff;
 252         my @xnq;
 253         my $xnq = \@xnq;
 254         foreach (split(/\n/, $txt)) {
 255                 if ($in_diff && s/^ //) { # diff context
 256                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 257                 } elsif (/^-- $/) { # email signature begins
 258                         $in_diff = undef;
 259                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 260                         # wait until "---" and "+++" to capture filenames
 261                         $in_diff = 1;
 262                         push @xnq, $_;
 263                 # traditional diff:
 264                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 265                         my ($opt, $fa, $fb) = ($1, $2, $3);
 266                         push @xnq, $_;
 267                         # only support unified:
 268                         next unless $opt =~ /[uU]/;
 269                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 270                                                         $xnq);
 271                 } elsif (m!^--- ("?[^/]+/.+)!) {
 272                         my $fn = $1;
 273                         $fn = (split('/', git_unquote($fn), 2))[1];
 274                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 275                         $in_diff = 1;
 276                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 277                         my $fn = $1;
 278                         $fn = (split('/', git_unquote($fn), 2))[1];
 279                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 280                         $in_diff = 1;
 281                 } elsif (/^--- (\S+)/) {
 282                         $in_diff = $1;
 283                         push @xnq, $_;
 284                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 285                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 286                                                         $1, $xnq);
 287                 } elsif ($in_diff && s/^\+//) { # diff added
 288                         index_diff_inc($self, $_, 'XDFB', $xnq);
 289                 } elsif ($in_diff && s/^-//) { # diff removed
 290                         index_diff_inc($self, $_, 'XDFA', $xnq);
 291                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 292                         my ($ba, $bb) = ($1, $2);
 293                         index_git_blob_id($doc, 'XDFPRE', $ba);
 294                         index_git_blob_id($doc, 'XDFPOST', $bb);
 295                         $in_diff = 1;
 296                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 297                         # traditional diff w/o -p
 298                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 299                         # hunk header context
 300                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 301                 # ignore the following lines:
 302                 } elsif (/^(?:dis)similarity index/ ||
 303                                 /^(?:old|new) mode/ ||
 304                                 /^(?:deleted|new) file mode/ ||
 305                                 /^(?:copy|rename) (?:from|to) / ||
 306                                 /^(?:dis)?similarity index / ||
 307                                 /^\\ No newline at end of file/ ||
 308                                 /^Binary files .* differ/) {
 309                         push @xnq, $_;
 310                 } elsif ($_ eq '') {
 311                         # possible to be in diff context, some mail may be
 312                         # stripped by MUA or even GNU diff(1).  "git apply"
 313                         # treats a bare "\n" as diff context, too
 314                 } else {
 315                         push @xnq, $_;
 316                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 317                         $in_diff = undef;
 318                 }
 319         }
 320
 321         index_text($self, join("\n", @xnq), 1, 'XNQ');
 322 }
 323
 324 sub index_xapian { # msg_iter callback
 325         my $part = $_[0]->[0]; # ignore $depth and $idx
 326         my ($self, $doc) = @{$_[1]};
 327         my $ct = $part->content_type || 'text/plain';
 328         my $fn = $part->filename;
 329         if (defined $fn && $fn ne '') {
 330                 index_phrase($self, $fn, 1, 'XFN');
 331         }
 332         if ($part->{is_submsg}) {
 333                 my $mids = mids_for_index($part);
 334                 index_ids($self, $doc, $part, $mids);
 335                 my $smsg = bless {}, 'PublicInbox::Smsg';
 336                 $smsg->populate($part);
 337                 index_headers($self, $smsg);
 338         }
 339
 340         my ($s, undef) = msg_part_text($part, $ct);
 341         defined $s or return;
 342         $_[0]->[0] = $part = undef; # free memory
 343
 344         # split off quoted and unquoted blocks:
 345         my @sections = PublicInbox::MsgIter::split_quotes($s);
 346         undef $s; # free memory
 347         for my $txt (@sections) {
 348                 if ($txt =~ /\A>/) {
 349                         index_text($self, $txt, 0, 'XQUOT');
 350                 } else {
 351                         # does it look like a diff?
 352                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 353                                 index_diff($self, $txt, $doc);
 354                         } else {
 355                                 index_text($self, $txt, 1, 'XNQ');
 356                         }
 357                 }
 358                 undef $txt; # free memory
 359         }
 360 }
 361
 362 sub index_list_id ($$$) {
 363         my ($self, $doc, $hdr) = @_;
 364         for my $l ($hdr->header_raw('List-Id')) {
 365                 $l =~ /<([^>]+)>/ or next;
 366                 my $lid = lc $1;
 367                 $doc->add_boolean_term('G' . $lid);
 368                 index_phrase($self, $lid, 1, 'XL'); # probabilistic
 369         }
 370 }
 371
 372 sub index_ids ($$$$) {
 373         my ($self, $doc, $hdr, $mids) = @_;
 374         for my $mid (@$mids) {
 375                 index_phrase($self, $mid, 1, 'XM');
 376
 377                 # because too many Message-IDs are prefixed with
 378                 # "Pine.LNX."...
 379                 if ($mid =~ /\w{12,}/) {
 380                         my @long = ($mid =~ /(\w{3,}+)/g);
 381                         index_phrase($self, join(' ', @long), 1, 'XM');
 382                 }
 383         }
 384         $doc->add_boolean_term('Q' . $_) for @$mids;
 385         index_list_id($self, $doc, $hdr);
 386 }
 387
 388 sub eml2doc ($$$;$) {
 389         my ($self, $eml, $smsg, $mids) = @_;
 390         $mids //= mids_for_index($eml);
 391         my $doc = $X->{Document}->new;
 392         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 393         my @ds = gmtime($smsg->{ds});
 394         my $yyyymmdd = strftime('%Y%m%d', @ds);
 395         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 396         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 397         add_val($doc, PublicInbox::Search::DT(), $dt);
 398         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 399         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 400         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 401
 402         my $tg = term_generator($self);
 403         $tg->set_document($doc);
 404         index_headers($self, $smsg);
 405
 406         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 407                 $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 408         }
 409         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 410         index_ids($self, $doc, $eml, $mids);
 411
 412         # by default, we maintain compatibility with v1.5.0 and earlier
 413         # by writing to docdata.glass, users who never exect to downgrade can
 414         # use --skip-docdata
 415         if (!$self->{-skip_docdata}) {
 416                 # WWW doesn't need {to} or {cc}, only NNTP
 417                 $smsg->{to} = $smsg->{cc} = '';
 418                 $smsg->parse_references($eml, $mids);
 419                 my $data = $smsg->to_doc_data;
 420                 $doc->set_data($data);
 421         }
 422
 423         if (my $altid = $self->{-altid}) {
 424                 foreach my $alt (@$altid) {
 425                         my $pfx = $alt->{xprefix};
 426                         foreach my $mid (@$mids) {
 427                                 my $id = $alt->mid2alt($mid);
 428                                 next unless defined $id;
 429                                 $doc->add_boolean_term($pfx . $id);
 430                         }
 431                 }
 432         }
 433         $doc;
 434 }
 435
 436 sub add_xapian ($$$$) {
 437         my ($self, $eml, $smsg, $mids) = @_;
 438         begin_txn_lazy($self);
 439         my $merge_vmd = delete $smsg->{-merge_vmd};
 440         my $doc = eml2doc($self, $eml, $smsg, $mids);
 441         if (my $old = $merge_vmd ? _get_doc($self, $smsg->{num}) : undef) {
 442                 my @x = @VMD_MAP;
 443                 while (my ($field, $pfx) = splice(@x, 0, 2)) {
 444                         for my $term (xap_terms($pfx, $old)) {
 445                                 $doc->add_boolean_term($pfx.$term);
 446                         }
 447                 }
 448         }
 449         $self->{xdb}->replace_document($smsg->{num}, $doc);
 450 }
 451
 452 sub _msgmap_init ($) {
 453         my ($self) = @_;
 454         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx}->version != 1;
 455         $self->{mm} //= do {
 456                 require PublicInbox::Msgmap;
 457                 PublicInbox::Msgmap->new_file($self->{ibx}, 1);
 458         };
 459 }
 460
 461 sub add_message {
 462         # mime = PublicInbox::Eml or Email::MIME object
 463         my ($self, $mime, $smsg, $sync) = @_;
 464         begin_txn_lazy($self);
 465         my $mids = mids_for_index($mime);
 466         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 467         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 468         $smsg->{num} //= do { # v1
 469                 _msgmap_init($self);
 470                 index_mm($self, $mime, $smsg->{blob}, $sync);
 471         };
 472
 473         # v1 and tests only:
 474         $smsg->populate($mime, $sync);
 475         $smsg->{bytes} //= length($mime->as_string);
 476
 477         eval {
 478                 # order matters, overview stores every possible piece of
 479                 # data in doc_data (deflated).  Xapian only stores a subset
 480                 # of the fields which exist in over.sqlite3.  We may stop
 481                 # storing doc_data in Xapian sometime after we get multi-inbox
 482                 # search working.
 483                 if (my $oidx = $self->{oidx}) { # v1 only
 484                         $oidx->add_overview($mime, $smsg);
 485                 }
 486                 if (need_xapian($self)) {
 487                         add_xapian($self, $mime, $smsg, $mids);
 488                 }
 489         };
 490
 491         if ($@) {
 492                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 493                 return undef;
 494         }
 495         $smsg->{num};
 496 }
 497
 498 sub _get_doc ($$) {
 499         my ($self, $docid) = @_;
 500         my $doc = eval { $self->{xdb}->get_document($docid) };
 501         $doc // do {
 502                 warn "E: $@\n" if $@;
 503                 warn "E: #$docid missing in Xapian\n";
 504                 undef;
 505         }
 506 }
 507
 508 sub add_eidx_info {
 509         my ($self, $docid, $eidx_key, $eml) = @_;
 510         begin_txn_lazy($self);
 511         my $doc = _get_doc($self, $docid) or return;
 512         term_generator($self)->set_document($doc);
 513
 514         # '.' is special for lei_store
 515         $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 516
 517         index_list_id($self, $doc, $eml);
 518         $self->{xdb}->replace_document($docid, $doc);
 519 }
 520
 521 sub get_terms {
 522         my ($self, $pfx, $docid) = @_;
 523         begin_txn_lazy($self);
 524         xap_terms($pfx, $self->{xdb}, $docid);
 525 }
 526
 527 sub remove_eidx_info {
 528         my ($self, $docid, $eidx_key, $eml) = @_;
 529         begin_txn_lazy($self);
 530         my $doc = _get_doc($self, $docid) or return;
 531         eval { $doc->remove_term('O'.$eidx_key) };
 532         warn "W: ->remove_term O$eidx_key: $@\n" if $@;
 533         for my $l ($eml ? $eml->header_raw('List-Id') : ()) {
 534                 $l =~ /<([^>]+)>/ or next;
 535                 my $lid = lc $1;
 536                 eval { $doc->remove_term('G' . $lid) };
 537                 warn "W: ->remove_term G$lid: $@\n" if $@;
 538
 539                 # nb: we don't remove the XL probabilistic terms
 540                 # since terms may overlap if cross-posted.
 541                 #
 542                 # IOW, a message which has both <foo.example.com>
 543                 # and <bar.example.com> would have overlapping
 544                 # "XLexample" and "XLcom" as terms and which we
 545                 # wouldn't know if they're safe to remove if we just
 546                 # unindex <foo.example.com> while preserving
 547                 # <bar.example.com>.
 548                 #
 549                 # In any case, this entire sub is will likely never
 550                 # be needed and users using the "l:" prefix are probably
 551                 # rarer.
 552         }
 553         $self->{xdb}->replace_document($docid, $doc);
 554 }
 555
 556 sub set_vmd {
 557         my ($self, $docid, $vmd) = @_;
 558         begin_txn_lazy($self);
 559         my $doc = _get_doc($self, $docid) or return;
 560         my ($end, @rm, @add);
 561         my @x = @VMD_MAP;
 562         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 563                 my $set = $vmd->{$field} // next;
 564                 my %keep = map { $_ => 1 } @$set;
 565                 my %add = %keep;
 566                 $end //= $doc->termlist_end;
 567                 for (my $cur = $doc->termlist_begin; $cur != $end; $cur++) {
 568                         $cur->skip_to($pfx);
 569                         last if $cur == $end;
 570                         my $v = $cur->get_termname;
 571                         $v =~ s/\A$pfx//s or next;
 572                         $keep{$v} ? delete($add{$v}) : push(@rm, $pfx.$v);
 573                 }
 574                 push(@add, map { $pfx.$_ } keys %add);
 575         }
 576         return unless scalar(@rm) || scalar(@add);
 577         $doc->remove_term($_) for @rm;
 578         $doc->add_boolean_term($_) for @add;
 579         $self->{xdb}->replace_document($docid, $doc);
 580 }
 581
 582 sub apply_vmd_mod ($$) {
 583         my ($doc, $vmd_mod) = @_;
 584         my $updated = 0;
 585         my @x = @VMD_MAP;
 586         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 587                 # field: "L" or "kw"
 588                 for my $val (@{$vmd_mod->{"-$field"} // []}) {
 589                         eval {
 590                                 $doc->remove_term($pfx . $val);
 591                                 ++$updated;
 592                         };
 593                 }
 594                 for my $val (@{$vmd_mod->{"+$field"} // []}) {
 595                         $doc->add_boolean_term($pfx . $val);
 596                         ++$updated;
 597                 }
 598         }
 599         $updated;
 600 }
 601
 602 sub add_vmd {
 603         my ($self, $docid, $vmd) = @_;
 604         begin_txn_lazy($self);
 605         my $doc = _get_doc($self, $docid) or return;
 606         my @x = @VMD_MAP;
 607         my $updated = 0;
 608         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 609                 my $add = $vmd->{$field} // next;
 610                 $doc->add_boolean_term($pfx . $_) for @$add;
 611                 $updated += scalar(@$add);
 612         }
 613         $updated += apply_vmd_mod($doc, $vmd);
 614         $self->{xdb}->replace_document($docid, $doc) if $updated;
 615 }
 616
 617 sub remove_vmd {
 618         my ($self, $docid, $vmd) = @_;
 619         begin_txn_lazy($self);
 620         my $doc = _get_doc($self, $docid) or return;
 621         my $replace;
 622         my @x = @VMD_MAP;
 623         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 624                 my $rm = $vmd->{$field} // next;
 625                 for (@$rm) {
 626                         eval {
 627                                 $doc->remove_term($pfx . $_);
 628                                 $replace = 1;
 629                         };
 630                 }
 631         }
 632         $self->{xdb}->replace_document($docid, $doc) if $replace;
 633 }
 634
 635 sub update_vmd {
 636         my ($self, $docid, $vmd_mod) = @_;
 637         begin_txn_lazy($self);
 638         my $doc = _get_doc($self, $docid) or return;
 639         my $updated = apply_vmd_mod($doc, $vmd_mod);
 640         $self->{xdb}->replace_document($docid, $doc) if $updated;
 641         $updated;
 642 }
 643
 644 sub xdb_remove {
 645         my ($self, @docids) = @_;
 646         begin_txn_lazy($self);
 647         my $xdb = $self->{xdb} // die 'BUG: missing {xdb}';
 648         for my $docid (@docids) {
 649                 eval { $xdb->delete_document($docid) };
 650                 warn "E: #$docid not in in Xapian? $@\n" if $@;
 651         }
 652 }
 653
 654 sub xdb_remove_quiet {
 655         my ($self, $docid) = @_;
 656         begin_txn_lazy($self);
 657         my $xdb = $self->{xdb} // die 'BUG: missing {xdb}';
 658         eval { $xdb->delete_document($docid) };
 659         ++$self->{-quiet_rm} unless $@;
 660 }
 661
 662 sub nr_quiet_rm { delete($_[0]->{-quiet_rm}) // 0 }
 663
 664 sub index_git_blob_id {
 665         my ($doc, $pfx, $objid) = @_;
 666
 667         my $len = length($objid);
 668         for (my $len = length($objid); $len >= 7; ) {
 669                 $doc->add_term($pfx.$objid);
 670                 $objid = substr($objid, 0, --$len);
 671         }
 672 }
 673
 674 # v1 only
 675 sub unindex_eml {
 676         my ($self, $oid, $eml) = @_;
 677         my $mids = mids($eml);
 678         my $nr = 0;
 679         my %tmp;
 680         for my $mid (@$mids) {
 681                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 682                 $nr += scalar @removed;
 683                 $tmp{$_}++ for @removed;
 684         }
 685         if (!$nr) {
 686                 my $m = join('> <', @$mids);
 687                 warn "W: <$m> missing for removal from overview\n";
 688         }
 689         while (my ($num, $nr) = each %tmp) {
 690                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 691         }
 692         if ($nr) {
 693                 $self->{mm}->num_delete($_) for (keys %tmp);
 694         } else { # just in case msgmap and over.sqlite3 become desynched:
 695                 $self->{mm}->mid_delete($mids->[0]);
 696         }
 697         xdb_remove($self, keys %tmp) if need_xapian($self);
 698 }
 699
 700 sub index_mm {
 701         my ($self, $mime, $oid, $sync) = @_;
 702         my $mids = mids($mime);
 703         my $mm = $self->{mm};
 704         if ($sync->{reindex}) {
 705                 my $oidx = $self->{oidx};
 706                 for my $mid (@$mids) {
 707                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 708                         return $num if defined $num;
 709                 }
 710                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 711         } else {
 712                 # fallback to num_for since filters like RubyLang set the number
 713                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 714         }
 715 }
 716
 717 sub is_bad_blob ($$$$) {
 718         my ($oid, $type, $size, $expect_oid) = @_;
 719         if ($type ne 'blob') {
 720                 carp "W: $expect_oid is not a blob (type=$type)";
 721                 return 1;
 722         }
 723         croak "BUG: $oid != $expect_oid" if $oid ne $expect_oid;
 724         $size == 0 ? 1 : 0; # size == 0 means purged
 725 }
 726
 727 sub index_both { # git->cat_async callback
 728         my ($bref, $oid, $type, $size, $sync) = @_;
 729         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 730         my ($nr, $max) = @$sync{qw(nr max)};
 731         ++$$nr;
 732         $$max -= $size;
 733         my $smsg = bless { blob => $oid }, 'PublicInbox::Smsg';
 734         $smsg->set_bytes($$bref, $size);
 735         my $self = $sync->{sidx};
 736         local $self->{current_info} = "$self->{current_info}: $oid";
 737         my $eml = PublicInbox::Eml->new($bref);
 738         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 739                 die "E: could not generate NNTP article number for $oid";
 740         add_message($self, $eml, $smsg, $sync);
 741         ++$self->{nidx};
 742         my $cur_cmt = $sync->{cur_cmt} // die 'BUG: {cur_cmt} missing';
 743         ${$sync->{latest_cmt}} = $cur_cmt;
 744 }
 745
 746 sub unindex_both { # git->cat_async callback
 747         my ($bref, $oid, $type, $size, $sync) = @_;
 748         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 749         my $self = $sync->{sidx};
 750         local $self->{current_info} = "$self->{current_info}: $oid";
 751         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 752         # may be undef if leftover
 753         if (defined(my $cur_cmt = $sync->{cur_cmt})) {
 754                 ${$sync->{latest_cmt}} = $cur_cmt;
 755         }
 756         ++$self->{nidx};
 757 }
 758
 759 sub with_umask {
 760         my $self = shift;
 761         ($self->{ibx} // $self->{eidx})->with_umask(@_);
 762 }
 763
 764 # called by public-inbox-index
 765 sub index_sync {
 766         my ($self, $opt) = @_;
 767         delete $self->{lock_path} if $opt->{-skip_lock};
 768         $self->with_umask(\&_index_sync, $self, $opt);
 769         if ($opt->{reindex} && !$opt->{quit} &&
 770                         !grep(defined, @$opt{qw(since until)})) {
 771                 my %again = %$opt;
 772                 delete @again{qw(rethread reindex)};
 773                 index_sync($self, \%again);
 774                 $opt->{quit} = $again{quit}; # propagate to caller
 775         }
 776 }
 777
 778 sub check_size { # check_async cb for -index --max-size=...
 779         my ($oid, $type, $size, $arg, $git) = @_;
 780         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 781         if ($size <= $arg->{max_size}) {
 782                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 783         } else {
 784                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 785         }
 786 }
 787
 788 sub v1_checkpoint ($$;$) {
 789         my ($self, $sync, $stk) = @_;
 790         $self->{ibx}->git->async_wait_all;
 791
 792         # $newest may be undef
 793         my $newest = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 794         if (defined($newest)) {
 795                 my $cur = $self->{mm}->last_commit;
 796                 if (need_update($self, $sync, $cur, $newest)) {
 797                         $self->{mm}->last_commit($newest);
 798                 }
 799         }
 800         ${$sync->{max}} = $self->{batch_bytes};
 801
 802         $self->{mm}->{dbh}->commit;
 803         eval { $self->{mm}->{dbh}->do('PRAGMA optimize') };
 804         my $xdb = $self->{xdb};
 805         if ($newest && $xdb) {
 806                 my $cur = $xdb->get_metadata('last_commit');
 807                 if (need_update($self, $sync, $cur, $newest)) {
 808                         $xdb->set_metadata('last_commit', $newest);
 809                 }
 810         }
 811         if ($stk) { # all done if $stk is passed
 812                 # let SearchView know a full --reindex was done so it can
 813                 # generate ->has_threadid-dependent links
 814                 if ($xdb && $sync->{reindex} && !ref($sync->{reindex})) {
 815                         my $n = $xdb->get_metadata('has_threadid');
 816                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 817                 }
 818                 $self->{oidx}->rethread_done($sync->{-opt}); # all done
 819         }
 820         commit_txn_lazy($self);
 821         $sync->{ibx}->git->cleanup;
 822         my $nr = ${$sync->{nr}};
 823         idx_release($self, $nr);
 824         # let another process do some work...
 825         if (my $pr = $sync->{-opt}->{-progress}) {
 826                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 827         }
 828         if (!$stk && !$sync->{quit}) { # more to come
 829                 begin_txn_lazy($self);
 830                 $self->{mm}->{dbh}->begin_work;
 831         }
 832 }
 833
 834 # only for v1
 835 sub process_stack {
 836         my ($self, $sync, $stk) = @_;
 837         my $git = $sync->{ibx}->git;
 838         my $max = $self->{batch_bytes};
 839         my $nr = 0;
 840         $sync->{nr} = \$nr;
 841         $sync->{max} = \$max;
 842         $sync->{sidx} = $self;
 843         $sync->{latest_cmt} = \(my $latest_cmt);
 844
 845         $self->{mm}->{dbh}->begin_work;
 846         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 847                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 848                 for my $oid (@leftovers) {
 849                         last if $sync->{quit};
 850                         $oid = unpack('H*', $oid);
 851                         $git->cat_async($oid, \&unindex_both, $sync);
 852                 }
 853         }
 854         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 855                 $sync->{index_oid} = \&index_both;
 856         }
 857         while (my ($f, $at, $ct, $oid, $cur_cmt) = $stk->pop_rec) {
 858                 my $arg = { %$sync, cur_cmt => $cur_cmt, oid => $oid };
 859                 last if $sync->{quit};
 860                 if ($f eq 'm') {
 861                         $arg->{autime} = $at;
 862                         $arg->{cotime} = $ct;
 863                         if ($sync->{max_size}) {
 864                                 $git->check_async($oid, \&check_size, $arg);
 865                         } else {
 866                                 $git->cat_async($oid, \&index_both, $arg);
 867                         }
 868                         v1_checkpoint($self, $sync) if $max <= 0;
 869                 } elsif ($f eq 'd') {
 870                         $git->cat_async($oid, \&unindex_both, $arg);
 871                 }
 872         }
 873         v1_checkpoint($self, $sync, $sync->{quit} ? undef : $stk);
 874 }
 875
 876 sub log2stack ($$$) {
 877         my ($sync, $git, $range) = @_;
 878         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 879         my ($add, $del);
 880         if ($sync->{ibx}->version == 1) {
 881                 my $path = $hex.'{2}/'.$hex.'{38}';
 882                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 883                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 884         } else {
 885                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 886                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 887         }
 888
 889         # Count the new files so they can be added newest to oldest
 890         # and still have numbers increasing from oldest to newest
 891         my @cmd = qw(log --raw -r --pretty=tformat:%at-%ct-%H
 892                         --no-notes --no-color --no-renames --no-abbrev);
 893         for my $k (qw(since until)) {
 894                 my $v = $sync->{-opt}->{$k} // next;
 895                 next if !$sync->{-opt}->{reindex};
 896                 push @cmd, "--$k=$v";
 897         }
 898         my $fh = $git->popen(@cmd, $range);
 899         my ($at, $ct, $stk, $cmt);
 900         while (<$fh>) {
 901                 return if $sync->{quit};
 902                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 903                         ($at, $ct, $cmt) = ($1 + 0, $2 + 0, $3);
 904                         $stk //= PublicInbox::IdxStack->new($cmt);
 905                 } elsif (/$del/) {
 906                         my $oid = $1;
 907                         if ($D) { # reindex case
 908                                 $D->{pack('H*', $oid)}++;
 909                         } else { # non-reindex case:
 910                                 $stk->push_rec('d', $at, $ct, $oid, $cmt);
 911                         }
 912                 } elsif (/$add/) {
 913                         my $oid = $1;
 914                         if ($D) {
 915                                 my $oid_bin = pack('H*', $oid);
 916                                 my $nr = --$D->{$oid_bin};
 917                                 delete($D->{$oid_bin}) if $nr <= 0;
 918                                 # nr < 0 (-1) means it never existed
 919                                 next if $nr >= 0;
 920                         }
 921                         $stk->push_rec('m', $at, $ct, $oid, $cmt);
 922                 }
 923         }
 924         close $fh or die "git log failed: \$?=$?";
 925         $stk //= PublicInbox::IdxStack->new;
 926         $stk->read_prepare;
 927 }
 928
 929 sub prepare_stack ($$) {
 930         my ($sync, $range) = @_;
 931         my $git = $sync->{ibx}->git;
 932
 933         if (index($range, '..') < 0) {
 934                 # don't show annoying git errors to users who run -index
 935                 # on empty inboxes
 936                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 937                 return PublicInbox::IdxStack->new->read_prepare if $?;
 938         }
 939         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 940         log2stack($sync, $git, $range);
 941 }
 942
 943 # --is-ancestor requires git 1.8.0+
 944 sub is_ancestor ($$$) {
 945         my ($git, $cur, $tip) = @_;
 946         return 0 unless $git->check($cur);
 947         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 948                 qw(merge-base --is-ancestor), $cur, $tip ];
 949         my $pid = spawn($cmd);
 950         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 951         $? == 0;
 952 }
 953
 954 sub need_update ($$$$) {
 955         my ($self, $sync, $cur, $new) = @_;
 956         my $git = $self->{ibx}->git;
 957         $cur //= ''; # XS Search::Xapian ->get_metadata doesn't give undef
 958
 959         # don't rewind if --{since,until,before,after} are in use
 960         return if $cur ne '' &&
 961                 grep(defined, @{$sync->{-opt}}{qw(since until)}) &&
 962                 is_ancestor($git, $new, $cur);
 963
 964         return 1 if $cur ne '' && !is_ancestor($git, $cur, $new);
 965         my $range = $cur eq '' ? $new : "$cur..$new";
 966         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 967         ($n eq '' || $n > 0);
 968 }
 969
 970 # The last git commit we indexed with Xapian or SQLite (msgmap)
 971 # This needs to account for cases where Xapian or SQLite is
 972 # out-of-date with respect to the other.
 973 sub _last_x_commit {
 974         my ($self, $mm) = @_;
 975         my $lm = $mm->last_commit || '';
 976         my $lx = '';
 977         if (need_xapian($self)) {
 978                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 979         } else {
 980                 $lx = $lm;
 981         }
 982         # Use last_commit from msgmap if it is older or unset
 983         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 984                 $lx = $lm;
 985         }
 986         $lx;
 987 }
 988
 989 sub reindex_from ($$) {
 990         my ($reindex, $last_commit) = @_;
 991         return $last_commit unless $reindex;
 992         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 993 }
 994
 995 sub quit_cb ($) {
 996         my ($sync) = @_;
 997         sub {
 998                 # we set {-opt}->{quit} too, so ->index_sync callers
 999                 # can abort multi-inbox loops this way
1000                 $sync->{quit} = $sync->{-opt}->{quit} = 1;
1001                 warn "gracefully quitting\n";
1002         }
1003 }
1004
1005 # indexes all unindexed messages (v1 only)
1006 sub _index_sync {
1007         my ($self, $opt) = @_;
1008         my $tip = $opt->{ref} || 'HEAD';
1009         my $ibx = $self->{ibx};
1010         local $self->{current_info} = "$ibx->{inboxdir}";
1011         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
1012         $ibx->git->batch_prepare;
1013         my $pr = $opt->{-progress};
1014         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
1015         my $quit = quit_cb($sync);
1016         local $SIG{QUIT} = $quit;
1017         local $SIG{INT} = $quit;
1018         local $SIG{TERM} = $quit;
1019         my $xdb = $self->begin_txn_lazy;
1020         $self->{oidx}->rethread_prepare($opt);
1021         my $mm = _msgmap_init($self);
1022         if ($sync->{reindex}) {
1023                 my $last = $mm->last_commit;
1024                 if ($last) {
1025                         $tip = $last;
1026                 } else {
1027                         # somebody just blindly added --reindex when indexing
1028                         # for the first time, allow it:
1029                         undef $sync->{reindex};
1030                 }
1031         }
1032         my $last_commit = _last_x_commit($self, $mm);
1033         my $lx = reindex_from($sync->{reindex}, $last_commit);
1034         my $range = $lx eq '' ? $tip : "$lx..$tip";
1035         $pr->("counting changes\n\t$range ... ") if $pr;
1036         my $stk = prepare_stack($sync, $range);
1037         $sync->{ntodo} = $stk ? $stk->num_records : 0;
1038         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
1039         process_stack($self, $sync, $stk) if !$sync->{quit};
1040 }
1041
1042 sub DESTROY {
1043         # order matters for unlocking
1044         $_[0]->{xdb} = undef;
1045         $_[0]->{lockfh} = undef;
1046 }
1047
1048 sub _begin_txn {
1049         my ($self) = @_;
1050         my $xdb = $self->{xdb} || idx_acquire($self);
1051         $self->{oidx}->begin_lazy if $self->{oidx};
1052         $xdb->begin_transaction if $xdb;
1053         $self->{txn} = 1;
1054         $xdb;
1055 }
1056
1057 sub begin_txn_lazy {
1058         my ($self) = @_;
1059         $self->with_umask(\&_begin_txn, $self) if !$self->{txn};
1060 }
1061
1062 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
1063 # This metadata is read by Admin::detect_indexlevel:
1064 sub set_metadata_once {
1065         my ($self) = @_;
1066
1067         return if $self->{shard}; # only continue if undef or 0, not >0
1068         my $xdb = $self->{xdb};
1069
1070         if (delete($self->{-set_has_threadid_once})) {
1071                 $xdb->set_metadata('has_threadid', '1');
1072         }
1073         if (delete($self->{-set_indexlevel_once})) {
1074                 my $level = $xdb->get_metadata('indexlevel');
1075                 if (!$level || $level ne 'medium') {
1076                         $xdb->set_metadata('indexlevel', 'medium');
1077                 }
1078         }
1079         if (delete($self->{-set_skip_docdata_once})) {
1080                 $xdb->get_metadata('skip_docdata') or
1081                         $xdb->set_metadata('skip_docdata', '1');
1082         }
1083 }
1084
1085 sub _commit_txn {
1086         my ($self) = @_;
1087         if (my $eidx = $self->{eidx}) {
1088                 $eidx->git->async_wait_all;
1089                 $eidx->{transact_bytes} = 0;
1090         }
1091         if (my $xdb = $self->{xdb}) {
1092                 set_metadata_once($self);
1093                 $xdb->commit_transaction;
1094         }
1095         $self->{oidx}->commit_lazy if $self->{oidx};
1096 }
1097
1098 sub commit_txn_lazy {
1099         my ($self) = @_;
1100         delete($self->{txn}) and
1101                 $self->with_umask(\&_commit_txn, $self);
1102 }
1103
1104 sub eidx_shard_new {
1105         my ($class, $eidx, $shard) = @_;
1106         my $self = bless {
1107                 eidx => $eidx,
1108                 xpfx => $eidx->{xpfx},
1109                 indexlevel => $eidx->{indexlevel},
1110                 -skip_docdata => 1,
1111                 shard => $shard,
1112                 creat => 1,
1113         }, $class;
1114         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
1115         $self;
1116 }
1117
1118 1;