lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 use constant {
  26         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  27                         0x7fffffff : 1_000_000,
  28         DEBUG => !!$ENV{DEBUG},
  29 };
  30
  31 my $xapianlevels = qr/\A(?:full|medium)\z/;
  32
  33 sub new {
  34         my ($class, $ibx, $creat, $shard) = @_;
  35         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  36         my $levels = qr/\A(?:full|medium|basic)\z/;
  37         my $inboxdir = $ibx->{inboxdir};
  38         my $version = $ibx->version;
  39         my $indexlevel = 'full';
  40         my $altid = $ibx->{altid};
  41         if ($altid) {
  42                 require PublicInbox::AltId;
  43                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  44         }
  45         if ($ibx->{indexlevel}) {
  46                 if ($ibx->{indexlevel} =~ $levels) {
  47                         $indexlevel = $ibx->{indexlevel};
  48                 } else {
  49                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  50                 }
  51         }
  52         $ibx = PublicInbox::InboxWritable->new($ibx);
  53         my $self = bless {
  54                 inboxdir => $inboxdir,
  55                 -inbox => $ibx,
  56                 git => $ibx->git,
  57                 -altid => $altid,
  58                 ibx_ver => $version,
  59                 indexlevel => $indexlevel,
  60         }, $class;
  61         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  62         $ibx->umask_prepare;
  63         if ($version == 1) {
  64                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  65                 my $dir = $self->xdir;
  66                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  67                 $self->{index_max_size} = $ibx->{index_max_size};
  68         } elsif ($version == 2) {
  69                 defined $shard or die "shard is required for v2\n";
  70                 # shard is a number
  71                 $self->{shard} = $shard;
  72                 $self->{lock_path} = undef;
  73         } else {
  74                 die "unsupported inbox version=$version\n";
  75         }
  76         $self->{creat} = ($creat || 0) == 1;
  77         $self;
  78 }
  79
  80 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  81
  82 sub _xdb_release {
  83         my ($self) = @_;
  84         if (need_xapian($self)) {
  85                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  86                 $xdb->close;
  87         }
  88         $self->lock_release if $self->{creat};
  89         undef;
  90 }
  91
  92 sub load_xapian_writable () {
  93         return 1 if $X->{WritableDatabase};
  94         PublicInbox::Search::load_xapian() or return;
  95         my $xap = $PublicInbox::Search::Xap;
  96         for (qw(Document TermGenerator WritableDatabase)) {
  97                 $X->{$_} = $xap.'::'.$_;
  98         }
  99         eval 'require '.$X->{WritableDatabase} or die;
 100         *sortable_serialise = $xap.'::sortable_serialise';
 101         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 102         $DB_OPEN = eval($xap.'::DB_OPEN()');
 103         1;
 104 }
 105
 106 sub _xdb_acquire {
 107         my ($self) = @_;
 108         my $flag;
 109         my $dir = $self->xdir;
 110         if (need_xapian($self)) {
 111                 croak 'already acquired' if $self->{xdb};
 112                 load_xapian_writable();
 113                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 114         }
 115         if ($self->{creat}) {
 116                 require File::Path;
 117                 $self->lock_acquire;
 118
 119                 # don't create empty Xapian directories if we don't need Xapian
 120                 my $is_shard = defined($self->{shard});
 121                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 122                         File::Path::mkpath($dir);
 123                 }
 124         }
 125         return unless defined $flag;
 126         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 127         if ($@) {
 128                 die "Failed opening $dir: ", $@;
 129         }
 130         $self->{xdb} = $xdb;
 131 }
 132
 133 sub add_val ($$$) {
 134         my ($doc, $col, $num) = @_;
 135         $num = sortable_serialise($num);
 136         $doc->add_value($col, $num);
 137 }
 138
 139 sub term_generator ($) { # write-only
 140         my ($self) = @_;
 141
 142         $self->{term_generator} //= do {
 143                 my $tg = $X->{TermGenerator}->new;
 144                 $tg->set_stemmer($self->stemmer);
 145                 $tg;
 146         }
 147 }
 148
 149 sub index_text ($$$$) {
 150         my ($self, $text, $wdf_inc, $prefix) = @_;
 151         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 152
 153         if ($self->{indexlevel} eq 'full') {
 154                 $tg->index_text($text, $wdf_inc, $prefix);
 155                 $tg->increase_termpos;
 156         } else {
 157                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 158         }
 159 }
 160
 161 sub index_users ($$) {
 162         my ($self, $smsg) = @_;
 163
 164         my $from = $smsg->from;
 165         my $to = $smsg->to;
 166         my $cc = $smsg->cc;
 167
 168         index_text($self, $from, 1, 'A'); # A - author
 169         index_text($self, $to, 1, 'XTO') if $to ne '';
 170         index_text($self, $cc, 1, 'XCC') if $cc ne '';
 171 }
 172
 173 sub index_diff_inc ($$$$) {
 174         my ($self, $text, $pfx, $xnq) = @_;
 175         if (@$xnq) {
 176                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 177                 @$xnq = ();
 178         }
 179         index_text($self, $text, 1, $pfx);
 180 }
 181
 182 sub index_old_diff_fn {
 183         my ($self, $seen, $fa, $fb, $xnq) = @_;
 184
 185         # no renames or space support for traditional diffs,
 186         # find the number of leading common paths to strip:
 187         my @fa = split('/', $fa);
 188         my @fb = split('/', $fb);
 189         while (scalar(@fa) && scalar(@fb)) {
 190                 $fa = join('/', @fa);
 191                 $fb = join('/', @fb);
 192                 if ($fa eq $fb) {
 193                         unless ($seen->{$fa}++) {
 194                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 195                         }
 196                         return 1;
 197                 }
 198                 shift @fa;
 199                 shift @fb;
 200         }
 201         0;
 202 }
 203
 204 sub index_diff ($$$) {
 205         my ($self, $txt, $doc) = @_;
 206         my %seen;
 207         my $in_diff;
 208         my @xnq;
 209         my $xnq = \@xnq;
 210         foreach (split(/\n/, $txt)) {
 211                 if ($in_diff && s/^ //) { # diff context
 212                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 213                 } elsif (/^-- $/) { # email signature begins
 214                         $in_diff = undef;
 215                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 216                         # wait until "---" and "+++" to capture filenames
 217                         $in_diff = 1;
 218                 # traditional diff:
 219                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 220                         my ($opt, $fa, $fb) = ($1, $2, $3);
 221                         push @xnq, $_;
 222                         # only support unified:
 223                         next unless $opt =~ /[uU]/;
 224                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 225                                                         $xnq);
 226                 } elsif (m!^--- ("?[^/]+/.+)!) {
 227                         my $fn = $1;
 228                         $fn = (split('/', git_unquote($fn), 2))[1];
 229                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 230                         $in_diff = 1;
 231                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 232                         my $fn = $1;
 233                         $fn = (split('/', git_unquote($fn), 2))[1];
 234                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 235                         $in_diff = 1;
 236                 } elsif (/^--- (\S+)/) {
 237                         $in_diff = $1;
 238                         push @xnq, $_;
 239                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 240                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 241                                                         $1, $xnq);
 242                 } elsif ($in_diff && s/^\+//) { # diff added
 243                         index_diff_inc($self, $_, 'XDFB', $xnq);
 244                 } elsif ($in_diff && s/^-//) { # diff removed
 245                         index_diff_inc($self, $_, 'XDFA', $xnq);
 246                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 247                         my ($ba, $bb) = ($1, $2);
 248                         index_git_blob_id($doc, 'XDFPRE', $ba);
 249                         index_git_blob_id($doc, 'XDFPOST', $bb);
 250                         $in_diff = 1;
 251                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 252                         # traditional diff w/o -p
 253                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 254                         # hunk header context
 255                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 256                 # ignore the following lines:
 257                 } elsif (/^(?:dis)similarity index/ ||
 258                                 /^(?:old|new) mode/ ||
 259                                 /^(?:deleted|new) file mode/ ||
 260                                 /^(?:copy|rename) (?:from|to) / ||
 261                                 /^(?:dis)?similarity index / ||
 262                                 /^\\ No newline at end of file/ ||
 263                                 /^Binary files .* differ/) {
 264                         push @xnq, $_;
 265                 } elsif ($_ eq '') {
 266                         # possible to be in diff context, some mail may be
 267                         # stripped by MUA or even GNU diff(1).  "git apply"
 268                         # treats a bare "\n" as diff context, too
 269                 } else {
 270                         push @xnq, $_;
 271                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 272                         $in_diff = undef;
 273                 }
 274         }
 275
 276         index_text($self, join("\n", @xnq), 1, 'XNQ');
 277 }
 278
 279 sub index_xapian { # msg_iter callback
 280         my $part = $_[0]->[0]; # ignore $depth and @idx
 281         my ($self, $doc) = @{$_[1]};
 282         my $ct = $part->content_type || 'text/plain';
 283         my $fn = $part->filename;
 284         if (defined $fn && $fn ne '') {
 285                 index_text($self, $fn, 1, 'XFN');
 286         }
 287
 288         my ($s, undef) = msg_part_text($part, $ct);
 289         defined $s or return;
 290         $_[0]->[0] = $part = undef; # free memory
 291
 292         # split off quoted and unquoted blocks:
 293         my @sections = PublicInbox::MsgIter::split_quotes($s);
 294         undef $s; # free memory
 295         for my $txt (@sections) {
 296                 if ($txt =~ /\A>/) {
 297                         index_text($self, $txt, 0, 'XQUOT');
 298                 } else {
 299                         # does it look like a diff?
 300                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 301                                 index_diff($self, $txt, $doc);
 302                         } else {
 303                                 index_text($self, $txt, 1, 'XNQ');
 304                         }
 305                 }
 306                 undef $txt; # free memory
 307         }
 308 }
 309
 310 sub add_xapian ($$$$) {
 311         my ($self, $mime, $smsg, $mids) = @_;
 312         $smsg->{mime} = $mime; # XXX dangerous
 313         my $hdr = $mime->header_obj;
 314         my $doc = $X->{Document}->new;
 315         my $subj = $smsg->subject;
 316         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 317         my @ds = gmtime($smsg->{ds});
 318         my $yyyymmdd = strftime('%Y%m%d', @ds);
 319         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 320         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 321         add_val($doc, PublicInbox::Search::DT(), $dt);
 322
 323         my $tg = term_generator($self);
 324
 325         $tg->set_document($doc);
 326         index_text($self, $subj, 1, 'S') if $subj;
 327         index_users($self, $smsg);
 328
 329         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 330         foreach my $mid (@$mids) {
 331                 index_text($self, $mid, 1, 'XM');
 332
 333                 # because too many Message-IDs are prefixed with
 334                 # "Pine.LNX."...
 335                 if ($mid =~ /\w{12,}/) {
 336                         my @long = ($mid =~ /(\w{3,}+)/g);
 337                         index_text($self, join(' ', @long), 1, 'XM');
 338                 }
 339         }
 340         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 341         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 342         my $data = $smsg->to_doc_data;
 343         $doc->set_data($data);
 344         if (my $altid = $self->{-altid}) {
 345                 foreach my $alt (@$altid) {
 346                         my $pfx = $alt->{xprefix};
 347                         foreach my $mid (@$mids) {
 348                                 my $id = $alt->mid2alt($mid);
 349                                 next unless defined $id;
 350                                 $doc->add_boolean_term($pfx . $id);
 351                         }
 352                 }
 353         }
 354         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 355         for my $l ($hdr->header_raw('List-Id')) {
 356                 $l =~ /<([^>]+)>/ or next;
 357                 my $lid = $1;
 358                 $doc->add_boolean_term('G' . $lid);
 359                 index_text($self, $lid, 1, 'XL'); # probabilistic
 360         }
 361         $self->{xdb}->replace_document($smsg->{num}, $doc);
 362 }
 363
 364 sub _msgmap_init ($) {
 365         my ($self) = @_;
 366         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 367         $self->{mm} //= eval {
 368                 require PublicInbox::Msgmap;
 369                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 370         };
 371 }
 372
 373 sub add_message {
 374         # mime = Email::MIME object
 375         my ($self, $mime, $smsg) = @_;
 376         my $hdr = $mime->header_obj;
 377         my $mids = mids_for_index($hdr);
 378         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 379         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 380         $smsg->{num} //= do { # v1
 381                 _msgmap_init($self);
 382                 index_mm($self, $mime);
 383         };
 384
 385         # v1 and tests only:
 386         $smsg->{ds} //= msg_datestamp($hdr, $self->{autime});
 387         $smsg->{ts} //= msg_timestamp($hdr, $self->{cotime});
 388
 389         eval {
 390                 # order matters, overview stores every possible piece of
 391                 # data in doc_data (deflated).  Xapian only stores a subset
 392                 # of the fields which exist in over.sqlite3.  We may stop
 393                 # storing doc_data in Xapian sometime after we get multi-inbox
 394                 # search working.
 395                 if (my $over = $self->{over}) { # v1 only
 396                         $over->add_overview($mime, $smsg);
 397                 }
 398                 if (need_xapian($self)) {
 399                         add_xapian($self, $mime, $smsg, $mids);
 400                 }
 401         };
 402
 403         if ($@) {
 404                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 405                 return undef;
 406         }
 407         $smsg->{num};
 408 }
 409
 410 # returns begin and end PostingIterator
 411 sub find_doc_ids {
 412         my ($self, $termval) = @_;
 413         my $db = $self->{xdb};
 414
 415         ($db->postlist_begin($termval), $db->postlist_end($termval));
 416 }
 417
 418 # v1 only
 419 sub batch_do {
 420         my ($self, $termval, $cb) = @_;
 421         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 422         while (1) {
 423                 my ($head, $tail) = $self->find_doc_ids($termval);
 424                 return if $head == $tail;
 425                 my @ids;
 426                 for (; $head != $tail && @ids < $batch_size; $head++) {
 427                         push @ids, $head->get_docid;
 428                 }
 429                 $cb->(\@ids);
 430         }
 431 }
 432
 433 # v1 only, where $mid is unique
 434 sub remove_message {
 435         my ($self, $mid) = @_;
 436         $mid = mid_clean($mid);
 437
 438         if (my $over = $self->{over}) {
 439                 my $nr = eval { $over->remove_oid(undef, $mid) };
 440                 if ($@) {
 441                         warn "failed to remove <$mid> from overview: $@\n";
 442                 } elsif ($nr == 0) {
 443                         warn "<$mid> missing for removal from overview\n";
 444                 }
 445         }
 446         return unless need_xapian($self);
 447         my $db = $self->{xdb};
 448         my $nr = 0;
 449         eval {
 450                 batch_do($self, 'Q' . $mid, sub {
 451                         my ($ids) = @_;
 452                         $db->delete_document($_) for @$ids;
 453                         $nr += scalar @$ids;
 454                 });
 455         };
 456         if ($@) {
 457                 warn "failed to remove <$mid> from Xapian: $@\n";
 458         } elsif ($nr == 0) {
 459                 warn "<$mid> missing for removal from Xapian\n";
 460         }
 461 }
 462
 463 # MID is a hint in V2
 464 sub remove_by_oid {
 465         my ($self, $oid, $mid) = @_;
 466
 467         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 468
 469         return unless need_xapian($self);
 470         my $db = $self->{xdb};
 471
 472         # XXX careful, we cannot use batch_do here since we conditionally
 473         # delete documents based on other factors, so we cannot call
 474         # find_doc_ids twice.
 475         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 476         return if $head == $tail;
 477
 478         # there is only ONE element in @delete unless we
 479         # have bugs in our v2writable deduplication check
 480         my @delete;
 481         for (; $head != $tail; $head++) {
 482                 my $docid = $head->get_docid;
 483                 my $doc = $db->get_document($docid);
 484                 my $smsg = PublicInbox::Smsg->wrap($mid);
 485                 $smsg->load_expand($doc);
 486                 if ($smsg->{blob} eq $oid) {
 487                         push(@delete, $docid);
 488                 }
 489         }
 490         $db->delete_document($_) foreach @delete;
 491         scalar(@delete);
 492 }
 493
 494 sub index_git_blob_id {
 495         my ($doc, $pfx, $objid) = @_;
 496
 497         my $len = length($objid);
 498         for (my $len = length($objid); $len >= 7; ) {
 499                 $doc->add_term($pfx.$objid);
 500                 $objid = substr($objid, 0, --$len);
 501         }
 502 }
 503
 504 sub unindex_blob {
 505         my ($self, $mime) = @_;
 506         my $mid = eval { mid_mime($mime) };
 507         $self->remove_message($mid) if defined $mid;
 508 }
 509
 510 sub index_mm {
 511         my ($self, $mime) = @_;
 512         my $mid = mid_mime($mime);
 513         my $mm = $self->{mm};
 514         my $num;
 515
 516         if (defined $self->{regen_down}) {
 517                 $num = $mm->num_for($mid) and return $num;
 518
 519                 while (($num = $self->{regen_down}--) > 0) {
 520                         if ($mm->mid_set($num, $mid) != 0) {
 521                                 return $num;
 522                         }
 523                 }
 524         } elsif (defined $self->{regen_up}) {
 525                 $num = $mm->num_for($mid) and return $num;
 526
 527                 # this is to fixup old bugs due to add-remove-add
 528                 while (($num = ++$self->{regen_up})) {
 529                         if ($mm->mid_set($num, $mid) != 0) {
 530                                 return $num;
 531                         }
 532                 }
 533         }
 534
 535         $num = $mm->mid_insert($mid) and return $num;
 536
 537         # fallback to num_for since filters like RubyLang set the number
 538         $mm->num_for($mid);
 539 }
 540
 541 sub unindex_mm {
 542         my ($self, $mime) = @_;
 543         $self->{mm}->mid_delete(mid_mime($mime));
 544 }
 545
 546 sub index_both {
 547         my ($self, $mime, $smsg) = @_;
 548         my $num = index_mm($self, $mime);
 549         $smsg->{num} = $num;
 550         add_message($self, $mime, $smsg);
 551 }
 552
 553 sub unindex_both {
 554         my ($self, $mime) = @_;
 555         unindex_blob($self, $mime);
 556         unindex_mm($self, $mime);
 557 }
 558
 559 sub do_cat_mail {
 560         my ($git, $blob, $sizeref) = @_;
 561         my $str = $git->cat_file($blob, $sizeref) or
 562                 die "BUG: $blob not found in $git->{git_dir}";
 563         PublicInbox::MIME->new($str);
 564 }
 565
 566 # called by public-inbox-index
 567 sub index_sync {
 568         my ($self, $opts) = @_;
 569         delete $self->{lock_path} if $opts->{-skip_lock};
 570         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 571 }
 572
 573 sub batch_adjust ($$$$$) {
 574         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 575         $$max -= $bytes;
 576         if ($$max <= 0) {
 577                 $$max = BATCH_BYTES;
 578                 $batch_cb->($nr, $latest);
 579         }
 580 }
 581
 582 sub too_big ($$$) {
 583         my ($self, $git, $oid) = @_;
 584         my $max_size = $self->{index_max_size} or return;
 585         my (undef, undef, $size) = $git->check($oid);
 586         die "E: bad $oid in $git->{git_dir}\n" if !defined($size);
 587         return if $size <= $max_size;
 588         warn "W: skipping $oid ($size > $max_size)\n";
 589         1;
 590 }
 591
 592 # only for v1
 593 sub read_log {
 594         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 595         my $hex = '[a-f0-9]';
 596         my $h40 = $hex .'{40}';
 597         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 598         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 599         my $git = $self->{git};
 600         my $latest;
 601         my $bytes;
 602         my $max = BATCH_BYTES;
 603         local $/ = "\n";
 604         my %D;
 605         my $line;
 606         my $newest;
 607         my $nr = 0;
 608         while (defined($line = <$log>)) {
 609                 if ($line =~ /$addmsg/o) {
 610                         my $blob = $1;
 611                         if (delete $D{$blob}) {
 612                                 if (defined $self->{regen_down}) {
 613                                         my $num = $self->{regen_down}--;
 614                                         $self->{mm}->num_highwater($num);
 615                                 }
 616                                 next;
 617                         }
 618                         next if too_big($self, $git, $blob);
 619                         my $mime = do_cat_mail($git, $blob, \$bytes);
 620                         my $smsg = bless {}, 'PublicInbox::Smsg';
 621                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 622                         $smsg->{blob} = $blob;
 623                         $smsg->{bytes} = $bytes;
 624                         $add_cb->($self, $mime, $smsg);
 625                 } elsif ($line =~ /$delmsg/o) {
 626                         my $blob = $1;
 627                         $D{$blob} = 1 unless too_big($self, $git, $blob);
 628                 } elsif ($line =~ /^commit ($h40)/o) {
 629                         $latest = $1;
 630                         $newest ||= $latest;
 631                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 632                         $self->{autime} = $1;
 633                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 634                         $self->{cotime} = $1;
 635                 }
 636         }
 637         close($log) or die "git log failed: \$?=$?";
 638         # get the leftovers
 639         foreach my $blob (keys %D) {
 640                 my $mime = do_cat_mail($git, $blob, \$bytes);
 641                 $del_cb->($self, $mime);
 642         }
 643         $batch_cb->($nr, $latest, $newest);
 644 }
 645
 646 sub _git_log {
 647         my ($self, $opts, $range) = @_;
 648         my $git = $self->{git};
 649
 650         if (index($range, '..') < 0) {
 651                 # don't show annoying git errors to users who run -index
 652                 # on empty inboxes
 653                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 654                 if ($?) {
 655                         open my $fh, '<', '/dev/null' or
 656                                 die "failed to open /dev/null: $!\n";
 657                         return $fh;
 658                 }
 659         }
 660
 661         # Count the new files so they can be added newest to oldest
 662         # and still have numbers increasing from oldest to newest
 663         my $fcount = 0;
 664         my $pr = $opts->{-progress};
 665         $pr->("counting changes\n\t$range ... ") if $pr;
 666         # can't use 'rev-list --count' if we use --diff-filter
 667         my $fh = $git->popen(qw(log --pretty=tformat:%h
 668                              --no-notes --no-color --no-renames
 669                              --diff-filter=AM), $range);
 670         ++$fcount while <$fh>;
 671         close $fh or die "git log failed: \$?=$?";
 672         my $high = $self->{mm}->num_highwater;
 673         $pr->("$fcount\n") if $pr; # continue previous line
 674         $self->{ntodo} = $fcount;
 675
 676         if (index($range, '..') < 0) {
 677                 if ($high && $high == $fcount) {
 678                         # fix up old bugs in full indexes which caused messages to
 679                         # not appear in Msgmap
 680                         $self->{regen_up} = $high;
 681                 } else {
 682                         # normal regen is for for fresh data
 683                         $self->{regen_down} = $fcount;
 684                 }
 685         } else {
 686                 # Give oldest messages the smallest numbers
 687                 $self->{regen_down} = $high + $fcount;
 688         }
 689
 690         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 691                                 --raw -r --no-abbrev/, $range);
 692 }
 693
 694 # --is-ancestor requires git 1.8.0+
 695 sub is_ancestor ($$$) {
 696         my ($git, $cur, $tip) = @_;
 697         return 0 unless $git->check($cur);
 698         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 699                 qw(merge-base --is-ancestor), $cur, $tip ];
 700         my $pid = spawn($cmd);
 701         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 702         $? == 0;
 703 }
 704
 705 sub need_update ($$$) {
 706         my ($self, $cur, $new) = @_;
 707         my $git = $self->{git};
 708         return 1 if $cur && !is_ancestor($git, $cur, $new);
 709         my $range = $cur eq '' ? $new : "$cur..$new";
 710         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 711         ($n eq '' || $n > 0);
 712 }
 713
 714 # The last git commit we indexed with Xapian or SQLite (msgmap)
 715 # This needs to account for cases where Xapian or SQLite is
 716 # out-of-date with respect to the other.
 717 sub _last_x_commit {
 718         my ($self, $mm) = @_;
 719         my $lm = $mm->last_commit || '';
 720         my $lx = '';
 721         if (need_xapian($self)) {
 722                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 723         } else {
 724                 $lx = $lm;
 725         }
 726         # Use last_commit from msgmap if it is older or unset
 727         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 728                 $lx = $lm;
 729         }
 730         $lx;
 731 }
 732
 733 sub reindex_from ($$) {
 734         my ($reindex, $last_commit) = @_;
 735         return $last_commit unless $reindex;
 736         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 737 }
 738
 739 # indexes all unindexed messages (v1 only)
 740 sub _index_sync {
 741         my ($self, $opts) = @_;
 742         my $tip = $opts->{ref} || 'HEAD';
 743         my ($last_commit, $lx, $xlog);
 744         my $git = $self->{git};
 745         $git->batch_prepare;
 746         my $pr = $opts->{-progress};
 747
 748         my $xdb = $self->begin_txn_lazy;
 749         my $mm = _msgmap_init($self);
 750         do {
 751                 if ($xlog) {
 752                         close($xlog) or die "git log failed: \$?=$?";
 753                         $xlog = undef;
 754                 }
 755                 $last_commit = _last_x_commit($self, $mm);
 756                 $lx = reindex_from($opts->{reindex}, $last_commit);
 757
 758                 $self->{over}->rollback_lazy;
 759                 $self->{over}->disconnect;
 760                 $git->cleanup;
 761                 delete $self->{txn};
 762                 $xdb->cancel_transaction if $xdb;
 763                 $xdb = _xdb_release($self);
 764
 765                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 766                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 767                 $xlog = _git_log($self, $opts, $range);
 768
 769                 $xdb = $self->begin_txn_lazy;
 770         } while (_last_x_commit($self, $mm) ne $last_commit);
 771
 772         my $dbh = $mm->{dbh} if $mm;
 773         my $cb = sub {
 774                 my ($nr, $commit, $newest) = @_;
 775                 if ($dbh) {
 776                         if ($newest) {
 777                                 my $cur = $mm->last_commit || '';
 778                                 if (need_update($self, $cur, $newest)) {
 779                                         $mm->last_commit($newest);
 780                                 }
 781                         }
 782                         $dbh->commit;
 783                 }
 784                 if ($newest && need_xapian($self)) {
 785                         my $cur = $xdb->get_metadata('last_commit');
 786                         if (need_update($self, $cur, $newest)) {
 787                                 $xdb->set_metadata('last_commit', $newest);
 788                         }
 789                 }
 790                 $self->commit_txn_lazy;
 791                 $git->cleanup;
 792                 $xdb = _xdb_release($self);
 793                 # let another process do some work... <
 794                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 795                 if (!$newest) {
 796                         $xdb = $self->begin_txn_lazy;
 797                         $dbh->begin_work if $dbh;
 798                 }
 799         };
 800
 801         $dbh->begin_work;
 802         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 803 }
 804
 805 sub DESTROY {
 806         # order matters for unlocking
 807         $_[0]->{xdb} = undef;
 808         $_[0]->{lockfh} = undef;
 809 }
 810
 811 # remote_* subs are only used by SearchIdxPart
 812 sub remote_commit {
 813         my ($self) = @_;
 814         if (my $w = $self->{w}) {
 815                 print $w "commit\n" or die "failed to write commit: $!";
 816         } else {
 817                 $self->commit_txn_lazy;
 818         }
 819 }
 820
 821 sub remote_close {
 822         my ($self) = @_;
 823         if (my $w = delete $self->{w}) {
 824                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 825                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 826                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 827                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 828                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 829         } else {
 830                 die "transaction in progress $self\n" if $self->{txn};
 831                 $self->_xdb_release if $self->{xdb};
 832         }
 833 }
 834
 835 sub remote_remove {
 836         my ($self, $oid, $mid) = @_;
 837         if (my $w = $self->{w}) {
 838                 # triggers remove_by_oid in a shard
 839                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 840         } else {
 841                 $self->begin_txn_lazy;
 842                 $self->remove_by_oid($oid, $mid);
 843         }
 844 }
 845
 846 sub begin_txn_lazy {
 847         my ($self) = @_;
 848         return if $self->{txn};
 849
 850         $self->{-inbox}->with_umask(sub {
 851                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 852                 $self->{over}->begin_lazy if $self->{over};
 853                 $xdb->begin_transaction if $xdb;
 854                 $self->{txn} = 1;
 855                 $xdb;
 856         });
 857 }
 858
 859 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 860 # This metadata is read by Admin::detect_indexlevel:
 861 sub set_indexlevel {
 862         my ($self) = @_;
 863
 864         if (!$self->{shard} && # undef or 0, not >0
 865                         delete($self->{-set_indexlevel_once})) {
 866                 my $xdb = $self->{xdb};
 867                 my $level = $xdb->get_metadata('indexlevel');
 868                 if (!$level || $level ne 'medium') {
 869                         $xdb->set_metadata('indexlevel', 'medium');
 870                 }
 871         }
 872 }
 873
 874 sub commit_txn_lazy {
 875         my ($self) = @_;
 876         delete $self->{txn} or return;
 877         $self->{-inbox}->with_umask(sub {
 878                 if (my $xdb = $self->{xdb}) {
 879                         set_indexlevel($self);
 880                         $xdb->commit_transaction;
 881                 }
 882                 $self->{over}->commit_lazy if $self->{over};
 883         });
 884 }
 885
 886 sub worker_done {
 887         my ($self) = @_;
 888         if (need_xapian($self)) {
 889                 die "$$ $0 xdb not released\n" if $self->{xdb};
 890         }
 891         die "$$ $0 still in transaction\n" if $self->{txn};
 892 }
 893
 894 1;