lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids references/;
  15 use PublicInbox::MsgIter;
  16 use Carp qw(croak);
  17 use POSIX qw(strftime);
  18 require PublicInbox::Git;
  19
  20 use constant {
  21         PERM_UMASK => 0,
  22         OLD_PERM_GROUP => 1,
  23         OLD_PERM_EVERYBODY => 2,
  24         PERM_GROUP => 0660,
  25         PERM_EVERYBODY => 0664,
  26         BATCH_BYTES => 1_000_000,
  27         DEBUG => !!$ENV{DEBUG},
  28 };
  29
  30 my %GIT_ESC = (
  31         a => "\a",
  32         b => "\b",
  33         f => "\f",
  34         n => "\n",
  35         r => "\r",
  36         t => "\t",
  37         v => "\013",
  38 );
  39
  40 sub git_unquote ($) {
  41         my ($s) = @_;
  42         return $s unless ($s =~ /\A"(.*)"\z/);
  43         $s = $1;
  44         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  45         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  46         $s;
  47 }
  48
  49 sub new {
  50         my ($class, $ibx, $creat, $part) = @_;
  51         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  52         my $git_dir = $mainrepo;
  53         my ($altid, $git);
  54         my $version = 1;
  55         if (ref $ibx) {
  56                 $mainrepo = $ibx->{mainrepo};
  57                 $altid = $ibx->{altid};
  58                 $version = $ibx->{version} || 1;
  59                 if ($altid) {
  60                         require PublicInbox::AltId;
  61                         $altid = [ map {
  62                                 PublicInbox::AltId->new($ibx, $_);
  63                         } @$altid ];
  64                 }
  65                 $git = $ibx->git;
  66         } else {
  67                 $git = PublicInbox::Git->new($git_dir); # v1 only
  68         }
  69         require Search::Xapian::WritableDatabase;
  70         my $self = bless {
  71                 mainrepo => $mainrepo,
  72                 git => $git,
  73                 -altid => $altid,
  74                 version => $version,
  75         }, $class;
  76         my $perm = $self->_git_config_perm;
  77         my $umask = _umask_for($perm);
  78         $self->{umask} = $umask;
  79         if ($version == 1) {
  80                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  81         } elsif ($version == 2) {
  82                 defined $part or die "partition is required for v2\n";
  83                 # partition is a number or "all"
  84                 $self->{partition} = $part;
  85                 $self->{lock_path} = undef;
  86                 $self->{msgmap_path} = "$mainrepo/msgmap.sqlite3";
  87         } else {
  88                 die "unsupported inbox version=$version\n";
  89         }
  90         $self->{creat} = ($creat || 0) == 1;
  91         $self;
  92 }
  93
  94 sub _xdb_release {
  95         my ($self) = @_;
  96         my $xdb = delete $self->{xdb} or croak 'not acquired';
  97         $xdb->close;
  98         $self->lock_release if $self->{creat};
  99         undef;
 100 }
 101
 102 sub _xdb_acquire {
 103         my ($self) = @_;
 104         croak 'already acquired' if $self->{xdb};
 105         my $dir = $self->xdir;
 106         my $flag = Search::Xapian::DB_OPEN;
 107         if ($self->{creat}) {
 108                 require File::Path;
 109                 $self->lock_acquire;
 110                 File::Path::mkpath($dir);
 111                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 112         }
 113         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 114 }
 115
 116 sub add_val ($$$) {
 117         my ($doc, $col, $num) = @_;
 118         $num = Search::Xapian::sortable_serialise($num);
 119         $doc->add_value($col, $num);
 120 }
 121
 122 sub add_values ($$) {
 123         my ($doc, $values) = @_;
 124
 125         my $ts = $values->[PublicInbox::Search::TS];
 126         add_val($doc, PublicInbox::Search::TS, $ts);
 127
 128         my $num = $values->[PublicInbox::Search::NUM];
 129         defined($num) and add_val($doc, PublicInbox::Search::NUM, $num);
 130
 131         my $bytes = $values->[PublicInbox::Search::BYTES];
 132         defined($bytes) and add_val($doc, PublicInbox::Search::BYTES, $bytes);
 133
 134         my $lines = $values->[PublicInbox::Search::LINES];
 135         add_val($doc, PublicInbox::Search::LINES, $lines);
 136
 137         my $ds = $values->[PublicInbox::Search::DS];
 138         add_val($doc, PublicInbox::Search::DS, $ds);
 139         my $yyyymmdd = strftime('%Y%m%d', gmtime($ds));
 140         add_val($doc, PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 141 }
 142
 143 sub index_users ($$) {
 144         my ($tg, $smsg) = @_;
 145
 146         my $from = $smsg->from;
 147         my $to = $smsg->to;
 148         my $cc = $smsg->cc;
 149
 150         $tg->index_text($from, 1, 'A'); # A - author
 151         $tg->increase_termpos;
 152         $tg->index_text($to, 1, 'XTO') if $to ne '';
 153         $tg->increase_termpos;
 154         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 155         $tg->increase_termpos;
 156 }
 157
 158 sub index_diff_inc ($$$$) {
 159         my ($tg, $text, $pfx, $xnq) = @_;
 160         if (@$xnq) {
 161                 $tg->index_text(join("\n", @$xnq), 1, 'XNQ');
 162                 $tg->increase_termpos;
 163                 @$xnq = ();
 164         }
 165         $tg->index_text($text, 1, $pfx);
 166         $tg->increase_termpos;
 167 }
 168
 169 sub index_old_diff_fn {
 170         my ($tg, $seen, $fa, $fb, $xnq) = @_;
 171
 172         # no renames or space support for traditional diffs,
 173         # find the number of leading common paths to strip:
 174         my @fa = split('/', $fa);
 175         my @fb = split('/', $fb);
 176         while (scalar(@fa) && scalar(@fb)) {
 177                 $fa = join('/', @fa);
 178                 $fb = join('/', @fb);
 179                 if ($fa eq $fb) {
 180                         unless ($seen->{$fa}++) {
 181                                 index_diff_inc($tg, $fa, 'XDFN', $xnq);
 182                         }
 183                         return 1;
 184                 }
 185                 shift @fa;
 186                 shift @fb;
 187         }
 188         0;
 189 }
 190
 191 sub index_diff ($$$) {
 192         my ($tg, $lines, $doc) = @_;
 193         my %seen;
 194         my $in_diff;
 195         my @xnq;
 196         my $xnq = \@xnq;
 197         foreach (@$lines) {
 198                 if ($in_diff && s/^ //) { # diff context
 199                         index_diff_inc($tg, $_, 'XDFCTX', $xnq);
 200                 } elsif (/^-- $/) { # email signature begins
 201                         $in_diff = undef;
 202                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 203                         my ($fa, $fb) = ($1, $2);
 204                         my $fn = (split('/', git_unquote($fa), 2))[1];
 205                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 206                         $fn = (split('/', git_unquote($fb), 2))[1];
 207                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 208                         $in_diff = 1;
 209                 # traditional diff:
 210                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 211                         my ($opt, $fa, $fb) = ($1, $2, $3);
 212                         push @xnq, $_;
 213                         # only support unified:
 214                         next unless $opt =~ /[uU]/;
 215                         $in_diff = index_old_diff_fn($tg, \%seen, $fa, $fb,
 216                                                         $xnq);
 217                 } elsif (m!^--- ("?a/.+)!) {
 218                         my $fn = (split('/', git_unquote($1), 2))[1];
 219                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 220                         $in_diff = 1;
 221                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 222                         my $fn = (split('/', git_unquote($1), 2))[1];
 223                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 224                         $in_diff = 1;
 225                 } elsif (/^--- (\S+)/) {
 226                         $in_diff = $1;
 227                         push @xnq, $_;
 228                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 229                         $in_diff = index_old_diff_fn($tg, \%seen, $in_diff, $1,
 230                                                         $xnq);
 231                 } elsif ($in_diff && s/^\+//) { # diff added
 232                         index_diff_inc($tg, $_, 'XDFB', $xnq);
 233                 } elsif ($in_diff && s/^-//) { # diff removed
 234                         index_diff_inc($tg, $_, 'XDFA', $xnq);
 235                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 236                         my ($ba, $bb) = ($1, $2);
 237                         index_git_blob_id($doc, 'XDFPRE', $ba);
 238                         index_git_blob_id($doc, 'XDFPOST', $bb);
 239                         $in_diff = 1;
 240                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 241                         # traditional diff w/o -p
 242                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 243                         # hunk header context
 244                         index_diff_inc($tg, $1, 'XDFHH', $xnq);
 245                 # ignore the following lines:
 246                 } elsif (/^(?:dis)similarity index/ ||
 247                                 /^(?:old|new) mode/ ||
 248                                 /^(?:deleted|new) file mode/ ||
 249                                 /^(?:copy|rename) (?:from|to) / ||
 250                                 /^(?:dis)?similarity index / ||
 251                                 /^\\ No newline at end of file/ ||
 252                                 /^Binary files .* differ/) {
 253                         push @xnq, $_;
 254                 } elsif ($_ eq '') {
 255                         $in_diff = undef;
 256                 } else {
 257                         push @xnq, $_;
 258                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 259                         $in_diff = undef;
 260                 }
 261         }
 262
 263         $tg->index_text(join("\n", @xnq), 1, 'XNQ');
 264         $tg->increase_termpos;
 265 }
 266
 267 sub index_body ($$$) {
 268         my ($tg, $lines, $doc) = @_;
 269         my $txt = join("\n", @$lines);
 270         if ($doc) {
 271                 # does it look like a diff?
 272                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 273                         $txt = undef;
 274                         index_diff($tg, $lines, $doc);
 275                 } else {
 276                         $tg->index_text($txt, 1, 'XNQ');
 277                 }
 278         } else {
 279                 $tg->index_text($txt, 0, 'XQUOT');
 280         }
 281         $tg->increase_termpos;
 282         @$lines = ();
 283 }
 284
 285 sub add_message {
 286         # mime = Email::MIME object
 287         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 288         my $doc_id;
 289         my $mids = mids($mime->header_obj);
 290         my $skel = $self->{skeleton};
 291
 292         eval {
 293                 my $smsg = PublicInbox::SearchMsg->new($mime);
 294                 my $doc = $smsg->{doc};
 295                 my $subj = $smsg->subject;
 296                 my $xpath;
 297                 if ($subj ne '') {
 298                         $xpath = $self->subject_path($subj);
 299                         $xpath = id_compress($xpath);
 300                 }
 301
 302                 my $lines = $mime->body_raw =~ tr!\n!\n!;
 303                 my @values = ($smsg->ds, $num, $bytes, $lines, $smsg->ts);
 304                 add_values($doc, \@values);
 305
 306                 my $tg = $self->term_generator;
 307
 308                 $tg->set_document($doc);
 309                 $tg->index_text($subj, 1, 'S') if $subj;
 310                 $tg->increase_termpos;
 311
 312                 index_users($tg, $smsg);
 313
 314                 msg_iter($mime, sub {
 315                         my ($part, $depth, @idx) = @{$_[0]};
 316                         my $ct = $part->content_type || 'text/plain';
 317                         my $fn = $part->filename;
 318                         if (defined $fn && $fn ne '') {
 319                                 $tg->index_text($fn, 1, 'XFN');
 320                         }
 321
 322                         return if $ct =~ m!\btext/x?html\b!i;
 323
 324                         my $s = eval { $part->body_str };
 325                         if ($@) {
 326                                 if ($ct =~ m!\btext/plain\b!i) {
 327                                         # Try to assume UTF-8 because Alpine
 328                                         # seems to do wacky things and set
 329                                         # charset=X-UNKNOWN
 330                                         $part->charset_set('UTF-8');
 331                                         $s = eval { $part->body_str };
 332                                         $s = $part->body if $@;
 333                                 }
 334                         }
 335                         defined $s or return;
 336
 337                         my (@orig, @quot);
 338                         my $body = $part->body;
 339                         my @lines = split(/\n/, $body);
 340                         while (defined(my $l = shift @lines)) {
 341                                 if ($l =~ /^>/) {
 342                                         index_body($tg, \@orig, $doc) if @orig;
 343                                         push @quot, $l;
 344                                 } else {
 345                                         index_body($tg, \@quot, 0) if @quot;
 346                                         push @orig, $l;
 347                                 }
 348                         }
 349                         index_body($tg, \@quot, 0) if @quot;
 350                         index_body($tg, \@orig, $doc) if @orig;
 351                 });
 352
 353                 # populates smsg->references for smsg->to_doc_data
 354                 my $refs = parse_references($smsg);
 355                 $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 356                 my $data = $smsg->to_doc_data($oid, $mid0);
 357                 foreach my $mid (@$mids) {
 358                         $tg->index_text($mid, 1, 'XM');
 359                 }
 360                 $doc->set_data($data);
 361                 if (my $altid = $self->{-altid}) {
 362                         foreach my $alt (@$altid) {
 363                                 my $pfx = $alt->{xprefix};
 364                                 foreach my $mid (@$mids) {
 365                                         my $id = $alt->mid2alt($mid);
 366                                         next unless defined $id;
 367                                         $doc->add_boolean_term($pfx . $id);
 368                                 }
 369                         }
 370                 }
 371
 372                 $self->delete_article($num) if defined $num; # for reindexing
 373                 if ($skel) {
 374                         push @values, $mids, $xpath, $data;
 375                         $skel->index_skeleton(\@values);
 376                         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 377                         $doc->add_boolean_term('XNUM' . $num) if defined $num;
 378                         $doc_id = $self->{xdb}->add_document($doc);
 379                 } else {
 380                         $doc_id = link_and_save($self, $doc, $mids, $refs,
 381                                                 $num, $xpath);
 382                 }
 383         };
 384
 385         if ($@) {
 386                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 387                 return undef;
 388         }
 389         $doc_id;
 390 }
 391
 392 # returns begin and end PostingIterator
 393 sub find_doc_ids {
 394         my ($self, $termval) = @_;
 395         my $db = $self->{xdb};
 396
 397         ($db->postlist_begin($termval), $db->postlist_end($termval));
 398 }
 399
 400 sub batch_do {
 401         my ($self, $termval, $cb) = @_;
 402         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 403         while (1) {
 404                 my ($head, $tail) = $self->find_doc_ids($termval);
 405                 return if $head == $tail;
 406                 my @ids;
 407                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 408                         push @ids, $head->get_docid;
 409                 }
 410                 $cb->(\@ids);
 411         }
 412 }
 413
 414 sub remove_message {
 415         my ($self, $mid) = @_;
 416         my $db = $self->{xdb};
 417         my $called;
 418         $mid = mid_clean($mid);
 419
 420         eval {
 421                 batch_do($self, 'Q' . $mid, sub {
 422                         my ($ids) = @_;
 423                         $db->delete_document($_) for @$ids;
 424                         $called = 1;
 425                 });
 426         };
 427         if ($@) {
 428                 warn "failed to remove message <$mid>: $@\n";
 429         } elsif (!$called) {
 430                 warn "cannot remove non-existent <$mid>\n";
 431         }
 432 }
 433
 434 sub delete_article {
 435         my ($self, $num) = @_;
 436         my $ndel = 0;
 437         batch_do($self, 'XNUM' . $num, sub {
 438                 my ($ids) = @_;
 439                 $ndel += scalar @$ids;
 440                 $self->{xdb}->delete_document($_) for @$ids;
 441         });
 442 }
 443
 444 # MID is a hint in V2
 445 sub remove_by_oid {
 446         my ($self, $oid, $mid) = @_;
 447         my $db = $self->{xdb};
 448
 449         # XXX careful, we cannot use batch_do here since we conditionally
 450         # delete documents based on other factors, so we cannot call
 451         # find_doc_ids twice.
 452         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 453         return if $head == $tail;
 454
 455         # there is only ONE element in @delete unless we
 456         # have bugs in our v2writable deduplication check
 457         my @delete;
 458         for (; $head != $tail; $head->inc) {
 459                 my $docid = $head->get_docid;
 460                 my $doc = $db->get_document($docid);
 461                 my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 462                 $smsg->load_expand;
 463                 push(@delete, $docid) if $smsg->{blob} eq $oid;
 464         }
 465         $db->delete_document($_) foreach @delete;
 466         scalar(@delete);
 467 }
 468
 469 sub term_generator { # write-only
 470         my ($self) = @_;
 471
 472         my $tg = $self->{term_generator};
 473         return $tg if $tg;
 474
 475         $tg = Search::Xapian::TermGenerator->new;
 476         $tg->set_stemmer($self->stemmer);
 477
 478         $self->{term_generator} = $tg;
 479 }
 480
 481 # increments last_thread_id counter
 482 # returns a 64-bit integer represented as a decimal string
 483 sub next_thread_id {
 484         my ($self) = @_;
 485         my $db = $self->{xdb};
 486         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 487
 488         $db->set_metadata('last_thread_id', ++$last_thread_id);
 489
 490         $last_thread_id;
 491 }
 492
 493 sub parse_references ($) {
 494         my ($smsg) = @_;
 495         my $mime = $smsg->{mime};
 496         my $hdr = $mime->header_obj;
 497         my $refs = references($hdr);
 498         return $refs if scalar(@$refs) == 0;
 499
 500         # prevent circular references via References here:
 501         my %mids = map { $_ => 1 } @{mids($hdr)};
 502         my @keep;
 503         foreach my $ref (@$refs) {
 504                 if (length($ref) > PublicInbox::MID::MAX_MID_SIZE) {
 505                         warn "References: <$ref> too long, ignoring\n";
 506                         next;
 507                 }
 508                 next if $mids{$ref};
 509                 push @keep, $ref;
 510         }
 511         $smsg->{references} = '<'.join('> <', @keep).'>' if @keep;
 512         \@keep;
 513 }
 514
 515 sub link_doc {
 516         my ($self, $doc, $refs, $old_tid) = @_;
 517         my $tid;
 518
 519         if (@$refs) {
 520                 # first ref *should* be the thread root,
 521                 # but we can never trust clients to do the right thing
 522                 my $ref = shift @$refs;
 523                 $tid = resolve_mid_to_tid($self, $ref);
 524                 merge_threads($self, $tid, $old_tid) if defined $old_tid;
 525
 526                 # the rest of the refs should point to this tid:
 527                 foreach $ref (@$refs) {
 528                         my $ptid = resolve_mid_to_tid($self, $ref);
 529                         merge_threads($self, $tid, $ptid);
 530                 }
 531         } else {
 532                 $tid = defined $old_tid ? $old_tid : $self->next_thread_id;
 533         }
 534         $doc->add_boolean_term('G' . $tid);
 535         $tid;
 536 }
 537
 538 sub link_and_save {
 539         my ($self, $doc, $mids, $refs, $num, $xpath) = @_;
 540         my $db = $self->{xdb};
 541         my $old_tid;
 542         my $doc_id;
 543         $doc->add_boolean_term('XNUM' . $num) if defined $num;
 544         $doc->add_boolean_term('XPATH' . $xpath) if defined $xpath;
 545         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 546
 547         my $vivified = 0;
 548         $self->{skel} and die "Should not have read-only skel here\n";;
 549         foreach my $mid (@$mids) {
 550                 $self->each_smsg_by_mid($mid, sub {
 551                         my ($cur) = @_;
 552                         my $type = $cur->type;
 553                         my $cur_tid = $cur->thread_id;
 554                         $old_tid = $cur_tid unless defined $old_tid;
 555                         if ($type eq 'mail') {
 556                                 # do not break existing mail messages,
 557                                 # just merge the threads
 558                                 merge_threads($self, $old_tid, $cur_tid);
 559                                 return 1;
 560                         }
 561                         if ($type ne 'ghost') {
 562                                 die "<$mid> has a bad type: $type\n";
 563                         }
 564                         my $tid = link_doc($self, $doc, $refs, $old_tid);
 565                         $old_tid = $tid unless defined $old_tid;
 566                         $doc_id = $cur->{doc_id};
 567                         $self->{xdb}->replace_document($doc_id, $doc);
 568                         ++$vivified;
 569                         1;
 570                 });
 571         }
 572         if ($vivified > 1) {
 573                 my $id = '<'.join('> <', @$mids).'>';
 574                 warn "BUG: vivified multiple ($vivified) ghosts for $id\n";
 575         }
 576         # not really important, but we return any vivified ghost docid, here:
 577         return $doc_id if defined $doc_id;
 578         link_doc($self, $doc, $refs, $old_tid);
 579         $self->{xdb}->add_document($doc);
 580 }
 581
 582 sub index_git_blob_id {
 583         my ($doc, $pfx, $objid) = @_;
 584
 585         my $len = length($objid);
 586         for (my $len = length($objid); $len >= 7; ) {
 587                 $doc->add_term($pfx.$objid);
 588                 $objid = substr($objid, 0, --$len);
 589         }
 590 }
 591
 592 sub unindex_blob {
 593         my ($self, $mime) = @_;
 594         my $mid = eval { mid_clean(mid_mime($mime)) };
 595         $self->remove_message($mid) if defined $mid;
 596 }
 597
 598 sub index_mm {
 599         my ($self, $mime) = @_;
 600         my $mid = mid_clean(mid_mime($mime));
 601         my $mm = $self->{mm};
 602         my $num = $mm->mid_insert($mid);
 603         return $num if defined $num;
 604
 605         # fallback to num_for since filters like RubyLang set the number
 606         $mm->num_for($mid);
 607 }
 608
 609 sub unindex_mm {
 610         my ($self, $mime) = @_;
 611         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 612 }
 613
 614 sub index_mm2 {
 615         my ($self, $mime, $bytes, $blob) = @_;
 616         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 617         add_message($self, $mime, $bytes, $num, $blob);
 618 }
 619
 620 sub unindex_mm2 {
 621         my ($self, $mime) = @_;
 622         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 623         unindex_blob($self, $mime);
 624 }
 625
 626 sub index_both {
 627         my ($self, $mime, $bytes, $blob) = @_;
 628         my $num = index_mm($self, $mime);
 629         add_message($self, $mime, $bytes, $num, $blob);
 630 }
 631
 632 sub unindex_both {
 633         my ($self, $mime) = @_;
 634         unindex_blob($self, $mime);
 635         unindex_mm($self, $mime);
 636 }
 637
 638 sub do_cat_mail {
 639         my ($git, $blob, $sizeref) = @_;
 640         my $mime = eval {
 641                 my $str = $git->cat_file($blob, $sizeref);
 642                 # fixup bugs from import:
 643                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 644                 PublicInbox::MIME->new($str);
 645         };
 646         $@ ? undef : $mime;
 647 }
 648
 649 sub index_sync {
 650         my ($self, $opts) = @_;
 651         with_umask($self, sub { $self->_index_sync($opts) });
 652 }
 653
 654 sub batch_adjust ($$$$) {
 655         my ($max, $bytes, $batch_cb, $latest) = @_;
 656         $$max -= $bytes;
 657         if ($$max <= 0) {
 658                 $$max = BATCH_BYTES;
 659                 $batch_cb->($latest, 1);
 660         }
 661 }
 662
 663 # only for v1
 664 sub rlog {
 665         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 666         my $hex = '[a-f0-9]';
 667         my $h40 = $hex .'{40}';
 668         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 669         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 670         my $git = $self->{git};
 671         my $latest;
 672         my $bytes;
 673         my $max = BATCH_BYTES;
 674         local $/ = "\n";
 675         my $line;
 676         while (defined($line = <$log>)) {
 677                 if ($line =~ /$addmsg/o) {
 678                         my $blob = $1;
 679                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 680                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 681                         $add_cb->($self, $mime, $bytes, $blob);
 682                 } elsif ($line =~ /$delmsg/o) {
 683                         my $blob = $1;
 684                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 685                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 686                         $del_cb->($self, $mime);
 687                 } elsif ($line =~ /^commit ($h40)/o) {
 688                         $latest = $1;
 689                 }
 690         }
 691         $batch_cb->($latest, 0);
 692 }
 693
 694 sub _msgmap_init {
 695         my ($self) = @_;
 696         $self->{mm} ||= eval {
 697                 require PublicInbox::Msgmap;
 698                 my $msgmap_path = $self->{msgmap_path};
 699                 if (defined $msgmap_path) { # v2
 700                         PublicInbox::Msgmap->new_file($msgmap_path, 1);
 701                 } else {
 702                         PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 703                 }
 704         };
 705 }
 706
 707 sub _git_log {
 708         my ($self, $range) = @_;
 709         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 710                                 --raw -r --no-abbrev/, $range);
 711 }
 712
 713 # indexes all unindexed messages
 714 sub _index_sync {
 715         my ($self, $opts) = @_;
 716         my $tip = $opts->{ref} || 'HEAD';
 717         my $reindex = $opts->{reindex};
 718         my ($mkey, $last_commit, $lx, $xlog);
 719         $self->{git}->batch_prepare;
 720         my $xdb = _xdb_acquire($self);
 721         $xdb->begin_transaction;
 722         do {
 723                 $xlog = undef;
 724                 $mkey = 'last_commit';
 725                 $last_commit = $xdb->get_metadata('last_commit');
 726                 $lx = $last_commit;
 727                 if ($reindex) {
 728                         $lx = '';
 729                         $mkey = undef if $last_commit ne '';
 730                 }
 731                 $xdb->cancel_transaction;
 732                 $xdb = _xdb_release($self);
 733
 734                 # ensure we leak no FDs to "git log"
 735                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 736                 $xlog = _git_log($self, $range);
 737
 738                 $xdb = _xdb_acquire($self);
 739                 $xdb->begin_transaction;
 740         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 741
 742         my $mm = _msgmap_init($self);
 743         my $dbh = $mm->{dbh} if $mm;
 744         my $mm_only;
 745         my $cb = sub {
 746                 my ($commit, $more) = @_;
 747                 if ($dbh) {
 748                         $mm->last_commit($commit) if $commit;
 749                         $dbh->commit;
 750                 }
 751                 if (!$mm_only) {
 752                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 753                         $xdb->commit_transaction;
 754                         $xdb = _xdb_release($self);
 755                 }
 756                 # let another process do some work... <
 757                 if ($more) {
 758                         if (!$mm_only) {
 759                                 $xdb = _xdb_acquire($self);
 760                                 $xdb->begin_transaction;
 761                         }
 762                         $dbh->begin_work if $dbh;
 763                 }
 764         };
 765
 766         if ($mm) {
 767                 $dbh->begin_work;
 768                 my $lm = $mm->last_commit || '';
 769                 if ($lm eq $lx) {
 770                         # Common case is the indexes are synced,
 771                         # we only need to run git-log once:
 772                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 773                 } else {
 774                         # Uncommon case, msgmap and xapian are out-of-sync
 775                         # do not care for performance (but git is fast :>)
 776                         # This happens if we have to reindex Xapian since
 777                         # msgmap is a frozen format and our Xapian format
 778                         # is evolving.
 779                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 780
 781                         # first, ensure msgmap is up-to-date:
 782                         my $mkey_prev = $mkey;
 783                         $mkey = undef; # ignore xapian, for now
 784                         my $mlog = _git_log($self, $r);
 785                         $mm_only = 1;
 786                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 787                         $mm_only = $mlog = undef;
 788
 789                         # now deal with Xapian
 790                         $mkey = $mkey_prev;
 791                         $dbh = undef;
 792                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 793                 }
 794         } else {
 795                 # user didn't install DBD::SQLite and DBI
 796                 rlog($self, $xlog, *add_message, *unindex_blob, $cb);
 797         }
 798 }
 799
 800 # this will create a ghost as necessary
 801 sub resolve_mid_to_tid {
 802         my ($self, $mid) = @_;
 803         my $tid;
 804         $self->each_smsg_by_mid($mid, sub {
 805                 my ($smsg) = @_;
 806                 my $cur_tid = $smsg->thread_id;
 807                 if (defined $tid) {
 808                         merge_threads($self, $tid, $cur_tid);
 809                 } else {
 810                         $tid = $smsg->thread_id;
 811                 }
 812                 1;
 813         });
 814         return $tid if defined $tid;
 815
 816         $self->create_ghost($mid)->thread_id;
 817 }
 818
 819 sub create_ghost {
 820         my ($self, $mid) = @_;
 821
 822         my $tid = $self->next_thread_id;
 823         my $doc = Search::Xapian::Document->new;
 824         $doc->add_boolean_term('Q' . $mid);
 825         $doc->add_boolean_term('G' . $tid);
 826         $doc->add_boolean_term('T' . 'ghost');
 827
 828         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 829         $self->{xdb}->add_document($doc);
 830
 831         $smsg;
 832 }
 833
 834 sub merge_threads {
 835         my ($self, $winner_tid, $loser_tid) = @_;
 836         return if $winner_tid == $loser_tid;
 837         my $db = $self->{xdb};
 838         batch_do($self, 'G' . $loser_tid, sub {
 839                 my ($ids) = @_;
 840                 foreach my $docid (@$ids) {
 841                         my $doc = $db->get_document($docid);
 842                         $doc->remove_term('G' . $loser_tid);
 843                         $doc->add_boolean_term('G' . $winner_tid);
 844                         $db->replace_document($docid, $doc);
 845                 }
 846         });
 847 }
 848
 849 sub _read_git_config_perm {
 850         my ($self) = @_;
 851         my @cmd = qw(config);
 852         if ($self->{version} == 2) {
 853                 push @cmd, "--file=$self->{mainrepo}/all.git/config";
 854         }
 855         my $fh = $self->{git}->popen(@cmd, 'core.sharedRepository');
 856         local $/ = "\n";
 857         my $perm = <$fh>;
 858         chomp $perm if defined $perm;
 859         $perm;
 860 }
 861
 862 sub _git_config_perm {
 863         my $self = shift;
 864         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 865         return PERM_GROUP if (!defined($perm) || $perm eq '');
 866         return PERM_UMASK if ($perm eq 'umask');
 867         return PERM_GROUP if ($perm eq 'group');
 868         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 869                 return PERM_EVERYBODY;
 870         }
 871         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 872         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 873
 874         my $i = oct($perm);
 875         return PERM_UMASK if ($i == PERM_UMASK);
 876         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 877         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 878
 879         if (($i & 0600) != 0600) {
 880                 die "core.sharedRepository mode invalid: ".
 881                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 882         }
 883         ($i & 0666);
 884 }
 885
 886 sub _umask_for {
 887         my ($perm) = @_; # _git_config_perm return value
 888         my $rv = $perm;
 889         return umask if $rv == 0;
 890
 891         # set +x bit if +r or +w were set
 892         $rv |= 0100 if ($rv & 0600);
 893         $rv |= 0010 if ($rv & 0060);
 894         $rv |= 0001 if ($rv & 0006);
 895         (~$rv & 0777);
 896 }
 897
 898 sub with_umask {
 899         my ($self, $cb) = @_;
 900         my $old = umask $self->{umask};
 901         my $rv = eval { $cb->() };
 902         my $err = $@;
 903         umask $old;
 904         die $err if $err;
 905         $rv;
 906 }
 907
 908 sub DESTROY {
 909         # order matters for unlocking
 910         $_[0]->{xdb} = undef;
 911         $_[0]->{lockfh} = undef;
 912 }
 913
 914 # remote_* subs are only used by SearchIdxPart and SearchIdxSkeleton
 915 sub remote_commit {
 916         my ($self) = @_;
 917         if (my $w = $self->{w}) {
 918                 print $w "commit\n" or die "failed to write commit: $!";
 919         } else {
 920                 $self->commit_txn_lazy;
 921                 if (my $skel = $self->{skeleton}) {
 922                         $skel->commit_txn_lazy;
 923                 }
 924         }
 925 }
 926
 927 sub remote_close {
 928         my ($self) = @_;
 929         if (my $w = delete $self->{w}) {
 930                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 931                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 932                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 933                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 934                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 935         } else {
 936                 die "transaction in progress $self\n" if $self->{txn};
 937                 $self->_xdb_release if $self->{xdb};
 938         }
 939 }
 940
 941 sub remote_remove {
 942         my ($self, $oid, $mid) = @_;
 943         if (my $w = $self->{w}) {
 944                 # triggers remove_by_oid in partition or skeleton
 945                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 946         } else {
 947                 $self->begin_txn_lazy;
 948                 $self->remove_by_oid($oid, $mid);
 949         }
 950 }
 951
 952 sub begin_txn_lazy {
 953         my ($self) = @_;
 954         return if $self->{txn};
 955         my $xdb = $self->{xdb} || $self->_xdb_acquire;
 956         $xdb->begin_transaction;
 957         $self->{txn} = 1;
 958 }
 959
 960 sub commit_txn_lazy {
 961         my ($self) = @_;
 962         delete $self->{txn} or return;
 963         $self->{xdb}->commit_transaction;
 964 }
 965
 966 sub worker_done {
 967         my ($self) = @_;
 968         die "$$ $0 xdb not released\n" if $self->{xdb};
 969         die "$$ $0 still in transaction\n" if $self->{txn};
 970 }
 971
 972 1;