lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::Search qw(xap_terms);
  15 use PublicInbox::InboxWritable;
  16 use PublicInbox::MID qw(mids_for_index mids);
  17 use PublicInbox::MsgIter;
  18 use PublicInbox::IdxStack;
  19 use Carp qw(croak carp);
  20 use POSIX qw(strftime);
  21 use Time::Local qw(timegm);
  22 use PublicInbox::OverIdx;
  23 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  24 use PublicInbox::Git qw(git_unquote);
  25 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  26 use PublicInbox::Address;
  27 use Config;
  28 our @EXPORT_OK = qw(log2stack is_ancestor check_size prepare_stack
  29         index_text term_generator add_val is_bad_blob);
  30 my $X = \%PublicInbox::Search::X;
  31 our ($DB_CREATE_OR_OPEN, $DB_OPEN);
  32 our $DB_NO_SYNC = 0;
  33 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff :
  34         # assume a typical 64-bit system has 8x more RAM than a
  35         # typical 32-bit system:
  36         (($Config{ptrsize} >= 8 ? 8192 : 1024) * 1024);
  37
  38 use constant DEBUG => !!$ENV{DEBUG};
  39
  40 my $xapianlevels = qr/\A(?:full|medium)\z/;
  41 my $hex = '[a-f0-9]';
  42 my $OID = $hex .'{40,}';
  43 my @VMD_MAP = (kw => 'K', L => 'L');
  44 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  45
  46 sub new {
  47         my ($class, $ibx, $creat, $shard) = @_;
  48         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  49         my $inboxdir = $ibx->{inboxdir};
  50         my $version = $ibx->version;
  51         my $indexlevel = 'full';
  52         my $altid = $ibx->{altid};
  53         if ($altid) {
  54                 require PublicInbox::AltId;
  55                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  56         }
  57         if ($ibx->{indexlevel}) {
  58                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  59                         $indexlevel = $ibx->{indexlevel};
  60                 } else {
  61                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  62                 }
  63         }
  64         $ibx = PublicInbox::InboxWritable->new($ibx);
  65         my $self = PublicInbox::Search->new($ibx);
  66         bless $self, $class;
  67         $self->{ibx} = $ibx;
  68         $self->{-altid} = $altid;
  69         $self->{indexlevel} = $indexlevel;
  70         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  71         if ($ibx->{-skip_docdata}) {
  72                 $self->{-set_skip_docdata_once} = 1;
  73                 $self->{-skip_docdata} = 1;
  74         }
  75         if ($version == 1) {
  76                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  77                 my $dir = $self->xdir;
  78                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  79                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  80         } elsif ($version == 2) {
  81                 defined $shard or die "shard is required for v2\n";
  82                 # shard is a number
  83                 $self->{shard} = $shard;
  84                 $self->{lock_path} = undef;
  85         } else {
  86                 die "unsupported inbox version=$version\n";
  87         }
  88         $self->{creat} = ($creat || 0) == 1;
  89         $self;
  90 }
  91
  92 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  93
  94 sub idx_release {
  95         my ($self, $wake) = @_;
  96         if (need_xapian($self)) {
  97                 my $xdb = delete $self->{xdb} or croak '{xdb} not acquired';
  98                 $xdb->close;
  99         }
 100         $self->lock_release($wake) if $self->{creat};
 101         undef;
 102 }
 103
 104 sub load_xapian_writable () {
 105         return 1 if $X->{WritableDatabase};
 106         PublicInbox::Search::load_xapian() or die "failed to load Xapian: $@\n";
 107         my $xap = $PublicInbox::Search::Xap;
 108         for (qw(Document TermGenerator WritableDatabase)) {
 109                 $X->{$_} = $xap.'::'.$_;
 110         }
 111         eval 'require '.$X->{WritableDatabase} or die;
 112         *sortable_serialise = $xap.'::sortable_serialise';
 113         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 114         $DB_OPEN = eval($xap.'::DB_OPEN()');
 115         my $ver = (eval($xap.'::major_version()') << 16) |
 116                 (eval($xap.'::minor_version()') << 8) |
 117                 eval($xap.'::revision()');
 118         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 119         # Xapian v1.2.21..v1.2.24 were missing close-on-exec on OFD locks
 120         $X->{CLOEXEC_UNSET} = 1 if $ver >= 0x010215 && $ver <= 0x010218;
 121         1;
 122 }
 123
 124 sub idx_acquire {
 125         my ($self) = @_;
 126         my $flag;
 127         my $dir = $self->xdir;
 128         if (need_xapian($self)) {
 129                 croak 'already acquired' if $self->{xdb};
 130                 load_xapian_writable();
 131                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 132         }
 133         if ($self->{creat}) {
 134                 require File::Path;
 135                 $self->lock_acquire;
 136
 137                 # don't create empty Xapian directories if we don't need Xapian
 138                 my $is_shard = defined($self->{shard});
 139                 if (!-d $dir && (!$is_shard ||
 140                                 ($is_shard && need_xapian($self)))) {
 141                         File::Path::mkpath($dir);
 142                         nodatacow_dir($dir);
 143                         $self->{-set_has_threadid_once} = 1;
 144                 }
 145         }
 146         return unless defined $flag;
 147         $flag |= $DB_NO_SYNC if ($self->{ibx} // $self->{eidx})->{-no_fsync};
 148         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 149         croak "Failed opening $dir: $@" if $@;
 150         $self->{xdb} = $xdb;
 151 }
 152
 153 sub add_val ($$$) {
 154         my ($doc, $col, $num) = @_;
 155         $num = sortable_serialise($num);
 156         $doc->add_value($col, $num);
 157 }
 158
 159 sub term_generator ($) { # write-only
 160         my ($self) = @_;
 161
 162         $self->{term_generator} //= do {
 163                 my $tg = $X->{TermGenerator}->new;
 164                 $tg->set_stemmer(PublicInbox::Search::stemmer($self));
 165                 $tg;
 166         }
 167 }
 168
 169 sub index_phrase ($$$$) {
 170         my ($self, $text, $wdf_inc, $prefix) = @_;
 171
 172         my $tg = term_generator($self);
 173         $tg->index_text($text, $wdf_inc, $prefix);
 174         $tg->increase_termpos;
 175 }
 176
 177 sub index_text ($$$$) {
 178         my ($self, $text, $wdf_inc, $prefix) = @_;
 179
 180         if ($self->{indexlevel} eq 'full') {
 181                 index_phrase($self, $text, $wdf_inc, $prefix);
 182         } else {
 183                 my $tg = term_generator($self);
 184                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 185         }
 186 }
 187
 188 sub index_headers ($$) {
 189         my ($self, $smsg) = @_;
 190         my @x = (from => 'A', to => 'XTO', cc => 'XCC'); # A: Author
 191         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 192                 my $val = $smsg->{$field};
 193                 next if $val eq '';
 194                 # include "(comments)" after the address, too, so not using
 195                 # PublicInbox::Address::names or pairs
 196                 index_text($self, $val, 1, $pfx);
 197
 198                 # we need positional info for email addresses since they
 199                 # can be considered phrases
 200                 if ($self->{indexlevel} eq 'medium') {
 201                         for my $addr (PublicInbox::Address::emails($val)) {
 202                                 index_phrase($self, $addr, 1, $pfx);
 203                         }
 204                 }
 205         }
 206         @x = (subject => 'S');
 207         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 208                 my $val = $smsg->{$field};
 209                 index_text($self, $val, 1, $pfx) if $val ne '';
 210         }
 211 }
 212
 213 sub index_diff_inc ($$$$) {
 214         my ($self, $text, $pfx, $xnq) = @_;
 215         if (@$xnq) {
 216                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 217                 @$xnq = ();
 218         }
 219         if ($pfx eq 'XDFN') {
 220                 index_phrase($self, $text, 1, $pfx);
 221         } else {
 222                 index_text($self, $text, 1, $pfx);
 223         }
 224 }
 225
 226 sub index_old_diff_fn {
 227         my ($self, $seen, $fa, $fb, $xnq) = @_;
 228
 229         # no renames or space support for traditional diffs,
 230         # find the number of leading common paths to strip:
 231         my @fa = split('/', $fa);
 232         my @fb = split('/', $fb);
 233         while (scalar(@fa) && scalar(@fb)) {
 234                 $fa = join('/', @fa);
 235                 $fb = join('/', @fb);
 236                 if ($fa eq $fb) {
 237                         unless ($seen->{$fa}++) {
 238                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 239                         }
 240                         return 1;
 241                 }
 242                 shift @fa;
 243                 shift @fb;
 244         }
 245         0;
 246 }
 247
 248 sub index_diff ($$$) {
 249         my ($self, $txt, $doc) = @_;
 250         my %seen;
 251         my $in_diff;
 252         my @xnq;
 253         my $xnq = \@xnq;
 254         foreach (split(/\n/, $txt)) {
 255                 if ($in_diff && s/^ //) { # diff context
 256                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 257                 } elsif (/^-- $/) { # email signature begins
 258                         $in_diff = undef;
 259                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 260                         # wait until "---" and "+++" to capture filenames
 261                         $in_diff = 1;
 262                 # traditional diff:
 263                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 264                         my ($opt, $fa, $fb) = ($1, $2, $3);
 265                         push @xnq, $_;
 266                         # only support unified:
 267                         next unless $opt =~ /[uU]/;
 268                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 269                                                         $xnq);
 270                 } elsif (m!^--- ("?[^/]+/.+)!) {
 271                         my $fn = $1;
 272                         $fn = (split('/', git_unquote($fn), 2))[1];
 273                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 274                         $in_diff = 1;
 275                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 276                         my $fn = $1;
 277                         $fn = (split('/', git_unquote($fn), 2))[1];
 278                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 279                         $in_diff = 1;
 280                 } elsif (/^--- (\S+)/) {
 281                         $in_diff = $1;
 282                         push @xnq, $_;
 283                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 284                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 285                                                         $1, $xnq);
 286                 } elsif ($in_diff && s/^\+//) { # diff added
 287                         index_diff_inc($self, $_, 'XDFB', $xnq);
 288                 } elsif ($in_diff && s/^-//) { # diff removed
 289                         index_diff_inc($self, $_, 'XDFA', $xnq);
 290                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 291                         my ($ba, $bb) = ($1, $2);
 292                         index_git_blob_id($doc, 'XDFPRE', $ba);
 293                         index_git_blob_id($doc, 'XDFPOST', $bb);
 294                         $in_diff = 1;
 295                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 296                         # traditional diff w/o -p
 297                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 298                         # hunk header context
 299                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 300                 # ignore the following lines:
 301                 } elsif (/^(?:dis)similarity index/ ||
 302                                 /^(?:old|new) mode/ ||
 303                                 /^(?:deleted|new) file mode/ ||
 304                                 /^(?:copy|rename) (?:from|to) / ||
 305                                 /^(?:dis)?similarity index / ||
 306                                 /^\\ No newline at end of file/ ||
 307                                 /^Binary files .* differ/) {
 308                         push @xnq, $_;
 309                 } elsif ($_ eq '') {
 310                         # possible to be in diff context, some mail may be
 311                         # stripped by MUA or even GNU diff(1).  "git apply"
 312                         # treats a bare "\n" as diff context, too
 313                 } else {
 314                         push @xnq, $_;
 315                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 316                         $in_diff = undef;
 317                 }
 318         }
 319
 320         index_text($self, join("\n", @xnq), 1, 'XNQ');
 321 }
 322
 323 sub index_xapian { # msg_iter callback
 324         my $part = $_[0]->[0]; # ignore $depth and $idx
 325         my ($self, $doc) = @{$_[1]};
 326         my $ct = $part->content_type || 'text/plain';
 327         my $fn = $part->filename;
 328         if (defined $fn && $fn ne '') {
 329                 index_phrase($self, $fn, 1, 'XFN');
 330         }
 331         if ($part->{is_submsg}) {
 332                 my $mids = mids_for_index($part);
 333                 index_ids($self, $doc, $part, $mids);
 334                 my $smsg = bless {}, 'PublicInbox::Smsg';
 335                 $smsg->populate($part);
 336                 index_headers($self, $smsg);
 337         }
 338
 339         my ($s, undef) = msg_part_text($part, $ct);
 340         defined $s or return;
 341         $_[0]->[0] = $part = undef; # free memory
 342
 343         # split off quoted and unquoted blocks:
 344         my @sections = PublicInbox::MsgIter::split_quotes($s);
 345         undef $s; # free memory
 346         for my $txt (@sections) {
 347                 if ($txt =~ /\A>/) {
 348                         index_text($self, $txt, 0, 'XQUOT');
 349                 } else {
 350                         # does it look like a diff?
 351                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 352                                 index_diff($self, $txt, $doc);
 353                         } else {
 354                                 index_text($self, $txt, 1, 'XNQ');
 355                         }
 356                 }
 357                 undef $txt; # free memory
 358         }
 359 }
 360
 361 sub index_list_id ($$$) {
 362         my ($self, $doc, $hdr) = @_;
 363         for my $l ($hdr->header_raw('List-Id')) {
 364                 $l =~ /<([^>]+)>/ or next;
 365                 my $lid = lc $1;
 366                 $doc->add_boolean_term('G' . $lid);
 367                 index_phrase($self, $lid, 1, 'XL'); # probabilistic
 368         }
 369 }
 370
 371 sub index_ids ($$$$) {
 372         my ($self, $doc, $hdr, $mids) = @_;
 373         for my $mid (@$mids) {
 374                 index_phrase($self, $mid, 1, 'XM');
 375
 376                 # because too many Message-IDs are prefixed with
 377                 # "Pine.LNX."...
 378                 if ($mid =~ /\w{12,}/) {
 379                         my @long = ($mid =~ /(\w{3,}+)/g);
 380                         index_phrase($self, join(' ', @long), 1, 'XM');
 381                 }
 382         }
 383         $doc->add_boolean_term('Q' . $_) for @$mids;
 384         index_list_id($self, $doc, $hdr);
 385 }
 386
 387 sub eml2doc ($$$;$) {
 388         my ($self, $eml, $smsg, $mids) = @_;
 389         $mids //= mids_for_index($eml);
 390         my $doc = $X->{Document}->new;
 391         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 392         my @ds = gmtime($smsg->{ds});
 393         my $yyyymmdd = strftime('%Y%m%d', @ds);
 394         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 395         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 396         add_val($doc, PublicInbox::Search::DT(), $dt);
 397         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 398         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 399         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 400
 401         my $tg = term_generator($self);
 402         $tg->set_document($doc);
 403         index_headers($self, $smsg);
 404
 405         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 406                 $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 407         }
 408         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 409         index_ids($self, $doc, $eml, $mids);
 410
 411         # by default, we maintain compatibility with v1.5.0 and earlier
 412         # by writing to docdata.glass, users who never exect to downgrade can
 413         # use --skip-docdata
 414         if (!$self->{-skip_docdata}) {
 415                 # WWW doesn't need {to} or {cc}, only NNTP
 416                 $smsg->{to} = $smsg->{cc} = '';
 417                 $smsg->parse_references($eml, $mids);
 418                 my $data = $smsg->to_doc_data;
 419                 $doc->set_data($data);
 420         }
 421
 422         if (my $altid = $self->{-altid}) {
 423                 foreach my $alt (@$altid) {
 424                         my $pfx = $alt->{xprefix};
 425                         foreach my $mid (@$mids) {
 426                                 my $id = $alt->mid2alt($mid);
 427                                 next unless defined $id;
 428                                 $doc->add_boolean_term($pfx . $id);
 429                         }
 430                 }
 431         }
 432         $doc;
 433 }
 434
 435 sub add_xapian ($$$$) {
 436         my ($self, $eml, $smsg, $mids) = @_;
 437         begin_txn_lazy($self);
 438         my $merge_vmd = delete $smsg->{-merge_vmd};
 439         my $doc = eml2doc($self, $eml, $smsg, $mids);
 440         if (my $old = $merge_vmd ? _get_doc($self, $smsg->{num}) : undef) {
 441                 my @x = @VMD_MAP;
 442                 while (my ($field, $pfx) = splice(@x, 0, 2)) {
 443                         for my $term (xap_terms($pfx, $old)) {
 444                                 $doc->add_boolean_term($pfx.$term);
 445                         }
 446                 }
 447         }
 448         $self->{xdb}->replace_document($smsg->{num}, $doc);
 449 }
 450
 451 sub _msgmap_init ($) {
 452         my ($self) = @_;
 453         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx}->version != 1;
 454         $self->{mm} //= eval {
 455                 require PublicInbox::Msgmap;
 456                 PublicInbox::Msgmap->new_file($self->{ibx}, 1);
 457         };
 458 }
 459
 460 sub add_message {
 461         # mime = PublicInbox::Eml or Email::MIME object
 462         my ($self, $mime, $smsg, $sync) = @_;
 463         begin_txn_lazy($self);
 464         my $mids = mids_for_index($mime);
 465         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 466         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 467         $smsg->{num} //= do { # v1
 468                 _msgmap_init($self);
 469                 index_mm($self, $mime, $smsg->{blob}, $sync);
 470         };
 471
 472         # v1 and tests only:
 473         $smsg->populate($mime, $sync);
 474         $smsg->{bytes} //= length($mime->as_string);
 475
 476         eval {
 477                 # order matters, overview stores every possible piece of
 478                 # data in doc_data (deflated).  Xapian only stores a subset
 479                 # of the fields which exist in over.sqlite3.  We may stop
 480                 # storing doc_data in Xapian sometime after we get multi-inbox
 481                 # search working.
 482                 if (my $oidx = $self->{oidx}) { # v1 only
 483                         $oidx->add_overview($mime, $smsg);
 484                 }
 485                 if (need_xapian($self)) {
 486                         add_xapian($self, $mime, $smsg, $mids);
 487                 }
 488         };
 489
 490         if ($@) {
 491                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 492                 return undef;
 493         }
 494         $smsg->{num};
 495 }
 496
 497 sub _get_doc ($$) {
 498         my ($self, $docid) = @_;
 499         my $doc = eval { $self->{xdb}->get_document($docid) };
 500         $doc // do {
 501                 warn "E: $@\n" if $@;
 502                 warn "E: #$docid missing in Xapian\n";
 503                 undef;
 504         }
 505 }
 506
 507 sub add_eidx_info {
 508         my ($self, $docid, $eidx_key, $eml) = @_;
 509         begin_txn_lazy($self);
 510         my $doc = _get_doc($self, $docid) or return;
 511         term_generator($self)->set_document($doc);
 512
 513         # '.' is special for lei_store
 514         $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 515
 516         index_list_id($self, $doc, $eml);
 517         $self->{xdb}->replace_document($docid, $doc);
 518 }
 519
 520 sub remove_eidx_info {
 521         my ($self, $docid, $eidx_key, $eml) = @_;
 522         begin_txn_lazy($self);
 523         my $doc = _get_doc($self, $docid) or return;
 524         eval { $doc->remove_term('O'.$eidx_key) };
 525         warn "W: ->remove_term O$eidx_key: $@\n" if $@;
 526         for my $l ($eml ? $eml->header_raw('List-Id') : ()) {
 527                 $l =~ /<([^>]+)>/ or next;
 528                 my $lid = lc $1;
 529                 eval { $doc->remove_term('G' . $lid) };
 530                 warn "W: ->remove_term G$lid: $@\n" if $@;
 531
 532                 # nb: we don't remove the XL probabilistic terms
 533                 # since terms may overlap if cross-posted.
 534                 #
 535                 # IOW, a message which has both <foo.example.com>
 536                 # and <bar.example.com> would have overlapping
 537                 # "XLexample" and "XLcom" as terms and which we
 538                 # wouldn't know if they're safe to remove if we just
 539                 # unindex <foo.example.com> while preserving
 540                 # <bar.example.com>.
 541                 #
 542                 # In any case, this entire sub is will likely never
 543                 # be needed and users using the "l:" prefix are probably
 544                 # rarer.
 545         }
 546         $self->{xdb}->replace_document($docid, $doc);
 547 }
 548
 549 sub set_vmd {
 550         my ($self, $docid, $vmd) = @_;
 551         begin_txn_lazy($self);
 552         my $doc = _get_doc($self, $docid) or return;
 553         my ($end, @rm, @add);
 554         my @x = @VMD_MAP;
 555         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 556                 my $set = $vmd->{$field} // next;
 557                 my %keep = map { $_ => 1 } @$set;
 558                 my %add = %keep;
 559                 $end //= $doc->termlist_end;
 560                 for (my $cur = $doc->termlist_begin; $cur != $end; $cur++) {
 561                         $cur->skip_to($pfx);
 562                         last if $cur == $end;
 563                         my $v = $cur->get_termname;
 564                         $v =~ s/\A$pfx//s or next;
 565                         $keep{$v} ? delete($add{$v}) : push(@rm, $pfx.$v);
 566                 }
 567                 push(@add, map { $pfx.$_ } keys %add);
 568         }
 569         return unless scalar(@rm) || scalar(@add);
 570         $doc->remove_term($_) for @rm;
 571         $doc->add_boolean_term($_) for @add;
 572         $self->{xdb}->replace_document($docid, $doc);
 573 }
 574
 575 sub apply_vmd_mod ($$) {
 576         my ($doc, $vmd_mod) = @_;
 577         my $updated = 0;
 578         my @x = @VMD_MAP;
 579         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 580                 # field: "L" or "kw"
 581                 for my $val (@{$vmd_mod->{"-$field"} // []}) {
 582                         eval {
 583                                 $doc->remove_term($pfx . $val);
 584                                 ++$updated;
 585                         };
 586                 }
 587                 for my $val (@{$vmd_mod->{"+$field"} // []}) {
 588                         $doc->add_boolean_term($pfx . $val);
 589                         ++$updated;
 590                 }
 591         }
 592         $updated;
 593 }
 594
 595 sub add_vmd {
 596         my ($self, $docid, $vmd) = @_;
 597         begin_txn_lazy($self);
 598         my $doc = _get_doc($self, $docid) or return;
 599         my @x = @VMD_MAP;
 600         my $updated = 0;
 601         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 602                 my $add = $vmd->{$field} // next;
 603                 $doc->add_boolean_term($pfx . $_) for @$add;
 604                 $updated += scalar(@$add);
 605         }
 606         $updated += apply_vmd_mod($doc, $vmd);
 607         $self->{xdb}->replace_document($docid, $doc) if $updated;
 608 }
 609
 610 sub remove_vmd {
 611         my ($self, $docid, $vmd) = @_;
 612         begin_txn_lazy($self);
 613         my $doc = _get_doc($self, $docid) or return;
 614         my $replace;
 615         my @x = @VMD_MAP;
 616         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 617                 my $rm = $vmd->{$field} // next;
 618                 for (@$rm) {
 619                         eval {
 620                                 $doc->remove_term($pfx . $_);
 621                                 $replace = 1;
 622                         };
 623                 }
 624         }
 625         $self->{xdb}->replace_document($docid, $doc) if $replace;
 626 }
 627
 628 sub update_vmd {
 629         my ($self, $docid, $vmd_mod) = @_;
 630         begin_txn_lazy($self);
 631         my $doc = _get_doc($self, $docid) or return;
 632         my $updated = apply_vmd_mod($doc, $vmd_mod);
 633         $self->{xdb}->replace_document($docid, $doc) if $updated;
 634         $updated;
 635 }
 636
 637 sub xdb_remove {
 638         my ($self, @docids) = @_;
 639         begin_txn_lazy($self);
 640         my $xdb = $self->{xdb} // die 'BUG: missing {xdb}';
 641         for my $docid (@docids) {
 642                 eval { $xdb->delete_document($docid) };
 643                 warn "E: #$docid not in in Xapian? $@\n" if $@;
 644         }
 645 }
 646
 647 sub xdb_remove_quiet {
 648         my ($self, $docid) = @_;
 649         begin_txn_lazy($self);
 650         my $xdb = $self->{xdb} // die 'BUG: missing {xdb}';
 651         eval { $xdb->delete_document($docid) };
 652         ++$self->{-quiet_rm} unless $@;
 653 }
 654
 655 sub nr_quiet_rm { delete($_[0]->{-quiet_rm}) // 0 }
 656
 657 sub index_git_blob_id {
 658         my ($doc, $pfx, $objid) = @_;
 659
 660         my $len = length($objid);
 661         for (my $len = length($objid); $len >= 7; ) {
 662                 $doc->add_term($pfx.$objid);
 663                 $objid = substr($objid, 0, --$len);
 664         }
 665 }
 666
 667 # v1 only
 668 sub unindex_eml {
 669         my ($self, $oid, $eml) = @_;
 670         my $mids = mids($eml);
 671         my $nr = 0;
 672         my %tmp;
 673         for my $mid (@$mids) {
 674                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 675                 $nr += scalar @removed;
 676                 $tmp{$_}++ for @removed;
 677         }
 678         if (!$nr) {
 679                 my $m = join('> <', @$mids);
 680                 warn "W: <$m> missing for removal from overview\n";
 681         }
 682         while (my ($num, $nr) = each %tmp) {
 683                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 684         }
 685         if ($nr) {
 686                 $self->{mm}->num_delete($_) for (keys %tmp);
 687         } else { # just in case msgmap and over.sqlite3 become desynched:
 688                 $self->{mm}->mid_delete($mids->[0]);
 689         }
 690         xdb_remove($self, keys %tmp) if need_xapian($self);
 691 }
 692
 693 sub index_mm {
 694         my ($self, $mime, $oid, $sync) = @_;
 695         my $mids = mids($mime);
 696         my $mm = $self->{mm};
 697         if ($sync->{reindex}) {
 698                 my $oidx = $self->{oidx};
 699                 for my $mid (@$mids) {
 700                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 701                         return $num if defined $num;
 702                 }
 703                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 704         } else {
 705                 # fallback to num_for since filters like RubyLang set the number
 706                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 707         }
 708 }
 709
 710 sub is_bad_blob ($$$$) {
 711         my ($oid, $type, $size, $expect_oid) = @_;
 712         if ($type ne 'blob') {
 713                 carp "W: $expect_oid is not a blob (type=$type)";
 714                 return 1;
 715         }
 716         croak "BUG: $oid != $expect_oid" if $oid ne $expect_oid;
 717         $size == 0 ? 1 : 0; # size == 0 means purged
 718 }
 719
 720 sub index_both { # git->cat_async callback
 721         my ($bref, $oid, $type, $size, $sync) = @_;
 722         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 723         my ($nr, $max) = @$sync{qw(nr max)};
 724         ++$$nr;
 725         $$max -= $size;
 726         my $smsg = bless { blob => $oid }, 'PublicInbox::Smsg';
 727         $smsg->set_bytes($$bref, $size);
 728         my $self = $sync->{sidx};
 729         local $self->{current_info} = "$self->{current_info}: $oid";
 730         my $eml = PublicInbox::Eml->new($bref);
 731         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 732                 die "E: could not generate NNTP article number for $oid";
 733         add_message($self, $eml, $smsg, $sync);
 734         ++$self->{nidx};
 735         my $cur_cmt = $sync->{cur_cmt} // die 'BUG: {cur_cmt} missing';
 736         ${$sync->{latest_cmt}} = $cur_cmt;
 737 }
 738
 739 sub unindex_both { # git->cat_async callback
 740         my ($bref, $oid, $type, $size, $sync) = @_;
 741         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 742         my $self = $sync->{sidx};
 743         local $self->{current_info} = "$self->{current_info}: $oid";
 744         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 745         # may be undef if leftover
 746         if (defined(my $cur_cmt = $sync->{cur_cmt})) {
 747                 ${$sync->{latest_cmt}} = $cur_cmt;
 748         }
 749         ++$self->{nidx};
 750 }
 751
 752 sub with_umask {
 753         my $self = shift;
 754         ($self->{ibx} // $self->{eidx})->with_umask(@_);
 755 }
 756
 757 # called by public-inbox-index
 758 sub index_sync {
 759         my ($self, $opt) = @_;
 760         delete $self->{lock_path} if $opt->{-skip_lock};
 761         $self->with_umask(\&_index_sync, $self, $opt);
 762         if ($opt->{reindex} && !$opt->{quit} &&
 763                         !grep(defined, @$opt{qw(since until)})) {
 764                 my %again = %$opt;
 765                 delete @again{qw(rethread reindex)};
 766                 index_sync($self, \%again);
 767                 $opt->{quit} = $again{quit}; # propagate to caller
 768         }
 769 }
 770
 771 sub check_size { # check_async cb for -index --max-size=...
 772         my ($oid, $type, $size, $arg, $git) = @_;
 773         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 774         if ($size <= $arg->{max_size}) {
 775                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 776         } else {
 777                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 778         }
 779 }
 780
 781 sub v1_checkpoint ($$;$) {
 782         my ($self, $sync, $stk) = @_;
 783         $self->{ibx}->git->async_wait_all;
 784
 785         # $newest may be undef
 786         my $newest = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 787         if (defined($newest)) {
 788                 my $cur = $self->{mm}->last_commit;
 789                 if (need_update($self, $sync, $cur, $newest)) {
 790                         $self->{mm}->last_commit($newest);
 791                 }
 792         }
 793         ${$sync->{max}} = $self->{batch_bytes};
 794
 795         $self->{mm}->{dbh}->commit;
 796         my $xdb = $self->{xdb};
 797         if ($newest && $xdb) {
 798                 my $cur = $xdb->get_metadata('last_commit');
 799                 if (need_update($self, $sync, $cur, $newest)) {
 800                         $xdb->set_metadata('last_commit', $newest);
 801                 }
 802         }
 803         if ($stk) { # all done if $stk is passed
 804                 # let SearchView know a full --reindex was done so it can
 805                 # generate ->has_threadid-dependent links
 806                 if ($xdb && $sync->{reindex} && !ref($sync->{reindex})) {
 807                         my $n = $xdb->get_metadata('has_threadid');
 808                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 809                 }
 810                 $self->{oidx}->rethread_done($sync->{-opt}); # all done
 811         }
 812         commit_txn_lazy($self);
 813         $sync->{ibx}->git->cleanup;
 814         my $nr = ${$sync->{nr}};
 815         idx_release($self, $nr);
 816         # let another process do some work...
 817         if (my $pr = $sync->{-opt}->{-progress}) {
 818                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 819         }
 820         if (!$stk && !$sync->{quit}) { # more to come
 821                 begin_txn_lazy($self);
 822                 $self->{mm}->{dbh}->begin_work;
 823         }
 824 }
 825
 826 # only for v1
 827 sub process_stack {
 828         my ($self, $sync, $stk) = @_;
 829         my $git = $sync->{ibx}->git;
 830         my $max = $self->{batch_bytes};
 831         my $nr = 0;
 832         $sync->{nr} = \$nr;
 833         $sync->{max} = \$max;
 834         $sync->{sidx} = $self;
 835         $sync->{latest_cmt} = \(my $latest_cmt);
 836
 837         $self->{mm}->{dbh}->begin_work;
 838         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 839                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 840                 for my $oid (@leftovers) {
 841                         last if $sync->{quit};
 842                         $oid = unpack('H*', $oid);
 843                         $git->cat_async($oid, \&unindex_both, $sync);
 844                 }
 845         }
 846         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 847                 $sync->{index_oid} = \&index_both;
 848         }
 849         while (my ($f, $at, $ct, $oid, $cur_cmt) = $stk->pop_rec) {
 850                 my $arg = { %$sync, cur_cmt => $cur_cmt, oid => $oid };
 851                 last if $sync->{quit};
 852                 if ($f eq 'm') {
 853                         $arg->{autime} = $at;
 854                         $arg->{cotime} = $ct;
 855                         if ($sync->{max_size}) {
 856                                 $git->check_async($oid, \&check_size, $arg);
 857                         } else {
 858                                 $git->cat_async($oid, \&index_both, $arg);
 859                         }
 860                         v1_checkpoint($self, $sync) if $max <= 0;
 861                 } elsif ($f eq 'd') {
 862                         $git->cat_async($oid, \&unindex_both, $arg);
 863                 }
 864         }
 865         v1_checkpoint($self, $sync, $sync->{quit} ? undef : $stk);
 866 }
 867
 868 sub log2stack ($$$) {
 869         my ($sync, $git, $range) = @_;
 870         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 871         my ($add, $del);
 872         if ($sync->{ibx}->version == 1) {
 873                 my $path = $hex.'{2}/'.$hex.'{38}';
 874                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 875                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 876         } else {
 877                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 878                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 879         }
 880
 881         # Count the new files so they can be added newest to oldest
 882         # and still have numbers increasing from oldest to newest
 883         my @cmd = qw(log --raw -r --pretty=tformat:%at-%ct-%H
 884                         --no-notes --no-color --no-renames --no-abbrev);
 885         for my $k (qw(since until)) {
 886                 my $v = $sync->{-opt}->{$k} // next;
 887                 next if !$sync->{-opt}->{reindex};
 888                 push @cmd, "--$k=$v";
 889         }
 890         my $fh = $git->popen(@cmd, $range);
 891         my ($at, $ct, $stk, $cmt);
 892         while (<$fh>) {
 893                 return if $sync->{quit};
 894                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 895                         ($at, $ct, $cmt) = ($1 + 0, $2 + 0, $3);
 896                         $stk //= PublicInbox::IdxStack->new($cmt);
 897                 } elsif (/$del/) {
 898                         my $oid = $1;
 899                         if ($D) { # reindex case
 900                                 $D->{pack('H*', $oid)}++;
 901                         } else { # non-reindex case:
 902                                 $stk->push_rec('d', $at, $ct, $oid, $cmt);
 903                         }
 904                 } elsif (/$add/) {
 905                         my $oid = $1;
 906                         if ($D) {
 907                                 my $oid_bin = pack('H*', $oid);
 908                                 my $nr = --$D->{$oid_bin};
 909                                 delete($D->{$oid_bin}) if $nr <= 0;
 910                                 # nr < 0 (-1) means it never existed
 911                                 next if $nr >= 0;
 912                         }
 913                         $stk->push_rec('m', $at, $ct, $oid, $cmt);
 914                 }
 915         }
 916         close $fh or die "git log failed: \$?=$?";
 917         $stk //= PublicInbox::IdxStack->new;
 918         $stk->read_prepare;
 919 }
 920
 921 sub prepare_stack ($$) {
 922         my ($sync, $range) = @_;
 923         my $git = $sync->{ibx}->git;
 924
 925         if (index($range, '..') < 0) {
 926                 # don't show annoying git errors to users who run -index
 927                 # on empty inboxes
 928                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 929                 return PublicInbox::IdxStack->new->read_prepare if $?;
 930         }
 931         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 932         log2stack($sync, $git, $range);
 933 }
 934
 935 # --is-ancestor requires git 1.8.0+
 936 sub is_ancestor ($$$) {
 937         my ($git, $cur, $tip) = @_;
 938         return 0 unless $git->check($cur);
 939         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 940                 qw(merge-base --is-ancestor), $cur, $tip ];
 941         my $pid = spawn($cmd);
 942         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 943         $? == 0;
 944 }
 945
 946 sub need_update ($$$$) {
 947         my ($self, $sync, $cur, $new) = @_;
 948         my $git = $self->{ibx}->git;
 949         $cur //= ''; # XS Search::Xapian ->get_metadata doesn't give undef
 950
 951         # don't rewind if --{since,until,before,after} are in use
 952         return if $cur ne '' &&
 953                 grep(defined, @{$sync->{-opt}}{qw(since until)}) &&
 954                 is_ancestor($git, $new, $cur);
 955
 956         return 1 if $cur ne '' && !is_ancestor($git, $cur, $new);
 957         my $range = $cur eq '' ? $new : "$cur..$new";
 958         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 959         ($n eq '' || $n > 0);
 960 }
 961
 962 # The last git commit we indexed with Xapian or SQLite (msgmap)
 963 # This needs to account for cases where Xapian or SQLite is
 964 # out-of-date with respect to the other.
 965 sub _last_x_commit {
 966         my ($self, $mm) = @_;
 967         my $lm = $mm->last_commit || '';
 968         my $lx = '';
 969         if (need_xapian($self)) {
 970                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 971         } else {
 972                 $lx = $lm;
 973         }
 974         # Use last_commit from msgmap if it is older or unset
 975         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 976                 $lx = $lm;
 977         }
 978         $lx;
 979 }
 980
 981 sub reindex_from ($$) {
 982         my ($reindex, $last_commit) = @_;
 983         return $last_commit unless $reindex;
 984         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 985 }
 986
 987 sub quit_cb ($) {
 988         my ($sync) = @_;
 989         sub {
 990                 # we set {-opt}->{quit} too, so ->index_sync callers
 991                 # can abort multi-inbox loops this way
 992                 $sync->{quit} = $sync->{-opt}->{quit} = 1;
 993                 warn "gracefully quitting\n";
 994         }
 995 }
 996
 997 # indexes all unindexed messages (v1 only)
 998 sub _index_sync {
 999         my ($self, $opt) = @_;
1000         my $tip = $opt->{ref} || 'HEAD';
1001         my $ibx = $self->{ibx};
1002         local $self->{current_info} = "$ibx->{inboxdir}";
1003         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
1004         $ibx->git->batch_prepare;
1005         my $pr = $opt->{-progress};
1006         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
1007         my $quit = quit_cb($sync);
1008         local $SIG{QUIT} = $quit;
1009         local $SIG{INT} = $quit;
1010         local $SIG{TERM} = $quit;
1011         my $xdb = $self->begin_txn_lazy;
1012         $self->{oidx}->rethread_prepare($opt);
1013         my $mm = _msgmap_init($self);
1014         if ($sync->{reindex}) {
1015                 my $last = $mm->last_commit;
1016                 if ($last) {
1017                         $tip = $last;
1018                 } else {
1019                         # somebody just blindly added --reindex when indexing
1020                         # for the first time, allow it:
1021                         undef $sync->{reindex};
1022                 }
1023         }
1024         my $last_commit = _last_x_commit($self, $mm);
1025         my $lx = reindex_from($sync->{reindex}, $last_commit);
1026         my $range = $lx eq '' ? $tip : "$lx..$tip";
1027         $pr->("counting changes\n\t$range ... ") if $pr;
1028         my $stk = prepare_stack($sync, $range);
1029         $sync->{ntodo} = $stk ? $stk->num_records : 0;
1030         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
1031         process_stack($self, $sync, $stk) if !$sync->{quit};
1032 }
1033
1034 sub DESTROY {
1035         # order matters for unlocking
1036         $_[0]->{xdb} = undef;
1037         $_[0]->{lockfh} = undef;
1038 }
1039
1040 sub _begin_txn {
1041         my ($self) = @_;
1042         my $xdb = $self->{xdb} || idx_acquire($self);
1043         $self->{oidx}->begin_lazy if $self->{oidx};
1044         $xdb->begin_transaction if $xdb;
1045         $self->{txn} = 1;
1046         $xdb;
1047 }
1048
1049 sub begin_txn_lazy {
1050         my ($self) = @_;
1051         $self->with_umask(\&_begin_txn, $self) if !$self->{txn};
1052 }
1053
1054 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
1055 # This metadata is read by Admin::detect_indexlevel:
1056 sub set_metadata_once {
1057         my ($self) = @_;
1058
1059         return if $self->{shard}; # only continue if undef or 0, not >0
1060         my $xdb = $self->{xdb};
1061
1062         if (delete($self->{-set_has_threadid_once})) {
1063                 $xdb->set_metadata('has_threadid', '1');
1064         }
1065         if (delete($self->{-set_indexlevel_once})) {
1066                 my $level = $xdb->get_metadata('indexlevel');
1067                 if (!$level || $level ne 'medium') {
1068                         $xdb->set_metadata('indexlevel', 'medium');
1069                 }
1070         }
1071         if (delete($self->{-set_skip_docdata_once})) {
1072                 $xdb->get_metadata('skip_docdata') or
1073                         $xdb->set_metadata('skip_docdata', '1');
1074         }
1075 }
1076
1077 sub _commit_txn {
1078         my ($self) = @_;
1079         if (my $eidx = $self->{eidx}) {
1080                 $eidx->git->async_wait_all;
1081                 $eidx->{transact_bytes} = 0;
1082         }
1083         if (my $xdb = $self->{xdb}) {
1084                 set_metadata_once($self);
1085                 $xdb->commit_transaction;
1086         }
1087         $self->{oidx}->commit_lazy if $self->{oidx};
1088 }
1089
1090 sub commit_txn_lazy {
1091         my ($self) = @_;
1092         delete($self->{txn}) and
1093                 $self->with_umask(\&_commit_txn, $self);
1094 }
1095
1096 sub eidx_shard_new {
1097         my ($class, $eidx, $shard) = @_;
1098         my $self = bless {
1099                 eidx => $eidx,
1100                 xpfx => $eidx->{xpfx},
1101                 indexlevel => $eidx->{indexlevel},
1102                 -skip_docdata => 1,
1103                 shard => $shard,
1104                 creat => 1,
1105         }, $class;
1106         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
1107         $self;
1108 }
1109
1110 1;