lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 require PublicInbox::Git;
  21 use Compress::Zlib qw(compress);
  22
  23 use constant {
  24         BATCH_BYTES => 10_000_000,
  25         DEBUG => !!$ENV{DEBUG},
  26 };
  27
  28 my %GIT_ESC = (
  29         a => "\a",
  30         b => "\b",
  31         f => "\f",
  32         n => "\n",
  33         r => "\r",
  34         t => "\t",
  35         v => "\013",
  36 );
  37
  38 sub git_unquote ($) {
  39         my ($s) = @_;
  40         return $s unless ($s =~ /\A"(.*)"\z/);
  41         $s = $1;
  42         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  43         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  44         $s;
  45 }
  46
  47 sub new {
  48         my ($class, $ibx, $creat, $part) = @_;
  49         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  50         my $git_dir = $mainrepo;
  51         my ($altid, $git);
  52         my $version = 1;
  53         if (ref $ibx) {
  54                 $mainrepo = $ibx->{mainrepo};
  55                 $altid = $ibx->{altid};
  56                 $version = $ibx->{version} || 1;
  57                 if ($altid) {
  58                         require PublicInbox::AltId;
  59                         $altid = [ map {
  60                                 PublicInbox::AltId->new($ibx, $_);
  61                         } @$altid ];
  62                 }
  63         } else { # v1
  64                 $ibx = { mainrepo => $git_dir, version => 1 };
  65         }
  66         $ibx = PublicInbox::InboxWritable->new($ibx);
  67         require Search::Xapian::WritableDatabase;
  68         my $self = bless {
  69                 mainrepo => $mainrepo,
  70                 -inbox => $ibx,
  71                 git => $ibx->git,
  72                 -altid => $altid,
  73                 version => $version,
  74         }, $class;
  75         $ibx->umask_prepare;
  76         if ($version == 1) {
  77                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  78                 my $dir = $self->xdir;
  79                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  80         } elsif ($version == 2) {
  81                 defined $part or die "partition is required for v2\n";
  82                 # partition is a number
  83                 $self->{partition} = $part;
  84                 $self->{lock_path} = undef;
  85         } else {
  86                 die "unsupported inbox version=$version\n";
  87         }
  88         $self->{creat} = ($creat || 0) == 1;
  89         $self;
  90 }
  91
  92 sub _xdb_release {
  93         my ($self) = @_;
  94         my $xdb = delete $self->{xdb} or croak 'not acquired';
  95         $xdb->close;
  96         $self->lock_release if $self->{creat};
  97         undef;
  98 }
  99
 100 sub _xdb_acquire {
 101         my ($self) = @_;
 102         croak 'already acquired' if $self->{xdb};
 103         my $dir = $self->xdir;
 104         my $flag = Search::Xapian::DB_OPEN;
 105         if ($self->{creat}) {
 106                 require File::Path;
 107                 $self->lock_acquire;
 108                 File::Path::mkpath($dir);
 109                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 110         }
 111         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 112 }
 113
 114 sub add_val ($$$) {
 115         my ($doc, $col, $num) = @_;
 116         $num = Search::Xapian::sortable_serialise($num);
 117         $doc->add_value($col, $num);
 118 }
 119
 120 sub index_users ($$) {
 121         my ($tg, $smsg) = @_;
 122
 123         my $from = $smsg->from;
 124         my $to = $smsg->to;
 125         my $cc = $smsg->cc;
 126
 127         $tg->index_text($from, 1, 'A'); # A - author
 128         $tg->increase_termpos;
 129         $tg->index_text($to, 1, 'XTO') if $to ne '';
 130         $tg->increase_termpos;
 131         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 132         $tg->increase_termpos;
 133 }
 134
 135 sub index_diff_inc ($$$$) {
 136         my ($tg, $text, $pfx, $xnq) = @_;
 137         if (@$xnq) {
 138                 $tg->index_text(join("\n", @$xnq), 1, 'XNQ');
 139                 $tg->increase_termpos;
 140                 @$xnq = ();
 141         }
 142         $tg->index_text($text, 1, $pfx);
 143         $tg->increase_termpos;
 144 }
 145
 146 sub index_old_diff_fn {
 147         my ($tg, $seen, $fa, $fb, $xnq) = @_;
 148
 149         # no renames or space support for traditional diffs,
 150         # find the number of leading common paths to strip:
 151         my @fa = split('/', $fa);
 152         my @fb = split('/', $fb);
 153         while (scalar(@fa) && scalar(@fb)) {
 154                 $fa = join('/', @fa);
 155                 $fb = join('/', @fb);
 156                 if ($fa eq $fb) {
 157                         unless ($seen->{$fa}++) {
 158                                 index_diff_inc($tg, $fa, 'XDFN', $xnq);
 159                         }
 160                         return 1;
 161                 }
 162                 shift @fa;
 163                 shift @fb;
 164         }
 165         0;
 166 }
 167
 168 sub index_diff ($$$) {
 169         my ($tg, $lines, $doc) = @_;
 170         my %seen;
 171         my $in_diff;
 172         my @xnq;
 173         my $xnq = \@xnq;
 174         foreach (@$lines) {
 175                 if ($in_diff && s/^ //) { # diff context
 176                         index_diff_inc($tg, $_, 'XDFCTX', $xnq);
 177                 } elsif (/^-- $/) { # email signature begins
 178                         $in_diff = undef;
 179                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 180                         my ($fa, $fb) = ($1, $2);
 181                         my $fn = (split('/', git_unquote($fa), 2))[1];
 182                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 183                         $fn = (split('/', git_unquote($fb), 2))[1];
 184                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 185                         $in_diff = 1;
 186                 # traditional diff:
 187                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 188                         my ($opt, $fa, $fb) = ($1, $2, $3);
 189                         push @xnq, $_;
 190                         # only support unified:
 191                         next unless $opt =~ /[uU]/;
 192                         $in_diff = index_old_diff_fn($tg, \%seen, $fa, $fb,
 193                                                         $xnq);
 194                 } elsif (m!^--- ("?a/.+)!) {
 195                         my $fn = (split('/', git_unquote($1), 2))[1];
 196                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 197                         $in_diff = 1;
 198                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 199                         my $fn = (split('/', git_unquote($1), 2))[1];
 200                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 201                         $in_diff = 1;
 202                 } elsif (/^--- (\S+)/) {
 203                         $in_diff = $1;
 204                         push @xnq, $_;
 205                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 206                         $in_diff = index_old_diff_fn($tg, \%seen, $in_diff, $1,
 207                                                         $xnq);
 208                 } elsif ($in_diff && s/^\+//) { # diff added
 209                         index_diff_inc($tg, $_, 'XDFB', $xnq);
 210                 } elsif ($in_diff && s/^-//) { # diff removed
 211                         index_diff_inc($tg, $_, 'XDFA', $xnq);
 212                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 213                         my ($ba, $bb) = ($1, $2);
 214                         index_git_blob_id($doc, 'XDFPRE', $ba);
 215                         index_git_blob_id($doc, 'XDFPOST', $bb);
 216                         $in_diff = 1;
 217                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 218                         # traditional diff w/o -p
 219                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 220                         # hunk header context
 221                         index_diff_inc($tg, $1, 'XDFHH', $xnq);
 222                 # ignore the following lines:
 223                 } elsif (/^(?:dis)similarity index/ ||
 224                                 /^(?:old|new) mode/ ||
 225                                 /^(?:deleted|new) file mode/ ||
 226                                 /^(?:copy|rename) (?:from|to) / ||
 227                                 /^(?:dis)?similarity index / ||
 228                                 /^\\ No newline at end of file/ ||
 229                                 /^Binary files .* differ/) {
 230                         push @xnq, $_;
 231                 } elsif ($_ eq '') {
 232                         $in_diff = undef;
 233                 } else {
 234                         push @xnq, $_;
 235                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 236                         $in_diff = undef;
 237                 }
 238         }
 239
 240         $tg->index_text(join("\n", @xnq), 1, 'XNQ');
 241         $tg->increase_termpos;
 242 }
 243
 244 sub index_body ($$$) {
 245         my ($tg, $lines, $doc) = @_;
 246         my $txt = join("\n", @$lines);
 247         if ($doc) {
 248                 # does it look like a diff?
 249                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 250                         $txt = undef;
 251                         index_diff($tg, $lines, $doc);
 252                 } else {
 253                         $tg->index_text($txt, 1, 'XNQ');
 254                 }
 255         } else {
 256                 $tg->index_text($txt, 0, 'XQUOT');
 257         }
 258         $tg->increase_termpos;
 259         @$lines = ();
 260 }
 261
 262 sub add_message {
 263         # mime = Email::MIME object
 264         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 265         my $doc_id;
 266         my $mids = mids($mime->header_obj);
 267         $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 268         unless (defined $num) { # v1
 269                 my $mm = $self->_msgmap_init;
 270                 $num = $mm->mid_insert($mid0) || $mm->num_for($mid0);
 271         }
 272         eval {
 273                 my $smsg = PublicInbox::SearchMsg->new($mime);
 274                 my $doc = $smsg->{doc};
 275                 my $subj = $smsg->subject;
 276
 277                 $smsg->{lines} = $mime->body_raw =~ tr!\n!\n!;
 278                 defined $bytes or $bytes = length($mime->as_string);
 279                 $smsg->{bytes} = $bytes;
 280
 281                 add_val($doc, PublicInbox::Search::TS(), $smsg->ts);
 282                 my @ds = gmtime($smsg->ds);
 283                 my $yyyymmdd = strftime('%Y%m%d', @ds);
 284                 add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 285                 my $dt = strftime('%Y%m%d%H%M%S', @ds);
 286                 add_val($doc, PublicInbox::Search::DT(), $dt);
 287                 my @vals = ($smsg->{ts}, $smsg->{ds});
 288
 289                 my $tg = $self->term_generator;
 290
 291                 $tg->set_document($doc);
 292                 $tg->index_text($subj, 1, 'S') if $subj;
 293                 $tg->increase_termpos;
 294
 295                 index_users($tg, $smsg);
 296
 297                 msg_iter($mime, sub {
 298                         my ($part, $depth, @idx) = @{$_[0]};
 299                         my $ct = $part->content_type || 'text/plain';
 300                         my $fn = $part->filename;
 301                         if (defined $fn && $fn ne '') {
 302                                 $tg->index_text($fn, 1, 'XFN');
 303                         }
 304
 305                         return if $ct =~ m!\btext/x?html\b!i;
 306
 307                         my $s = eval { $part->body_str };
 308                         if ($@) {
 309                                 if ($ct =~ m!\btext/plain\b!i) {
 310                                         # Try to assume UTF-8 because Alpine
 311                                         # seems to do wacky things and set
 312                                         # charset=X-UNKNOWN
 313                                         $part->charset_set('UTF-8');
 314                                         $s = eval { $part->body_str };
 315                                         $s = $part->body if $@;
 316                                 }
 317                         }
 318                         defined $s or return;
 319
 320                         my (@orig, @quot);
 321                         my $body = $part->body;
 322                         my @lines = split(/\n/, $body);
 323                         while (defined(my $l = shift @lines)) {
 324                                 if ($l =~ /^>/) {
 325                                         index_body($tg, \@orig, $doc) if @orig;
 326                                         push @quot, $l;
 327                                 } else {
 328                                         index_body($tg, \@quot, 0) if @quot;
 329                                         push @orig, $l;
 330                                 }
 331                         }
 332                         index_body($tg, \@quot, 0) if @quot;
 333                         index_body($tg, \@orig, $doc) if @orig;
 334                 });
 335
 336                 # populates smsg->references for smsg->to_doc_data
 337                 my $data = $smsg->to_doc_data($oid, $mid0);
 338                 foreach my $mid (@$mids) {
 339                         $tg->index_text($mid, 1, 'XM');
 340                 }
 341                 $doc->set_data($data);
 342                 if (my $altid = $self->{-altid}) {
 343                         foreach my $alt (@$altid) {
 344                                 my $pfx = $alt->{xprefix};
 345                                 foreach my $mid (@$mids) {
 346                                         my $id = $alt->mid2alt($mid);
 347                                         next unless defined $id;
 348                                         $doc->add_boolean_term($pfx . $id);
 349                                 }
 350                         }
 351                 }
 352
 353                 $self->delete_article($num) if defined $num; # for reindexing
 354
 355                 if (my $over = $self->{over}) {
 356                         utf8::encode($data);
 357                         $data = compress($data);
 358                         my $refs = $over->parse_references($smsg, $mid0, $mids);
 359                         my $xpath;
 360                         if ($subj ne '') {
 361                                 $xpath = $self->subject_path($subj);
 362                                 $xpath = id_compress($xpath);
 363                         }
 364
 365                         push @vals, $num, $mids, $refs, $xpath, $data;
 366                         $over->add_over(\@vals);
 367                 }
 368                 $doc->add_boolean_term('Q' . $_) foreach @$mids;
 369                 $doc->add_boolean_term('XNUM' . $num) if defined $num;
 370                 $doc_id = $self->{xdb}->add_document($doc);
 371         };
 372
 373         if ($@) {
 374                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 375                 return undef;
 376         }
 377         $doc_id;
 378 }
 379
 380 # returns begin and end PostingIterator
 381 sub find_doc_ids {
 382         my ($self, $termval) = @_;
 383         my $db = $self->{xdb};
 384
 385         ($db->postlist_begin($termval), $db->postlist_end($termval));
 386 }
 387
 388 sub batch_do {
 389         my ($self, $termval, $cb) = @_;
 390         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 391         while (1) {
 392                 my ($head, $tail) = $self->find_doc_ids($termval);
 393                 return if $head == $tail;
 394                 my @ids;
 395                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 396                         push @ids, $head->get_docid;
 397                 }
 398                 $cb->(\@ids);
 399         }
 400 }
 401
 402 sub remove_message {
 403         my ($self, $mid) = @_;
 404         my $db = $self->{xdb};
 405         my $called;
 406         $mid = mid_clean($mid);
 407
 408         eval {
 409                 batch_do($self, 'Q' . $mid, sub {
 410                         my ($ids) = @_;
 411                         $db->delete_document($_) for @$ids;
 412                         $called = 1;
 413                 });
 414         };
 415         if ($@) {
 416                 warn "failed to remove message <$mid>: $@\n";
 417         } elsif (!$called) {
 418                 warn "cannot remove non-existent <$mid>\n";
 419         }
 420 }
 421
 422 sub delete_article {
 423         my ($self, $num) = @_;
 424         my $ndel = 0;
 425         batch_do($self, 'XNUM' . $num, sub {
 426                 my ($ids) = @_;
 427                 $ndel += scalar @$ids;
 428                 $self->{xdb}->delete_document($_) for @$ids;
 429         });
 430 }
 431
 432 # MID is a hint in V2
 433 sub remove_by_oid {
 434         my ($self, $oid, $mid) = @_;
 435         my $db = $self->{xdb};
 436
 437         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 438
 439         # XXX careful, we cannot use batch_do here since we conditionally
 440         # delete documents based on other factors, so we cannot call
 441         # find_doc_ids twice.
 442         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 443         return if $head == $tail;
 444
 445         # there is only ONE element in @delete unless we
 446         # have bugs in our v2writable deduplication check
 447         my @delete;
 448         for (; $head != $tail; $head->inc) {
 449                 my $docid = $head->get_docid;
 450                 my $doc = $db->get_document($docid);
 451                 my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 452                 $smsg->load_expand;
 453                 if ($smsg->{blob} eq $oid) {
 454                         push(@delete, $docid);
 455                 }
 456         }
 457         $db->delete_document($_) foreach @delete;
 458         scalar(@delete);
 459 }
 460
 461 sub term_generator { # write-only
 462         my ($self) = @_;
 463
 464         my $tg = $self->{term_generator};
 465         return $tg if $tg;
 466
 467         $tg = Search::Xapian::TermGenerator->new;
 468         $tg->set_stemmer($self->stemmer);
 469
 470         $self->{term_generator} = $tg;
 471 }
 472
 473 sub index_git_blob_id {
 474         my ($doc, $pfx, $objid) = @_;
 475
 476         my $len = length($objid);
 477         for (my $len = length($objid); $len >= 7; ) {
 478                 $doc->add_term($pfx.$objid);
 479                 $objid = substr($objid, 0, --$len);
 480         }
 481 }
 482
 483 sub unindex_blob {
 484         my ($self, $mime) = @_;
 485         my $mid = eval { mid_clean(mid_mime($mime)) };
 486         $self->remove_message($mid) if defined $mid;
 487 }
 488
 489 sub index_mm {
 490         my ($self, $mime) = @_;
 491         my $mid = mid_clean(mid_mime($mime));
 492         my $mm = $self->{mm};
 493         my $num = $mm->mid_insert($mid);
 494         return $num if defined $num;
 495
 496         # fallback to num_for since filters like RubyLang set the number
 497         $mm->num_for($mid);
 498 }
 499
 500 sub unindex_mm {
 501         my ($self, $mime) = @_;
 502         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 503 }
 504
 505 sub index_mm2 {
 506         my ($self, $mime, $bytes, $blob) = @_;
 507         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 508         add_message($self, $mime, $bytes, $num, $blob);
 509 }
 510
 511 sub unindex_mm2 {
 512         my ($self, $mime) = @_;
 513         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 514         unindex_blob($self, $mime);
 515 }
 516
 517 sub index_both {
 518         my ($self, $mime, $bytes, $blob) = @_;
 519         my $num = index_mm($self, $mime);
 520         add_message($self, $mime, $bytes, $num, $blob);
 521 }
 522
 523 sub unindex_both {
 524         my ($self, $mime) = @_;
 525         unindex_blob($self, $mime);
 526         unindex_mm($self, $mime);
 527 }
 528
 529 sub do_cat_mail {
 530         my ($git, $blob, $sizeref) = @_;
 531         my $mime = eval {
 532                 my $str = $git->cat_file($blob, $sizeref);
 533                 # fixup bugs from import:
 534                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 535                 PublicInbox::MIME->new($str);
 536         };
 537         $@ ? undef : $mime;
 538 }
 539
 540 sub index_sync {
 541         my ($self, $opts) = @_;
 542         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 543 }
 544
 545 sub batch_adjust ($$$$) {
 546         my ($max, $bytes, $batch_cb, $latest) = @_;
 547         $$max -= $bytes;
 548         if ($$max <= 0) {
 549                 $$max = BATCH_BYTES;
 550                 $batch_cb->($latest, 1);
 551         }
 552 }
 553
 554 # only for v1
 555 sub rlog {
 556         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 557         my $hex = '[a-f0-9]';
 558         my $h40 = $hex .'{40}';
 559         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 560         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 561         my $git = $self->{git};
 562         my $latest;
 563         my $bytes;
 564         my $max = BATCH_BYTES;
 565         local $/ = "\n";
 566         my $line;
 567         while (defined($line = <$log>)) {
 568                 if ($line =~ /$addmsg/o) {
 569                         my $blob = $1;
 570                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 571                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 572                         $add_cb->($self, $mime, $bytes, $blob);
 573                 } elsif ($line =~ /$delmsg/o) {
 574                         my $blob = $1;
 575                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 576                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 577                         $del_cb->($self, $mime);
 578                 } elsif ($line =~ /^commit ($h40)/o) {
 579                         $latest = $1;
 580                 }
 581         }
 582         $batch_cb->($latest, 0);
 583 }
 584
 585 sub _msgmap_init {
 586         my ($self) = @_;
 587         die "BUG: _msgmap_init is only for v1\n" if $self->{version} != 1;
 588         $self->{mm} ||= eval {
 589                 require PublicInbox::Msgmap;
 590                 PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 591         };
 592 }
 593
 594 sub _git_log {
 595         my ($self, $range) = @_;
 596         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 597                                 --raw -r --no-abbrev/, $range);
 598 }
 599
 600 # indexes all unindexed messages (v1 only)
 601 sub _index_sync {
 602         my ($self, $opts) = @_;
 603         my $tip = $opts->{ref} || 'HEAD';
 604         my $reindex = $opts->{reindex};
 605         my ($mkey, $last_commit, $lx, $xlog);
 606         $self->{git}->batch_prepare;
 607         my $xdb = $self->begin_txn_lazy;
 608         do {
 609                 $xlog = undef;
 610                 $mkey = 'last_commit';
 611                 $last_commit = $xdb->get_metadata('last_commit');
 612                 $lx = $last_commit;
 613                 if ($reindex) {
 614                         $lx = '';
 615                         $mkey = undef if $last_commit ne '';
 616                 }
 617                 $self->{over}->rollback_lazy;
 618                 $self->{over}->disconnect;
 619                 delete $self->{txn};
 620                 $xdb->cancel_transaction;
 621                 $xdb = _xdb_release($self);
 622
 623                 # ensure we leak no FDs to "git log"
 624                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 625                 $xlog = _git_log($self, $range);
 626
 627                 $xdb = $self->begin_txn_lazy;
 628         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 629
 630         my $mm = _msgmap_init($self);
 631         my $dbh = $mm->{dbh} if $mm;
 632         my $mm_only;
 633         my $cb = sub {
 634                 my ($commit, $more) = @_;
 635                 if ($dbh) {
 636                         $mm->last_commit($commit) if $commit;
 637                         $dbh->commit;
 638                 }
 639                 if (!$mm_only) {
 640                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 641                         $self->commit_txn_lazy;
 642                 }
 643                 # let another process do some work... <
 644                 if ($more) {
 645                         if (!$mm_only) {
 646                                 $xdb = $self->begin_txn_lazy;
 647                         }
 648                         $dbh->begin_work if $dbh;
 649                 }
 650         };
 651
 652         if ($mm) {
 653                 $dbh->begin_work;
 654                 my $lm = $mm->last_commit || '';
 655                 if ($lm eq $lx) {
 656                         # Common case is the indexes are synced,
 657                         # we only need to run git-log once:
 658                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 659                 } else {
 660                         # Uncommon case, msgmap and xapian are out-of-sync
 661                         # do not care for performance (but git is fast :>)
 662                         # This happens if we have to reindex Xapian since
 663                         # msgmap is a frozen format and our Xapian format
 664                         # is evolving.
 665                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 666
 667                         # first, ensure msgmap is up-to-date:
 668                         my $mkey_prev = $mkey;
 669                         $mkey = undef; # ignore xapian, for now
 670                         my $mlog = _git_log($self, $r);
 671                         $mm_only = 1;
 672                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 673                         $mm_only = $mlog = undef;
 674
 675                         # now deal with Xapian
 676                         $mkey = $mkey_prev;
 677                         $dbh = undef;
 678                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 679                 }
 680         } else {
 681                 # user didn't install DBD::SQLite and DBI
 682                 rlog($self, $xlog, *add_message, *unindex_blob, $cb);
 683         }
 684 }
 685
 686 sub DESTROY {
 687         # order matters for unlocking
 688         $_[0]->{xdb} = undef;
 689         $_[0]->{lockfh} = undef;
 690 }
 691
 692 # remote_* subs are only used by SearchIdxPart
 693 sub remote_commit {
 694         my ($self) = @_;
 695         if (my $w = $self->{w}) {
 696                 print $w "commit\n" or die "failed to write commit: $!";
 697         } else {
 698                 $self->commit_txn_lazy;
 699         }
 700 }
 701
 702 sub remote_close {
 703         my ($self) = @_;
 704         if (my $w = delete $self->{w}) {
 705                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 706                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 707                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 708                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 709                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 710         } else {
 711                 die "transaction in progress $self\n" if $self->{txn};
 712                 $self->_xdb_release if $self->{xdb};
 713         }
 714 }
 715
 716 sub remote_remove {
 717         my ($self, $oid, $mid) = @_;
 718         if (my $w = $self->{w}) {
 719                 # triggers remove_by_oid in a partition
 720                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 721         } else {
 722                 $self->begin_txn_lazy;
 723                 $self->remove_by_oid($oid, $mid);
 724         }
 725 }
 726
 727 sub begin_txn_lazy {
 728         my ($self) = @_;
 729         return if $self->{txn};
 730         my $xdb = $self->{xdb} || $self->_xdb_acquire;
 731         $self->{over}->begin_lazy if $self->{over};
 732         $xdb->begin_transaction;
 733         $self->{txn} = 1;
 734         $xdb;
 735 }
 736
 737 sub commit_txn_lazy {
 738         my ($self) = @_;
 739         delete $self->{txn} or return;
 740         $self->{xdb}->commit_transaction;
 741         $self->{over}->commit_lazy if $self->{over};
 742 }
 743
 744 sub worker_done {
 745         my ($self) = @_;
 746         die "$$ $0 xdb not released\n" if $self->{xdb};
 747         die "$$ $0 still in transaction\n" if $self->{txn};
 748 }
 749
 750 1;