lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22
  23 use constant {
  24         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  25                         0x7fffffff : 1_000_000,
  26         DEBUG => !!$ENV{DEBUG},
  27 };
  28
  29 my $xapianlevels = qr/\A(?:full|medium)\z/;
  30
  31 sub new {
  32         my ($class, $ibx, $creat, $shard) = @_;
  33         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  34         my $levels = qr/\A(?:full|medium|basic)\z/;
  35         my $inboxdir = $ibx->{inboxdir};
  36         my $version = $ibx->{version} || 1;
  37         my $indexlevel = 'full';
  38         my $altid = $ibx->{altid};
  39         if ($altid) {
  40                 require PublicInbox::AltId;
  41                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  42         }
  43         if ($ibx->{indexlevel}) {
  44                 if ($ibx->{indexlevel} =~ $levels) {
  45                         $indexlevel = $ibx->{indexlevel};
  46                 } else {
  47                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  48                 }
  49         }
  50         $ibx = PublicInbox::InboxWritable->new($ibx);
  51         my $self = bless {
  52                 inboxdir => $inboxdir,
  53                 -inbox => $ibx,
  54                 git => $ibx->git,
  55                 -altid => $altid,
  56                 version => $version,
  57                 indexlevel => $indexlevel,
  58         }, $class;
  59         $ibx->umask_prepare;
  60         if ($version == 1) {
  61                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  62                 my $dir = $self->xdir;
  63                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  64         } elsif ($version == 2) {
  65                 defined $shard or die "shard is required for v2\n";
  66                 # shard is a number
  67                 $self->{shard} = $shard;
  68                 $self->{lock_path} = undef;
  69         } else {
  70                 die "unsupported inbox version=$version\n";
  71         }
  72         $self->{creat} = ($creat || 0) == 1;
  73         $self;
  74 }
  75
  76 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  77
  78 sub _xdb_release {
  79         my ($self) = @_;
  80         if (need_xapian($self)) {
  81                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  82                 $xdb->close;
  83         }
  84         $self->lock_release if $self->{creat};
  85         undef;
  86 }
  87
  88 sub _xdb_acquire {
  89         my ($self) = @_;
  90         my $flag;
  91         my $dir = $self->xdir;
  92         if (need_xapian($self)) {
  93                 croak 'already acquired' if $self->{xdb};
  94                 PublicInbox::Search::load_xapian();
  95                 require Search::Xapian::WritableDatabase;
  96                 $flag = $self->{creat} ?
  97                         Search::Xapian::DB_CREATE_OR_OPEN() :
  98                         Search::Xapian::DB_OPEN();
  99         }
 100         if ($self->{creat}) {
 101                 require File::Path;
 102                 $self->lock_acquire;
 103
 104                 # don't create empty Xapian directories if we don't need Xapian
 105                 my $is_shard = defined($self->{shard});
 106                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 107                         File::Path::mkpath($dir);
 108                 }
 109         }
 110         return unless defined $flag;
 111         my $xdb = eval { Search::Xapian::WritableDatabase->new($dir, $flag) };
 112         if ($@) {
 113                 die "Failed opening $dir: ", $@;
 114         }
 115         $self->{xdb} = $xdb;
 116 }
 117
 118 sub add_val ($$$) {
 119         my ($doc, $col, $num) = @_;
 120         $num = Search::Xapian::sortable_serialise($num);
 121         $doc->add_value($col, $num);
 122 }
 123
 124 sub index_text ($$$$)
 125 {
 126         my ($self, $field, $n, $text) = @_;
 127         my $tg = $self->term_generator;
 128
 129         if ($self->{indexlevel} eq 'full') {
 130                 $tg->index_text($field, $n, $text);
 131                 $tg->increase_termpos;
 132         } else {
 133                 $tg->index_text_without_positions($field, $n, $text);
 134         }
 135 }
 136
 137 sub index_users ($$) {
 138         my ($self, $smsg) = @_;
 139
 140         my $from = $smsg->from;
 141         my $to = $smsg->to;
 142         my $cc = $smsg->cc;
 143
 144         $self->index_text($from, 1, 'A'); # A - author
 145         $self->index_text($to, 1, 'XTO') if $to ne '';
 146         $self->index_text($cc, 1, 'XCC') if $cc ne '';
 147 }
 148
 149 sub index_diff_inc ($$$$) {
 150         my ($self, $text, $pfx, $xnq) = @_;
 151         if (@$xnq) {
 152                 $self->index_text(join("\n", @$xnq), 1, 'XNQ');
 153                 @$xnq = ();
 154         }
 155         $self->index_text($text, 1, $pfx);
 156 }
 157
 158 sub index_old_diff_fn {
 159         my ($self, $seen, $fa, $fb, $xnq) = @_;
 160
 161         # no renames or space support for traditional diffs,
 162         # find the number of leading common paths to strip:
 163         my @fa = split('/', $fa);
 164         my @fb = split('/', $fb);
 165         while (scalar(@fa) && scalar(@fb)) {
 166                 $fa = join('/', @fa);
 167                 $fb = join('/', @fb);
 168                 if ($fa eq $fb) {
 169                         unless ($seen->{$fa}++) {
 170                                 $self->index_diff_inc($fa, 'XDFN', $xnq);
 171                         }
 172                         return 1;
 173                 }
 174                 shift @fa;
 175                 shift @fb;
 176         }
 177         0;
 178 }
 179
 180 sub index_diff ($$$) {
 181         my ($self, $lines, $doc) = @_;
 182         my %seen;
 183         my $in_diff;
 184         my @xnq;
 185         my $xnq = \@xnq;
 186         foreach (@$lines) {
 187                 if ($in_diff && s/^ //) { # diff context
 188                         $self->index_diff_inc($_, 'XDFCTX', $xnq);
 189                 } elsif (/^-- $/) { # email signature begins
 190                         $in_diff = undef;
 191                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 192                         my ($fa, $fb) = ($1, $2);
 193                         my $fn = (split('/', git_unquote($fa), 2))[1];
 194                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 195                         $fn = (split('/', git_unquote($fb), 2))[1];
 196                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 197                         $in_diff = 1;
 198                 # traditional diff:
 199                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 200                         my ($opt, $fa, $fb) = ($1, $2, $3);
 201                         push @xnq, $_;
 202                         # only support unified:
 203                         next unless $opt =~ /[uU]/;
 204                         $in_diff = $self->index_old_diff_fn(\%seen, $fa, $fb,
 205                                                         $xnq);
 206                 } elsif (m!^--- ("?a/.+)!) {
 207                         my $fn = (split('/', git_unquote($1), 2))[1];
 208                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 209                         $in_diff = 1;
 210                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 211                         my $fn = (split('/', git_unquote($1), 2))[1];
 212                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 213                         $in_diff = 1;
 214                 } elsif (/^--- (\S+)/) {
 215                         $in_diff = $1;
 216                         push @xnq, $_;
 217                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 218                         $in_diff = $self->index_old_diff_fn(\%seen, $in_diff, $1,
 219                                                         $xnq);
 220                 } elsif ($in_diff && s/^\+//) { # diff added
 221                         $self->index_diff_inc($_, 'XDFB', $xnq);
 222                 } elsif ($in_diff && s/^-//) { # diff removed
 223                         $self->index_diff_inc($_, 'XDFA', $xnq);
 224                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 225                         my ($ba, $bb) = ($1, $2);
 226                         index_git_blob_id($doc, 'XDFPRE', $ba);
 227                         index_git_blob_id($doc, 'XDFPOST', $bb);
 228                         $in_diff = 1;
 229                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 230                         # traditional diff w/o -p
 231                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 232                         # hunk header context
 233                         $self->index_diff_inc($1, 'XDFHH', $xnq);
 234                 # ignore the following lines:
 235                 } elsif (/^(?:dis)similarity index/ ||
 236                                 /^(?:old|new) mode/ ||
 237                                 /^(?:deleted|new) file mode/ ||
 238                                 /^(?:copy|rename) (?:from|to) / ||
 239                                 /^(?:dis)?similarity index / ||
 240                                 /^\\ No newline at end of file/ ||
 241                                 /^Binary files .* differ/) {
 242                         push @xnq, $_;
 243                 } elsif ($_ eq '') {
 244                         $in_diff = undef;
 245                 } else {
 246                         push @xnq, $_;
 247                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 248                         $in_diff = undef;
 249                 }
 250         }
 251
 252         $self->index_text(join("\n", @xnq), 1, 'XNQ');
 253 }
 254
 255 sub index_body ($$$) {
 256         my ($self, $lines, $doc) = @_;
 257         my $txt = join("\n", @$lines);
 258         if ($doc) {
 259                 # does it look like a diff?
 260                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 261                         $txt = undef;
 262                         $self->index_diff($lines, $doc);
 263                 } else {
 264                         $self->index_text($txt, 1, 'XNQ');
 265                 }
 266         } else {
 267                 $self->index_text($txt, 0, 'XQUOT');
 268         }
 269         @$lines = ();
 270 }
 271
 272 sub add_xapian ($$$$$) {
 273         my ($self, $mime, $num, $oid, $mids, $mid0) = @_;
 274         my $smsg = PublicInbox::SearchMsg->new($mime);
 275         my $doc = Search::Xapian::Document->new;
 276         my $subj = $smsg->subject;
 277         add_val($doc, PublicInbox::Search::TS(), $smsg->ts);
 278         my @ds = gmtime($smsg->ds);
 279         my $yyyymmdd = strftime('%Y%m%d', @ds);
 280         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 281         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 282         add_val($doc, PublicInbox::Search::DT(), $dt);
 283
 284         my $tg = $self->term_generator;
 285
 286         $tg->set_document($doc);
 287         $self->index_text($subj, 1, 'S') if $subj;
 288         $self->index_users($smsg);
 289
 290         msg_iter($mime, sub {
 291                 my ($part, $depth, @idx) = @{$_[0]};
 292                 my $ct = $part->content_type || 'text/plain';
 293                 my $fn = $part->filename;
 294                 if (defined $fn && $fn ne '') {
 295                         $self->index_text($fn, 1, 'XFN');
 296                 }
 297
 298                 my ($s, undef) = msg_part_text($part, $ct);
 299                 defined $s or return;
 300
 301                 my (@orig, @quot);
 302                 my @lines = split(/\n/, $s);
 303                 while (defined(my $l = shift @lines)) {
 304                         if ($l =~ /^>/) {
 305                                 $self->index_body(\@orig, $doc) if @orig;
 306                                 push @quot, $l;
 307                         } else {
 308                                 $self->index_body(\@quot, 0) if @quot;
 309                                 push @orig, $l;
 310                         }
 311                 }
 312                 $self->index_body(\@quot, 0) if @quot;
 313                 $self->index_body(\@orig, $doc) if @orig;
 314         });
 315
 316         foreach my $mid (@$mids) {
 317                 $self->index_text($mid, 1, 'XM');
 318
 319                 # because too many Message-IDs are prefixed with
 320                 # "Pine.LNX."...
 321                 if ($mid =~ /\w{12,}/) {
 322                         my @long = ($mid =~ /(\w{3,}+)/g);
 323                         $self->index_text(join(' ', @long), 1, 'XM');
 324                 }
 325         }
 326         $smsg->{to} = $smsg->{cc} = '';
 327         PublicInbox::OverIdx::parse_references($smsg, $mid0, $mids);
 328         my $data = $smsg->to_doc_data($oid, $mid0);
 329         $doc->set_data($data);
 330         if (my $altid = $self->{-altid}) {
 331                 foreach my $alt (@$altid) {
 332                         my $pfx = $alt->{xprefix};
 333                         foreach my $mid (@$mids) {
 334                                 my $id = $alt->mid2alt($mid);
 335                                 next unless defined $id;
 336                                 $doc->add_boolean_term($pfx . $id);
 337                         }
 338                 }
 339         }
 340         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 341         $self->{xdb}->replace_document($num, $doc);
 342 }
 343
 344 sub add_message {
 345         # mime = Email::MIME object
 346         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 347         my $mids = mids_for_index($mime->header_obj);
 348         $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 349         unless (defined $num) { # v1
 350                 $self->_msgmap_init;
 351                 $num = index_mm($self, $mime);
 352         }
 353         eval {
 354                 if (need_xapian($self)) {
 355                         $self->add_xapian($mime, $num, $oid, $mids, $mid0)
 356                 }
 357                 if (my $over = $self->{over}) {
 358                         $over->add_overview($mime, $bytes, $num, $oid, $mid0);
 359                 }
 360         };
 361
 362         if ($@) {
 363                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 364                 return undef;
 365         }
 366         $num;
 367 }
 368
 369 # returns begin and end PostingIterator
 370 sub find_doc_ids {
 371         my ($self, $termval) = @_;
 372         my $db = $self->{xdb};
 373
 374         ($db->postlist_begin($termval), $db->postlist_end($termval));
 375 }
 376
 377 # v1 only
 378 sub batch_do {
 379         my ($self, $termval, $cb) = @_;
 380         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 381         while (1) {
 382                 my ($head, $tail) = $self->find_doc_ids($termval);
 383                 return if $head == $tail;
 384                 my @ids;
 385                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 386                         push @ids, $head->get_docid;
 387                 }
 388                 $cb->(\@ids);
 389         }
 390 }
 391
 392 # v1 only, where $mid is unique
 393 sub remove_message {
 394         my ($self, $mid) = @_;
 395         $mid = mid_clean($mid);
 396
 397         if (my $over = $self->{over}) {
 398                 my $nr = eval { $over->remove_oid(undef, $mid) };
 399                 if ($@) {
 400                         warn "failed to remove <$mid> from overview: $@\n";
 401                 } elsif ($nr == 0) {
 402                         warn "<$mid> missing for removal from overview\n";
 403                 }
 404         }
 405         return unless need_xapian($self);
 406         my $db = $self->{xdb};
 407         my $nr = 0;
 408         eval {
 409                 batch_do($self, 'Q' . $mid, sub {
 410                         my ($ids) = @_;
 411                         $db->delete_document($_) for @$ids;
 412                         $nr = scalar @$ids;
 413                 });
 414         };
 415         if ($@) {
 416                 warn "failed to remove <$mid> from Xapian: $@\n";
 417         } elsif ($nr == 0) {
 418                 warn "<$mid> missing for removal from Xapian\n";
 419         }
 420 }
 421
 422 # MID is a hint in V2
 423 sub remove_by_oid {
 424         my ($self, $oid, $mid) = @_;
 425
 426         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 427
 428         return unless need_xapian($self);
 429         my $db = $self->{xdb};
 430
 431         # XXX careful, we cannot use batch_do here since we conditionally
 432         # delete documents based on other factors, so we cannot call
 433         # find_doc_ids twice.
 434         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 435         return if $head == $tail;
 436
 437         # there is only ONE element in @delete unless we
 438         # have bugs in our v2writable deduplication check
 439         my @delete;
 440         for (; $head != $tail; $head->inc) {
 441                 my $docid = $head->get_docid;
 442                 my $doc = $db->get_document($docid);
 443                 my $smsg = PublicInbox::SearchMsg->wrap($mid);
 444                 $smsg->load_expand($doc);
 445                 if ($smsg->{blob} eq $oid) {
 446                         push(@delete, $docid);
 447                 }
 448         }
 449         $db->delete_document($_) foreach @delete;
 450         scalar(@delete);
 451 }
 452
 453 sub term_generator { # write-only
 454         my ($self) = @_;
 455
 456         my $tg = $self->{term_generator};
 457         return $tg if $tg;
 458
 459         $tg = Search::Xapian::TermGenerator->new;
 460         $tg->set_stemmer($self->stemmer);
 461
 462         $self->{term_generator} = $tg;
 463 }
 464
 465 sub index_git_blob_id {
 466         my ($doc, $pfx, $objid) = @_;
 467
 468         my $len = length($objid);
 469         for (my $len = length($objid); $len >= 7; ) {
 470                 $doc->add_term($pfx.$objid);
 471                 $objid = substr($objid, 0, --$len);
 472         }
 473 }
 474
 475 sub unindex_blob {
 476         my ($self, $mime) = @_;
 477         my $mid = eval { mid_clean(mid_mime($mime)) };
 478         $self->remove_message($mid) if defined $mid;
 479 }
 480
 481 sub index_mm {
 482         my ($self, $mime) = @_;
 483         my $mid = mid_clean(mid_mime($mime));
 484         my $mm = $self->{mm};
 485         my $num;
 486
 487         if (defined $self->{regen_down}) {
 488                 $num = $mm->num_for($mid) and return $num;
 489
 490                 while (($num = $self->{regen_down}--) > 0) {
 491                         if ($mm->mid_set($num, $mid) != 0) {
 492                                 return $num;
 493                         }
 494                 }
 495         } elsif (defined $self->{regen_up}) {
 496                 $num = $mm->num_for($mid) and return $num;
 497
 498                 # this is to fixup old bugs due to add-remove-add
 499                 while (($num = ++$self->{regen_up})) {
 500                         if ($mm->mid_set($num, $mid) != 0) {
 501                                 return $num;
 502                         }
 503                 }
 504         }
 505
 506         $num = $mm->mid_insert($mid) and return $num;
 507
 508         # fallback to num_for since filters like RubyLang set the number
 509         $mm->num_for($mid);
 510 }
 511
 512 sub unindex_mm {
 513         my ($self, $mime) = @_;
 514         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 515 }
 516
 517 sub index_both {
 518         my ($self, $mime, $bytes, $blob) = @_;
 519         my $num = index_mm($self, $mime);
 520         add_message($self, $mime, $bytes, $num, $blob);
 521 }
 522
 523 sub unindex_both {
 524         my ($self, $mime) = @_;
 525         unindex_blob($self, $mime);
 526         unindex_mm($self, $mime);
 527 }
 528
 529 sub do_cat_mail {
 530         my ($git, $blob, $sizeref) = @_;
 531         my $mime = eval {
 532                 my $str = $git->cat_file($blob, $sizeref);
 533                 # fixup bugs from import:
 534                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 535                 PublicInbox::MIME->new($str);
 536         };
 537         $@ ? undef : $mime;
 538 }
 539
 540 # called by public-inbox-index
 541 sub index_sync {
 542         my ($self, $opts) = @_;
 543         delete $self->{lock_path} if $opts->{-skip_lock};
 544         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 545 }
 546
 547 sub batch_adjust ($$$$$) {
 548         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 549         $$max -= $bytes;
 550         if ($$max <= 0) {
 551                 $$max = BATCH_BYTES;
 552                 $batch_cb->($nr, $latest);
 553         }
 554 }
 555
 556 # only for v1
 557 sub read_log {
 558         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 559         my $hex = '[a-f0-9]';
 560         my $h40 = $hex .'{40}';
 561         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 562         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 563         my $git = $self->{git};
 564         my $latest;
 565         my $bytes;
 566         my $max = BATCH_BYTES;
 567         local $/ = "\n";
 568         my %D;
 569         my $line;
 570         my $newest;
 571         my $nr = 0;
 572         while (defined($line = <$log>)) {
 573                 if ($line =~ /$addmsg/o) {
 574                         my $blob = $1;
 575                         if (delete $D{$blob}) {
 576                                 if (defined $self->{regen_down}) {
 577                                         my $num = $self->{regen_down}--;
 578                                         $self->{mm}->num_highwater($num);
 579                                 }
 580                                 next;
 581                         }
 582                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 583                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 584                         $add_cb->($self, $mime, $bytes, $blob);
 585                 } elsif ($line =~ /$delmsg/o) {
 586                         my $blob = $1;
 587                         $D{$blob} = 1;
 588                 } elsif ($line =~ /^commit ($h40)/o) {
 589                         $latest = $1;
 590                         $newest ||= $latest;
 591                 }
 592         }
 593         # get the leftovers
 594         foreach my $blob (keys %D) {
 595                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 596                 $del_cb->($self, $mime);
 597         }
 598         $batch_cb->($nr, $latest, $newest);
 599 }
 600
 601 sub _msgmap_init {
 602         my ($self) = @_;
 603         die "BUG: _msgmap_init is only for v1\n" if $self->{version} != 1;
 604         $self->{mm} ||= eval {
 605                 require PublicInbox::Msgmap;
 606                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 607         };
 608 }
 609
 610 sub _git_log {
 611         my ($self, $opts, $range) = @_;
 612         my $git = $self->{git};
 613
 614         if (index($range, '..') < 0) {
 615                 # don't show annoying git errrors to users who run -index
 616                 # on empty inboxes
 617                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 618                 if ($?) {
 619                         open my $fh, '<', '/dev/null' or
 620                                 die "failed to open /dev/null: $!\n";
 621                         return $fh;
 622                 }
 623         }
 624
 625         # Count the new files so they can be added newest to oldest
 626         # and still have numbers increasing from oldest to newest
 627         my $fcount = 0;
 628         my $pr = $opts->{-progress};
 629         $pr->("counting changes\n\t$range ... ") if $pr;
 630         # can't use 'rev-list --count' if we use --diff-filter
 631         my $fh = $git->popen(qw(log --pretty=tformat:%h
 632                              --no-notes --no-color --no-renames
 633                              --diff-filter=AM), $range);
 634         ++$fcount while <$fh>;
 635         close $fh;
 636         my $high = $self->{mm}->num_highwater;
 637         $pr->("$fcount\n") if $pr; # continue previous line
 638         $self->{ntodo} = $fcount;
 639
 640         if (index($range, '..') < 0) {
 641                 if ($high && $high == $fcount) {
 642                         # fix up old bugs in full indexes which caused messages to
 643                         # not appear in Msgmap
 644                         $self->{regen_up} = $high;
 645                 } else {
 646                         # normal regen is for for fresh data
 647                         $self->{regen_down} = $fcount;
 648                 }
 649         } else {
 650                 # Give oldest messages the smallest numbers
 651                 $self->{regen_down} = $high + $fcount;
 652         }
 653
 654         $git->popen(qw/log --no-notes --no-color --no-renames
 655                                 --raw -r --no-abbrev/, $range);
 656 }
 657
 658 # --is-ancestor requires git 1.8.0+
 659 sub is_ancestor ($$$) {
 660         my ($git, $cur, $tip) = @_;
 661         return 0 unless $git->check($cur);
 662         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 663                 qw(merge-base --is-ancestor), $cur, $tip ];
 664         my $pid = spawn($cmd);
 665         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 666         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 667         $? == 0;
 668 }
 669
 670 sub need_update ($$$) {
 671         my ($self, $cur, $new) = @_;
 672         my $git = $self->{git};
 673         return 1 if $cur && !is_ancestor($git, $cur, $new);
 674         my $range = $cur eq '' ? $new : "$cur..$new";
 675         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 676         ($n eq '' || $n > 0);
 677 }
 678
 679 # The last git commit we indexed with Xapian or SQLite (msgmap)
 680 # This needs to account for cases where Xapian or SQLite is
 681 # out-of-date with respect to the other.
 682 sub _last_x_commit {
 683         my ($self, $mm) = @_;
 684         my $lm = $mm->last_commit || '';
 685         my $lx = '';
 686         if (need_xapian($self)) {
 687                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 688         } else {
 689                 $lx = $lm;
 690         }
 691         # Use last_commit from msgmap if it is older or unset
 692         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 693                 $lx = $lm;
 694         }
 695         $lx;
 696 }
 697
 698 sub reindex_from ($$) {
 699         my ($reindex, $last_commit) = @_;
 700         return $last_commit unless $reindex;
 701         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 702 }
 703
 704 # indexes all unindexed messages (v1 only)
 705 sub _index_sync {
 706         my ($self, $opts) = @_;
 707         my $tip = $opts->{ref} || 'HEAD';
 708         my ($last_commit, $lx, $xlog);
 709         my $git = $self->{git};
 710         $git->batch_prepare;
 711         my $pr = $opts->{-progress};
 712
 713         my $xdb = $self->begin_txn_lazy;
 714         my $mm = _msgmap_init($self);
 715         do {
 716                 $xlog = undef;
 717                 $last_commit = _last_x_commit($self, $mm);
 718                 $lx = reindex_from($opts->{reindex}, $last_commit);
 719
 720                 $self->{over}->rollback_lazy;
 721                 $self->{over}->disconnect;
 722                 $git->cleanup;
 723                 delete $self->{txn};
 724                 $xdb->cancel_transaction if $xdb;
 725                 $xdb = _xdb_release($self);
 726
 727                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 728                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 729                 $xlog = _git_log($self, $opts, $range);
 730
 731                 $xdb = $self->begin_txn_lazy;
 732         } while (_last_x_commit($self, $mm) ne $last_commit);
 733
 734         my $dbh = $mm->{dbh} if $mm;
 735         my $cb = sub {
 736                 my ($nr, $commit, $newest) = @_;
 737                 if ($dbh) {
 738                         if ($newest) {
 739                                 my $cur = $mm->last_commit || '';
 740                                 if (need_update($self, $cur, $newest)) {
 741                                         $mm->last_commit($newest);
 742                                 }
 743                         }
 744                         $dbh->commit;
 745                 }
 746                 if ($newest && need_xapian($self)) {
 747                         my $cur = $xdb->get_metadata('last_commit');
 748                         if (need_update($self, $cur, $newest)) {
 749                                 $xdb->set_metadata('last_commit', $newest);
 750                         }
 751                 }
 752                 $self->commit_txn_lazy;
 753                 $git->cleanup;
 754                 $xdb = _xdb_release($self);
 755                 # let another process do some work... <
 756                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 757                 if (!$newest) {
 758                         $xdb = $self->begin_txn_lazy;
 759                         $dbh->begin_work if $dbh;
 760                 }
 761         };
 762
 763         $dbh->begin_work;
 764         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 765 }
 766
 767 sub DESTROY {
 768         # order matters for unlocking
 769         $_[0]->{xdb} = undef;
 770         $_[0]->{lockfh} = undef;
 771 }
 772
 773 # remote_* subs are only used by SearchIdxPart
 774 sub remote_commit {
 775         my ($self) = @_;
 776         if (my $w = $self->{w}) {
 777                 print $w "commit\n" or die "failed to write commit: $!";
 778         } else {
 779                 $self->commit_txn_lazy;
 780         }
 781 }
 782
 783 sub remote_close {
 784         my ($self) = @_;
 785         if (my $w = delete $self->{w}) {
 786                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 787                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 788                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 789                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 790                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 791         } else {
 792                 die "transaction in progress $self\n" if $self->{txn};
 793                 $self->_xdb_release if $self->{xdb};
 794         }
 795 }
 796
 797 sub remote_remove {
 798         my ($self, $oid, $mid) = @_;
 799         if (my $w = $self->{w}) {
 800                 # triggers remove_by_oid in a shard
 801                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 802         } else {
 803                 $self->begin_txn_lazy;
 804                 $self->remove_by_oid($oid, $mid);
 805         }
 806 }
 807
 808 sub begin_txn_lazy {
 809         my ($self) = @_;
 810         return if $self->{txn};
 811
 812         $self->{-inbox}->with_umask(sub {
 813                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 814                 $self->{over}->begin_lazy if $self->{over};
 815                 $xdb->begin_transaction if $xdb;
 816                 $self->{txn} = 1;
 817                 $xdb;
 818         });
 819 }
 820
 821 sub commit_txn_lazy {
 822         my ($self) = @_;
 823         delete $self->{txn} or return;
 824         $self->{-inbox}->with_umask(sub {
 825                 if (my $xdb = $self->{xdb}) {
 826
 827                         # store 'indexlevel=medium' in v2 shard=0 and
 828                         # v1 (only one shard)
 829                         # This metadata is read by Admin::detect_indexlevel:
 830                         if (!$self->{shard} # undef or 0, not >0
 831                             && $self->{indexlevel} eq 'medium') {
 832                                 $xdb->set_metadata('indexlevel', 'medium');
 833                         }
 834
 835                         $xdb->commit_transaction;
 836                 }
 837                 $self->{over}->commit_lazy if $self->{over};
 838         });
 839 }
 840
 841 sub worker_done {
 842         my ($self) = @_;
 843         if (need_xapian($self)) {
 844                 die "$$ $0 xdb not released\n" if $self->{xdb};
 845         }
 846         die "$$ $0 still in transaction\n" if $self->{txn};
 847 }
 848
 849 1;