lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 use constant {
  26         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  27                         0x7fffffff : 1_000_000,
  28         DEBUG => !!$ENV{DEBUG},
  29 };
  30
  31 my $xapianlevels = qr/\A(?:full|medium)\z/;
  32
  33 sub new {
  34         my ($class, $ibx, $creat, $shard) = @_;
  35         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  36         my $levels = qr/\A(?:full|medium|basic)\z/;
  37         my $inboxdir = $ibx->{inboxdir};
  38         my $version = $ibx->version;
  39         my $indexlevel = 'full';
  40         my $altid = $ibx->{altid};
  41         if ($altid) {
  42                 require PublicInbox::AltId;
  43                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  44         }
  45         if ($ibx->{indexlevel}) {
  46                 if ($ibx->{indexlevel} =~ $levels) {
  47                         $indexlevel = $ibx->{indexlevel};
  48                 } else {
  49                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  50                 }
  51         }
  52         $ibx = PublicInbox::InboxWritable->new($ibx);
  53         my $self = bless {
  54                 inboxdir => $inboxdir,
  55                 -inbox => $ibx,
  56                 git => $ibx->git,
  57                 -altid => $altid,
  58                 ibx_ver => $version,
  59                 indexlevel => $indexlevel,
  60         }, $class;
  61         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  62         $ibx->umask_prepare;
  63         if ($version == 1) {
  64                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  65                 my $dir = $self->xdir;
  66                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  67         } elsif ($version == 2) {
  68                 defined $shard or die "shard is required for v2\n";
  69                 # shard is a number
  70                 $self->{shard} = $shard;
  71                 $self->{lock_path} = undef;
  72         } else {
  73                 die "unsupported inbox version=$version\n";
  74         }
  75         $self->{creat} = ($creat || 0) == 1;
  76         $self;
  77 }
  78
  79 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  80
  81 sub _xdb_release {
  82         my ($self) = @_;
  83         if (need_xapian($self)) {
  84                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  85                 $xdb->close;
  86         }
  87         $self->lock_release if $self->{creat};
  88         undef;
  89 }
  90
  91 sub load_xapian_writable () {
  92         return 1 if $X->{WritableDatabase};
  93         PublicInbox::Search::load_xapian() or return;
  94         my $xap = $PublicInbox::Search::Xap;
  95         for (qw(Document TermGenerator WritableDatabase)) {
  96                 $X->{$_} = $xap.'::'.$_;
  97         }
  98         eval 'require '.$X->{WritableDatabase} or die;
  99         *sortable_serialise = $xap.'::sortable_serialise';
 100         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 101         $DB_OPEN = eval($xap.'::DB_OPEN()');
 102         1;
 103 }
 104
 105 sub _xdb_acquire {
 106         my ($self) = @_;
 107         my $flag;
 108         my $dir = $self->xdir;
 109         if (need_xapian($self)) {
 110                 croak 'already acquired' if $self->{xdb};
 111                 load_xapian_writable();
 112                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 113         }
 114         if ($self->{creat}) {
 115                 require File::Path;
 116                 $self->lock_acquire;
 117
 118                 # don't create empty Xapian directories if we don't need Xapian
 119                 my $is_shard = defined($self->{shard});
 120                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 121                         File::Path::mkpath($dir);
 122                 }
 123         }
 124         return unless defined $flag;
 125         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 126         if ($@) {
 127                 die "Failed opening $dir: ", $@;
 128         }
 129         $self->{xdb} = $xdb;
 130 }
 131
 132 sub add_val ($$$) {
 133         my ($doc, $col, $num) = @_;
 134         $num = sortable_serialise($num);
 135         $doc->add_value($col, $num);
 136 }
 137
 138 sub term_generator ($) { # write-only
 139         my ($self) = @_;
 140
 141         $self->{term_generator} //= do {
 142                 my $tg = $X->{TermGenerator}->new;
 143                 $tg->set_stemmer($self->stemmer);
 144                 $tg;
 145         }
 146 }
 147
 148 sub index_text ($$$$) {
 149         my ($self, $text, $wdf_inc, $prefix) = @_;
 150         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 151
 152         if ($self->{indexlevel} eq 'full') {
 153                 $tg->index_text($text, $wdf_inc, $prefix);
 154                 $tg->increase_termpos;
 155         } else {
 156                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 157         }
 158 }
 159
 160 sub index_users ($$) {
 161         my ($self, $smsg) = @_;
 162
 163         my $from = $smsg->from;
 164         my $to = $smsg->to;
 165         my $cc = $smsg->cc;
 166
 167         index_text($self, $from, 1, 'A'); # A - author
 168         index_text($self, $to, 1, 'XTO') if $to ne '';
 169         index_text($self, $cc, 1, 'XCC') if $cc ne '';
 170 }
 171
 172 sub index_diff_inc ($$$$) {
 173         my ($self, $text, $pfx, $xnq) = @_;
 174         if (@$xnq) {
 175                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 176                 @$xnq = ();
 177         }
 178         index_text($self, $text, 1, $pfx);
 179 }
 180
 181 sub index_old_diff_fn {
 182         my ($self, $seen, $fa, $fb, $xnq) = @_;
 183
 184         # no renames or space support for traditional diffs,
 185         # find the number of leading common paths to strip:
 186         my @fa = split('/', $fa);
 187         my @fb = split('/', $fb);
 188         while (scalar(@fa) && scalar(@fb)) {
 189                 $fa = join('/', @fa);
 190                 $fb = join('/', @fb);
 191                 if ($fa eq $fb) {
 192                         unless ($seen->{$fa}++) {
 193                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 194                         }
 195                         return 1;
 196                 }
 197                 shift @fa;
 198                 shift @fb;
 199         }
 200         0;
 201 }
 202
 203 sub index_diff ($$$) {
 204         my ($self, $txt, $doc) = @_;
 205         my %seen;
 206         my $in_diff;
 207         my @xnq;
 208         my $xnq = \@xnq;
 209         foreach (split(/\n/, $txt)) {
 210                 if ($in_diff && s/^ //) { # diff context
 211                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 212                 } elsif (/^-- $/) { # email signature begins
 213                         $in_diff = undef;
 214                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 215                         # wait until "---" and "+++" to capture filenames
 216                         $in_diff = 1;
 217                 # traditional diff:
 218                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 219                         my ($opt, $fa, $fb) = ($1, $2, $3);
 220                         push @xnq, $_;
 221                         # only support unified:
 222                         next unless $opt =~ /[uU]/;
 223                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 224                                                         $xnq);
 225                 } elsif (m!^--- ("?[^/]+/.+)!) {
 226                         my $fn = $1;
 227                         $fn = (split('/', git_unquote($fn), 2))[1];
 228                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 229                         $in_diff = 1;
 230                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 231                         my $fn = $1;
 232                         $fn = (split('/', git_unquote($fn), 2))[1];
 233                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 234                         $in_diff = 1;
 235                 } elsif (/^--- (\S+)/) {
 236                         $in_diff = $1;
 237                         push @xnq, $_;
 238                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 239                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 240                                                         $1, $xnq);
 241                 } elsif ($in_diff && s/^\+//) { # diff added
 242                         index_diff_inc($self, $_, 'XDFB', $xnq);
 243                 } elsif ($in_diff && s/^-//) { # diff removed
 244                         index_diff_inc($self, $_, 'XDFA', $xnq);
 245                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 246                         my ($ba, $bb) = ($1, $2);
 247                         index_git_blob_id($doc, 'XDFPRE', $ba);
 248                         index_git_blob_id($doc, 'XDFPOST', $bb);
 249                         $in_diff = 1;
 250                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 251                         # traditional diff w/o -p
 252                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 253                         # hunk header context
 254                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 255                 # ignore the following lines:
 256                 } elsif (/^(?:dis)similarity index/ ||
 257                                 /^(?:old|new) mode/ ||
 258                                 /^(?:deleted|new) file mode/ ||
 259                                 /^(?:copy|rename) (?:from|to) / ||
 260                                 /^(?:dis)?similarity index / ||
 261                                 /^\\ No newline at end of file/ ||
 262                                 /^Binary files .* differ/) {
 263                         push @xnq, $_;
 264                 } elsif ($_ eq '') {
 265                         # possible to be in diff context, some mail may be
 266                         # stripped by MUA or even GNU diff(1).  "git apply"
 267                         # treats a bare "\n" as diff context, too
 268                 } else {
 269                         push @xnq, $_;
 270                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 271                         $in_diff = undef;
 272                 }
 273         }
 274
 275         index_text($self, join("\n", @xnq), 1, 'XNQ');
 276 }
 277
 278 sub index_body ($$$) {
 279         my ($self, $txt, $doc) = @_;
 280         if ($doc) {
 281                 # does it look like a diff?
 282                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 283                         index_diff($self, $txt, $doc);
 284                 } else {
 285                         index_text($self, $txt, 1, 'XNQ');
 286                 }
 287         } else {
 288                 index_text($self, $txt, 0, 'XQUOT');
 289         }
 290 }
 291
 292 sub index_xapian { # msg_iter callback
 293         my ($part, $depth, @idx) = @{$_[0]};
 294         my ($self, $doc) = @{$_[1]};
 295         my $ct = $part->content_type || 'text/plain';
 296         my $fn = $part->filename;
 297         if (defined $fn && $fn ne '') {
 298                 index_text($self, $fn, 1, 'XFN');
 299         }
 300
 301         my ($s, undef) = msg_part_text($part, $ct);
 302         defined $s or return;
 303
 304         # split off quoted and unquoted blocks:
 305         my @sections = split(/((?:^>[^\n]*\n)+)/sm, $s);
 306         $part = $s = undef;
 307         index_body($self, $_, /\A>/ ? 0 : $doc) for @sections;
 308 }
 309
 310 sub add_xapian ($$$$) {
 311         my ($self, $mime, $smsg, $mids) = @_;
 312         $smsg->{mime} = $mime; # XXX dangerous
 313         my $hdr = $mime->header_obj;
 314         my $doc = $X->{Document}->new;
 315         my $subj = $smsg->subject;
 316         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 317         my @ds = gmtime($smsg->{ds});
 318         my $yyyymmdd = strftime('%Y%m%d', @ds);
 319         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 320         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 321         add_val($doc, PublicInbox::Search::DT(), $dt);
 322
 323         my $tg = term_generator($self);
 324
 325         $tg->set_document($doc);
 326         index_text($self, $subj, 1, 'S') if $subj;
 327         index_users($self, $smsg);
 328
 329         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 330         foreach my $mid (@$mids) {
 331                 index_text($self, $mid, 1, 'XM');
 332
 333                 # because too many Message-IDs are prefixed with
 334                 # "Pine.LNX."...
 335                 if ($mid =~ /\w{12,}/) {
 336                         my @long = ($mid =~ /(\w{3,}+)/g);
 337                         index_text($self, join(' ', @long), 1, 'XM');
 338                 }
 339         }
 340         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 341         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 342         my $data = $smsg->to_doc_data;
 343         $doc->set_data($data);
 344         if (my $altid = $self->{-altid}) {
 345                 foreach my $alt (@$altid) {
 346                         my $pfx = $alt->{xprefix};
 347                         foreach my $mid (@$mids) {
 348                                 my $id = $alt->mid2alt($mid);
 349                                 next unless defined $id;
 350                                 $doc->add_boolean_term($pfx . $id);
 351                         }
 352                 }
 353         }
 354         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 355         $self->{xdb}->replace_document($smsg->{num}, $doc);
 356 }
 357
 358 sub _msgmap_init ($) {
 359         my ($self) = @_;
 360         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 361         $self->{mm} //= eval {
 362                 require PublicInbox::Msgmap;
 363                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 364         };
 365 }
 366
 367 sub add_message {
 368         # mime = Email::MIME object
 369         my ($self, $mime, $smsg) = @_;
 370         my $hdr = $mime->header_obj;
 371         my $mids = mids_for_index($hdr);
 372         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 373         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 374         $smsg->{num} //= do { # v1
 375                 _msgmap_init($self);
 376                 index_mm($self, $mime);
 377         };
 378
 379         # v1 and tests only:
 380         $smsg->{ds} //= msg_datestamp($hdr, $self->{autime});
 381         $smsg->{ts} //= msg_timestamp($hdr, $self->{cotime});
 382
 383         eval {
 384                 # order matters, overview stores every possible piece of
 385                 # data in doc_data (deflated).  Xapian only stores a subset
 386                 # of the fields which exist in over.sqlite3.  We may stop
 387                 # storing doc_data in Xapian sometime after we get multi-inbox
 388                 # search working.
 389                 if (my $over = $self->{over}) { # v1 only
 390                         $over->add_overview($mime, $smsg);
 391                 }
 392                 if (need_xapian($self)) {
 393                         add_xapian($self, $mime, $smsg, $mids);
 394                 }
 395         };
 396
 397         if ($@) {
 398                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 399                 return undef;
 400         }
 401         $smsg->{num};
 402 }
 403
 404 # returns begin and end PostingIterator
 405 sub find_doc_ids {
 406         my ($self, $termval) = @_;
 407         my $db = $self->{xdb};
 408
 409         ($db->postlist_begin($termval), $db->postlist_end($termval));
 410 }
 411
 412 # v1 only
 413 sub batch_do {
 414         my ($self, $termval, $cb) = @_;
 415         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 416         while (1) {
 417                 my ($head, $tail) = $self->find_doc_ids($termval);
 418                 return if $head == $tail;
 419                 my @ids;
 420                 for (; $head != $tail && @ids < $batch_size; $head++) {
 421                         push @ids, $head->get_docid;
 422                 }
 423                 $cb->(\@ids);
 424         }
 425 }
 426
 427 # v1 only, where $mid is unique
 428 sub remove_message {
 429         my ($self, $mid) = @_;
 430         $mid = mid_clean($mid);
 431
 432         if (my $over = $self->{over}) {
 433                 my $nr = eval { $over->remove_oid(undef, $mid) };
 434                 if ($@) {
 435                         warn "failed to remove <$mid> from overview: $@\n";
 436                 } elsif ($nr == 0) {
 437                         warn "<$mid> missing for removal from overview\n";
 438                 }
 439         }
 440         return unless need_xapian($self);
 441         my $db = $self->{xdb};
 442         my $nr = 0;
 443         eval {
 444                 batch_do($self, 'Q' . $mid, sub {
 445                         my ($ids) = @_;
 446                         $db->delete_document($_) for @$ids;
 447                         $nr += scalar @$ids;
 448                 });
 449         };
 450         if ($@) {
 451                 warn "failed to remove <$mid> from Xapian: $@\n";
 452         } elsif ($nr == 0) {
 453                 warn "<$mid> missing for removal from Xapian\n";
 454         }
 455 }
 456
 457 # MID is a hint in V2
 458 sub remove_by_oid {
 459         my ($self, $oid, $mid) = @_;
 460
 461         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 462
 463         return unless need_xapian($self);
 464         my $db = $self->{xdb};
 465
 466         # XXX careful, we cannot use batch_do here since we conditionally
 467         # delete documents based on other factors, so we cannot call
 468         # find_doc_ids twice.
 469         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 470         return if $head == $tail;
 471
 472         # there is only ONE element in @delete unless we
 473         # have bugs in our v2writable deduplication check
 474         my @delete;
 475         for (; $head != $tail; $head++) {
 476                 my $docid = $head->get_docid;
 477                 my $doc = $db->get_document($docid);
 478                 my $smsg = PublicInbox::Smsg->wrap($mid);
 479                 $smsg->load_expand($doc);
 480                 if ($smsg->{blob} eq $oid) {
 481                         push(@delete, $docid);
 482                 }
 483         }
 484         $db->delete_document($_) foreach @delete;
 485         scalar(@delete);
 486 }
 487
 488 sub index_git_blob_id {
 489         my ($doc, $pfx, $objid) = @_;
 490
 491         my $len = length($objid);
 492         for (my $len = length($objid); $len >= 7; ) {
 493                 $doc->add_term($pfx.$objid);
 494                 $objid = substr($objid, 0, --$len);
 495         }
 496 }
 497
 498 sub unindex_blob {
 499         my ($self, $mime) = @_;
 500         my $mid = eval { mid_clean(mid_mime($mime)) };
 501         $self->remove_message($mid) if defined $mid;
 502 }
 503
 504 sub index_mm {
 505         my ($self, $mime) = @_;
 506         my $mid = mid_clean(mid_mime($mime));
 507         my $mm = $self->{mm};
 508         my $num;
 509
 510         if (defined $self->{regen_down}) {
 511                 $num = $mm->num_for($mid) and return $num;
 512
 513                 while (($num = $self->{regen_down}--) > 0) {
 514                         if ($mm->mid_set($num, $mid) != 0) {
 515                                 return $num;
 516                         }
 517                 }
 518         } elsif (defined $self->{regen_up}) {
 519                 $num = $mm->num_for($mid) and return $num;
 520
 521                 # this is to fixup old bugs due to add-remove-add
 522                 while (($num = ++$self->{regen_up})) {
 523                         if ($mm->mid_set($num, $mid) != 0) {
 524                                 return $num;
 525                         }
 526                 }
 527         }
 528
 529         $num = $mm->mid_insert($mid) and return $num;
 530
 531         # fallback to num_for since filters like RubyLang set the number
 532         $mm->num_for($mid);
 533 }
 534
 535 sub unindex_mm {
 536         my ($self, $mime) = @_;
 537         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 538 }
 539
 540 sub index_both {
 541         my ($self, $mime, $smsg) = @_;
 542         my $num = index_mm($self, $mime);
 543         $smsg->{num} = $num;
 544         add_message($self, $mime, $smsg);
 545 }
 546
 547 sub unindex_both {
 548         my ($self, $mime) = @_;
 549         unindex_blob($self, $mime);
 550         unindex_mm($self, $mime);
 551 }
 552
 553 sub do_cat_mail {
 554         my ($git, $blob, $sizeref) = @_;
 555         my $mime = eval {
 556                 my $str = $git->cat_file($blob, $sizeref);
 557                 # fixup bugs from import:
 558                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 559                 PublicInbox::MIME->new($str);
 560         };
 561         $@ ? undef : $mime;
 562 }
 563
 564 # called by public-inbox-index
 565 sub index_sync {
 566         my ($self, $opts) = @_;
 567         delete $self->{lock_path} if $opts->{-skip_lock};
 568         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 569 }
 570
 571 sub batch_adjust ($$$$$) {
 572         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 573         $$max -= $bytes;
 574         if ($$max <= 0) {
 575                 $$max = BATCH_BYTES;
 576                 $batch_cb->($nr, $latest);
 577         }
 578 }
 579
 580 # only for v1
 581 sub read_log {
 582         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 583         my $hex = '[a-f0-9]';
 584         my $h40 = $hex .'{40}';
 585         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 586         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 587         my $git = $self->{git};
 588         my $latest;
 589         my $bytes;
 590         my $max = BATCH_BYTES;
 591         local $/ = "\n";
 592         my %D;
 593         my $line;
 594         my $newest;
 595         my $nr = 0;
 596         while (defined($line = <$log>)) {
 597                 if ($line =~ /$addmsg/o) {
 598                         my $blob = $1;
 599                         if (delete $D{$blob}) {
 600                                 if (defined $self->{regen_down}) {
 601                                         my $num = $self->{regen_down}--;
 602                                         $self->{mm}->num_highwater($num);
 603                                 }
 604                                 next;
 605                         }
 606                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 607                         my $smsg = bless {}, 'PublicInbox::Smsg';
 608                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 609                         $smsg->{blob} = $blob;
 610                         $smsg->{bytes} = $bytes;
 611                         $add_cb->($self, $mime, $smsg);
 612                 } elsif ($line =~ /$delmsg/o) {
 613                         my $blob = $1;
 614                         $D{$blob} = 1;
 615                 } elsif ($line =~ /^commit ($h40)/o) {
 616                         $latest = $1;
 617                         $newest ||= $latest;
 618                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 619                         $self->{autime} = $1;
 620                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 621                         $self->{cotime} = $1;
 622                 }
 623         }
 624         close($log) or die "git log failed: \$?=$?";
 625         # get the leftovers
 626         foreach my $blob (keys %D) {
 627                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 628                 $del_cb->($self, $mime);
 629         }
 630         $batch_cb->($nr, $latest, $newest);
 631 }
 632
 633 sub _git_log {
 634         my ($self, $opts, $range) = @_;
 635         my $git = $self->{git};
 636
 637         if (index($range, '..') < 0) {
 638                 # don't show annoying git errrors to users who run -index
 639                 # on empty inboxes
 640                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 641                 if ($?) {
 642                         open my $fh, '<', '/dev/null' or
 643                                 die "failed to open /dev/null: $!\n";
 644                         return $fh;
 645                 }
 646         }
 647
 648         # Count the new files so they can be added newest to oldest
 649         # and still have numbers increasing from oldest to newest
 650         my $fcount = 0;
 651         my $pr = $opts->{-progress};
 652         $pr->("counting changes\n\t$range ... ") if $pr;
 653         # can't use 'rev-list --count' if we use --diff-filter
 654         my $fh = $git->popen(qw(log --pretty=tformat:%h
 655                              --no-notes --no-color --no-renames
 656                              --diff-filter=AM), $range);
 657         ++$fcount while <$fh>;
 658         close $fh or die "git log failed: \$?=$?";
 659         my $high = $self->{mm}->num_highwater;
 660         $pr->("$fcount\n") if $pr; # continue previous line
 661         $self->{ntodo} = $fcount;
 662
 663         if (index($range, '..') < 0) {
 664                 if ($high && $high == $fcount) {
 665                         # fix up old bugs in full indexes which caused messages to
 666                         # not appear in Msgmap
 667                         $self->{regen_up} = $high;
 668                 } else {
 669                         # normal regen is for for fresh data
 670                         $self->{regen_down} = $fcount;
 671                 }
 672         } else {
 673                 # Give oldest messages the smallest numbers
 674                 $self->{regen_down} = $high + $fcount;
 675         }
 676
 677         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 678                                 --raw -r --no-abbrev/, $range);
 679 }
 680
 681 # --is-ancestor requires git 1.8.0+
 682 sub is_ancestor ($$$) {
 683         my ($git, $cur, $tip) = @_;
 684         return 0 unless $git->check($cur);
 685         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 686                 qw(merge-base --is-ancestor), $cur, $tip ];
 687         my $pid = spawn($cmd);
 688         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 689         $? == 0;
 690 }
 691
 692 sub need_update ($$$) {
 693         my ($self, $cur, $new) = @_;
 694         my $git = $self->{git};
 695         return 1 if $cur && !is_ancestor($git, $cur, $new);
 696         my $range = $cur eq '' ? $new : "$cur..$new";
 697         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 698         ($n eq '' || $n > 0);
 699 }
 700
 701 # The last git commit we indexed with Xapian or SQLite (msgmap)
 702 # This needs to account for cases where Xapian or SQLite is
 703 # out-of-date with respect to the other.
 704 sub _last_x_commit {
 705         my ($self, $mm) = @_;
 706         my $lm = $mm->last_commit || '';
 707         my $lx = '';
 708         if (need_xapian($self)) {
 709                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 710         } else {
 711                 $lx = $lm;
 712         }
 713         # Use last_commit from msgmap if it is older or unset
 714         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 715                 $lx = $lm;
 716         }
 717         $lx;
 718 }
 719
 720 sub reindex_from ($$) {
 721         my ($reindex, $last_commit) = @_;
 722         return $last_commit unless $reindex;
 723         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 724 }
 725
 726 # indexes all unindexed messages (v1 only)
 727 sub _index_sync {
 728         my ($self, $opts) = @_;
 729         my $tip = $opts->{ref} || 'HEAD';
 730         my ($last_commit, $lx, $xlog);
 731         my $git = $self->{git};
 732         $git->batch_prepare;
 733         my $pr = $opts->{-progress};
 734
 735         my $xdb = $self->begin_txn_lazy;
 736         my $mm = _msgmap_init($self);
 737         do {
 738                 if ($xlog) {
 739                         close($xlog) or die "git log failed: \$?=$?";
 740                         $xlog = undef;
 741                 }
 742                 $last_commit = _last_x_commit($self, $mm);
 743                 $lx = reindex_from($opts->{reindex}, $last_commit);
 744
 745                 $self->{over}->rollback_lazy;
 746                 $self->{over}->disconnect;
 747                 $git->cleanup;
 748                 delete $self->{txn};
 749                 $xdb->cancel_transaction if $xdb;
 750                 $xdb = _xdb_release($self);
 751
 752                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 753                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 754                 $xlog = _git_log($self, $opts, $range);
 755
 756                 $xdb = $self->begin_txn_lazy;
 757         } while (_last_x_commit($self, $mm) ne $last_commit);
 758
 759         my $dbh = $mm->{dbh} if $mm;
 760         my $cb = sub {
 761                 my ($nr, $commit, $newest) = @_;
 762                 if ($dbh) {
 763                         if ($newest) {
 764                                 my $cur = $mm->last_commit || '';
 765                                 if (need_update($self, $cur, $newest)) {
 766                                         $mm->last_commit($newest);
 767                                 }
 768                         }
 769                         $dbh->commit;
 770                 }
 771                 if ($newest && need_xapian($self)) {
 772                         my $cur = $xdb->get_metadata('last_commit');
 773                         if (need_update($self, $cur, $newest)) {
 774                                 $xdb->set_metadata('last_commit', $newest);
 775                         }
 776                 }
 777                 $self->commit_txn_lazy;
 778                 $git->cleanup;
 779                 $xdb = _xdb_release($self);
 780                 # let another process do some work... <
 781                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 782                 if (!$newest) {
 783                         $xdb = $self->begin_txn_lazy;
 784                         $dbh->begin_work if $dbh;
 785                 }
 786         };
 787
 788         $dbh->begin_work;
 789         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 790 }
 791
 792 sub DESTROY {
 793         # order matters for unlocking
 794         $_[0]->{xdb} = undef;
 795         $_[0]->{lockfh} = undef;
 796 }
 797
 798 # remote_* subs are only used by SearchIdxPart
 799 sub remote_commit {
 800         my ($self) = @_;
 801         if (my $w = $self->{w}) {
 802                 print $w "commit\n" or die "failed to write commit: $!";
 803         } else {
 804                 $self->commit_txn_lazy;
 805         }
 806 }
 807
 808 sub remote_close {
 809         my ($self) = @_;
 810         if (my $w = delete $self->{w}) {
 811                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 812                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 813                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 814                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 815                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 816         } else {
 817                 die "transaction in progress $self\n" if $self->{txn};
 818                 $self->_xdb_release if $self->{xdb};
 819         }
 820 }
 821
 822 sub remote_remove {
 823         my ($self, $oid, $mid) = @_;
 824         if (my $w = $self->{w}) {
 825                 # triggers remove_by_oid in a shard
 826                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 827         } else {
 828                 $self->begin_txn_lazy;
 829                 $self->remove_by_oid($oid, $mid);
 830         }
 831 }
 832
 833 sub begin_txn_lazy {
 834         my ($self) = @_;
 835         return if $self->{txn};
 836
 837         $self->{-inbox}->with_umask(sub {
 838                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 839                 $self->{over}->begin_lazy if $self->{over};
 840                 $xdb->begin_transaction if $xdb;
 841                 $self->{txn} = 1;
 842                 $xdb;
 843         });
 844 }
 845
 846 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 847 # This metadata is read by Admin::detect_indexlevel:
 848 sub set_indexlevel {
 849         my ($self) = @_;
 850
 851         if (!$self->{shard} && # undef or 0, not >0
 852                         delete($self->{-set_indexlevel_once})) {
 853                 my $xdb = $self->{xdb};
 854                 my $level = $xdb->get_metadata('indexlevel');
 855                 if (!$level || $level ne 'medium') {
 856                         $xdb->set_metadata('indexlevel', 'medium');
 857                 }
 858         }
 859 }
 860
 861 sub commit_txn_lazy {
 862         my ($self) = @_;
 863         delete $self->{txn} or return;
 864         $self->{-inbox}->with_umask(sub {
 865                 if (my $xdb = $self->{xdb}) {
 866                         set_indexlevel($self);
 867                         $xdb->commit_transaction;
 868                 }
 869                 $self->{over}->commit_lazy if $self->{over};
 870         });
 871 }
 872
 873 sub worker_done {
 874         my ($self) = @_;
 875         if (need_xapian($self)) {
 876                 die "$$ $0 xdb not released\n" if $self->{xdb};
 877         }
 878         die "$$ $0 still in transaction\n" if $self->{txn};
 879 }
 880
 881 1;