lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak);
  19 use POSIX qw(strftime);
  20 use PublicInbox::OverIdx;
  21 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  22 use PublicInbox::Git qw(git_unquote);
  23 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  24 our @EXPORT_OK = qw(crlf_adjust log2stack is_ancestor check_size);
  25 my $X = \%PublicInbox::Search::X;
  26 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  27 our $DB_NO_SYNC = 0;
  28 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  29 use constant DEBUG => !!$ENV{DEBUG};
  30
  31 my $xapianlevels = qr/\A(?:full|medium)\z/;
  32 my $hex = '[a-f0-9]';
  33 my $OID = $hex .'{40,}';
  34
  35 sub new {
  36         my ($class, $ibx, $creat, $shard) = @_;
  37         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  38         my $levels = qr/\A(?:full|medium|basic)\z/;
  39         my $inboxdir = $ibx->{inboxdir};
  40         my $version = $ibx->version;
  41         my $indexlevel = 'full';
  42         my $altid = $ibx->{altid};
  43         if ($altid) {
  44                 require PublicInbox::AltId;
  45                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  46         }
  47         if ($ibx->{indexlevel}) {
  48                 if ($ibx->{indexlevel} =~ $levels) {
  49                         $indexlevel = $ibx->{indexlevel};
  50                 } else {
  51                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  52                 }
  53         }
  54         $ibx = PublicInbox::InboxWritable->new($ibx);
  55         my $self = bless {
  56                 ibx => $ibx,
  57                 xpfx => $inboxdir, # for xpfx_init
  58                 -altid => $altid,
  59                 ibx_ver => $version,
  60                 indexlevel => $indexlevel,
  61         }, $class;
  62         $self->xpfx_init;
  63         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  64         if ($ibx->{-skip_docdata}) {
  65                 $self->{-set_skip_docdata_once} = 1;
  66                 $self->{-skip_docdata} = 1;
  67         }
  68         $ibx->umask_prepare;
  69         if ($version == 1) {
  70                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  71                 my $dir = $self->xdir;
  72                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  73                 $self->{over}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  74         } elsif ($version == 2) {
  75                 defined $shard or die "shard is required for v2\n";
  76                 # shard is a number
  77                 $self->{shard} = $shard;
  78                 $self->{lock_path} = undef;
  79         } else {
  80                 die "unsupported inbox version=$version\n";
  81         }
  82         $self->{creat} = ($creat || 0) == 1;
  83         $self;
  84 }
  85
  86 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  87
  88 sub idx_release {
  89         my ($self, $wake) = @_;
  90         if (need_xapian($self)) {
  91                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  92                 $xdb->close;
  93         }
  94         $self->lock_release($wake) if $self->{creat};
  95         undef;
  96 }
  97
  98 sub load_xapian_writable () {
  99         return 1 if $X->{WritableDatabase};
 100         PublicInbox::Search::load_xapian() or return;
 101         my $xap = $PublicInbox::Search::Xap;
 102         for (qw(Document TermGenerator WritableDatabase)) {
 103                 $X->{$_} = $xap.'::'.$_;
 104         }
 105         eval 'require '.$X->{WritableDatabase} or die;
 106         *sortable_serialise = $xap.'::sortable_serialise';
 107         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 108         $DB_OPEN = eval($xap.'::DB_OPEN()');
 109         my $ver = (eval($xap.'::major_version()') << 16) |
 110                 (eval($xap.'::minor_version()') << 8);
 111         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 112         1;
 113 }
 114
 115 sub idx_acquire {
 116         my ($self) = @_;
 117         my $flag;
 118         my $dir = $self->xdir;
 119         if (need_xapian($self)) {
 120                 croak 'already acquired' if $self->{xdb};
 121                 load_xapian_writable();
 122                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 123         }
 124         if ($self->{creat}) {
 125                 require File::Path;
 126                 $self->lock_acquire;
 127
 128                 # don't create empty Xapian directories if we don't need Xapian
 129                 my $is_shard = defined($self->{shard});
 130                 if (!-d $dir && (!$is_shard ||
 131                                 ($is_shard && need_xapian($self)))) {
 132                         File::Path::mkpath($dir);
 133                         nodatacow_dir($dir);
 134                         $self->{-set_has_threadid_once} = 1;
 135                 }
 136         }
 137         return unless defined $flag;
 138         $flag |= $DB_NO_SYNC if $self->{ibx}->{-no_fsync};
 139         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 140         if ($@) {
 141                 die "Failed opening $dir: ", $@;
 142         }
 143         $self->{xdb} = $xdb;
 144 }
 145
 146 sub add_val ($$$) {
 147         my ($doc, $col, $num) = @_;
 148         $num = sortable_serialise($num);
 149         $doc->add_value($col, $num);
 150 }
 151
 152 sub term_generator ($) { # write-only
 153         my ($self) = @_;
 154
 155         $self->{term_generator} //= do {
 156                 my $tg = $X->{TermGenerator}->new;
 157                 $tg->set_stemmer($self->stemmer);
 158                 $tg;
 159         }
 160 }
 161
 162 sub index_text ($$$$) {
 163         my ($self, $text, $wdf_inc, $prefix) = @_;
 164         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 165
 166         if ($self->{indexlevel} eq 'full') {
 167                 $tg->index_text($text, $wdf_inc, $prefix);
 168                 $tg->increase_termpos;
 169         } else {
 170                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 171         }
 172 }
 173
 174 sub index_headers ($$) {
 175         my ($self, $smsg) = @_;
 176         my @x = (from => 'A', # Author
 177                 subject => 'S', to => 'XTO', cc => 'XCC');
 178         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 179                 my $val = $smsg->{$field};
 180                 index_text($self, $val, 1, $pfx) if $val ne '';
 181         }
 182 }
 183
 184 sub index_diff_inc ($$$$) {
 185         my ($self, $text, $pfx, $xnq) = @_;
 186         if (@$xnq) {
 187                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 188                 @$xnq = ();
 189         }
 190         index_text($self, $text, 1, $pfx);
 191 }
 192
 193 sub index_old_diff_fn {
 194         my ($self, $seen, $fa, $fb, $xnq) = @_;
 195
 196         # no renames or space support for traditional diffs,
 197         # find the number of leading common paths to strip:
 198         my @fa = split('/', $fa);
 199         my @fb = split('/', $fb);
 200         while (scalar(@fa) && scalar(@fb)) {
 201                 $fa = join('/', @fa);
 202                 $fb = join('/', @fb);
 203                 if ($fa eq $fb) {
 204                         unless ($seen->{$fa}++) {
 205                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 206                         }
 207                         return 1;
 208                 }
 209                 shift @fa;
 210                 shift @fb;
 211         }
 212         0;
 213 }
 214
 215 sub index_diff ($$$) {
 216         my ($self, $txt, $doc) = @_;
 217         my %seen;
 218         my $in_diff;
 219         my @xnq;
 220         my $xnq = \@xnq;
 221         foreach (split(/\n/, $txt)) {
 222                 if ($in_diff && s/^ //) { # diff context
 223                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 224                 } elsif (/^-- $/) { # email signature begins
 225                         $in_diff = undef;
 226                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 227                         # wait until "---" and "+++" to capture filenames
 228                         $in_diff = 1;
 229                 # traditional diff:
 230                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 231                         my ($opt, $fa, $fb) = ($1, $2, $3);
 232                         push @xnq, $_;
 233                         # only support unified:
 234                         next unless $opt =~ /[uU]/;
 235                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 236                                                         $xnq);
 237                 } elsif (m!^--- ("?[^/]+/.+)!) {
 238                         my $fn = $1;
 239                         $fn = (split('/', git_unquote($fn), 2))[1];
 240                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 241                         $in_diff = 1;
 242                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 243                         my $fn = $1;
 244                         $fn = (split('/', git_unquote($fn), 2))[1];
 245                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 246                         $in_diff = 1;
 247                 } elsif (/^--- (\S+)/) {
 248                         $in_diff = $1;
 249                         push @xnq, $_;
 250                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 251                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 252                                                         $1, $xnq);
 253                 } elsif ($in_diff && s/^\+//) { # diff added
 254                         index_diff_inc($self, $_, 'XDFB', $xnq);
 255                 } elsif ($in_diff && s/^-//) { # diff removed
 256                         index_diff_inc($self, $_, 'XDFA', $xnq);
 257                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 258                         my ($ba, $bb) = ($1, $2);
 259                         index_git_blob_id($doc, 'XDFPRE', $ba);
 260                         index_git_blob_id($doc, 'XDFPOST', $bb);
 261                         $in_diff = 1;
 262                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 263                         # traditional diff w/o -p
 264                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 265                         # hunk header context
 266                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 267                 # ignore the following lines:
 268                 } elsif (/^(?:dis)similarity index/ ||
 269                                 /^(?:old|new) mode/ ||
 270                                 /^(?:deleted|new) file mode/ ||
 271                                 /^(?:copy|rename) (?:from|to) / ||
 272                                 /^(?:dis)?similarity index / ||
 273                                 /^\\ No newline at end of file/ ||
 274                                 /^Binary files .* differ/) {
 275                         push @xnq, $_;
 276                 } elsif ($_ eq '') {
 277                         # possible to be in diff context, some mail may be
 278                         # stripped by MUA or even GNU diff(1).  "git apply"
 279                         # treats a bare "\n" as diff context, too
 280                 } else {
 281                         push @xnq, $_;
 282                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 283                         $in_diff = undef;
 284                 }
 285         }
 286
 287         index_text($self, join("\n", @xnq), 1, 'XNQ');
 288 }
 289
 290 sub index_xapian { # msg_iter callback
 291         my $part = $_[0]->[0]; # ignore $depth and $idx
 292         my ($self, $doc) = @{$_[1]};
 293         my $ct = $part->content_type || 'text/plain';
 294         my $fn = $part->filename;
 295         if (defined $fn && $fn ne '') {
 296                 index_text($self, $fn, 1, 'XFN');
 297         }
 298         if ($part->{is_submsg}) {
 299                 my $mids = mids_for_index($part);
 300                 index_ids($self, $doc, $part, $mids);
 301                 my $smsg = bless {}, 'PublicInbox::Smsg';
 302                 $smsg->populate($part);
 303                 index_headers($self, $smsg);
 304         }
 305
 306         my ($s, undef) = msg_part_text($part, $ct);
 307         defined $s or return;
 308         $_[0]->[0] = $part = undef; # free memory
 309
 310         # split off quoted and unquoted blocks:
 311         my @sections = PublicInbox::MsgIter::split_quotes($s);
 312         undef $s; # free memory
 313         for my $txt (@sections) {
 314                 if ($txt =~ /\A>/) {
 315                         index_text($self, $txt, 0, 'XQUOT');
 316                 } else {
 317                         # does it look like a diff?
 318                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 319                                 index_diff($self, $txt, $doc);
 320                         } else {
 321                                 index_text($self, $txt, 1, 'XNQ');
 322                         }
 323                 }
 324                 undef $txt; # free memory
 325         }
 326 }
 327
 328 sub index_ids ($$$$) {
 329         my ($self, $doc, $hdr, $mids) = @_;
 330         for my $mid (@$mids) {
 331                 index_text($self, $mid, 1, 'XM');
 332
 333                 # because too many Message-IDs are prefixed with
 334                 # "Pine.LNX."...
 335                 if ($mid =~ /\w{12,}/) {
 336                         my @long = ($mid =~ /(\w{3,}+)/g);
 337                         index_text($self, join(' ', @long), 1, 'XM');
 338                 }
 339         }
 340         $doc->add_boolean_term('Q' . $_) for @$mids;
 341         for my $l ($hdr->header_raw('List-Id')) {
 342                 $l =~ /<([^>]+)>/ or next;
 343                 my $lid = $1;
 344                 $doc->add_boolean_term('G' . $lid);
 345                 index_text($self, $lid, 1, 'XL'); # probabilistic
 346         }
 347 }
 348
 349 sub add_xapian ($$$$) {
 350         my ($self, $eml, $smsg, $mids) = @_;
 351         my $doc = $X->{Document}->new;
 352         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 353         my @ds = gmtime($smsg->{ds});
 354         my $yyyymmdd = strftime('%Y%m%d', @ds);
 355         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 356         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 357         add_val($doc, PublicInbox::Search::DT(), $dt);
 358         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 359         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 360         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 361
 362         my $tg = term_generator($self);
 363         $tg->set_document($doc);
 364         index_headers($self, $smsg);
 365
 366         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 367         index_ids($self, $doc, $eml, $mids);
 368
 369         # by default, we maintain compatibility with v1.5.0 and earlier
 370         # by writing to docdata.glass, users who never exect to downgrade can
 371         # use --skip-docdata
 372         if (!$self->{-skip_docdata}) {
 373                 # WWW doesn't need {to} or {cc}, only NNTP
 374                 $smsg->{to} = $smsg->{cc} = '';
 375                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 376                 my $data = $smsg->to_doc_data;
 377                 $doc->set_data($data);
 378         }
 379
 380         if (my $altid = $self->{-altid}) {
 381                 foreach my $alt (@$altid) {
 382                         my $pfx = $alt->{xprefix};
 383                         foreach my $mid (@$mids) {
 384                                 my $id = $alt->mid2alt($mid);
 385                                 next unless defined $id;
 386                                 $doc->add_boolean_term($pfx . $id);
 387                         }
 388                 }
 389         }
 390         $self->{xdb}->replace_document($smsg->{num}, $doc);
 391 }
 392
 393 sub _msgmap_init ($) {
 394         my ($self) = @_;
 395         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 396         $self->{mm} //= eval {
 397                 require PublicInbox::Msgmap;
 398                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 399                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 400         };
 401 }
 402
 403 sub add_message {
 404         # mime = PublicInbox::Eml or Email::MIME object
 405         my ($self, $mime, $smsg, $sync) = @_;
 406         my $mids = mids_for_index($mime);
 407         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 408         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 409         $smsg->{num} //= do { # v1
 410                 _msgmap_init($self);
 411                 index_mm($self, $mime, $smsg->{blob}, $sync);
 412         };
 413
 414         # v1 and tests only:
 415         $smsg->populate($mime, $sync);
 416         $smsg->{bytes} //= length($mime->as_string);
 417
 418         eval {
 419                 # order matters, overview stores every possible piece of
 420                 # data in doc_data (deflated).  Xapian only stores a subset
 421                 # of the fields which exist in over.sqlite3.  We may stop
 422                 # storing doc_data in Xapian sometime after we get multi-inbox
 423                 # search working.
 424                 if (my $over = $self->{over}) { # v1 only
 425                         $over->add_overview($mime, $smsg);
 426                 }
 427                 if (need_xapian($self)) {
 428                         add_xapian($self, $mime, $smsg, $mids);
 429                 }
 430         };
 431
 432         if ($@) {
 433                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 434                 return undef;
 435         }
 436         $smsg->{num};
 437 }
 438
 439 sub xdb_remove {
 440         my ($self, $oid, @removed) = @_;
 441         my $xdb = $self->{xdb} or return;
 442         for my $num (@removed) {
 443                 my $doc = eval { $xdb->get_document($num) };
 444                 unless ($doc) {
 445                         warn "E: $@\n" if $@;
 446                         warn "E: #$num $oid missing in Xapian\n";
 447                         next;
 448                 }
 449                 my $smsg = bless {}, 'PublicInbox::Smsg';
 450                 $smsg->load_expand($doc);
 451                 my $blob = $smsg->{blob} // '(unset)';
 452                 if ($blob eq $oid) {
 453                         $xdb->delete_document($num);
 454                 } else {
 455                         warn "E: #$num $oid != $blob in Xapian\n";
 456                 }
 457         }
 458 }
 459
 460 sub remove_by_oid {
 461         my ($self, $oid, $num) = @_;
 462         die "BUG: remove_by_oid is v2-only\n" if $self->{over};
 463         $self->begin_txn_lazy;
 464         xdb_remove($self, $oid, $num) if need_xapian($self);
 465 }
 466
 467 sub index_git_blob_id {
 468         my ($doc, $pfx, $objid) = @_;
 469
 470         my $len = length($objid);
 471         for (my $len = length($objid); $len >= 7; ) {
 472                 $doc->add_term($pfx.$objid);
 473                 $objid = substr($objid, 0, --$len);
 474         }
 475 }
 476
 477 # v1 only
 478 sub unindex_eml {
 479         my ($self, $oid, $eml) = @_;
 480         my $mids = mids($eml);
 481         my $nr = 0;
 482         my %tmp;
 483         for my $mid (@$mids) {
 484                 my @removed = eval { $self->{over}->remove_oid($oid, $mid) };
 485                 if ($@) {
 486                         warn "E: failed to remove <$mid> from overview: $@\n";
 487                 } else {
 488                         $nr += scalar @removed;
 489                         $tmp{$_}++ for @removed;
 490                 }
 491         }
 492         if (!$nr) {
 493                 $mids = join('> <', @$mids);
 494                 warn "W: <$mids> missing for removal from overview\n";
 495         }
 496         while (my ($num, $nr) = each %tmp) {
 497                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 498         }
 499         if ($nr) {
 500                 $self->{mm}->num_delete($_) for (keys %tmp);
 501         } else { # just in case msgmap and over.sqlite3 become desynched:
 502                 $self->{mm}->mid_delete($mids->[0]);
 503         }
 504         xdb_remove($self, $oid, keys %tmp) if need_xapian($self);
 505 }
 506
 507 sub index_mm {
 508         my ($self, $mime, $oid, $sync) = @_;
 509         my $mids = mids($mime);
 510         my $mm = $self->{mm};
 511         if ($sync->{reindex}) {
 512                 my $over = $self->{over};
 513                 for my $mid (@$mids) {
 514                         my ($num, undef) = $over->num_mid0_for_oid($oid, $mid);
 515                         return $num if defined $num;
 516                 }
 517                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 518         } else {
 519                 # fallback to num_for since filters like RubyLang set the number
 520                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 521         }
 522 }
 523
 524 # returns the number of bytes to add if given a non-CRLF arg
 525 sub crlf_adjust ($) {
 526         if (index($_[0], "\r\n") < 0) {
 527                 # common case is LF-only, every \n needs an \r;
 528                 # so favor a cheap tr// over an expensive m//g
 529                 $_[0] =~ tr/\n/\n/;
 530         } else { # count number of '\n' w/o '\r', expensive:
 531                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 532         }
 533 }
 534
 535 sub index_both { # git->cat_async callback
 536         my ($bref, $oid, $type, $size, $sync) = @_;
 537         my ($nr, $max) = @$sync{qw(nr max)};
 538         ++$$nr;
 539         $$max -= $size;
 540         $size += crlf_adjust($$bref);
 541         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 542         my $self = $sync->{sidx};
 543         my $eml = PublicInbox::Eml->new($bref);
 544         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 545                 die "E: could not generate NNTP article number for $oid";
 546         add_message($self, $eml, $smsg, $sync);
 547 }
 548
 549 sub unindex_both { # git->cat_async callback
 550         my ($bref, $oid, $type, $size, $self) = @_;
 551         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 552 }
 553
 554 # called by public-inbox-index
 555 sub index_sync {
 556         my ($self, $opt) = @_;
 557         delete $self->{lock_path} if $opt->{-skip_lock};
 558         $self->{ibx}->with_umask(\&_index_sync, $self, $opt);
 559         if ($opt->{reindex}) {
 560                 my %again = %$opt;
 561                 delete @again{qw(rethread reindex)};
 562                 index_sync($self, \%again);
 563         }
 564 }
 565
 566 sub check_size { # check_async cb for -index --max-size=...
 567         my ($oid, $type, $size, $arg, $git) = @_;
 568         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 569         if ($size <= $arg->{max_size}) {
 570                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 571         } else {
 572                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 573         }
 574 }
 575
 576 sub v1_checkpoint ($$;$) {
 577         my ($self, $sync, $stk) = @_;
 578         $self->{ibx}->git->check_async_wait;
 579         $self->{ibx}->git->cat_async_wait;
 580
 581         # latest_cmt may be undef
 582         my $newest = $stk ? $stk->{latest_cmt} : undef;
 583         if ($newest) {
 584                 my $cur = $self->{mm}->last_commit || '';
 585                 if (need_update($self, $cur, $newest)) {
 586                         $self->{mm}->last_commit($newest);
 587                 }
 588         } else {
 589                 ${$sync->{max}} = $self->{batch_bytes};
 590         }
 591
 592         $self->{mm}->{dbh}->commit;
 593         if ($newest && need_xapian($self)) {
 594                 my $xdb = $self->{xdb};
 595                 my $cur = $xdb->get_metadata('last_commit');
 596                 if (need_update($self, $cur, $newest)) {
 597                         $xdb->set_metadata('last_commit', $newest);
 598                 }
 599
 600                 # let SearchView know a full --reindex was done so it can
 601                 # generate ->has_threadid-dependent links
 602                 if ($sync->{reindex} && !ref($sync->{reindex})) {
 603                         my $n = $xdb->get_metadata('has_threadid');
 604                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 605                 }
 606         }
 607
 608         $self->{over}->rethread_done($sync->{-opt}) if $newest; # all done
 609         commit_txn_lazy($self);
 610         $self->{ibx}->git->cleanup;
 611         my $nr = ${$sync->{nr}};
 612         idx_release($self, $nr);
 613         # let another process do some work...
 614         if (my $pr = $sync->{-opt}->{-progress}) {
 615                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 616         }
 617         if (!$stk) { # more to come
 618                 begin_txn_lazy($self);
 619                 $self->{mm}->{dbh}->begin_work;
 620         }
 621 }
 622
 623 # only for v1
 624 sub process_stack {
 625         my ($self, $sync, $stk) = @_;
 626         my $git = $self->{ibx}->git;
 627         my $max = $self->{batch_bytes};
 628         my $nr = 0;
 629         $sync->{nr} = \$nr;
 630         $sync->{max} = \$max;
 631         $sync->{sidx} = $self;
 632
 633         $self->{mm}->{dbh}->begin_work;
 634         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 635                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 636                 for my $oid (@leftovers) {
 637                         $oid = unpack('H*', $oid);
 638                         $git->cat_async($oid, \&unindex_both, $self);
 639                 }
 640         }
 641         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 642                 $sync->{index_oid} = \&index_both;
 643         }
 644         while (my ($f, $at, $ct, $oid) = $stk->pop_rec) {
 645                 if ($f eq 'm') {
 646                         my $arg = { %$sync, autime => $at, cotime => $ct };
 647                         if ($sync->{max_size}) {
 648                                 $git->check_async($oid, \&check_size, $arg);
 649                         } else {
 650                                 $git->cat_async($oid, \&index_both, $arg);
 651                         }
 652                         v1_checkpoint($self, $sync) if $max <= 0;
 653                 } elsif ($f eq 'd') {
 654                         $git->cat_async($oid, \&unindex_both, $self);
 655                 }
 656         }
 657         v1_checkpoint($self, $sync, $stk);
 658 }
 659
 660 sub log2stack ($$$$) {
 661         my ($sync, $git, $range, $ibx) = @_;
 662         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 663         my ($add, $del);
 664         if ($ibx->version == 1) {
 665                 my $path = $hex.'{2}/'.$hex.'{38}';
 666                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 667                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 668         } else {
 669                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 670                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 671         }
 672
 673         # Count the new files so they can be added newest to oldest
 674         # and still have numbers increasing from oldest to newest
 675         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 676                                 --no-notes --no-color --no-renames --no-abbrev),
 677                                 $range);
 678         my ($at, $ct, $stk);
 679         while (<$fh>) {
 680                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 681                         ($at, $ct) = ($1 + 0, $2 + 0);
 682                         $stk //= PublicInbox::IdxStack->new($3);
 683                 } elsif (/$del/) {
 684                         my $oid = $1;
 685                         if ($D) { # reindex case
 686                                 $D->{pack('H*', $oid)}++;
 687                         } else { # non-reindex case:
 688                                 $stk->push_rec('d', $at, $ct, $oid);
 689                         }
 690                 } elsif (/$add/) {
 691                         my $oid = $1;
 692                         if ($D) {
 693                                 my $oid_bin = pack('H*', $oid);
 694                                 my $nr = --$D->{$oid_bin};
 695                                 delete($D->{$oid_bin}) if $nr <= 0;
 696
 697                                 # nr < 0 (-1) means it never existed
 698                                 $stk->push_rec('m', $at, $ct, $oid) if $nr < 0;
 699                         } else {
 700                                 $stk->push_rec('m', $at, $ct, $oid);
 701                         }
 702                 }
 703         }
 704         close $fh or die "git log failed: \$?=$?";
 705         $stk //= PublicInbox::IdxStack->new;
 706         $stk->read_prepare;
 707 }
 708
 709 sub prepare_stack ($$$) {
 710         my ($self, $sync, $range) = @_;
 711         my $git = $self->{ibx}->git;
 712
 713         if (index($range, '..') < 0) {
 714                 # don't show annoying git errors to users who run -index
 715                 # on empty inboxes
 716                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 717                 return PublicInbox::IdxStack->new->read_prepare if $?;
 718         }
 719         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 720         log2stack($sync, $git, $range, $self->{ibx});
 721 }
 722
 723 # --is-ancestor requires git 1.8.0+
 724 sub is_ancestor ($$$) {
 725         my ($git, $cur, $tip) = @_;
 726         return 0 unless $git->check($cur);
 727         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 728                 qw(merge-base --is-ancestor), $cur, $tip ];
 729         my $pid = spawn($cmd);
 730         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 731         $? == 0;
 732 }
 733
 734 sub need_update ($$$) {
 735         my ($self, $cur, $new) = @_;
 736         my $git = $self->{ibx}->git;
 737         return 1 if $cur && !is_ancestor($git, $cur, $new);
 738         my $range = $cur eq '' ? $new : "$cur..$new";
 739         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 740         ($n eq '' || $n > 0);
 741 }
 742
 743 # The last git commit we indexed with Xapian or SQLite (msgmap)
 744 # This needs to account for cases where Xapian or SQLite is
 745 # out-of-date with respect to the other.
 746 sub _last_x_commit {
 747         my ($self, $mm) = @_;
 748         my $lm = $mm->last_commit || '';
 749         my $lx = '';
 750         if (need_xapian($self)) {
 751                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 752         } else {
 753                 $lx = $lm;
 754         }
 755         # Use last_commit from msgmap if it is older or unset
 756         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 757                 $lx = $lm;
 758         }
 759         $lx;
 760 }
 761
 762 sub reindex_from ($$) {
 763         my ($reindex, $last_commit) = @_;
 764         return $last_commit unless $reindex;
 765         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 766 }
 767
 768 # indexes all unindexed messages (v1 only)
 769 sub _index_sync {
 770         my ($self, $opt) = @_;
 771         my $tip = $opt->{ref} || 'HEAD';
 772         my $git = $self->{ibx}->git;
 773         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 774         $git->batch_prepare;
 775         my $pr = $opt->{-progress};
 776         my $sync = { reindex => $opt->{reindex}, -opt => $opt };
 777         my $xdb = $self->begin_txn_lazy;
 778         $self->{over}->rethread_prepare($opt);
 779         my $mm = _msgmap_init($self);
 780         if ($sync->{reindex}) {
 781                 my $last = $mm->last_commit;
 782                 if ($last) {
 783                         $tip = $last;
 784                 } else {
 785                         # somebody just blindly added --reindex when indexing
 786                         # for the first time, allow it:
 787                         undef $sync->{reindex};
 788                 }
 789         }
 790         my $last_commit = _last_x_commit($self, $mm);
 791         my $lx = reindex_from($sync->{reindex}, $last_commit);
 792         my $range = $lx eq '' ? $tip : "$lx..$tip";
 793         $pr->("counting changes\n\t$range ... ") if $pr;
 794         my $stk = prepare_stack($self, $sync, $range);
 795         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 796         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 797         process_stack($self, $sync, $stk);
 798 }
 799
 800 sub DESTROY {
 801         # order matters for unlocking
 802         $_[0]->{xdb} = undef;
 803         $_[0]->{lockfh} = undef;
 804 }
 805
 806 sub _begin_txn {
 807         my ($self) = @_;
 808         my $xdb = $self->{xdb} || idx_acquire($self);
 809         $self->{over}->begin_lazy if $self->{over};
 810         $xdb->begin_transaction if $xdb;
 811         $self->{txn} = 1;
 812         $xdb;
 813 }
 814
 815 sub begin_txn_lazy {
 816         my ($self) = @_;
 817         $self->{ibx}->with_umask(\&_begin_txn, $self) if !$self->{txn};
 818 }
 819
 820 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 821 # This metadata is read by Admin::detect_indexlevel:
 822 sub set_metadata_once {
 823         my ($self) = @_;
 824
 825         return if $self->{shard}; # only continue if undef or 0, not >0
 826         my $xdb = $self->{xdb};
 827
 828         if (delete($self->{-set_has_threadid_once})) {
 829                 $xdb->set_metadata('has_threadid', '1');
 830         }
 831         if (delete($self->{-set_indexlevel_once})) {
 832                 my $level = $xdb->get_metadata('indexlevel');
 833                 if (!$level || $level ne 'medium') {
 834                         $xdb->set_metadata('indexlevel', 'medium');
 835                 }
 836         }
 837         if (delete($self->{-set_skip_docdata_once})) {
 838                 $xdb->get_metadata('skip_docdata') or
 839                         $xdb->set_metadata('skip_docdata', '1');
 840         }
 841 }
 842
 843 sub _commit_txn {
 844         my ($self) = @_;
 845         if (my $xdb = $self->{xdb}) {
 846                 set_metadata_once($self);
 847                 $xdb->commit_transaction;
 848         }
 849         $self->{over}->commit_lazy if $self->{over};
 850 }
 851
 852 sub commit_txn_lazy {
 853         my ($self) = @_;
 854         delete($self->{txn}) and
 855                 $self->{ibx}->with_umask(\&_commit_txn, $self);
 856 }
 857
 858 sub worker_done {
 859         my ($self) = @_;
 860         if (need_xapian($self)) {
 861                 die "$$ $0 xdb not released\n" if $self->{xdb};
 862         }
 863         die "$$ $0 still in transaction\n" if $self->{txn};
 864 }
 865
 866 1;