lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::Search qw(xap_terms);
  15 use PublicInbox::InboxWritable;
  16 use PublicInbox::MID qw(mids_for_index mids);
  17 use PublicInbox::MsgIter;
  18 use PublicInbox::IdxStack;
  19 use Carp qw(croak carp);
  20 use POSIX qw(strftime);
  21 use Time::Local qw(timegm);
  22 use PublicInbox::OverIdx;
  23 use PublicInbox::Spawn qw(spawn);
  24 use PublicInbox::Git qw(git_unquote);
  25 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  26 use PublicInbox::Address;
  27 use Config;
  28 our @EXPORT_OK = qw(log2stack is_ancestor check_size prepare_stack
  29         index_text term_generator add_val is_bad_blob);
  30 my $X = \%PublicInbox::Search::X;
  31 our ($DB_CREATE_OR_OPEN, $DB_OPEN);
  32 our $DB_NO_SYNC = 0;
  33 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff :
  34         # assume a typical 64-bit system has 8x more RAM than a
  35         # typical 32-bit system:
  36         (($Config{ptrsize} >= 8 ? 8192 : 1024) * 1024);
  37
  38 use constant DEBUG => !!$ENV{DEBUG};
  39
  40 my $xapianlevels = qr/\A(?:full|medium)\z/;
  41 my $hex = '[a-f0-9]';
  42 my $OID = $hex .'{40,}';
  43 my @VMD_MAP = (kw => 'K', L => 'L');
  44 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  45
  46 sub new {
  47         my ($class, $ibx, $creat, $shard) = @_;
  48         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  49         my $inboxdir = $ibx->{inboxdir};
  50         my $version = $ibx->version;
  51         my $indexlevel = 'full';
  52         my $altid = $ibx->{altid};
  53         if ($altid) {
  54                 require PublicInbox::AltId;
  55                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  56         }
  57         if ($ibx->{indexlevel}) {
  58                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  59                         $indexlevel = $ibx->{indexlevel};
  60                 } else {
  61                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  62                 }
  63         }
  64         $ibx = PublicInbox::InboxWritable->new($ibx);
  65         my $self = PublicInbox::Search->new($ibx);
  66         bless $self, $class;
  67         $self->{ibx} = $ibx;
  68         $self->{-altid} = $altid;
  69         $self->{indexlevel} = $indexlevel;
  70         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  71         if ($ibx->{-skip_docdata}) {
  72                 $self->{-set_skip_docdata_once} = 1;
  73                 $self->{-skip_docdata} = 1;
  74         }
  75         if ($version == 1) {
  76                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  77                 my $dir = $self->xdir;
  78                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  79                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  80         } elsif ($version == 2) {
  81                 defined $shard or die "shard is required for v2\n";
  82                 # shard is a number
  83                 $self->{shard} = $shard;
  84                 $self->{lock_path} = undef;
  85         } else {
  86                 die "unsupported inbox version=$version\n";
  87         }
  88         $self->{creat} = ($creat || 0) == 1;
  89         $self;
  90 }
  91
  92 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  93
  94 sub idx_release {
  95         my ($self, $wake) = @_;
  96         if (need_xapian($self)) {
  97                 my $xdb = delete $self->{xdb} or croak '{xdb} not acquired';
  98                 $xdb->close;
  99         }
 100         $self->lock_release($wake) if $self->{creat};
 101         undef;
 102 }
 103
 104 sub load_xapian_writable () {
 105         return 1 if $X->{WritableDatabase};
 106         PublicInbox::Search::load_xapian() or die "failed to load Xapian: $@\n";
 107         my $xap = $PublicInbox::Search::Xap;
 108         for (qw(Document TermGenerator WritableDatabase)) {
 109                 $X->{$_} = $xap.'::'.$_;
 110         }
 111         eval 'require '.$X->{WritableDatabase} or die;
 112         *sortable_serialise = $xap.'::sortable_serialise';
 113         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 114         $DB_OPEN = eval($xap.'::DB_OPEN()');
 115         my $ver = (eval($xap.'::major_version()') << 16) |
 116                 (eval($xap.'::minor_version()') << 8) |
 117                 eval($xap.'::revision()');
 118         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 119         # Xapian v1.2.21..v1.2.24 were missing close-on-exec on OFD locks
 120         $X->{CLOEXEC_UNSET} = 1 if $ver >= 0x010215 && $ver <= 0x010218;
 121         1;
 122 }
 123
 124 sub idx_acquire {
 125         my ($self) = @_;
 126         my $flag;
 127         my $dir = $self->xdir;
 128         if (need_xapian($self)) {
 129                 croak 'already acquired' if $self->{xdb};
 130                 load_xapian_writable();
 131                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 132         }
 133         if ($self->{creat}) {
 134                 require File::Path;
 135                 $self->lock_acquire;
 136
 137                 # don't create empty Xapian directories if we don't need Xapian
 138                 my $is_shard = defined($self->{shard});
 139                 if (!-d $dir && (!$is_shard ||
 140                                 ($is_shard && need_xapian($self)))) {
 141                         File::Path::mkpath($dir);
 142                         require PublicInbox::Syscall;
 143                         PublicInbox::Syscall::nodatacow_dir($dir);
 144                         $self->{-set_has_threadid_once} = 1;
 145                 }
 146         }
 147         return unless defined $flag;
 148         $flag |= $DB_NO_SYNC if ($self->{ibx} // $self->{eidx})->{-no_fsync};
 149         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 150         croak "Failed opening $dir: $@" if $@;
 151         $self->{xdb} = $xdb;
 152 }
 153
 154 sub add_val ($$$) {
 155         my ($doc, $col, $num) = @_;
 156         $num = sortable_serialise($num);
 157         $doc->add_value($col, $num);
 158 }
 159
 160 sub term_generator ($) { # write-only
 161         my ($self) = @_;
 162
 163         $self->{term_generator} //= do {
 164                 my $tg = $X->{TermGenerator}->new;
 165                 $tg->set_stemmer(PublicInbox::Search::stemmer($self));
 166                 $tg;
 167         }
 168 }
 169
 170 sub index_phrase ($$$$) {
 171         my ($self, $text, $wdf_inc, $prefix) = @_;
 172
 173         my $tg = term_generator($self);
 174         $tg->index_text($text, $wdf_inc, $prefix);
 175         $tg->increase_termpos;
 176 }
 177
 178 sub index_text ($$$$) {
 179         my ($self, $text, $wdf_inc, $prefix) = @_;
 180
 181         if ($self->{indexlevel} eq 'full') {
 182                 index_phrase($self, $text, $wdf_inc, $prefix);
 183         } else {
 184                 my $tg = term_generator($self);
 185                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 186         }
 187 }
 188
 189 sub index_headers ($$) {
 190         my ($self, $smsg) = @_;
 191         my @x = (from => 'A', to => 'XTO', cc => 'XCC'); # A: Author
 192         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 193                 my $val = $smsg->{$field};
 194                 next if $val eq '';
 195                 # include "(comments)" after the address, too, so not using
 196                 # PublicInbox::Address::names or pairs
 197                 index_text($self, $val, 1, $pfx);
 198
 199                 # we need positional info for email addresses since they
 200                 # can be considered phrases
 201                 if ($self->{indexlevel} eq 'medium') {
 202                         for my $addr (PublicInbox::Address::emails($val)) {
 203                                 index_phrase($self, $addr, 1, $pfx);
 204                         }
 205                 }
 206         }
 207         @x = (subject => 'S');
 208         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 209                 my $val = $smsg->{$field};
 210                 index_text($self, $val, 1, $pfx) if $val ne '';
 211         }
 212 }
 213
 214 sub index_diff_inc ($$$$) {
 215         my ($self, $text, $pfx, $xnq) = @_;
 216         if (@$xnq) {
 217                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 218                 @$xnq = ();
 219         }
 220         if ($pfx eq 'XDFN') {
 221                 index_phrase($self, $text, 1, $pfx);
 222         } else {
 223                 index_text($self, $text, 1, $pfx);
 224         }
 225 }
 226
 227 sub index_old_diff_fn {
 228         my ($self, $seen, $fa, $fb, $xnq) = @_;
 229
 230         # no renames or space support for traditional diffs,
 231         # find the number of leading common paths to strip:
 232         my @fa = split('/', $fa);
 233         my @fb = split('/', $fb);
 234         while (scalar(@fa) && scalar(@fb)) {
 235                 $fa = join('/', @fa);
 236                 $fb = join('/', @fb);
 237                 if ($fa eq $fb) {
 238                         unless ($seen->{$fa}++) {
 239                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 240                         }
 241                         return 1;
 242                 }
 243                 shift @fa;
 244                 shift @fb;
 245         }
 246         0;
 247 }
 248
 249 sub index_diff ($$$) {
 250         my ($self, $txt, $doc) = @_;
 251         my %seen;
 252         my $in_diff;
 253         my @xnq;
 254         my $xnq = \@xnq;
 255         foreach (split(/\n/, $txt)) {
 256                 if ($in_diff && s/^ //) { # diff context
 257                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 258                 } elsif (/^-- $/) { # email signature begins
 259                         $in_diff = undef;
 260                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 261                         # wait until "---" and "+++" to capture filenames
 262                         $in_diff = 1;
 263                         push @xnq, $_;
 264                 # traditional diff:
 265                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 266                         my ($opt, $fa, $fb) = ($1, $2, $3);
 267                         push @xnq, $_;
 268                         # only support unified:
 269                         next unless $opt =~ /[uU]/;
 270                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 271                                                         $xnq);
 272                 } elsif (m!^--- ("?[^/]+/.+)!) {
 273                         my $fn = $1;
 274                         $fn = (split('/', git_unquote($fn), 2))[1];
 275                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 276                         $in_diff = 1;
 277                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 278                         my $fn = $1;
 279                         $fn = (split('/', git_unquote($fn), 2))[1];
 280                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 281                         $in_diff = 1;
 282                 } elsif (/^--- (\S+)/) {
 283                         $in_diff = $1;
 284                         push @xnq, $_;
 285                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 286                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 287                                                         $1, $xnq);
 288                 } elsif ($in_diff && s/^\+//) { # diff added
 289                         index_diff_inc($self, $_, 'XDFB', $xnq);
 290                 } elsif ($in_diff && s/^-//) { # diff removed
 291                         index_diff_inc($self, $_, 'XDFA', $xnq);
 292                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 293                         my ($ba, $bb) = ($1, $2);
 294                         index_git_blob_id($doc, 'XDFPRE', $ba);
 295                         index_git_blob_id($doc, 'XDFPOST', $bb);
 296                         $in_diff = 1;
 297                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 298                         # traditional diff w/o -p
 299                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 300                         # hunk header context
 301                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 302                 # ignore the following lines:
 303                 } elsif (/^(?:dis)similarity index/ ||
 304                                 /^(?:old|new) mode/ ||
 305                                 /^(?:deleted|new) file mode/ ||
 306                                 /^(?:copy|rename) (?:from|to) / ||
 307                                 /^(?:dis)?similarity index / ||
 308                                 /^\\ No newline at end of file/ ||
 309                                 /^Binary files .* differ/) {
 310                         push @xnq, $_;
 311                 } elsif ($_ eq '') {
 312                         # possible to be in diff context, some mail may be
 313                         # stripped by MUA or even GNU diff(1).  "git apply"
 314                         # treats a bare "\n" as diff context, too
 315                 } else {
 316                         push @xnq, $_;
 317                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 318                         $in_diff = undef;
 319                 }
 320         }
 321
 322         index_text($self, join("\n", @xnq), 1, 'XNQ');
 323 }
 324
 325 sub index_xapian { # msg_iter callback
 326         my $part = $_[0]->[0]; # ignore $depth and $idx
 327         my ($self, $doc) = @{$_[1]};
 328         my $ct = $part->content_type || 'text/plain';
 329         my $fn = $part->filename;
 330         if (defined $fn && $fn ne '') {
 331                 index_phrase($self, $fn, 1, 'XFN');
 332         }
 333         if ($part->{is_submsg}) {
 334                 my $mids = mids_for_index($part);
 335                 index_ids($self, $doc, $part, $mids);
 336                 my $smsg = bless {}, 'PublicInbox::Smsg';
 337                 $smsg->populate($part);
 338                 index_headers($self, $smsg);
 339         }
 340
 341         my ($s, undef) = msg_part_text($part, $ct);
 342         defined $s or return;
 343         $_[0]->[0] = $part = undef; # free memory
 344
 345         # split off quoted and unquoted blocks:
 346         my @sections = PublicInbox::MsgIter::split_quotes($s);
 347         undef $s; # free memory
 348         for my $txt (@sections) {
 349                 if ($txt =~ /\A>/) {
 350                         index_text($self, $txt, 0, 'XQUOT');
 351                 } else {
 352                         # does it look like a diff?
 353                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 354                                 index_diff($self, $txt, $doc);
 355                         } else {
 356                                 index_text($self, $txt, 1, 'XNQ');
 357                         }
 358                 }
 359                 undef $txt; # free memory
 360         }
 361 }
 362
 363 sub index_list_id ($$$) {
 364         my ($self, $doc, $hdr) = @_;
 365         for my $l ($hdr->header_raw('List-Id')) {
 366                 $l =~ /<([^>]+)>/ or next;
 367                 my $lid = lc $1;
 368                 $doc->add_boolean_term('G' . $lid);
 369                 index_phrase($self, $lid, 1, 'XL'); # probabilistic
 370         }
 371 }
 372
 373 sub index_ids ($$$$) {
 374         my ($self, $doc, $hdr, $mids) = @_;
 375         for my $mid (@$mids) {
 376                 index_phrase($self, $mid, 1, 'XM');
 377
 378                 # because too many Message-IDs are prefixed with
 379                 # "Pine.LNX."...
 380                 if ($mid =~ /\w{12,}/) {
 381                         my @long = ($mid =~ /(\w{3,}+)/g);
 382                         index_phrase($self, join(' ', @long), 1, 'XM');
 383                 }
 384         }
 385         $doc->add_boolean_term('Q' . $_) for @$mids;
 386         index_list_id($self, $doc, $hdr);
 387 }
 388
 389 sub eml2doc ($$$;$) {
 390         my ($self, $eml, $smsg, $mids) = @_;
 391         $mids //= mids_for_index($eml);
 392         my $doc = $X->{Document}->new;
 393         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 394         my @ds = gmtime($smsg->{ds});
 395         my $yyyymmdd = strftime('%Y%m%d', @ds);
 396         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 397         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 398         add_val($doc, PublicInbox::Search::DT(), $dt);
 399         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 400         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 401         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 402
 403         my $tg = term_generator($self);
 404         $tg->set_document($doc);
 405         index_headers($self, $smsg);
 406
 407         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 408                 $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 409         }
 410         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 411         index_ids($self, $doc, $eml, $mids);
 412
 413         # by default, we maintain compatibility with v1.5.0 and earlier
 414         # by writing to docdata.glass, users who never exect to downgrade can
 415         # use --skip-docdata
 416         if (!$self->{-skip_docdata}) {
 417                 # WWW doesn't need {to} or {cc}, only NNTP
 418                 $smsg->{to} = $smsg->{cc} = '';
 419                 $smsg->parse_references($eml, $mids);
 420                 my $data = $smsg->to_doc_data;
 421                 $doc->set_data($data);
 422         }
 423
 424         if (my $altid = $self->{-altid}) {
 425                 foreach my $alt (@$altid) {
 426                         my $pfx = $alt->{xprefix};
 427                         foreach my $mid (@$mids) {
 428                                 my $id = $alt->mid2alt($mid);
 429                                 next unless defined $id;
 430                                 $doc->add_boolean_term($pfx . $id);
 431                         }
 432                 }
 433         }
 434         $doc;
 435 }
 436
 437 sub add_xapian ($$$$) {
 438         my ($self, $eml, $smsg, $mids) = @_;
 439         begin_txn_lazy($self);
 440         my $merge_vmd = delete $smsg->{-merge_vmd};
 441         my $doc = eml2doc($self, $eml, $smsg, $mids);
 442         if (my $old = $merge_vmd ? _get_doc($self, $smsg->{num}) : undef) {
 443                 my @x = @VMD_MAP;
 444                 while (my ($field, $pfx) = splice(@x, 0, 2)) {
 445                         for my $term (xap_terms($pfx, $old)) {
 446                                 $doc->add_boolean_term($pfx.$term);
 447                         }
 448                 }
 449         }
 450         $self->{xdb}->replace_document($smsg->{num}, $doc);
 451 }
 452
 453 sub _msgmap_init ($) {
 454         my ($self) = @_;
 455         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx}->version != 1;
 456         $self->{mm} //= do {
 457                 require PublicInbox::Msgmap;
 458                 PublicInbox::Msgmap->new_file($self->{ibx}, 1);
 459         };
 460 }
 461
 462 sub add_message {
 463         # mime = PublicInbox::Eml or Email::MIME object
 464         my ($self, $mime, $smsg, $sync) = @_;
 465         begin_txn_lazy($self);
 466         my $mids = mids_for_index($mime);
 467         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 468         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 469         $smsg->{num} //= do { # v1
 470                 _msgmap_init($self);
 471                 index_mm($self, $mime, $smsg->{blob}, $sync);
 472         };
 473
 474         # v1 and tests only:
 475         $smsg->populate($mime, $sync);
 476         $smsg->{bytes} //= length($mime->as_string);
 477
 478         eval {
 479                 # order matters, overview stores every possible piece of
 480                 # data in doc_data (deflated).  Xapian only stores a subset
 481                 # of the fields which exist in over.sqlite3.  We may stop
 482                 # storing doc_data in Xapian sometime after we get multi-inbox
 483                 # search working.
 484                 if (my $oidx = $self->{oidx}) { # v1 only
 485                         $oidx->add_overview($mime, $smsg);
 486                 }
 487                 if (need_xapian($self)) {
 488                         add_xapian($self, $mime, $smsg, $mids);
 489                 }
 490         };
 491
 492         if ($@) {
 493                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 494                 return undef;
 495         }
 496         $smsg->{num};
 497 }
 498
 499 sub _get_doc ($$) {
 500         my ($self, $docid) = @_;
 501         my $doc = eval { $self->{xdb}->get_document($docid) };
 502         $doc // do {
 503                 warn "E: $@\n" if $@;
 504                 warn "E: #$docid missing in Xapian\n";
 505                 undef;
 506         }
 507 }
 508
 509 sub add_eidx_info {
 510         my ($self, $docid, $eidx_key, $eml) = @_;
 511         begin_txn_lazy($self);
 512         my $doc = _get_doc($self, $docid) or return;
 513         term_generator($self)->set_document($doc);
 514
 515         # '.' is special for lei_store
 516         $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 517
 518         index_list_id($self, $doc, $eml);
 519         $self->{xdb}->replace_document($docid, $doc);
 520 }
 521
 522 sub get_terms {
 523         my ($self, $pfx, $docid) = @_;
 524         begin_txn_lazy($self);
 525         xap_terms($pfx, $self->{xdb}, $docid);
 526 }
 527
 528 sub remove_eidx_info {
 529         my ($self, $docid, $eidx_key, $eml) = @_;
 530         begin_txn_lazy($self);
 531         my $doc = _get_doc($self, $docid) or return;
 532         eval { $doc->remove_term('O'.$eidx_key) };
 533         warn "W: ->remove_term O$eidx_key: $@\n" if $@;
 534         for my $l ($eml ? $eml->header_raw('List-Id') : ()) {
 535                 $l =~ /<([^>]+)>/ or next;
 536                 my $lid = lc $1;
 537                 eval { $doc->remove_term('G' . $lid) };
 538                 warn "W: ->remove_term G$lid: $@\n" if $@;
 539
 540                 # nb: we don't remove the XL probabilistic terms
 541                 # since terms may overlap if cross-posted.
 542                 #
 543                 # IOW, a message which has both <foo.example.com>
 544                 # and <bar.example.com> would have overlapping
 545                 # "XLexample" and "XLcom" as terms and which we
 546                 # wouldn't know if they're safe to remove if we just
 547                 # unindex <foo.example.com> while preserving
 548                 # <bar.example.com>.
 549                 #
 550                 # In any case, this entire sub is will likely never
 551                 # be needed and users using the "l:" prefix are probably
 552                 # rarer.
 553         }
 554         $self->{xdb}->replace_document($docid, $doc);
 555 }
 556
 557 sub set_vmd {
 558         my ($self, $docid, $vmd) = @_;
 559         begin_txn_lazy($self);
 560         my $doc = _get_doc($self, $docid) or return;
 561         my ($end, @rm, @add);
 562         my @x = @VMD_MAP;
 563         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 564                 my $set = $vmd->{$field} // next;
 565                 my %keep = map { $_ => 1 } @$set;
 566                 my %add = %keep;
 567                 $end //= $doc->termlist_end;
 568                 for (my $cur = $doc->termlist_begin; $cur != $end; $cur++) {
 569                         $cur->skip_to($pfx);
 570                         last if $cur == $end;
 571                         my $v = $cur->get_termname;
 572                         $v =~ s/\A$pfx//s or next;
 573                         $keep{$v} ? delete($add{$v}) : push(@rm, $pfx.$v);
 574                 }
 575                 push(@add, map { $pfx.$_ } keys %add);
 576         }
 577         return unless scalar(@rm) || scalar(@add);
 578         $doc->remove_term($_) for @rm;
 579         $doc->add_boolean_term($_) for @add;
 580         $self->{xdb}->replace_document($docid, $doc);
 581 }
 582
 583 sub apply_vmd_mod ($$) {
 584         my ($doc, $vmd_mod) = @_;
 585         my $updated = 0;
 586         my @x = @VMD_MAP;
 587         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 588                 # field: "L" or "kw"
 589                 for my $val (@{$vmd_mod->{"-$field"} // []}) {
 590                         eval {
 591                                 $doc->remove_term($pfx . $val);
 592                                 ++$updated;
 593                         };
 594                 }
 595                 for my $val (@{$vmd_mod->{"+$field"} // []}) {
 596                         $doc->add_boolean_term($pfx . $val);
 597                         ++$updated;
 598                 }
 599         }
 600         $updated;
 601 }
 602
 603 sub add_vmd {
 604         my ($self, $docid, $vmd) = @_;
 605         begin_txn_lazy($self);
 606         my $doc = _get_doc($self, $docid) or return;
 607         my @x = @VMD_MAP;
 608         my $updated = 0;
 609         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 610                 my $add = $vmd->{$field} // next;
 611                 $doc->add_boolean_term($pfx . $_) for @$add;
 612                 $updated += scalar(@$add);
 613         }
 614         $updated += apply_vmd_mod($doc, $vmd);
 615         $self->{xdb}->replace_document($docid, $doc) if $updated;
 616 }
 617
 618 sub remove_vmd {
 619         my ($self, $docid, $vmd) = @_;
 620         begin_txn_lazy($self);
 621         my $doc = _get_doc($self, $docid) or return;
 622         my $replace;
 623         my @x = @VMD_MAP;
 624         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 625                 my $rm = $vmd->{$field} // next;
 626                 for (@$rm) {
 627                         eval {
 628                                 $doc->remove_term($pfx . $_);
 629                                 $replace = 1;
 630                         };
 631                 }
 632         }
 633         $self->{xdb}->replace_document($docid, $doc) if $replace;
 634 }
 635
 636 sub update_vmd {
 637         my ($self, $docid, $vmd_mod) = @_;
 638         begin_txn_lazy($self);
 639         my $doc = _get_doc($self, $docid) or return;
 640         my $updated = apply_vmd_mod($doc, $vmd_mod);
 641         $self->{xdb}->replace_document($docid, $doc) if $updated;
 642         $updated;
 643 }
 644
 645 sub xdb_remove {
 646         my ($self, @docids) = @_;
 647         begin_txn_lazy($self);
 648         my $xdb = $self->{xdb} // die 'BUG: missing {xdb}';
 649         for my $docid (@docids) {
 650                 eval { $xdb->delete_document($docid) };
 651                 warn "E: #$docid not in in Xapian? $@\n" if $@;
 652         }
 653 }
 654
 655 sub xdb_remove_quiet {
 656         my ($self, $docid) = @_;
 657         begin_txn_lazy($self);
 658         my $xdb = $self->{xdb} // die 'BUG: missing {xdb}';
 659         eval { $xdb->delete_document($docid) };
 660         ++$self->{-quiet_rm} unless $@;
 661 }
 662
 663 sub nr_quiet_rm { delete($_[0]->{-quiet_rm}) // 0 }
 664
 665 sub index_git_blob_id {
 666         my ($doc, $pfx, $objid) = @_;
 667
 668         my $len = length($objid);
 669         for (my $len = length($objid); $len >= 7; ) {
 670                 $doc->add_term($pfx.$objid);
 671                 $objid = substr($objid, 0, --$len);
 672         }
 673 }
 674
 675 # v1 only
 676 sub unindex_eml {
 677         my ($self, $oid, $eml) = @_;
 678         my $mids = mids($eml);
 679         my $nr = 0;
 680         my %tmp;
 681         for my $mid (@$mids) {
 682                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 683                 $nr += scalar @removed;
 684                 $tmp{$_}++ for @removed;
 685         }
 686         if (!$nr) {
 687                 my $m = join('> <', @$mids);
 688                 warn "W: <$m> missing for removal from overview\n";
 689         }
 690         while (my ($num, $nr) = each %tmp) {
 691                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 692         }
 693         if ($nr) {
 694                 $self->{mm}->num_delete($_) for (keys %tmp);
 695         } else { # just in case msgmap and over.sqlite3 become desynched:
 696                 $self->{mm}->mid_delete($mids->[0]);
 697         }
 698         xdb_remove($self, keys %tmp) if need_xapian($self);
 699 }
 700
 701 sub index_mm {
 702         my ($self, $mime, $oid, $sync) = @_;
 703         my $mids = mids($mime);
 704         my $mm = $self->{mm};
 705         if ($sync->{reindex}) {
 706                 my $oidx = $self->{oidx};
 707                 for my $mid (@$mids) {
 708                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 709                         return $num if defined $num;
 710                 }
 711                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 712         } else {
 713                 # fallback to num_for since filters like RubyLang set the number
 714                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 715         }
 716 }
 717
 718 sub is_bad_blob ($$$$) {
 719         my ($oid, $type, $size, $expect_oid) = @_;
 720         if ($type ne 'blob') {
 721                 carp "W: $expect_oid is not a blob (type=$type)";
 722                 return 1;
 723         }
 724         croak "BUG: $oid != $expect_oid" if $oid ne $expect_oid;
 725         $size == 0 ? 1 : 0; # size == 0 means purged
 726 }
 727
 728 sub index_both { # git->cat_async callback
 729         my ($bref, $oid, $type, $size, $sync) = @_;
 730         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 731         my ($nr, $max) = @$sync{qw(nr max)};
 732         ++$$nr;
 733         $$max -= $size;
 734         my $smsg = bless { blob => $oid }, 'PublicInbox::Smsg';
 735         $smsg->set_bytes($$bref, $size);
 736         my $self = $sync->{sidx};
 737         local $self->{current_info} = "$self->{current_info}: $oid";
 738         my $eml = PublicInbox::Eml->new($bref);
 739         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 740                 die "E: could not generate NNTP article number for $oid";
 741         add_message($self, $eml, $smsg, $sync);
 742         ++$self->{nidx};
 743         my $cur_cmt = $sync->{cur_cmt} // die 'BUG: {cur_cmt} missing';
 744         ${$sync->{latest_cmt}} = $cur_cmt;
 745 }
 746
 747 sub unindex_both { # git->cat_async callback
 748         my ($bref, $oid, $type, $size, $sync) = @_;
 749         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 750         my $self = $sync->{sidx};
 751         local $self->{current_info} = "$self->{current_info}: $oid";
 752         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 753         # may be undef if leftover
 754         if (defined(my $cur_cmt = $sync->{cur_cmt})) {
 755                 ${$sync->{latest_cmt}} = $cur_cmt;
 756         }
 757         ++$self->{nidx};
 758 }
 759
 760 sub with_umask {
 761         my $self = shift;
 762         ($self->{ibx} // $self->{eidx})->with_umask(@_);
 763 }
 764
 765 # called by public-inbox-index
 766 sub index_sync {
 767         my ($self, $opt) = @_;
 768         delete $self->{lock_path} if $opt->{-skip_lock};
 769         $self->with_umask(\&_index_sync, $self, $opt);
 770         if ($opt->{reindex} && !$opt->{quit} &&
 771                         !grep(defined, @$opt{qw(since until)})) {
 772                 my %again = %$opt;
 773                 delete @again{qw(rethread reindex)};
 774                 index_sync($self, \%again);
 775                 $opt->{quit} = $again{quit}; # propagate to caller
 776         }
 777 }
 778
 779 sub check_size { # check_async cb for -index --max-size=...
 780         my ($oid, $type, $size, $arg, $git) = @_;
 781         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 782         if ($size <= $arg->{max_size}) {
 783                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 784         } else {
 785                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 786         }
 787 }
 788
 789 sub v1_checkpoint ($$;$) {
 790         my ($self, $sync, $stk) = @_;
 791         $self->{ibx}->git->async_wait_all;
 792
 793         # $newest may be undef
 794         my $newest = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 795         if (defined($newest)) {
 796                 my $cur = $self->{mm}->last_commit;
 797                 if (need_update($self, $sync, $cur, $newest)) {
 798                         $self->{mm}->last_commit($newest);
 799                 }
 800         }
 801         ${$sync->{max}} = $self->{batch_bytes};
 802
 803         $self->{mm}->{dbh}->commit;
 804         eval { $self->{mm}->{dbh}->do('PRAGMA optimize') };
 805         my $xdb = $self->{xdb};
 806         if ($newest && $xdb) {
 807                 my $cur = $xdb->get_metadata('last_commit');
 808                 if (need_update($self, $sync, $cur, $newest)) {
 809                         $xdb->set_metadata('last_commit', $newest);
 810                 }
 811         }
 812         if ($stk) { # all done if $stk is passed
 813                 # let SearchView know a full --reindex was done so it can
 814                 # generate ->has_threadid-dependent links
 815                 if ($xdb && $sync->{reindex} && !ref($sync->{reindex})) {
 816                         my $n = $xdb->get_metadata('has_threadid');
 817                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 818                 }
 819                 $self->{oidx}->rethread_done($sync->{-opt}); # all done
 820         }
 821         commit_txn_lazy($self);
 822         $sync->{ibx}->git->cleanup;
 823         my $nr = ${$sync->{nr}};
 824         idx_release($self, $nr);
 825         # let another process do some work...
 826         if (my $pr = $sync->{-opt}->{-progress}) {
 827                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 828         }
 829         if (!$stk && !$sync->{quit}) { # more to come
 830                 begin_txn_lazy($self);
 831                 $self->{mm}->{dbh}->begin_work;
 832         }
 833 }
 834
 835 # only for v1
 836 sub process_stack {
 837         my ($self, $sync, $stk) = @_;
 838         my $git = $sync->{ibx}->git;
 839         my $max = $self->{batch_bytes};
 840         my $nr = 0;
 841         $sync->{nr} = \$nr;
 842         $sync->{max} = \$max;
 843         $sync->{sidx} = $self;
 844         $sync->{latest_cmt} = \(my $latest_cmt);
 845
 846         $self->{mm}->{dbh}->begin_work;
 847         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 848                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 849                 for my $oid (@leftovers) {
 850                         last if $sync->{quit};
 851                         $oid = unpack('H*', $oid);
 852                         $git->cat_async($oid, \&unindex_both, $sync);
 853                 }
 854         }
 855         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 856                 $sync->{index_oid} = \&index_both;
 857         }
 858         while (my ($f, $at, $ct, $oid, $cur_cmt) = $stk->pop_rec) {
 859                 my $arg = { %$sync, cur_cmt => $cur_cmt, oid => $oid };
 860                 last if $sync->{quit};
 861                 if ($f eq 'm') {
 862                         $arg->{autime} = $at;
 863                         $arg->{cotime} = $ct;
 864                         if ($sync->{max_size}) {
 865                                 $git->check_async($oid, \&check_size, $arg);
 866                         } else {
 867                                 $git->cat_async($oid, \&index_both, $arg);
 868                         }
 869                         v1_checkpoint($self, $sync) if $max <= 0;
 870                 } elsif ($f eq 'd') {
 871                         $git->cat_async($oid, \&unindex_both, $arg);
 872                 }
 873         }
 874         v1_checkpoint($self, $sync, $sync->{quit} ? undef : $stk);
 875 }
 876
 877 sub log2stack ($$$) {
 878         my ($sync, $git, $range) = @_;
 879         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 880         my ($add, $del);
 881         if ($sync->{ibx}->version == 1) {
 882                 my $path = $hex.'{2}/'.$hex.'{38}';
 883                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 884                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 885         } else {
 886                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 887                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 888         }
 889
 890         # Count the new files so they can be added newest to oldest
 891         # and still have numbers increasing from oldest to newest
 892         my @cmd = qw(log --raw -r --pretty=tformat:%at-%ct-%H
 893                         --no-notes --no-color --no-renames --no-abbrev);
 894         for my $k (qw(since until)) {
 895                 my $v = $sync->{-opt}->{$k} // next;
 896                 next if !$sync->{-opt}->{reindex};
 897                 push @cmd, "--$k=$v";
 898         }
 899         my $fh = $git->popen(@cmd, $range);
 900         my ($at, $ct, $stk, $cmt, $l);
 901         while (defined($l = <$fh>)) {
 902                 return if $sync->{quit};
 903                 if ($l =~ /\A([0-9]+)-([0-9]+)-($OID)$/o) {
 904                         ($at, $ct, $cmt) = ($1 + 0, $2 + 0, $3);
 905                         $stk //= PublicInbox::IdxStack->new($cmt);
 906                 } elsif ($l =~ /$del/) {
 907                         my $oid = $1;
 908                         if ($D) { # reindex case
 909                                 $D->{pack('H*', $oid)}++;
 910                         } else { # non-reindex case:
 911                                 $stk->push_rec('d', $at, $ct, $oid, $cmt);
 912                         }
 913                 } elsif ($l =~ /$add/) {
 914                         my $oid = $1;
 915                         if ($D) {
 916                                 my $oid_bin = pack('H*', $oid);
 917                                 my $nr = --$D->{$oid_bin};
 918                                 delete($D->{$oid_bin}) if $nr <= 0;
 919                                 # nr < 0 (-1) means it never existed
 920                                 next if $nr >= 0;
 921                         }
 922                         $stk->push_rec('m', $at, $ct, $oid, $cmt);
 923                 }
 924         }
 925         close $fh or die "git log failed: \$?=$?";
 926         $stk //= PublicInbox::IdxStack->new;
 927         $stk->read_prepare;
 928 }
 929
 930 sub prepare_stack ($$) {
 931         my ($sync, $range) = @_;
 932         my $git = $sync->{ibx}->git;
 933
 934         if (index($range, '..') < 0) {
 935                 # don't show annoying git errors to users who run -index
 936                 # on empty inboxes
 937                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 938                 return PublicInbox::IdxStack->new->read_prepare if $?;
 939         }
 940         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 941         log2stack($sync, $git, $range);
 942 }
 943
 944 # --is-ancestor requires git 1.8.0+
 945 sub is_ancestor ($$$) {
 946         my ($git, $cur, $tip) = @_;
 947         return 0 unless $git->check($cur);
 948         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 949                 qw(merge-base --is-ancestor), $cur, $tip ];
 950         my $pid = spawn($cmd);
 951         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 952         $? == 0;
 953 }
 954
 955 sub need_update ($$$$) {
 956         my ($self, $sync, $cur, $new) = @_;
 957         my $git = $self->{ibx}->git;
 958         $cur //= ''; # XS Search::Xapian ->get_metadata doesn't give undef
 959
 960         # don't rewind if --{since,until,before,after} are in use
 961         return if $cur ne '' &&
 962                 grep(defined, @{$sync->{-opt}}{qw(since until)}) &&
 963                 is_ancestor($git, $new, $cur);
 964
 965         return 1 if $cur ne '' && !is_ancestor($git, $cur, $new);
 966         my $range = $cur eq '' ? $new : "$cur..$new";
 967         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 968         ($n eq '' || $n > 0);
 969 }
 970
 971 # The last git commit we indexed with Xapian or SQLite (msgmap)
 972 # This needs to account for cases where Xapian or SQLite is
 973 # out-of-date with respect to the other.
 974 sub _last_x_commit {
 975         my ($self, $mm) = @_;
 976         my $lm = $mm->last_commit || '';
 977         my $lx = '';
 978         if (need_xapian($self)) {
 979                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 980         } else {
 981                 $lx = $lm;
 982         }
 983         # Use last_commit from msgmap if it is older or unset
 984         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 985                 $lx = $lm;
 986         }
 987         $lx;
 988 }
 989
 990 sub reindex_from ($$) {
 991         my ($reindex, $last_commit) = @_;
 992         return $last_commit unless $reindex;
 993         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 994 }
 995
 996 sub quit_cb ($) {
 997         my ($sync) = @_;
 998         sub {
 999                 # we set {-opt}->{quit} too, so ->index_sync callers
1000                 # can abort multi-inbox loops this way
1001                 $sync->{quit} = $sync->{-opt}->{quit} = 1;
1002                 warn "gracefully quitting\n";
1003         }
1004 }
1005
1006 # indexes all unindexed messages (v1 only)
1007 sub _index_sync {
1008         my ($self, $opt) = @_;
1009         my $tip = $opt->{ref} || 'HEAD';
1010         my $ibx = $self->{ibx};
1011         local $self->{current_info} = "$ibx->{inboxdir}";
1012         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
1013         $ibx->git->batch_prepare;
1014         my $pr = $opt->{-progress};
1015         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
1016         my $quit = quit_cb($sync);
1017         local $SIG{QUIT} = $quit;
1018         local $SIG{INT} = $quit;
1019         local $SIG{TERM} = $quit;
1020         my $xdb = $self->begin_txn_lazy;
1021         $self->{oidx}->rethread_prepare($opt);
1022         my $mm = _msgmap_init($self);
1023         if ($sync->{reindex}) {
1024                 my $last = $mm->last_commit;
1025                 if ($last) {
1026                         $tip = $last;
1027                 } else {
1028                         # somebody just blindly added --reindex when indexing
1029                         # for the first time, allow it:
1030                         undef $sync->{reindex};
1031                 }
1032         }
1033         my $last_commit = _last_x_commit($self, $mm);
1034         my $lx = reindex_from($sync->{reindex}, $last_commit);
1035         my $range = $lx eq '' ? $tip : "$lx..$tip";
1036         $pr->("counting changes\n\t$range ... ") if $pr;
1037         my $stk = prepare_stack($sync, $range);
1038         $sync->{ntodo} = $stk ? $stk->num_records : 0;
1039         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
1040         process_stack($self, $sync, $stk) if !$sync->{quit};
1041 }
1042
1043 sub DESTROY {
1044         # order matters for unlocking
1045         $_[0]->{xdb} = undef;
1046         $_[0]->{lockfh} = undef;
1047 }
1048
1049 sub _begin_txn {
1050         my ($self) = @_;
1051         my $xdb = $self->{xdb} || idx_acquire($self);
1052         $self->{oidx}->begin_lazy if $self->{oidx};
1053         $xdb->begin_transaction if $xdb;
1054         $self->{txn} = 1;
1055         $xdb;
1056 }
1057
1058 sub begin_txn_lazy {
1059         my ($self) = @_;
1060         $self->with_umask(\&_begin_txn, $self) if !$self->{txn};
1061 }
1062
1063 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
1064 # This metadata is read by Admin::detect_indexlevel:
1065 sub set_metadata_once {
1066         my ($self) = @_;
1067
1068         return if $self->{shard}; # only continue if undef or 0, not >0
1069         my $xdb = $self->{xdb};
1070
1071         if (delete($self->{-set_has_threadid_once})) {
1072                 $xdb->set_metadata('has_threadid', '1');
1073         }
1074         if (delete($self->{-set_indexlevel_once})) {
1075                 my $level = $xdb->get_metadata('indexlevel');
1076                 if (!$level || $level ne 'medium') {
1077                         $xdb->set_metadata('indexlevel', 'medium');
1078                 }
1079         }
1080         if (delete($self->{-set_skip_docdata_once})) {
1081                 $xdb->get_metadata('skip_docdata') or
1082                         $xdb->set_metadata('skip_docdata', '1');
1083         }
1084 }
1085
1086 sub _commit_txn {
1087         my ($self) = @_;
1088         if (my $eidx = $self->{eidx}) {
1089                 $eidx->git->async_wait_all;
1090                 $eidx->{transact_bytes} = 0;
1091         }
1092         if (my $xdb = $self->{xdb}) {
1093                 set_metadata_once($self);
1094                 $xdb->commit_transaction;
1095         }
1096         $self->{oidx}->commit_lazy if $self->{oidx};
1097 }
1098
1099 sub commit_txn_lazy {
1100         my ($self) = @_;
1101         delete($self->{txn}) and
1102                 $self->with_umask(\&_commit_txn, $self);
1103 }
1104
1105 sub eidx_shard_new {
1106         my ($class, $eidx, $shard) = @_;
1107         my $self = bless {
1108                 eidx => $eidx,
1109                 xpfx => $eidx->{xpfx},
1110                 indexlevel => $eidx->{indexlevel},
1111                 -skip_docdata => 1,
1112                 shard => $shard,
1113                 creat => 1,
1114         }, $class;
1115         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
1116         $self;
1117 }
1118
1119 1;