lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 require PublicInbox::Git;
  22 use Compress::Zlib qw(compress);
  23
  24 use constant {
  25         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000,
  27         DEBUG => !!$ENV{DEBUG},
  28 };
  29
  30 my $xapianlevels = qr/\A(?:full|medium)\z/;
  31
  32 my %GIT_ESC = (
  33         a => "\a",
  34         b => "\b",
  35         f => "\f",
  36         n => "\n",
  37         r => "\r",
  38         t => "\t",
  39         v => "\013",
  40 );
  41
  42 sub git_unquote ($) {
  43         my ($s) = @_;
  44         return $s unless ($s =~ /\A"(.*)"\z/);
  45         $s = $1;
  46         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  47         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  48         $s;
  49 }
  50
  51 sub new {
  52         my ($class, $ibx, $creat, $part) = @_;
  53         my $levels = qr/\A(?:full|medium|basic)\z/;
  54         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  55         my $git_dir = $mainrepo;
  56         my ($altid, $git);
  57         my $version = 1;
  58         my $indexlevel = 'full';
  59         if (ref $ibx) {
  60                 $mainrepo = $ibx->{mainrepo};
  61                 $altid = $ibx->{altid};
  62                 $version = $ibx->{version} || 1;
  63                 if ($altid) {
  64                         require PublicInbox::AltId;
  65                         $altid = [ map {
  66                                 PublicInbox::AltId->new($ibx, $_);
  67                         } @$altid ];
  68                 }
  69                 if ($ibx->{indexlevel}) {
  70                         if ($ibx->{indexlevel} =~ $levels) {
  71                                 $indexlevel = $ibx->{indexlevel};
  72                         } else {
  73                                 die("Invalid indexlevel $ibx->{indexlevel}\n");
  74                         }
  75                 }
  76         } else { # v1
  77                 $ibx = { mainrepo => $git_dir, version => 1 };
  78         }
  79         $ibx = PublicInbox::InboxWritable->new($ibx);
  80         require Search::Xapian::WritableDatabase;
  81         my $self = bless {
  82                 mainrepo => $mainrepo,
  83                 -inbox => $ibx,
  84                 git => $ibx->git,
  85                 -altid => $altid,
  86                 version => $version,
  87                 indexlevel => $indexlevel,
  88         }, $class;
  89         $ibx->umask_prepare;
  90         if ($version == 1) {
  91                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  92                 my $dir = $self->xdir;
  93                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  94         } elsif ($version == 2) {
  95                 defined $part or die "partition is required for v2\n";
  96                 # partition is a number
  97                 $self->{partition} = $part;
  98                 $self->{lock_path} = undef;
  99         } else {
 100                 die "unsupported inbox version=$version\n";
 101         }
 102         $self->{creat} = ($creat || 0) == 1;
 103         $self;
 104 }
 105
 106 sub _xdb_release {
 107         my ($self) = @_;
 108         my $xdb = delete $self->{xdb} or croak 'not acquired';
 109         $xdb->close;
 110         $self->lock_release if $self->{creat};
 111         undef;
 112 }
 113
 114 sub _xdb_acquire {
 115         my ($self) = @_;
 116         croak 'already acquired' if $self->{xdb};
 117         my $dir = $self->xdir;
 118         my $flag = Search::Xapian::DB_OPEN;
 119         if ($self->{creat}) {
 120                 require File::Path;
 121                 $self->lock_acquire;
 122                 File::Path::mkpath($dir);
 123                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 124         }
 125         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 126 }
 127
 128 sub add_val ($$$) {
 129         my ($doc, $col, $num) = @_;
 130         $num = Search::Xapian::sortable_serialise($num);
 131         $doc->add_value($col, $num);
 132 }
 133
 134 sub index_text ($$$$)
 135 {
 136         my ($self, $field, $n, $text) = @_;
 137         my $tg = $self->term_generator;
 138
 139         if ($self->{indexlevel} eq 'full') {
 140                 $tg->index_text($field, $n, $text);
 141                 $tg->increase_termpos;
 142         } else {
 143                 $tg->index_text_without_positions($field, $n, $text);
 144         }
 145 }
 146
 147 sub index_users ($$) {
 148         my ($self, $smsg) = @_;
 149
 150         my $from = $smsg->from;
 151         my $to = $smsg->to;
 152         my $cc = $smsg->cc;
 153
 154         $self->index_text($from, 1, 'A'); # A - author
 155         $self->index_text($to, 1, 'XTO') if $to ne '';
 156         $self->index_text($cc, 1, 'XCC') if $cc ne '';
 157 }
 158
 159 sub index_diff_inc ($$$$) {
 160         my ($self, $text, $pfx, $xnq) = @_;
 161         if (@$xnq) {
 162                 $self->index_text(join("\n", @$xnq), 1, 'XNQ');
 163                 @$xnq = ();
 164         }
 165         $self->index_text($text, 1, $pfx);
 166 }
 167
 168 sub index_old_diff_fn {
 169         my ($self, $seen, $fa, $fb, $xnq) = @_;
 170
 171         # no renames or space support for traditional diffs,
 172         # find the number of leading common paths to strip:
 173         my @fa = split('/', $fa);
 174         my @fb = split('/', $fb);
 175         while (scalar(@fa) && scalar(@fb)) {
 176                 $fa = join('/', @fa);
 177                 $fb = join('/', @fb);
 178                 if ($fa eq $fb) {
 179                         unless ($seen->{$fa}++) {
 180                                 $self->index_diff_inc($fa, 'XDFN', $xnq);
 181                         }
 182                         return 1;
 183                 }
 184                 shift @fa;
 185                 shift @fb;
 186         }
 187         0;
 188 }
 189
 190 sub index_diff ($$$) {
 191         my ($self, $lines, $doc) = @_;
 192         my %seen;
 193         my $in_diff;
 194         my @xnq;
 195         my $xnq = \@xnq;
 196         foreach (@$lines) {
 197                 if ($in_diff && s/^ //) { # diff context
 198                         $self->index_diff_inc($_, 'XDFCTX', $xnq);
 199                 } elsif (/^-- $/) { # email signature begins
 200                         $in_diff = undef;
 201                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 202                         my ($fa, $fb) = ($1, $2);
 203                         my $fn = (split('/', git_unquote($fa), 2))[1];
 204                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 205                         $fn = (split('/', git_unquote($fb), 2))[1];
 206                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 207                         $in_diff = 1;
 208                 # traditional diff:
 209                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 210                         my ($opt, $fa, $fb) = ($1, $2, $3);
 211                         push @xnq, $_;
 212                         # only support unified:
 213                         next unless $opt =~ /[uU]/;
 214                         $in_diff = $self->index_old_diff_fn(\%seen, $fa, $fb,
 215                                                         $xnq);
 216                 } elsif (m!^--- ("?a/.+)!) {
 217                         my $fn = (split('/', git_unquote($1), 2))[1];
 218                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 219                         $in_diff = 1;
 220                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 221                         my $fn = (split('/', git_unquote($1), 2))[1];
 222                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 223                         $in_diff = 1;
 224                 } elsif (/^--- (\S+)/) {
 225                         $in_diff = $1;
 226                         push @xnq, $_;
 227                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 228                         $in_diff = $self->index_old_diff_fn(\%seen, $in_diff, $1,
 229                                                         $xnq);
 230                 } elsif ($in_diff && s/^\+//) { # diff added
 231                         $self->index_diff_inc($_, 'XDFB', $xnq);
 232                 } elsif ($in_diff && s/^-//) { # diff removed
 233                         $self->index_diff_inc($_, 'XDFA', $xnq);
 234                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 235                         my ($ba, $bb) = ($1, $2);
 236                         index_git_blob_id($doc, 'XDFPRE', $ba);
 237                         index_git_blob_id($doc, 'XDFPOST', $bb);
 238                         $in_diff = 1;
 239                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 240                         # traditional diff w/o -p
 241                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 242                         # hunk header context
 243                         $self->index_diff_inc($1, 'XDFHH', $xnq);
 244                 # ignore the following lines:
 245                 } elsif (/^(?:dis)similarity index/ ||
 246                                 /^(?:old|new) mode/ ||
 247                                 /^(?:deleted|new) file mode/ ||
 248                                 /^(?:copy|rename) (?:from|to) / ||
 249                                 /^(?:dis)?similarity index / ||
 250                                 /^\\ No newline at end of file/ ||
 251                                 /^Binary files .* differ/) {
 252                         push @xnq, $_;
 253                 } elsif ($_ eq '') {
 254                         $in_diff = undef;
 255                 } else {
 256                         push @xnq, $_;
 257                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 258                         $in_diff = undef;
 259                 }
 260         }
 261
 262         $self->index_text(join("\n", @xnq), 1, 'XNQ');
 263 }
 264
 265 sub index_body ($$$) {
 266         my ($self, $lines, $doc) = @_;
 267         my $txt = join("\n", @$lines);
 268         if ($doc) {
 269                 # does it look like a diff?
 270                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 271                         $txt = undef;
 272                         $self->index_diff($lines, $doc);
 273                 } else {
 274                         $self->index_text($txt, 1, 'XNQ');
 275                 }
 276         } else {
 277                 $self->index_text($txt, 0, 'XQUOT');
 278         }
 279         @$lines = ();
 280 }
 281
 282 sub add_xapian ($$$$$) {
 283         my ($self, $mime, $num, $oid, $mids, $mid0) = @_;
 284         my $smsg = PublicInbox::SearchMsg->new($mime);
 285         my $doc = Search::Xapian::Document->new;
 286         my $subj = $smsg->subject;
 287         add_val($doc, PublicInbox::Search::TS(), $smsg->ts);
 288         my @ds = gmtime($smsg->ds);
 289         my $yyyymmdd = strftime('%Y%m%d', @ds);
 290         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 291         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 292         add_val($doc, PublicInbox::Search::DT(), $dt);
 293
 294         my $tg = $self->term_generator;
 295
 296         $tg->set_document($doc);
 297         $self->index_text($subj, 1, 'S') if $subj;
 298         $self->index_users($smsg);
 299
 300         msg_iter($mime, sub {
 301                 my ($part, $depth, @idx) = @{$_[0]};
 302                 my $ct = $part->content_type || 'text/plain';
 303                 my $fn = $part->filename;
 304                 if (defined $fn && $fn ne '') {
 305                         $self->index_text($fn, 1, 'XFN');
 306                 }
 307
 308                 my ($s, undef) = msg_part_text($part, $ct);
 309                 defined $s or return;
 310
 311                 my (@orig, @quot);
 312                 my @lines = split(/\n/, $s);
 313                 while (defined(my $l = shift @lines)) {
 314                         if ($l =~ /^>/) {
 315                                 $self->index_body(\@orig, $doc) if @orig;
 316                                 push @quot, $l;
 317                         } else {
 318                                 $self->index_body(\@quot, 0) if @quot;
 319                                 push @orig, $l;
 320                         }
 321                 }
 322                 $self->index_body(\@quot, 0) if @quot;
 323                 $self->index_body(\@orig, $doc) if @orig;
 324         });
 325
 326         foreach my $mid (@$mids) {
 327                 $self->index_text($mid, 1, 'XM');
 328
 329                 # because too many Message-IDs are prefixed with
 330                 # "Pine.LNX."...
 331                 if ($mid =~ /\w{12,}/) {
 332                         my @long = ($mid =~ /(\w{3,}+)/g);
 333                         $self->index_text(join(' ', @long), 1, 'XM');
 334                 }
 335         }
 336         $smsg->{to} = $smsg->{cc} = '';
 337         PublicInbox::OverIdx::parse_references($smsg, $mid0, $mids);
 338         my $data = $smsg->to_doc_data($oid, $mid0);
 339         $doc->set_data($data);
 340         if (my $altid = $self->{-altid}) {
 341                 foreach my $alt (@$altid) {
 342                         my $pfx = $alt->{xprefix};
 343                         foreach my $mid (@$mids) {
 344                                 my $id = $alt->mid2alt($mid);
 345                                 next unless defined $id;
 346                                 $doc->add_boolean_term($pfx . $id);
 347                         }
 348                 }
 349         }
 350         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 351         $self->{xdb}->replace_document($num, $doc);
 352 }
 353
 354 sub add_message {
 355         # mime = Email::MIME object
 356         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 357         my $mids = mids($mime->header_obj);
 358         $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 359         unless (defined $num) { # v1
 360                 $self->_msgmap_init;
 361                 $num = index_mm($self, $mime);
 362         }
 363         eval {
 364                 if ($self->{indexlevel} =~ $xapianlevels) {
 365                         $self->add_xapian($mime, $num, $oid, $mids, $mid0)
 366                 }
 367                 if (my $over = $self->{over}) {
 368                         $over->add_overview($mime, $bytes, $num, $oid, $mid0);
 369                 }
 370         };
 371
 372         if ($@) {
 373                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 374                 return undef;
 375         }
 376         $num;
 377 }
 378
 379 # returns begin and end PostingIterator
 380 sub find_doc_ids {
 381         my ($self, $termval) = @_;
 382         my $db = $self->{xdb};
 383
 384         ($db->postlist_begin($termval), $db->postlist_end($termval));
 385 }
 386
 387 sub batch_do {
 388         my ($self, $termval, $cb) = @_;
 389         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 390         while (1) {
 391                 my ($head, $tail) = $self->find_doc_ids($termval);
 392                 return if $head == $tail;
 393                 my @ids;
 394                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 395                         push @ids, $head->get_docid;
 396                 }
 397                 $cb->(\@ids);
 398         }
 399 }
 400
 401 sub remove_message {
 402         my ($self, $mid) = @_;
 403         my $db = $self->{xdb};
 404         my $called;
 405         $mid = mid_clean($mid);
 406         my $over = $self->{over};
 407
 408         eval {
 409                 batch_do($self, 'Q' . $mid, sub {
 410                         my ($ids) = @_;
 411                         $db->delete_document($_) for @$ids;
 412                         $over->delete_articles($ids) if $over;
 413                         $called = 1;
 414                 });
 415         };
 416         if ($@) {
 417                 warn "failed to remove message <$mid>: $@\n";
 418         } elsif (!$called) {
 419                 warn "cannot remove non-existent <$mid>\n";
 420         }
 421 }
 422
 423 # MID is a hint in V2
 424 sub remove_by_oid {
 425         my ($self, $oid, $mid) = @_;
 426         my $db = $self->{xdb};
 427
 428         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 429
 430         # XXX careful, we cannot use batch_do here since we conditionally
 431         # delete documents based on other factors, so we cannot call
 432         # find_doc_ids twice.
 433         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 434         return if $head == $tail;
 435
 436         # there is only ONE element in @delete unless we
 437         # have bugs in our v2writable deduplication check
 438         my @delete;
 439         for (; $head != $tail; $head->inc) {
 440                 my $docid = $head->get_docid;
 441                 my $doc = $db->get_document($docid);
 442                 my $smsg = PublicInbox::SearchMsg->wrap($mid);
 443                 $smsg->load_expand($doc);
 444                 if ($smsg->{blob} eq $oid) {
 445                         push(@delete, $docid);
 446                 }
 447         }
 448         $db->delete_document($_) foreach @delete;
 449         scalar(@delete);
 450 }
 451
 452 sub term_generator { # write-only
 453         my ($self) = @_;
 454
 455         my $tg = $self->{term_generator};
 456         return $tg if $tg;
 457
 458         $tg = Search::Xapian::TermGenerator->new;
 459         $tg->set_stemmer($self->stemmer);
 460
 461         $self->{term_generator} = $tg;
 462 }
 463
 464 sub index_git_blob_id {
 465         my ($doc, $pfx, $objid) = @_;
 466
 467         my $len = length($objid);
 468         for (my $len = length($objid); $len >= 7; ) {
 469                 $doc->add_term($pfx.$objid);
 470                 $objid = substr($objid, 0, --$len);
 471         }
 472 }
 473
 474 sub unindex_blob {
 475         my ($self, $mime) = @_;
 476         my $mid = eval { mid_clean(mid_mime($mime)) };
 477         $self->remove_message($mid) if defined $mid;
 478 }
 479
 480 sub index_mm {
 481         my ($self, $mime) = @_;
 482         my $mid = mid_clean(mid_mime($mime));
 483         my $mm = $self->{mm};
 484         my $num;
 485
 486         if (defined $self->{regen_down}) {
 487                 $num = $mm->num_for($mid) and return $num;
 488
 489                 while (($num = $self->{regen_down}--) > 0) {
 490                         if ($mm->mid_set($num, $mid) != 0) {
 491                                 return $num;
 492                         }
 493                 }
 494         } elsif (defined $self->{regen_up}) {
 495                 $num = $mm->num_for($mid) and return $num;
 496
 497                 # this is to fixup old bugs due to add-remove-add
 498                 while (($num = ++$self->{regen_up})) {
 499                         if ($mm->mid_set($num, $mid) != 0) {
 500                                 return $num;
 501                         }
 502                 }
 503         }
 504
 505         $num = $mm->mid_insert($mid) and return $num;
 506
 507         # fallback to num_for since filters like RubyLang set the number
 508         $mm->num_for($mid);
 509 }
 510
 511 sub unindex_mm {
 512         my ($self, $mime) = @_;
 513         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 514 }
 515
 516 sub index_both {
 517         my ($self, $mime, $bytes, $blob) = @_;
 518         my $num = index_mm($self, $mime);
 519         add_message($self, $mime, $bytes, $num, $blob);
 520 }
 521
 522 sub unindex_both {
 523         my ($self, $mime) = @_;
 524         unindex_blob($self, $mime);
 525         unindex_mm($self, $mime);
 526 }
 527
 528 sub do_cat_mail {
 529         my ($git, $blob, $sizeref) = @_;
 530         my $mime = eval {
 531                 my $str = $git->cat_file($blob, $sizeref);
 532                 # fixup bugs from import:
 533                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 534                 PublicInbox::MIME->new($str);
 535         };
 536         $@ ? undef : $mime;
 537 }
 538
 539 sub index_sync {
 540         my ($self, $opts) = @_;
 541         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 542 }
 543
 544 sub batch_adjust ($$$$) {
 545         my ($max, $bytes, $batch_cb, $latest) = @_;
 546         $$max -= $bytes;
 547         if ($$max <= 0) {
 548                 $$max = BATCH_BYTES;
 549                 $batch_cb->($latest);
 550         }
 551 }
 552
 553 # only for v1
 554 sub read_log {
 555         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 556         my $hex = '[a-f0-9]';
 557         my $h40 = $hex .'{40}';
 558         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 559         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 560         my $git = $self->{git};
 561         my $latest;
 562         my $bytes;
 563         my $max = BATCH_BYTES;
 564         local $/ = "\n";
 565         my %D;
 566         my $line;
 567         my $newest;
 568         while (defined($line = <$log>)) {
 569                 if ($line =~ /$addmsg/o) {
 570                         my $blob = $1;
 571                         if (delete $D{$blob}) {
 572                                 if (defined $self->{regen_down}) {
 573                                         my $num = $self->{regen_down}--;
 574                                         $self->{mm}->num_highwater($num);
 575                                 }
 576                                 next;
 577                         }
 578                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 579                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 580                         $add_cb->($self, $mime, $bytes, $blob);
 581                 } elsif ($line =~ /$delmsg/o) {
 582                         my $blob = $1;
 583                         $D{$blob} = 1;
 584                 } elsif ($line =~ /^commit ($h40)/o) {
 585                         $latest = $1;
 586                         $newest ||= $latest;
 587                 }
 588         }
 589         # get the leftovers
 590         foreach my $blob (keys %D) {
 591                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 592                 $del_cb->($self, $mime);
 593         }
 594         $batch_cb->($latest, $newest);
 595 }
 596
 597 sub _msgmap_init {
 598         my ($self) = @_;
 599         die "BUG: _msgmap_init is only for v1\n" if $self->{version} != 1;
 600         $self->{mm} ||= eval {
 601                 require PublicInbox::Msgmap;
 602                 PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 603         };
 604 }
 605
 606 sub _git_log {
 607         my ($self, $range) = @_;
 608         my $git = $self->{git};
 609
 610         if (index($range, '..') < 0) {
 611                 # don't show annoying git errrors to users who run -index
 612                 # on empty inboxes
 613                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 614                 if ($?) {
 615                         open my $fh, '<', '/dev/null' or
 616                                 die "failed to open /dev/null: $!\n";
 617                         return $fh;
 618                 }
 619         }
 620
 621         # Count the new files so they can be added newest to oldest
 622         # and still have numbers increasing from oldest to newest
 623         my $fcount = 0;
 624         # can't use 'rev-list --count' if we use --diff-filter
 625         my $fh = $git->popen(qw(log --pretty=tformat:%h
 626                              --no-notes --no-color --no-renames
 627                              --diff-filter=AM), $range);
 628         ++$fcount while <$fh>;
 629         my $high = $self->{mm}->num_highwater;
 630
 631         if (index($range, '..') < 0) {
 632                 if ($high && $high == $fcount) {
 633                         # fix up old bugs in full indexes which caused messages to
 634                         # not appear in Msgmap
 635                         $self->{regen_up} = $high;
 636                 } else {
 637                         # normal regen is for for fresh data
 638                         $self->{regen_down} = $fcount;
 639                 }
 640         } else {
 641                 # Give oldest messages the smallest numbers
 642                 $self->{regen_down} = $high + $fcount;
 643         }
 644
 645         $git->popen(qw/log --no-notes --no-color --no-renames
 646                                 --raw -r --no-abbrev/, $range);
 647 }
 648
 649 # --is-ancestor requires git 1.8.0+
 650 sub is_ancestor ($$$) {
 651         my ($git, $cur, $tip) = @_;
 652         return 0 unless $git->check($cur);
 653         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 654                 qw(merge-base --is-ancestor), $cur, $tip ];
 655         my $pid = spawn($cmd);
 656         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 657         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 658         $? == 0;
 659 }
 660
 661 sub need_update ($$$) {
 662         my ($self, $cur, $new) = @_;
 663         my $git = $self->{git};
 664         return 1 if $cur && !is_ancestor($git, $cur, $new);
 665         my $range = $cur eq '' ? $new : "$cur..$new";
 666         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 667         ($n eq '' || $n > 0);
 668 }
 669
 670 # indexes all unindexed messages (v1 only)
 671 sub _index_sync {
 672         my ($self, $opts) = @_;
 673         my $tip = $opts->{ref} || 'HEAD';
 674         my $reindex = $opts->{reindex};
 675         my ($mkey, $last_commit, $lx, $xlog);
 676         my $git = $self->{git};
 677         $git->batch_prepare;
 678
 679         my $xdb = $self->begin_txn_lazy;
 680         my $mm = _msgmap_init($self);
 681         do {
 682                 $xlog = undef;
 683                 $mkey = 'last_commit';
 684                 $last_commit = $xdb->get_metadata('last_commit');
 685                 $lx = $last_commit;
 686                 if ($reindex) {
 687                         $lx = '';
 688                         $mkey = undef if $last_commit ne '';
 689                 }
 690
 691                 # use last_commit from msgmap if it is older or unset
 692                 my $lm = $mm->last_commit || '';
 693                 if (!$lm || ($lm && $lx && is_ancestor($git, $lm, $lx))) {
 694                         $lx = $lm;
 695                 }
 696
 697                 $self->{over}->rollback_lazy;
 698                 $self->{over}->disconnect;
 699                 $git->cleanup;
 700                 delete $self->{txn};
 701                 $xdb->cancel_transaction;
 702                 $xdb = _xdb_release($self);
 703
 704                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 705                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 706                 $xlog = _git_log($self, $range);
 707
 708                 $xdb = $self->begin_txn_lazy;
 709         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 710
 711         my $dbh = $mm->{dbh} if $mm;
 712         my $cb = sub {
 713                 my ($commit, $newest) = @_;
 714                 if ($dbh) {
 715                         if ($newest) {
 716                                 my $cur = $mm->last_commit || '';
 717                                 if (need_update($self, $cur, $newest)) {
 718                                         $mm->last_commit($newest);
 719                                 }
 720                         }
 721                         $dbh->commit;
 722                 }
 723                 if ($mkey && $newest && $self->{indexlevel} =~ $xapianlevels) {
 724                         my $cur = $xdb->get_metadata($mkey);
 725                         if (need_update($self, $cur, $newest)) {
 726                                 $xdb->set_metadata($mkey, $newest);
 727                         }
 728                 }
 729                 $self->commit_txn_lazy;
 730                 $git->cleanup;
 731                 $xdb = _xdb_release($self);
 732                 # let another process do some work... <
 733                 if (!$newest) {
 734                         $xdb = $self->begin_txn_lazy;
 735                         $dbh->begin_work if $dbh;
 736                 }
 737         };
 738
 739         $dbh->begin_work;
 740         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 741 }
 742
 743 sub DESTROY {
 744         # order matters for unlocking
 745         $_[0]->{xdb} = undef;
 746         $_[0]->{lockfh} = undef;
 747 }
 748
 749 # remote_* subs are only used by SearchIdxPart
 750 sub remote_commit {
 751         my ($self) = @_;
 752         if (my $w = $self->{w}) {
 753                 print $w "commit\n" or die "failed to write commit: $!";
 754         } else {
 755                 $self->commit_txn_lazy;
 756         }
 757 }
 758
 759 sub remote_close {
 760         my ($self) = @_;
 761         if (my $w = delete $self->{w}) {
 762                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 763                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 764                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 765                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 766                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 767         } else {
 768                 die "transaction in progress $self\n" if $self->{txn};
 769                 $self->_xdb_release if $self->{xdb};
 770         }
 771 }
 772
 773 sub remote_remove {
 774         my ($self, $oid, $mid) = @_;
 775         if (my $w = $self->{w}) {
 776                 # triggers remove_by_oid in a partition
 777                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 778         } else {
 779                 $self->begin_txn_lazy;
 780                 $self->remove_by_oid($oid, $mid);
 781         }
 782 }
 783
 784 sub begin_txn_lazy {
 785         my ($self) = @_;
 786         return if $self->{txn};
 787
 788         $self->{-inbox}->with_umask(sub {
 789                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 790                 $self->{over}->begin_lazy if $self->{over};
 791                 $xdb->begin_transaction;
 792                 $self->{txn} = 1;
 793                 $xdb;
 794         });
 795 }
 796
 797 sub commit_txn_lazy {
 798         my ($self) = @_;
 799         delete $self->{txn} or return;
 800         $self->{-inbox}->with_umask(sub {
 801                 $self->{xdb}->commit_transaction;
 802                 $self->{over}->commit_lazy if $self->{over};
 803         });
 804 }
 805
 806 sub worker_done {
 807         my ($self) = @_;
 808         die "$$ $0 xdb not released\n" if $self->{xdb};
 809         die "$$ $0 still in transaction\n" if $self->{txn};
 810 }
 811
 812 1;