lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::Search qw(xap_terms);
  15 use PublicInbox::InboxWritable;
  16 use PublicInbox::MID qw(mids_for_index mids);
  17 use PublicInbox::MsgIter;
  18 use PublicInbox::IdxStack;
  19 use Carp qw(croak carp);
  20 use POSIX qw(strftime);
  21 use Time::Local qw(timegm);
  22 use PublicInbox::OverIdx;
  23 use PublicInbox::Spawn qw(spawn);
  24 use PublicInbox::Git qw(git_unquote);
  25 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  26 use PublicInbox::Address;
  27 use Config;
  28 our @EXPORT_OK = qw(log2stack is_ancestor check_size prepare_stack
  29         index_text term_generator add_val is_bad_blob);
  30 my $X = \%PublicInbox::Search::X;
  31 our ($DB_CREATE_OR_OPEN, $DB_OPEN);
  32 our $DB_NO_SYNC = 0;
  33 our $DB_DANGEROUS = 0;
  34 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff :
  35         # assume a typical 64-bit system has 8x more RAM than a
  36         # typical 32-bit system:
  37         (($Config{ptrsize} >= 8 ? 8192 : 1024) * 1024);
  38
  39 use constant DEBUG => !!$ENV{DEBUG};
  40
  41 my $xapianlevels = qr/\A(?:full|medium)\z/;
  42 my $hex = '[a-f0-9]';
  43 my $OID = $hex .'{40,}';
  44 my @VMD_MAP = (kw => 'K', L => 'L');
  45 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  46
  47 sub new {
  48         my ($class, $ibx, $creat, $shard) = @_;
  49         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  50         my $inboxdir = $ibx->{inboxdir};
  51         my $version = $ibx->version;
  52         my $indexlevel = 'full';
  53         my $altid = $ibx->{altid};
  54         if ($altid) {
  55                 require PublicInbox::AltId;
  56                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  57         }
  58         if ($ibx->{indexlevel}) {
  59                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  60                         $indexlevel = $ibx->{indexlevel};
  61                 } else {
  62                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  63                 }
  64         }
  65         $ibx = PublicInbox::InboxWritable->new($ibx);
  66         my $self = PublicInbox::Search->new($ibx);
  67         bless $self, $class;
  68         $self->{ibx} = $ibx;
  69         $self->{-altid} = $altid;
  70         $self->{indexlevel} = $indexlevel;
  71         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  72         if ($ibx->{-skip_docdata}) {
  73                 $self->{-set_skip_docdata_once} = 1;
  74                 $self->{-skip_docdata} = 1;
  75         }
  76         if ($version == 1) {
  77                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  78                 my $dir = $self->xdir;
  79                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  80                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  81         } elsif ($version == 2) {
  82                 defined $shard or die "shard is required for v2\n";
  83                 # shard is a number
  84                 $self->{shard} = $shard;
  85                 $self->{lock_path} = undef;
  86         } else {
  87                 die "unsupported inbox version=$version\n";
  88         }
  89         $self->{creat} = ($creat || 0) == 1;
  90         $self;
  91 }
  92
  93 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  94
  95 sub idx_release {
  96         my ($self, $wake) = @_;
  97         if (need_xapian($self)) {
  98                 my $xdb = delete $self->{xdb} or croak '{xdb} not acquired';
  99                 $xdb->close;
 100         }
 101         $self->lock_release($wake) if $self->{creat};
 102         undef;
 103 }
 104
 105 sub load_xapian_writable () {
 106         return 1 if $X->{WritableDatabase};
 107         PublicInbox::Search::load_xapian() or die "failed to load Xapian: $@\n";
 108         my $xap = $PublicInbox::Search::Xap;
 109         for (qw(Document TermGenerator WritableDatabase)) {
 110                 $X->{$_} = $xap.'::'.$_;
 111         }
 112         eval 'require '.$X->{WritableDatabase} or die;
 113         *sortable_serialise = $xap.'::sortable_serialise';
 114         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 115         $DB_OPEN = eval($xap.'::DB_OPEN()');
 116         my $ver = (eval($xap.'::major_version()') << 16) |
 117                 (eval($xap.'::minor_version()') << 8) |
 118                 eval($xap.'::revision()');
 119         if ($ver >= 0x10400) {
 120                 $DB_NO_SYNC = 0x4;
 121                 $DB_DANGEROUS = 0x10;
 122         }
 123         # Xapian v1.2.21..v1.2.24 were missing close-on-exec on OFD locks
 124         $X->{CLOEXEC_UNSET} = 1 if $ver >= 0x010215 && $ver <= 0x010218;
 125         1;
 126 }
 127
 128 sub idx_acquire {
 129         my ($self) = @_;
 130         my $flag;
 131         my $dir = $self->xdir;
 132         if (need_xapian($self)) {
 133                 croak 'already acquired' if $self->{xdb};
 134                 load_xapian_writable();
 135                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 136         }
 137         if ($self->{creat}) {
 138                 require File::Path;
 139                 $self->lock_acquire;
 140
 141                 # don't create empty Xapian directories if we don't need Xapian
 142                 my $is_shard = defined($self->{shard});
 143                 if (!-d $dir && (!$is_shard ||
 144                                 ($is_shard && need_xapian($self)))) {
 145                         File::Path::mkpath($dir);
 146                         require PublicInbox::Syscall;
 147                         PublicInbox::Syscall::nodatacow_dir($dir);
 148                         $self->{-set_has_threadid_once} = 1;
 149                         if (($self->{ibx} // $self->{eidx})->{-dangerous}) {
 150                                 $flag |= $DB_DANGEROUS;
 151                         }
 152                 }
 153         }
 154         return unless defined $flag;
 155         $flag |= $DB_NO_SYNC if ($self->{ibx} // $self->{eidx})->{-no_fsync};
 156         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 157         croak "Failed opening $dir: $@" if $@;
 158         $self->{xdb} = $xdb;
 159 }
 160
 161 sub add_val ($$$) {
 162         my ($doc, $col, $num) = @_;
 163         $num = sortable_serialise($num);
 164         $doc->add_value($col, $num);
 165 }
 166
 167 sub term_generator ($) { # write-only
 168         my ($self) = @_;
 169
 170         $self->{term_generator} //= do {
 171                 my $tg = $X->{TermGenerator}->new;
 172                 $tg->set_stemmer(PublicInbox::Search::stemmer($self));
 173                 $tg;
 174         }
 175 }
 176
 177 sub index_phrase ($$$$) {
 178         my ($self, $text, $wdf_inc, $prefix) = @_;
 179
 180         my $tg = term_generator($self);
 181         $tg->index_text($text, $wdf_inc, $prefix);
 182         $tg->increase_termpos;
 183 }
 184
 185 sub index_text ($$$$) {
 186         my ($self, $text, $wdf_inc, $prefix) = @_;
 187
 188         if ($self->{indexlevel} eq 'full') {
 189                 index_phrase($self, $text, $wdf_inc, $prefix);
 190         } else {
 191                 my $tg = term_generator($self);
 192                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 193         }
 194 }
 195
 196 sub index_headers ($$) {
 197         my ($self, $smsg) = @_;
 198         my @x = (from => 'A', to => 'XTO', cc => 'XCC'); # A: Author
 199         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 200                 my $val = $smsg->{$field};
 201                 next if $val eq '';
 202                 # include "(comments)" after the address, too, so not using
 203                 # PublicInbox::Address::names or pairs
 204                 index_text($self, $val, 1, $pfx);
 205
 206                 # we need positional info for email addresses since they
 207                 # can be considered phrases
 208                 if ($self->{indexlevel} eq 'medium') {
 209                         for my $addr (PublicInbox::Address::emails($val)) {
 210                                 index_phrase($self, $addr, 1, $pfx);
 211                         }
 212                 }
 213         }
 214         @x = (subject => 'S');
 215         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 216                 my $val = $smsg->{$field};
 217                 index_text($self, $val, 1, $pfx) if $val ne '';
 218         }
 219 }
 220
 221 sub index_diff_inc ($$$$) {
 222         my ($self, $text, $pfx, $xnq) = @_;
 223         if (@$xnq) {
 224                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 225                 @$xnq = ();
 226         }
 227         if ($pfx eq 'XDFN') {
 228                 index_phrase($self, $text, 1, $pfx);
 229         } else {
 230                 index_text($self, $text, 1, $pfx);
 231         }
 232 }
 233
 234 sub index_old_diff_fn {
 235         my ($self, $seen, $fa, $fb, $xnq) = @_;
 236
 237         # no renames or space support for traditional diffs,
 238         # find the number of leading common paths to strip:
 239         my @fa = split('/', $fa);
 240         my @fb = split('/', $fb);
 241         while (scalar(@fa) && scalar(@fb)) {
 242                 $fa = join('/', @fa);
 243                 $fb = join('/', @fb);
 244                 if ($fa eq $fb) {
 245                         unless ($seen->{$fa}++) {
 246                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 247                         }
 248                         return 1;
 249                 }
 250                 shift @fa;
 251                 shift @fb;
 252         }
 253         0;
 254 }
 255
 256 sub index_diff ($$$) {
 257         my ($self, $txt, $doc) = @_;
 258         my %seen;
 259         my $in_diff;
 260         my @xnq;
 261         my $xnq = \@xnq;
 262         foreach (split(/\n/, $txt)) {
 263                 if ($in_diff && s/^ //) { # diff context
 264                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 265                 } elsif (/^-- $/) { # email signature begins
 266                         $in_diff = undef;
 267                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 268                         # wait until "---" and "+++" to capture filenames
 269                         $in_diff = 1;
 270                         push @xnq, $_;
 271                 # traditional diff:
 272                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 273                         my ($opt, $fa, $fb) = ($1, $2, $3);
 274                         push @xnq, $_;
 275                         # only support unified:
 276                         next unless $opt =~ /[uU]/;
 277                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 278                                                         $xnq);
 279                 } elsif (m!^--- ("?[^/]+/.+)!) {
 280                         my $fn = $1;
 281                         $fn = (split('/', git_unquote($fn), 2))[1];
 282                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 283                         $in_diff = 1;
 284                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 285                         my $fn = $1;
 286                         $fn = (split('/', git_unquote($fn), 2))[1];
 287                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 288                         $in_diff = 1;
 289                 } elsif (/^--- (\S+)/) {
 290                         $in_diff = $1;
 291                         push @xnq, $_;
 292                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 293                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 294                                                         $1, $xnq);
 295                 } elsif ($in_diff && s/^\+//) { # diff added
 296                         index_diff_inc($self, $_, 'XDFB', $xnq);
 297                 } elsif ($in_diff && s/^-//) { # diff removed
 298                         index_diff_inc($self, $_, 'XDFA', $xnq);
 299                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 300                         my ($ba, $bb) = ($1, $2);
 301                         index_git_blob_id($doc, 'XDFPRE', $ba);
 302                         index_git_blob_id($doc, 'XDFPOST', $bb);
 303                         $in_diff = 1;
 304                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 305                         # traditional diff w/o -p
 306                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 307                         # hunk header context
 308                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 309                 # ignore the following lines:
 310                 } elsif (/^(?:dis)similarity index/ ||
 311                                 /^(?:old|new) mode/ ||
 312                                 /^(?:deleted|new) file mode/ ||
 313                                 /^(?:copy|rename) (?:from|to) / ||
 314                                 /^(?:dis)?similarity index / ||
 315                                 /^\\ No newline at end of file/ ||
 316                                 /^Binary files .* differ/) {
 317                         push @xnq, $_;
 318                 } elsif ($_ eq '') {
 319                         # possible to be in diff context, some mail may be
 320                         # stripped by MUA or even GNU diff(1).  "git apply"
 321                         # treats a bare "\n" as diff context, too
 322                 } else {
 323                         push @xnq, $_;
 324                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 325                         $in_diff = undef;
 326                 }
 327         }
 328
 329         index_text($self, join("\n", @xnq), 1, 'XNQ');
 330 }
 331
 332 sub index_xapian { # msg_iter callback
 333         my $part = $_[0]->[0]; # ignore $depth and $idx
 334         my ($self, $doc) = @{$_[1]};
 335         my $ct = $part->content_type || 'text/plain';
 336         my $fn = $part->filename;
 337         if (defined $fn && $fn ne '') {
 338                 index_phrase($self, $fn, 1, 'XFN');
 339         }
 340         if ($part->{is_submsg}) {
 341                 my $mids = mids_for_index($part);
 342                 index_ids($self, $doc, $part, $mids);
 343                 my $smsg = bless {}, 'PublicInbox::Smsg';
 344                 $smsg->populate($part);
 345                 index_headers($self, $smsg);
 346         }
 347
 348         my ($s, undef) = msg_part_text($part, $ct);
 349         defined $s or return;
 350         $_[0]->[0] = $part = undef; # free memory
 351
 352         # split off quoted and unquoted blocks:
 353         my @sections = PublicInbox::MsgIter::split_quotes($s);
 354         undef $s; # free memory
 355         for my $txt (@sections) {
 356                 if ($txt =~ /\A>/) {
 357                         index_text($self, $txt, 0, 'XQUOT');
 358                 } else {
 359                         # does it look like a diff?
 360                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 361                                 index_diff($self, $txt, $doc);
 362                         } else {
 363                                 index_text($self, $txt, 1, 'XNQ');
 364                         }
 365                 }
 366                 undef $txt; # free memory
 367         }
 368 }
 369
 370 sub index_list_id ($$$) {
 371         my ($self, $doc, $hdr) = @_;
 372         for my $l ($hdr->header_raw('List-Id')) {
 373                 $l =~ /<([^>]+)>/ or next;
 374                 my $lid = lc $1;
 375                 $doc->add_boolean_term('G' . $lid);
 376                 index_phrase($self, $lid, 1, 'XL'); # probabilistic
 377         }
 378 }
 379
 380 sub index_ids ($$$$) {
 381         my ($self, $doc, $hdr, $mids) = @_;
 382         for my $mid (@$mids) {
 383                 index_phrase($self, $mid, 1, 'XM');
 384
 385                 # because too many Message-IDs are prefixed with
 386                 # "Pine.LNX."...
 387                 if ($mid =~ /\w{12,}/) {
 388                         my @long = ($mid =~ /(\w{3,}+)/g);
 389                         index_phrase($self, join(' ', @long), 1, 'XM');
 390                 }
 391         }
 392         $doc->add_boolean_term('Q' . $_) for @$mids;
 393         index_list_id($self, $doc, $hdr);
 394 }
 395
 396 sub eml2doc ($$$;$) {
 397         my ($self, $eml, $smsg, $mids) = @_;
 398         $mids //= mids_for_index($eml);
 399         my $doc = $X->{Document}->new;
 400         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 401         my @ds = gmtime($smsg->{ds});
 402         my $yyyymmdd = strftime('%Y%m%d', @ds);
 403         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 404         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 405         add_val($doc, PublicInbox::Search::DT(), $dt);
 406         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 407         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 408         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 409
 410         my $tg = term_generator($self);
 411         $tg->set_document($doc);
 412         index_headers($self, $smsg);
 413
 414         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 415                 $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 416         }
 417         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 418         index_ids($self, $doc, $eml, $mids);
 419
 420         # by default, we maintain compatibility with v1.5.0 and earlier
 421         # by writing to docdata.glass, users who never exect to downgrade can
 422         # use --skip-docdata
 423         if (!$self->{-skip_docdata}) {
 424                 # WWW doesn't need {to} or {cc}, only NNTP
 425                 $smsg->{to} = $smsg->{cc} = '';
 426                 $smsg->parse_references($eml, $mids);
 427                 my $data = $smsg->to_doc_data;
 428                 $doc->set_data($data);
 429         }
 430
 431         if (my $altid = $self->{-altid}) {
 432                 foreach my $alt (@$altid) {
 433                         my $pfx = $alt->{xprefix};
 434                         foreach my $mid (@$mids) {
 435                                 my $id = $alt->mid2alt($mid);
 436                                 next unless defined $id;
 437                                 $doc->add_boolean_term($pfx . $id);
 438                         }
 439                 }
 440         }
 441         $doc;
 442 }
 443
 444 sub add_xapian ($$$$) {
 445         my ($self, $eml, $smsg, $mids) = @_;
 446         begin_txn_lazy($self);
 447         my $merge_vmd = delete $smsg->{-merge_vmd};
 448         my $doc = eml2doc($self, $eml, $smsg, $mids);
 449         if (my $old = $merge_vmd ? _get_doc($self, $smsg->{num}) : undef) {
 450                 my @x = @VMD_MAP;
 451                 while (my ($field, $pfx) = splice(@x, 0, 2)) {
 452                         for my $term (xap_terms($pfx, $old)) {
 453                                 $doc->add_boolean_term($pfx.$term);
 454                         }
 455                 }
 456         }
 457         $self->{xdb}->replace_document($smsg->{num}, $doc);
 458 }
 459
 460 sub _msgmap_init ($) {
 461         my ($self) = @_;
 462         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx}->version != 1;
 463         $self->{mm} //= do {
 464                 require PublicInbox::Msgmap;
 465                 PublicInbox::Msgmap->new_file($self->{ibx}, 1);
 466         };
 467 }
 468
 469 sub add_message {
 470         # mime = PublicInbox::Eml or Email::MIME object
 471         my ($self, $mime, $smsg, $sync) = @_;
 472         begin_txn_lazy($self);
 473         my $mids = mids_for_index($mime);
 474         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 475         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 476         $smsg->{num} //= do { # v1
 477                 _msgmap_init($self);
 478                 index_mm($self, $mime, $smsg->{blob}, $sync);
 479         };
 480
 481         # v1 and tests only:
 482         $smsg->populate($mime, $sync);
 483         $smsg->{bytes} //= length($mime->as_string);
 484
 485         eval {
 486                 # order matters, overview stores every possible piece of
 487                 # data in doc_data (deflated).  Xapian only stores a subset
 488                 # of the fields which exist in over.sqlite3.  We may stop
 489                 # storing doc_data in Xapian sometime after we get multi-inbox
 490                 # search working.
 491                 if (my $oidx = $self->{oidx}) { # v1 only
 492                         $oidx->add_overview($mime, $smsg);
 493                 }
 494                 if (need_xapian($self)) {
 495                         add_xapian($self, $mime, $smsg, $mids);
 496                 }
 497         };
 498
 499         if ($@) {
 500                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 501                 return undef;
 502         }
 503         $smsg->{num};
 504 }
 505
 506 sub _get_doc ($$) {
 507         my ($self, $docid) = @_;
 508         my $doc = eval { $self->{xdb}->get_document($docid) };
 509         $doc // do {
 510                 warn "E: $@\n" if $@;
 511                 warn "E: #$docid missing in Xapian\n";
 512                 undef;
 513         }
 514 }
 515
 516 sub add_eidx_info {
 517         my ($self, $docid, $eidx_key, $eml) = @_;
 518         begin_txn_lazy($self);
 519         my $doc = _get_doc($self, $docid) or return;
 520         term_generator($self)->set_document($doc);
 521
 522         # '.' is special for lei_store
 523         $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 524
 525         index_list_id($self, $doc, $eml);
 526         $self->{xdb}->replace_document($docid, $doc);
 527 }
 528
 529 sub get_terms {
 530         my ($self, $pfx, $docid) = @_;
 531         begin_txn_lazy($self);
 532         xap_terms($pfx, $self->{xdb}, $docid);
 533 }
 534
 535 sub remove_eidx_info {
 536         my ($self, $docid, $eidx_key, $eml) = @_;
 537         begin_txn_lazy($self);
 538         my $doc = _get_doc($self, $docid) or return;
 539         eval { $doc->remove_term('O'.$eidx_key) };
 540         warn "W: ->remove_term O$eidx_key: $@\n" if $@;
 541         for my $l ($eml ? $eml->header_raw('List-Id') : ()) {
 542                 $l =~ /<([^>]+)>/ or next;
 543                 my $lid = lc $1;
 544                 eval { $doc->remove_term('G' . $lid) };
 545                 warn "W: ->remove_term G$lid: $@\n" if $@;
 546
 547                 # nb: we don't remove the XL probabilistic terms
 548                 # since terms may overlap if cross-posted.
 549                 #
 550                 # IOW, a message which has both <foo.example.com>
 551                 # and <bar.example.com> would have overlapping
 552                 # "XLexample" and "XLcom" as terms and which we
 553                 # wouldn't know if they're safe to remove if we just
 554                 # unindex <foo.example.com> while preserving
 555                 # <bar.example.com>.
 556                 #
 557                 # In any case, this entire sub is will likely never
 558                 # be needed and users using the "l:" prefix are probably
 559                 # rarer.
 560         }
 561         $self->{xdb}->replace_document($docid, $doc);
 562 }
 563
 564 sub set_vmd {
 565         my ($self, $docid, $vmd) = @_;
 566         begin_txn_lazy($self);
 567         my $doc = _get_doc($self, $docid) or return;
 568         my ($end, @rm, @add);
 569         my @x = @VMD_MAP;
 570         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 571                 my $set = $vmd->{$field} // next;
 572                 my %keep = map { $_ => 1 } @$set;
 573                 my %add = %keep;
 574                 $end //= $doc->termlist_end;
 575                 for (my $cur = $doc->termlist_begin; $cur != $end; $cur++) {
 576                         $cur->skip_to($pfx);
 577                         last if $cur == $end;
 578                         my $v = $cur->get_termname;
 579                         $v =~ s/\A$pfx//s or next;
 580                         $keep{$v} ? delete($add{$v}) : push(@rm, $pfx.$v);
 581                 }
 582                 push(@add, map { $pfx.$_ } keys %add);
 583         }
 584         return unless scalar(@rm) || scalar(@add);
 585         $doc->remove_term($_) for @rm;
 586         $doc->add_boolean_term($_) for @add;
 587         $self->{xdb}->replace_document($docid, $doc);
 588 }
 589
 590 sub apply_vmd_mod ($$) {
 591         my ($doc, $vmd_mod) = @_;
 592         my $updated = 0;
 593         my @x = @VMD_MAP;
 594         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 595                 # field: "L" or "kw"
 596                 for my $val (@{$vmd_mod->{"-$field"} // []}) {
 597                         eval {
 598                                 $doc->remove_term($pfx . $val);
 599                                 ++$updated;
 600                         };
 601                 }
 602                 for my $val (@{$vmd_mod->{"+$field"} // []}) {
 603                         $doc->add_boolean_term($pfx . $val);
 604                         ++$updated;
 605                 }
 606         }
 607         $updated;
 608 }
 609
 610 sub add_vmd {
 611         my ($self, $docid, $vmd) = @_;
 612         begin_txn_lazy($self);
 613         my $doc = _get_doc($self, $docid) or return;
 614         my @x = @VMD_MAP;
 615         my $updated = 0;
 616         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 617                 my $add = $vmd->{$field} // next;
 618                 $doc->add_boolean_term($pfx . $_) for @$add;
 619                 $updated += scalar(@$add);
 620         }
 621         $updated += apply_vmd_mod($doc, $vmd);
 622         $self->{xdb}->replace_document($docid, $doc) if $updated;
 623 }
 624
 625 sub remove_vmd {
 626         my ($self, $docid, $vmd) = @_;
 627         begin_txn_lazy($self);
 628         my $doc = _get_doc($self, $docid) or return;
 629         my $replace;
 630         my @x = @VMD_MAP;
 631         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 632                 my $rm = $vmd->{$field} // next;
 633                 for (@$rm) {
 634                         eval {
 635                                 $doc->remove_term($pfx . $_);
 636                                 $replace = 1;
 637                         };
 638                 }
 639         }
 640         $self->{xdb}->replace_document($docid, $doc) if $replace;
 641 }
 642
 643 sub update_vmd {
 644         my ($self, $docid, $vmd_mod) = @_;
 645         begin_txn_lazy($self);
 646         my $doc = _get_doc($self, $docid) or return;
 647         my $updated = apply_vmd_mod($doc, $vmd_mod);
 648         $self->{xdb}->replace_document($docid, $doc) if $updated;
 649         $updated;
 650 }
 651
 652 sub xdb_remove {
 653         my ($self, @docids) = @_;
 654         begin_txn_lazy($self);
 655         my $xdb = $self->{xdb} // die 'BUG: missing {xdb}';
 656         for my $docid (@docids) {
 657                 eval { $xdb->delete_document($docid) };
 658                 warn "E: #$docid not in in Xapian? $@\n" if $@;
 659         }
 660 }
 661
 662 sub xdb_remove_quiet {
 663         my ($self, $docid) = @_;
 664         begin_txn_lazy($self);
 665         my $xdb = $self->{xdb} // die 'BUG: missing {xdb}';
 666         eval { $xdb->delete_document($docid) };
 667         ++$self->{-quiet_rm} unless $@;
 668 }
 669
 670 sub nr_quiet_rm { delete($_[0]->{-quiet_rm}) // 0 }
 671
 672 sub index_git_blob_id {
 673         my ($doc, $pfx, $objid) = @_;
 674
 675         my $len = length($objid);
 676         for (my $len = length($objid); $len >= 7; ) {
 677                 $doc->add_term($pfx.$objid);
 678                 $objid = substr($objid, 0, --$len);
 679         }
 680 }
 681
 682 # v1 only
 683 sub unindex_eml {
 684         my ($self, $oid, $eml) = @_;
 685         my $mids = mids($eml);
 686         my $nr = 0;
 687         my %tmp;
 688         for my $mid (@$mids) {
 689                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 690                 $nr += scalar @removed;
 691                 $tmp{$_}++ for @removed;
 692         }
 693         if (!$nr) {
 694                 my $m = join('> <', @$mids);
 695                 warn "W: <$m> missing for removal from overview\n";
 696         }
 697         while (my ($num, $nr) = each %tmp) {
 698                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 699         }
 700         if ($nr) {
 701                 $self->{mm}->num_delete($_) for (keys %tmp);
 702         } else { # just in case msgmap and over.sqlite3 become desynched:
 703                 $self->{mm}->mid_delete($mids->[0]);
 704         }
 705         xdb_remove($self, keys %tmp) if need_xapian($self);
 706 }
 707
 708 sub index_mm {
 709         my ($self, $mime, $oid, $sync) = @_;
 710         my $mids = mids($mime);
 711         my $mm = $self->{mm};
 712         if ($sync->{reindex}) {
 713                 my $oidx = $self->{oidx};
 714                 for my $mid (@$mids) {
 715                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 716                         return $num if defined $num;
 717                 }
 718                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 719         } else {
 720                 # fallback to num_for since filters like RubyLang set the number
 721                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 722         }
 723 }
 724
 725 sub is_bad_blob ($$$$) {
 726         my ($oid, $type, $size, $expect_oid) = @_;
 727         if ($type ne 'blob') {
 728                 carp "W: $expect_oid is not a blob (type=$type)";
 729                 return 1;
 730         }
 731         croak "BUG: $oid != $expect_oid" if $oid ne $expect_oid;
 732         $size == 0 ? 1 : 0; # size == 0 means purged
 733 }
 734
 735 sub index_both { # git->cat_async callback
 736         my ($bref, $oid, $type, $size, $sync) = @_;
 737         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 738         my ($nr, $max) = @$sync{qw(nr max)};
 739         ++$$nr;
 740         $$max -= $size;
 741         my $smsg = bless { blob => $oid }, 'PublicInbox::Smsg';
 742         $smsg->set_bytes($$bref, $size);
 743         my $self = $sync->{sidx};
 744         local $self->{current_info} = "$self->{current_info}: $oid";
 745         my $eml = PublicInbox::Eml->new($bref);
 746         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 747                 die "E: could not generate NNTP article number for $oid";
 748         add_message($self, $eml, $smsg, $sync);
 749         ++$self->{nidx};
 750         my $cur_cmt = $sync->{cur_cmt} // die 'BUG: {cur_cmt} missing';
 751         ${$sync->{latest_cmt}} = $cur_cmt;
 752 }
 753
 754 sub unindex_both { # git->cat_async callback
 755         my ($bref, $oid, $type, $size, $sync) = @_;
 756         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 757         my $self = $sync->{sidx};
 758         local $self->{current_info} = "$self->{current_info}: $oid";
 759         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 760         # may be undef if leftover
 761         if (defined(my $cur_cmt = $sync->{cur_cmt})) {
 762                 ${$sync->{latest_cmt}} = $cur_cmt;
 763         }
 764         ++$self->{nidx};
 765 }
 766
 767 sub with_umask {
 768         my $self = shift;
 769         ($self->{ibx} // $self->{eidx})->with_umask(@_);
 770 }
 771
 772 # called by public-inbox-index
 773 sub index_sync {
 774         my ($self, $opt) = @_;
 775         delete $self->{lock_path} if $opt->{-skip_lock};
 776         $self->with_umask(\&_index_sync, $self, $opt);
 777         if ($opt->{reindex} && !$opt->{quit} &&
 778                         !grep(defined, @$opt{qw(since until)})) {
 779                 my %again = %$opt;
 780                 delete @again{qw(rethread reindex)};
 781                 index_sync($self, \%again);
 782                 $opt->{quit} = $again{quit}; # propagate to caller
 783         }
 784 }
 785
 786 sub check_size { # check_async cb for -index --max-size=...
 787         my ($oid, $type, $size, $arg, $git) = @_;
 788         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 789         if ($size <= $arg->{max_size}) {
 790                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 791         } else {
 792                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 793         }
 794 }
 795
 796 sub v1_checkpoint ($$;$) {
 797         my ($self, $sync, $stk) = @_;
 798         $self->{ibx}->git->async_wait_all;
 799
 800         # $newest may be undef
 801         my $newest = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 802         if (defined($newest)) {
 803                 my $cur = $self->{mm}->last_commit;
 804                 if (need_update($self, $sync, $cur, $newest)) {
 805                         $self->{mm}->last_commit($newest);
 806                 }
 807         }
 808         ${$sync->{max}} = $self->{batch_bytes};
 809
 810         $self->{mm}->{dbh}->commit;
 811         eval { $self->{mm}->{dbh}->do('PRAGMA optimize') };
 812         my $xdb = $self->{xdb};
 813         if ($newest && $xdb) {
 814                 my $cur = $xdb->get_metadata('last_commit');
 815                 if (need_update($self, $sync, $cur, $newest)) {
 816                         $xdb->set_metadata('last_commit', $newest);
 817                 }
 818         }
 819         if ($stk) { # all done if $stk is passed
 820                 # let SearchView know a full --reindex was done so it can
 821                 # generate ->has_threadid-dependent links
 822                 if ($xdb && $sync->{reindex} && !ref($sync->{reindex})) {
 823                         my $n = $xdb->get_metadata('has_threadid');
 824                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 825                 }
 826                 $self->{oidx}->rethread_done($sync->{-opt}); # all done
 827         }
 828         commit_txn_lazy($self);
 829         $sync->{ibx}->git->cleanup;
 830         my $nr = ${$sync->{nr}};
 831         idx_release($self, $nr);
 832         # let another process do some work...
 833         if (my $pr = $sync->{-opt}->{-progress}) {
 834                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 835         }
 836         if (!$stk && !$sync->{quit}) { # more to come
 837                 begin_txn_lazy($self);
 838                 $self->{mm}->{dbh}->begin_work;
 839         }
 840 }
 841
 842 # only for v1
 843 sub process_stack {
 844         my ($self, $sync, $stk) = @_;
 845         my $git = $sync->{ibx}->git;
 846         my $max = $self->{batch_bytes};
 847         my $nr = 0;
 848         $sync->{nr} = \$nr;
 849         $sync->{max} = \$max;
 850         $sync->{sidx} = $self;
 851         $sync->{latest_cmt} = \(my $latest_cmt);
 852
 853         $self->{mm}->{dbh}->begin_work;
 854         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 855                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 856                 for my $oid (@leftovers) {
 857                         last if $sync->{quit};
 858                         $oid = unpack('H*', $oid);
 859                         $git->cat_async($oid, \&unindex_both, $sync);
 860                 }
 861         }
 862         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 863                 $sync->{index_oid} = \&index_both;
 864         }
 865         while (my ($f, $at, $ct, $oid, $cur_cmt) = $stk->pop_rec) {
 866                 my $arg = { %$sync, cur_cmt => $cur_cmt, oid => $oid };
 867                 last if $sync->{quit};
 868                 if ($f eq 'm') {
 869                         $arg->{autime} = $at;
 870                         $arg->{cotime} = $ct;
 871                         if ($sync->{max_size}) {
 872                                 $git->check_async($oid, \&check_size, $arg);
 873                         } else {
 874                                 $git->cat_async($oid, \&index_both, $arg);
 875                         }
 876                         v1_checkpoint($self, $sync) if $max <= 0;
 877                 } elsif ($f eq 'd') {
 878                         $git->cat_async($oid, \&unindex_both, $arg);
 879                 }
 880         }
 881         v1_checkpoint($self, $sync, $sync->{quit} ? undef : $stk);
 882 }
 883
 884 sub log2stack ($$$) {
 885         my ($sync, $git, $range) = @_;
 886         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 887         my ($add, $del);
 888         if ($sync->{ibx}->version == 1) {
 889                 my $path = $hex.'{2}/'.$hex.'{38}';
 890                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 891                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 892         } else {
 893                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 894                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 895         }
 896
 897         # Count the new files so they can be added newest to oldest
 898         # and still have numbers increasing from oldest to newest
 899         my @cmd = qw(log --raw -r --pretty=tformat:%at-%ct-%H
 900                         --no-notes --no-color --no-renames --no-abbrev);
 901         for my $k (qw(since until)) {
 902                 my $v = $sync->{-opt}->{$k} // next;
 903                 next if !$sync->{-opt}->{reindex};
 904                 push @cmd, "--$k=$v";
 905         }
 906         my $fh = $git->popen(@cmd, $range);
 907         my ($at, $ct, $stk, $cmt, $l);
 908         while (defined($l = <$fh>)) {
 909                 return if $sync->{quit};
 910                 if ($l =~ /\A([0-9]+)-([0-9]+)-($OID)$/o) {
 911                         ($at, $ct, $cmt) = ($1 + 0, $2 + 0, $3);
 912                         $stk //= PublicInbox::IdxStack->new($cmt);
 913                 } elsif ($l =~ /$del/) {
 914                         my $oid = $1;
 915                         if ($D) { # reindex case
 916                                 $D->{pack('H*', $oid)}++;
 917                         } else { # non-reindex case:
 918                                 $stk->push_rec('d', $at, $ct, $oid, $cmt);
 919                         }
 920                 } elsif ($l =~ /$add/) {
 921                         my $oid = $1;
 922                         if ($D) {
 923                                 my $oid_bin = pack('H*', $oid);
 924                                 my $nr = --$D->{$oid_bin};
 925                                 delete($D->{$oid_bin}) if $nr <= 0;
 926                                 # nr < 0 (-1) means it never existed
 927                                 next if $nr >= 0;
 928                         }
 929                         $stk->push_rec('m', $at, $ct, $oid, $cmt);
 930                 }
 931         }
 932         close $fh or die "git log failed: \$?=$?";
 933         $stk //= PublicInbox::IdxStack->new;
 934         $stk->read_prepare;
 935 }
 936
 937 sub prepare_stack ($$) {
 938         my ($sync, $range) = @_;
 939         my $git = $sync->{ibx}->git;
 940
 941         if (index($range, '..') < 0) {
 942                 # don't show annoying git errors to users who run -index
 943                 # on empty inboxes
 944                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 945                 return PublicInbox::IdxStack->new->read_prepare if $?;
 946         }
 947         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 948         log2stack($sync, $git, $range);
 949 }
 950
 951 # --is-ancestor requires git 1.8.0+
 952 sub is_ancestor ($$$) {
 953         my ($git, $cur, $tip) = @_;
 954         return 0 unless $git->check($cur);
 955         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 956                 qw(merge-base --is-ancestor), $cur, $tip ];
 957         my $pid = spawn($cmd);
 958         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 959         $? == 0;
 960 }
 961
 962 sub need_update ($$$$) {
 963         my ($self, $sync, $cur, $new) = @_;
 964         my $git = $self->{ibx}->git;
 965         $cur //= ''; # XS Search::Xapian ->get_metadata doesn't give undef
 966
 967         # don't rewind if --{since,until,before,after} are in use
 968         return if $cur ne '' &&
 969                 grep(defined, @{$sync->{-opt}}{qw(since until)}) &&
 970                 is_ancestor($git, $new, $cur);
 971
 972         return 1 if $cur ne '' && !is_ancestor($git, $cur, $new);
 973         my $range = $cur eq '' ? $new : "$cur..$new";
 974         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 975         ($n eq '' || $n > 0);
 976 }
 977
 978 # The last git commit we indexed with Xapian or SQLite (msgmap)
 979 # This needs to account for cases where Xapian or SQLite is
 980 # out-of-date with respect to the other.
 981 sub _last_x_commit {
 982         my ($self, $mm) = @_;
 983         my $lm = $mm->last_commit || '';
 984         my $lx = '';
 985         if (need_xapian($self)) {
 986                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 987         } else {
 988                 $lx = $lm;
 989         }
 990         # Use last_commit from msgmap if it is older or unset
 991         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 992                 $lx = $lm;
 993         }
 994         $lx;
 995 }
 996
 997 sub reindex_from ($$) {
 998         my ($reindex, $last_commit) = @_;
 999         return $last_commit unless $reindex;
1000         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
1001 }
1002
1003 sub quit_cb ($) {
1004         my ($sync) = @_;
1005         sub {
1006                 # we set {-opt}->{quit} too, so ->index_sync callers
1007                 # can abort multi-inbox loops this way
1008                 $sync->{quit} = $sync->{-opt}->{quit} = 1;
1009                 warn "gracefully quitting\n";
1010         }
1011 }
1012
1013 # indexes all unindexed messages (v1 only)
1014 sub _index_sync {
1015         my ($self, $opt) = @_;
1016         my $tip = $opt->{ref} || 'HEAD';
1017         my $ibx = $self->{ibx};
1018         local $self->{current_info} = "$ibx->{inboxdir}";
1019         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
1020         $ibx->git->batch_prepare;
1021         my $pr = $opt->{-progress};
1022         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
1023         my $quit = quit_cb($sync);
1024         local $SIG{QUIT} = $quit;
1025         local $SIG{INT} = $quit;
1026         local $SIG{TERM} = $quit;
1027         my $xdb = $self->begin_txn_lazy;
1028         $self->{oidx}->rethread_prepare($opt);
1029         my $mm = _msgmap_init($self);
1030         if ($sync->{reindex}) {
1031                 my $last = $mm->last_commit;
1032                 if ($last) {
1033                         $tip = $last;
1034                 } else {
1035                         # somebody just blindly added --reindex when indexing
1036                         # for the first time, allow it:
1037                         undef $sync->{reindex};
1038                 }
1039         }
1040         my $last_commit = _last_x_commit($self, $mm);
1041         my $lx = reindex_from($sync->{reindex}, $last_commit);
1042         my $range = $lx eq '' ? $tip : "$lx..$tip";
1043         $pr->("counting changes\n\t$range ... ") if $pr;
1044         my $stk = prepare_stack($sync, $range);
1045         $sync->{ntodo} = $stk ? $stk->num_records : 0;
1046         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
1047         process_stack($self, $sync, $stk) if !$sync->{quit};
1048 }
1049
1050 sub DESTROY {
1051         # order matters for unlocking
1052         $_[0]->{xdb} = undef;
1053         $_[0]->{lockfh} = undef;
1054 }
1055
1056 sub _begin_txn {
1057         my ($self) = @_;
1058         my $xdb = $self->{xdb} || idx_acquire($self);
1059         $self->{oidx}->begin_lazy if $self->{oidx};
1060         $xdb->begin_transaction if $xdb;
1061         $self->{txn} = 1;
1062         $xdb;
1063 }
1064
1065 sub begin_txn_lazy {
1066         my ($self) = @_;
1067         $self->with_umask(\&_begin_txn, $self) if !$self->{txn};
1068 }
1069
1070 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
1071 # This metadata is read by Admin::detect_indexlevel:
1072 sub set_metadata_once {
1073         my ($self) = @_;
1074
1075         return if $self->{shard}; # only continue if undef or 0, not >0
1076         my $xdb = $self->{xdb};
1077
1078         if (delete($self->{-set_has_threadid_once})) {
1079                 $xdb->set_metadata('has_threadid', '1');
1080         }
1081         if (delete($self->{-set_indexlevel_once})) {
1082                 my $level = $xdb->get_metadata('indexlevel');
1083                 if (!$level || $level ne 'medium') {
1084                         $xdb->set_metadata('indexlevel', 'medium');
1085                 }
1086         }
1087         if (delete($self->{-set_skip_docdata_once})) {
1088                 $xdb->get_metadata('skip_docdata') or
1089                         $xdb->set_metadata('skip_docdata', '1');
1090         }
1091 }
1092
1093 sub _commit_txn {
1094         my ($self) = @_;
1095         if (my $eidx = $self->{eidx}) {
1096                 $eidx->git->async_wait_all;
1097                 $eidx->{transact_bytes} = 0;
1098         }
1099         if (my $xdb = $self->{xdb}) {
1100                 set_metadata_once($self);
1101                 $xdb->commit_transaction;
1102         }
1103         $self->{oidx}->commit_lazy if $self->{oidx};
1104 }
1105
1106 sub commit_txn_lazy {
1107         my ($self) = @_;
1108         delete($self->{txn}) and
1109                 $self->with_umask(\&_commit_txn, $self);
1110 }
1111
1112 sub eidx_shard_new {
1113         my ($class, $eidx, $shard) = @_;
1114         my $self = bless {
1115                 eidx => $eidx,
1116                 xpfx => $eidx->{xpfx},
1117                 indexlevel => $eidx->{indexlevel},
1118                 -skip_docdata => 1,
1119                 shard => $shard,
1120                 creat => 1,
1121         }, $class;
1122         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
1123         $self;
1124 }
1125
1126 1;