lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids references/;
  15 use PublicInbox::MsgIter;
  16 use Carp qw(croak);
  17 use POSIX qw(strftime);
  18 require PublicInbox::Git;
  19
  20 use constant {
  21         PERM_UMASK => 0,
  22         OLD_PERM_GROUP => 1,
  23         OLD_PERM_EVERYBODY => 2,
  24         PERM_GROUP => 0660,
  25         PERM_EVERYBODY => 0664,
  26         BATCH_BYTES => 1_000_000,
  27         DEBUG => !!$ENV{DEBUG},
  28 };
  29
  30 my %GIT_ESC = (
  31         a => "\a",
  32         b => "\b",
  33         f => "\f",
  34         n => "\n",
  35         r => "\r",
  36         t => "\t",
  37         v => "\013",
  38 );
  39
  40 sub git_unquote ($) {
  41         my ($s) = @_;
  42         return $s unless ($s =~ /\A"(.*)"\z/);
  43         $s = $1;
  44         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  45         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  46         $s;
  47 }
  48
  49 sub new {
  50         my ($class, $ibx, $creat, $part) = @_;
  51         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  52         my $git_dir = $mainrepo;
  53         my ($altid, $git);
  54         my $version = 1;
  55         if (ref $ibx) {
  56                 $mainrepo = $ibx->{mainrepo};
  57                 $altid = $ibx->{altid};
  58                 $version = $ibx->{version} || 1;
  59                 if ($altid) {
  60                         require PublicInbox::AltId;
  61                         $altid = [ map {
  62                                 PublicInbox::AltId->new($ibx, $_);
  63                         } @$altid ];
  64                 }
  65                 $git = $ibx->git;
  66         } else {
  67                 $git = PublicInbox::Git->new($git_dir); # v1 only
  68         }
  69         require Search::Xapian::WritableDatabase;
  70         my $self = bless {
  71                 mainrepo => $mainrepo,
  72                 git => $git,
  73                 -altid => $altid,
  74                 version => $version,
  75         }, $class;
  76         my $perm = $self->_git_config_perm;
  77         my $umask = _umask_for($perm);
  78         $self->{umask} = $umask;
  79         if ($version == 1) {
  80                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  81         } elsif ($version == 2) {
  82                 defined $part or die "partition is required for v2\n";
  83                 # partition is a number or "all"
  84                 $self->{partition} = $part;
  85                 $self->{lock_path} = undef;
  86                 $self->{msgmap_path} = "$mainrepo/msgmap.sqlite3";
  87         } else {
  88                 die "unsupported inbox version=$version\n";
  89         }
  90         $self->{creat} = ($creat || 0) == 1;
  91         $self;
  92 }
  93
  94 sub _xdb_release {
  95         my ($self) = @_;
  96         my $xdb = delete $self->{xdb} or croak 'not acquired';
  97         $xdb->close;
  98         $self->lock_release if $self->{creat};
  99         undef;
 100 }
 101
 102 sub _xdb_acquire {
 103         my ($self) = @_;
 104         croak 'already acquired' if $self->{xdb};
 105         my $dir = $self->xdir;
 106         my $flag = Search::Xapian::DB_OPEN;
 107         if ($self->{creat}) {
 108                 require File::Path;
 109                 $self->lock_acquire;
 110                 File::Path::mkpath($dir);
 111                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 112         }
 113         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 114 }
 115
 116 sub add_val ($$$) {
 117         my ($doc, $col, $num) = @_;
 118         $num = Search::Xapian::sortable_serialise($num);
 119         $doc->add_value($col, $num);
 120 }
 121
 122 sub add_values ($$) {
 123         my ($doc, $values) = @_;
 124
 125         my $ts = $values->[PublicInbox::Search::TS];
 126         add_val($doc, PublicInbox::Search::TS, $ts);
 127
 128         my $num = $values->[PublicInbox::Search::NUM];
 129         defined($num) and add_val($doc, PublicInbox::Search::NUM, $num);
 130
 131         my $bytes = $values->[PublicInbox::Search::BYTES];
 132         defined($bytes) and add_val($doc, PublicInbox::Search::BYTES, $bytes);
 133
 134         my $lines = $values->[PublicInbox::Search::LINES];
 135         add_val($doc, PublicInbox::Search::LINES, $lines);
 136
 137         my $ds = $values->[PublicInbox::Search::DS];
 138         add_val($doc, PublicInbox::Search::DS, $ds);
 139         my $yyyymmdd = strftime('%Y%m%d', gmtime($ds));
 140         add_val($doc, PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 141 }
 142
 143 sub index_users ($$) {
 144         my ($tg, $smsg) = @_;
 145
 146         my $from = $smsg->from;
 147         my $to = $smsg->to;
 148         my $cc = $smsg->cc;
 149
 150         $tg->index_text($from, 1, 'A'); # A - author
 151         $tg->increase_termpos;
 152         $tg->index_text($to, 1, 'XTO') if $to ne '';
 153         $tg->increase_termpos;
 154         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 155         $tg->increase_termpos;
 156 }
 157
 158 sub index_diff_inc ($$$$) {
 159         my ($tg, $text, $pfx, $xnq) = @_;
 160         if (@$xnq) {
 161                 $tg->index_text(join("\n", @$xnq), 1, 'XNQ');
 162                 $tg->increase_termpos;
 163                 @$xnq = ();
 164         }
 165         $tg->index_text($text, 1, $pfx);
 166         $tg->increase_termpos;
 167 }
 168
 169 sub index_old_diff_fn {
 170         my ($tg, $seen, $fa, $fb, $xnq) = @_;
 171
 172         # no renames or space support for traditional diffs,
 173         # find the number of leading common paths to strip:
 174         my @fa = split('/', $fa);
 175         my @fb = split('/', $fb);
 176         while (scalar(@fa) && scalar(@fb)) {
 177                 $fa = join('/', @fa);
 178                 $fb = join('/', @fb);
 179                 if ($fa eq $fb) {
 180                         unless ($seen->{$fa}++) {
 181                                 index_diff_inc($tg, $fa, 'XDFN', $xnq);
 182                         }
 183                         return 1;
 184                 }
 185                 shift @fa;
 186                 shift @fb;
 187         }
 188         0;
 189 }
 190
 191 sub index_diff ($$$) {
 192         my ($tg, $lines, $doc) = @_;
 193         my %seen;
 194         my $in_diff;
 195         my @xnq;
 196         my $xnq = \@xnq;
 197         foreach (@$lines) {
 198                 if ($in_diff && s/^ //) { # diff context
 199                         index_diff_inc($tg, $_, 'XDFCTX', $xnq);
 200                 } elsif (/^-- $/) { # email signature begins
 201                         $in_diff = undef;
 202                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 203                         my ($fa, $fb) = ($1, $2);
 204                         my $fn = (split('/', git_unquote($fa), 2))[1];
 205                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 206                         $fn = (split('/', git_unquote($fb), 2))[1];
 207                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 208                         $in_diff = 1;
 209                 # traditional diff:
 210                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 211                         my ($opt, $fa, $fb) = ($1, $2, $3);
 212                         push @xnq, $_;
 213                         # only support unified:
 214                         next unless $opt =~ /[uU]/;
 215                         $in_diff = index_old_diff_fn($tg, \%seen, $fa, $fb,
 216                                                         $xnq);
 217                 } elsif (m!^--- ("?a/.+)!) {
 218                         my $fn = (split('/', git_unquote($1), 2))[1];
 219                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 220                         $in_diff = 1;
 221                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 222                         my $fn = (split('/', git_unquote($1), 2))[1];
 223                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 224                         $in_diff = 1;
 225                 } elsif (/^--- (\S+)/) {
 226                         $in_diff = $1;
 227                         push @xnq, $_;
 228                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 229                         $in_diff = index_old_diff_fn($tg, \%seen, $in_diff, $1,
 230                                                         $xnq);
 231                 } elsif ($in_diff && s/^\+//) { # diff added
 232                         index_diff_inc($tg, $_, 'XDFB', $xnq);
 233                 } elsif ($in_diff && s/^-//) { # diff removed
 234                         index_diff_inc($tg, $_, 'XDFA', $xnq);
 235                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 236                         my ($ba, $bb) = ($1, $2);
 237                         index_git_blob_id($doc, 'XDFPRE', $ba);
 238                         index_git_blob_id($doc, 'XDFPOST', $bb);
 239                         $in_diff = 1;
 240                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 241                         # traditional diff w/o -p
 242                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 243                         # hunk header context
 244                         index_diff_inc($tg, $1, 'XDFHH', $xnq);
 245                 # ignore the following lines:
 246                 } elsif (/^(?:dis)similarity index/ ||
 247                                 /^(?:old|new) mode/ ||
 248                                 /^(?:deleted|new) file mode/ ||
 249                                 /^(?:copy|rename) (?:from|to) / ||
 250                                 /^(?:dis)?similarity index / ||
 251                                 /^\\ No newline at end of file/ ||
 252                                 /^Binary files .* differ/) {
 253                         push @xnq, $_;
 254                 } elsif ($_ eq '') {
 255                         $in_diff = undef;
 256                 } else {
 257                         push @xnq, $_;
 258                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 259                         $in_diff = undef;
 260                 }
 261         }
 262
 263         $tg->index_text(join("\n", @xnq), 1, 'XNQ');
 264         $tg->increase_termpos;
 265 }
 266
 267 sub index_body ($$$) {
 268         my ($tg, $lines, $doc) = @_;
 269         my $txt = join("\n", @$lines);
 270         if ($doc) {
 271                 # does it look like a diff?
 272                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 273                         $txt = undef;
 274                         index_diff($tg, $lines, $doc);
 275                 } else {
 276                         $tg->index_text($txt, 1, 'XNQ');
 277                 }
 278         } else {
 279                 $tg->index_text($txt, 0, 'XQUOT');
 280         }
 281         $tg->increase_termpos;
 282         @$lines = ();
 283 }
 284
 285 sub add_message {
 286         # mime = Email::MIME object
 287         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 288         my $doc_id;
 289         my $mids = mids($mime->header_obj);
 290         my $skel = $self->{skeleton};
 291
 292         eval {
 293                 my $smsg = PublicInbox::SearchMsg->new($mime);
 294                 my $doc = $smsg->{doc};
 295                 my $subj = $smsg->subject;
 296                 my $xpath;
 297                 if ($subj ne '') {
 298                         $xpath = $self->subject_path($subj);
 299                         $xpath = id_compress($xpath);
 300                 }
 301
 302                 my $lines = $mime->body_raw =~ tr!\n!\n!;
 303                 my @values = ($smsg->ds, $num, $bytes, $lines, $smsg->ts);
 304                 add_values($doc, \@values);
 305
 306                 my $tg = $self->term_generator;
 307
 308                 $tg->set_document($doc);
 309                 $tg->index_text($subj, 1, 'S') if $subj;
 310                 $tg->increase_termpos;
 311
 312                 index_users($tg, $smsg);
 313
 314                 msg_iter($mime, sub {
 315                         my ($part, $depth, @idx) = @{$_[0]};
 316                         my $ct = $part->content_type || 'text/plain';
 317                         my $fn = $part->filename;
 318                         if (defined $fn && $fn ne '') {
 319                                 $tg->index_text($fn, 1, 'XFN');
 320                         }
 321
 322                         return if $ct =~ m!\btext/x?html\b!i;
 323
 324                         my $s = eval { $part->body_str };
 325                         if ($@) {
 326                                 if ($ct =~ m!\btext/plain\b!i) {
 327                                         # Try to assume UTF-8 because Alpine
 328                                         # seems to do wacky things and set
 329                                         # charset=X-UNKNOWN
 330                                         $part->charset_set('UTF-8');
 331                                         $s = eval { $part->body_str };
 332                                         $s = $part->body if $@;
 333                                 }
 334                         }
 335                         defined $s or return;
 336
 337                         my (@orig, @quot);
 338                         my $body = $part->body;
 339                         my @lines = split(/\n/, $body);
 340                         while (defined(my $l = shift @lines)) {
 341                                 if ($l =~ /^>/) {
 342                                         index_body($tg, \@orig, $doc) if @orig;
 343                                         push @quot, $l;
 344                                 } else {
 345                                         index_body($tg, \@quot, 0) if @quot;
 346                                         push @orig, $l;
 347                                 }
 348                         }
 349                         index_body($tg, \@quot, 0) if @quot;
 350                         index_body($tg, \@orig, $doc) if @orig;
 351                 });
 352
 353                 # populates smsg->references for smsg->to_doc_data
 354                 my $refs = parse_references($smsg);
 355                 $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 356                 my $data = $smsg->to_doc_data($oid, $mid0);
 357                 foreach my $mid (@$mids) {
 358                         $tg->index_text($mid, 1, 'XM');
 359                 }
 360                 $doc->set_data($data);
 361                 if (my $altid = $self->{-altid}) {
 362                         foreach my $alt (@$altid) {
 363                                 my $pfx = $alt->{xprefix};
 364                                 foreach my $mid (@$mids) {
 365                                         my $id = $alt->mid2alt($mid);
 366                                         next unless defined $id;
 367                                         $doc->add_boolean_term($pfx . $id);
 368                                 }
 369                         }
 370                 }
 371
 372                 $self->delete_article($num) if defined $num; # for reindexing
 373                 if ($skel) {
 374                         push @values, $mids, $xpath, $data;
 375                         $skel->index_skeleton(\@values);
 376                         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 377                         $doc->add_boolean_term('XNUM' . $num) if defined $num;
 378                         $doc_id = $self->{xdb}->add_document($doc);
 379                 } else {
 380                         $doc_id = link_and_save($self, $doc, $mids, $refs,
 381                                                 $num, $xpath);
 382                 }
 383         };
 384
 385         if ($@) {
 386                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 387                 return undef;
 388         }
 389         $doc_id;
 390 }
 391
 392 sub batch_do {
 393         my ($self, $termval, $cb) = @_;
 394         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 395         while (1) {
 396                 my ($head, $tail) = $self->find_doc_ids($termval);
 397                 return if $head == $tail;
 398                 my @ids;
 399                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 400                         push @ids, $head->get_docid;
 401                 }
 402                 $cb->(\@ids);
 403         }
 404 }
 405
 406 sub remove_message {
 407         my ($self, $mid) = @_;
 408         my $db = $self->{xdb};
 409         my $called;
 410         $mid = mid_clean($mid);
 411
 412         eval {
 413                 batch_do($self, 'Q' . $mid, sub {
 414                         my ($ids) = @_;
 415                         $db->delete_document($_) for @$ids;
 416                         $called = 1;
 417                 });
 418         };
 419         if ($@) {
 420                 warn "failed to remove message <$mid>: $@\n";
 421         } elsif (!$called) {
 422                 warn "cannot remove non-existent <$mid>\n";
 423         }
 424 }
 425
 426 sub delete_article {
 427         my ($self, $num) = @_;
 428         my $ndel = 0;
 429         batch_do($self, 'XNUM' . $num, sub {
 430                 my ($ids) = @_;
 431                 $ndel += scalar @$ids;
 432                 $self->{xdb}->delete_document($_) for @$ids;
 433         });
 434 }
 435
 436 # MID is a hint in V2
 437 sub remove_by_oid {
 438         my ($self, $oid, $mid) = @_;
 439         my $db = $self->{xdb};
 440
 441         # XXX careful, we cannot use batch_do here since we conditionally
 442         # delete documents based on other factors, so we cannot call
 443         # find_doc_ids twice.
 444         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 445         return if $head == $tail;
 446
 447         # there is only ONE element in @delete unless we
 448         # have bugs in our v2writable deduplication check
 449         my @delete;
 450         for (; $head != $tail; $head->inc) {
 451                 my $docid = $head->get_docid;
 452                 my $doc = $db->get_document($docid);
 453                 my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 454                 $smsg->load_expand;
 455                 push(@delete, $docid) if $smsg->{blob} eq $oid;
 456         }
 457         $db->delete_document($_) foreach @delete;
 458         scalar(@delete);
 459 }
 460
 461 sub term_generator { # write-only
 462         my ($self) = @_;
 463
 464         my $tg = $self->{term_generator};
 465         return $tg if $tg;
 466
 467         $tg = Search::Xapian::TermGenerator->new;
 468         $tg->set_stemmer($self->stemmer);
 469
 470         $self->{term_generator} = $tg;
 471 }
 472
 473 # increments last_thread_id counter
 474 # returns a 64-bit integer represented as a decimal string
 475 sub next_thread_id {
 476         my ($self) = @_;
 477         my $db = $self->{xdb};
 478         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 479
 480         $db->set_metadata('last_thread_id', ++$last_thread_id);
 481
 482         $last_thread_id;
 483 }
 484
 485 sub parse_references ($) {
 486         my ($smsg) = @_;
 487         my $mime = $smsg->{mime};
 488         my $hdr = $mime->header_obj;
 489         my $refs = references($hdr);
 490         return $refs if scalar(@$refs) == 0;
 491
 492         # prevent circular references via References here:
 493         my %mids = map { $_ => 1 } @{mids($hdr)};
 494         my @keep;
 495         foreach my $ref (@$refs) {
 496                 if (length($ref) > PublicInbox::MID::MAX_MID_SIZE) {
 497                         warn "References: <$ref> too long, ignoring\n";
 498                         next;
 499                 }
 500                 next if $mids{$ref};
 501                 push @keep, $ref;
 502         }
 503         $smsg->{references} = '<'.join('> <', @keep).'>' if @keep;
 504         \@keep;
 505 }
 506
 507 sub link_doc {
 508         my ($self, $doc, $refs, $old_tid) = @_;
 509         my $tid;
 510
 511         if (@$refs) {
 512                 # first ref *should* be the thread root,
 513                 # but we can never trust clients to do the right thing
 514                 my $ref = shift @$refs;
 515                 $tid = resolve_mid_to_tid($self, $ref);
 516                 merge_threads($self, $tid, $old_tid) if defined $old_tid;
 517
 518                 # the rest of the refs should point to this tid:
 519                 foreach $ref (@$refs) {
 520                         my $ptid = resolve_mid_to_tid($self, $ref);
 521                         merge_threads($self, $tid, $ptid);
 522                 }
 523         } else {
 524                 $tid = defined $old_tid ? $old_tid : $self->next_thread_id;
 525         }
 526         $doc->add_boolean_term('G' . $tid);
 527         $tid;
 528 }
 529
 530 sub link_and_save {
 531         my ($self, $doc, $mids, $refs, $num, $xpath) = @_;
 532         my $db = $self->{xdb};
 533         my $old_tid;
 534         my $doc_id;
 535         $doc->add_boolean_term('XNUM' . $num) if defined $num;
 536         $doc->add_boolean_term('XPATH' . $xpath) if defined $xpath;
 537         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 538
 539         my $vivified = 0;
 540         $self->{skel} and die "Should not have read-only skel here\n";;
 541         foreach my $mid (@$mids) {
 542                 $self->each_smsg_by_mid($mid, sub {
 543                         my ($cur) = @_;
 544                         my $type = $cur->type;
 545                         my $cur_tid = $cur->thread_id;
 546                         $old_tid = $cur_tid unless defined $old_tid;
 547                         if ($type eq 'mail') {
 548                                 # do not break existing mail messages,
 549                                 # just merge the threads
 550                                 merge_threads($self, $old_tid, $cur_tid);
 551                                 return 1;
 552                         }
 553                         if ($type ne 'ghost') {
 554                                 die "<$mid> has a bad type: $type\n";
 555                         }
 556                         my $tid = link_doc($self, $doc, $refs, $old_tid);
 557                         $old_tid = $tid unless defined $old_tid;
 558                         $doc_id = $cur->{doc_id};
 559                         $self->{xdb}->replace_document($doc_id, $doc);
 560                         ++$vivified;
 561                         1;
 562                 });
 563         }
 564         # not really important, but we return any vivified ghost docid, here:
 565         return $doc_id if defined $doc_id;
 566         link_doc($self, $doc, $refs, $old_tid);
 567         $self->{xdb}->add_document($doc);
 568 }
 569
 570 sub index_git_blob_id {
 571         my ($doc, $pfx, $objid) = @_;
 572
 573         my $len = length($objid);
 574         for (my $len = length($objid); $len >= 7; ) {
 575                 $doc->add_term($pfx.$objid);
 576                 $objid = substr($objid, 0, --$len);
 577         }
 578 }
 579
 580 sub unindex_blob {
 581         my ($self, $mime) = @_;
 582         my $mid = eval { mid_clean(mid_mime($mime)) };
 583         $self->remove_message($mid) if defined $mid;
 584 }
 585
 586 sub index_mm {
 587         my ($self, $mime) = @_;
 588         my $mid = mid_clean(mid_mime($mime));
 589         my $mm = $self->{mm};
 590         my $num = $mm->mid_insert($mid);
 591         return $num if defined $num;
 592
 593         # fallback to num_for since filters like RubyLang set the number
 594         $mm->num_for($mid);
 595 }
 596
 597 sub unindex_mm {
 598         my ($self, $mime) = @_;
 599         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 600 }
 601
 602 sub index_mm2 {
 603         my ($self, $mime, $bytes, $blob) = @_;
 604         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 605         add_message($self, $mime, $bytes, $num, $blob);
 606 }
 607
 608 sub unindex_mm2 {
 609         my ($self, $mime) = @_;
 610         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 611         unindex_blob($self, $mime);
 612 }
 613
 614 sub index_both {
 615         my ($self, $mime, $bytes, $blob) = @_;
 616         my $num = index_mm($self, $mime);
 617         add_message($self, $mime, $bytes, $num, $blob);
 618 }
 619
 620 sub unindex_both {
 621         my ($self, $mime) = @_;
 622         unindex_blob($self, $mime);
 623         unindex_mm($self, $mime);
 624 }
 625
 626 sub do_cat_mail {
 627         my ($git, $blob, $sizeref) = @_;
 628         my $mime = eval {
 629                 my $str = $git->cat_file($blob, $sizeref);
 630                 # fixup bugs from import:
 631                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 632                 PublicInbox::MIME->new($str);
 633         };
 634         $@ ? undef : $mime;
 635 }
 636
 637 sub index_sync {
 638         my ($self, $opts) = @_;
 639         with_umask($self, sub { $self->_index_sync($opts) });
 640 }
 641
 642 sub batch_adjust ($$$$) {
 643         my ($max, $bytes, $batch_cb, $latest) = @_;
 644         $$max -= $bytes;
 645         if ($$max <= 0) {
 646                 $$max = BATCH_BYTES;
 647                 $batch_cb->($latest, 1);
 648         }
 649 }
 650
 651 # only for v1
 652 sub rlog {
 653         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 654         my $hex = '[a-f0-9]';
 655         my $h40 = $hex .'{40}';
 656         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 657         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 658         my $git = $self->{git};
 659         my $latest;
 660         my $bytes;
 661         my $max = BATCH_BYTES;
 662         local $/ = "\n";
 663         my $line;
 664         while (defined($line = <$log>)) {
 665                 if ($line =~ /$addmsg/o) {
 666                         my $blob = $1;
 667                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 668                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 669                         $add_cb->($self, $mime, $bytes, $blob);
 670                 } elsif ($line =~ /$delmsg/o) {
 671                         my $blob = $1;
 672                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 673                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 674                         $del_cb->($self, $mime);
 675                 } elsif ($line =~ /^commit ($h40)/o) {
 676                         $latest = $1;
 677                 }
 678         }
 679         $batch_cb->($latest, 0);
 680 }
 681
 682 sub _msgmap_init {
 683         my ($self) = @_;
 684         $self->{mm} ||= eval {
 685                 require PublicInbox::Msgmap;
 686                 my $msgmap_path = $self->{msgmap_path};
 687                 if (defined $msgmap_path) { # v2
 688                         PublicInbox::Msgmap->new_file($msgmap_path, 1);
 689                 } else {
 690                         PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 691                 }
 692         };
 693 }
 694
 695 sub _git_log {
 696         my ($self, $range) = @_;
 697         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 698                                 --raw -r --no-abbrev/, $range);
 699 }
 700
 701 # indexes all unindexed messages
 702 sub _index_sync {
 703         my ($self, $opts) = @_;
 704         my $tip = $opts->{ref} || 'HEAD';
 705         my $reindex = $opts->{reindex};
 706         my ($mkey, $last_commit, $lx, $xlog);
 707         $self->{git}->batch_prepare;
 708         my $xdb = _xdb_acquire($self);
 709         $xdb->begin_transaction;
 710         do {
 711                 $xlog = undef;
 712                 $mkey = 'last_commit';
 713                 $last_commit = $xdb->get_metadata('last_commit');
 714                 $lx = $last_commit;
 715                 if ($reindex) {
 716                         $lx = '';
 717                         $mkey = undef if $last_commit ne '';
 718                 }
 719                 $xdb->cancel_transaction;
 720                 $xdb = _xdb_release($self);
 721
 722                 # ensure we leak no FDs to "git log"
 723                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 724                 $xlog = _git_log($self, $range);
 725
 726                 $xdb = _xdb_acquire($self);
 727                 $xdb->begin_transaction;
 728         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 729
 730         my $mm = _msgmap_init($self);
 731         my $dbh = $mm->{dbh} if $mm;
 732         my $mm_only;
 733         my $cb = sub {
 734                 my ($commit, $more) = @_;
 735                 if ($dbh) {
 736                         $mm->last_commit($commit) if $commit;
 737                         $dbh->commit;
 738                 }
 739                 if (!$mm_only) {
 740                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 741                         $xdb->commit_transaction;
 742                         $xdb = _xdb_release($self);
 743                 }
 744                 # let another process do some work... <
 745                 if ($more) {
 746                         if (!$mm_only) {
 747                                 $xdb = _xdb_acquire($self);
 748                                 $xdb->begin_transaction;
 749                         }
 750                         $dbh->begin_work if $dbh;
 751                 }
 752         };
 753
 754         if ($mm) {
 755                 $dbh->begin_work;
 756                 my $lm = $mm->last_commit || '';
 757                 if ($lm eq $lx) {
 758                         # Common case is the indexes are synced,
 759                         # we only need to run git-log once:
 760                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 761                 } else {
 762                         # Uncommon case, msgmap and xapian are out-of-sync
 763                         # do not care for performance (but git is fast :>)
 764                         # This happens if we have to reindex Xapian since
 765                         # msgmap is a frozen format and our Xapian format
 766                         # is evolving.
 767                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 768
 769                         # first, ensure msgmap is up-to-date:
 770                         my $mkey_prev = $mkey;
 771                         $mkey = undef; # ignore xapian, for now
 772                         my $mlog = _git_log($self, $r);
 773                         $mm_only = 1;
 774                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 775                         $mm_only = $mlog = undef;
 776
 777                         # now deal with Xapian
 778                         $mkey = $mkey_prev;
 779                         $dbh = undef;
 780                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 781                 }
 782         } else {
 783                 # user didn't install DBD::SQLite and DBI
 784                 rlog($self, $xlog, *add_message, *unindex_blob, $cb);
 785         }
 786 }
 787
 788 # this will create a ghost as necessary
 789 sub resolve_mid_to_tid {
 790         my ($self, $mid) = @_;
 791         my $tid;
 792         $self->each_smsg_by_mid($mid, sub {
 793                 my ($smsg) = @_;
 794                 my $cur_tid = $smsg->thread_id;
 795                 if (defined $tid) {
 796                         merge_threads($self, $tid, $cur_tid);
 797                 } else {
 798                         $tid = $smsg->thread_id;
 799                 }
 800                 1;
 801         });
 802         return $tid if defined $tid;
 803
 804         $self->create_ghost($mid)->thread_id;
 805 }
 806
 807 sub create_ghost {
 808         my ($self, $mid) = @_;
 809
 810         my $tid = $self->next_thread_id;
 811         my $doc = Search::Xapian::Document->new;
 812         $doc->add_boolean_term('Q' . $mid);
 813         $doc->add_boolean_term('G' . $tid);
 814         $doc->add_boolean_term('T' . 'ghost');
 815
 816         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 817         $self->{xdb}->add_document($doc);
 818
 819         $smsg;
 820 }
 821
 822 sub merge_threads {
 823         my ($self, $winner_tid, $loser_tid) = @_;
 824         return if $winner_tid == $loser_tid;
 825         my $db = $self->{xdb};
 826         batch_do($self, 'G' . $loser_tid, sub {
 827                 my ($ids) = @_;
 828                 foreach my $docid (@$ids) {
 829                         my $doc = $db->get_document($docid);
 830                         $doc->remove_term('G' . $loser_tid);
 831                         $doc->add_boolean_term('G' . $winner_tid);
 832                         $db->replace_document($docid, $doc);
 833                 }
 834         });
 835 }
 836
 837 sub _read_git_config_perm {
 838         my ($self) = @_;
 839         my @cmd = qw(config);
 840         if ($self->{version} == 2) {
 841                 push @cmd, "--file=$self->{mainrepo}/all.git/config";
 842         }
 843         my $fh = $self->{git}->popen(@cmd, 'core.sharedRepository');
 844         local $/ = "\n";
 845         my $perm = <$fh>;
 846         chomp $perm if defined $perm;
 847         $perm;
 848 }
 849
 850 sub _git_config_perm {
 851         my $self = shift;
 852         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 853         return PERM_GROUP if (!defined($perm) || $perm eq '');
 854         return PERM_UMASK if ($perm eq 'umask');
 855         return PERM_GROUP if ($perm eq 'group');
 856         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 857                 return PERM_EVERYBODY;
 858         }
 859         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 860         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 861
 862         my $i = oct($perm);
 863         return PERM_UMASK if ($i == PERM_UMASK);
 864         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 865         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 866
 867         if (($i & 0600) != 0600) {
 868                 die "core.sharedRepository mode invalid: ".
 869                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 870         }
 871         ($i & 0666);
 872 }
 873
 874 sub _umask_for {
 875         my ($perm) = @_; # _git_config_perm return value
 876         my $rv = $perm;
 877         return umask if $rv == 0;
 878
 879         # set +x bit if +r or +w were set
 880         $rv |= 0100 if ($rv & 0600);
 881         $rv |= 0010 if ($rv & 0060);
 882         $rv |= 0001 if ($rv & 0006);
 883         (~$rv & 0777);
 884 }
 885
 886 sub with_umask {
 887         my ($self, $cb) = @_;
 888         my $old = umask $self->{umask};
 889         my $rv = eval { $cb->() };
 890         my $err = $@;
 891         umask $old;
 892         die $err if $err;
 893         $rv;
 894 }
 895
 896 sub DESTROY {
 897         # order matters for unlocking
 898         $_[0]->{xdb} = undef;
 899         $_[0]->{lockfh} = undef;
 900 }
 901
 902 # remote_* subs are only used by SearchIdxPart and SearchIdxSkeleton
 903 sub remote_commit {
 904         my ($self) = @_;
 905         if (my $w = $self->{w}) {
 906                 print $w "commit\n" or die "failed to write commit: $!";
 907         } else {
 908                 $self->commit_txn_lazy;
 909                 if (my $skel = $self->{skeleton}) {
 910                         $skel->commit_txn_lazy;
 911                 }
 912         }
 913 }
 914
 915 sub remote_close {
 916         my ($self) = @_;
 917         if (my $w = delete $self->{w}) {
 918                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 919                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 920                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 921                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 922                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 923         } else {
 924                 die "transaction in progress $self\n" if $self->{txn};
 925                 $self->_xdb_release if $self->{xdb};
 926         }
 927 }
 928
 929 sub remote_remove {
 930         my ($self, $oid, $mid) = @_;
 931         if (my $w = $self->{w}) {
 932                 # triggers remove_by_oid in partition or skeleton
 933                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 934         } else {
 935                 $self->begin_txn_lazy;
 936                 $self->remove_by_oid($oid, $mid);
 937         }
 938 }
 939
 940 sub begin_txn_lazy {
 941         my ($self) = @_;
 942         return if $self->{txn};
 943         my $xdb = $self->{xdb} || $self->_xdb_acquire;
 944         $xdb->begin_transaction;
 945         $self->{txn} = 1;
 946 }
 947
 948 sub commit_txn_lazy {
 949         my ($self) = @_;
 950         delete $self->{txn} or return;
 951         $self->{xdb}->commit_transaction;
 952 }
 953
 954 sub worker_done {
 955         my ($self) = @_;
 956         die "$$ $0 xdb not released\n" if $self->{xdb};
 957         die "$$ $0 still in transaction\n" if $self->{txn};
 958 }
 959
 960 1;