lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 use constant {
  26         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  27                         0x7fffffff : 1_000_000,
  28         DEBUG => !!$ENV{DEBUG},
  29 };
  30
  31 my $xapianlevels = qr/\A(?:full|medium)\z/;
  32
  33 sub new {
  34         my ($class, $ibx, $creat, $shard) = @_;
  35         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  36         my $levels = qr/\A(?:full|medium|basic)\z/;
  37         my $inboxdir = $ibx->{inboxdir};
  38         my $version = $ibx->version;
  39         my $indexlevel = 'full';
  40         my $altid = $ibx->{altid};
  41         if ($altid) {
  42                 require PublicInbox::AltId;
  43                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  44         }
  45         if ($ibx->{indexlevel}) {
  46                 if ($ibx->{indexlevel} =~ $levels) {
  47                         $indexlevel = $ibx->{indexlevel};
  48                 } else {
  49                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  50                 }
  51         }
  52         $ibx = PublicInbox::InboxWritable->new($ibx);
  53         my $self = bless {
  54                 inboxdir => $inboxdir,
  55                 -inbox => $ibx,
  56                 git => $ibx->git,
  57                 -altid => $altid,
  58                 ibx_ver => $version,
  59                 indexlevel => $indexlevel,
  60         }, $class;
  61         $ibx->umask_prepare;
  62         if ($version == 1) {
  63                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  64                 my $dir = $self->xdir;
  65                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  66         } elsif ($version == 2) {
  67                 defined $shard or die "shard is required for v2\n";
  68                 # shard is a number
  69                 $self->{shard} = $shard;
  70                 $self->{lock_path} = undef;
  71         } else {
  72                 die "unsupported inbox version=$version\n";
  73         }
  74         $self->{creat} = ($creat || 0) == 1;
  75         $self;
  76 }
  77
  78 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  79
  80 sub _xdb_release {
  81         my ($self) = @_;
  82         if (need_xapian($self)) {
  83                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  84                 $xdb->close;
  85         }
  86         $self->lock_release if $self->{creat};
  87         undef;
  88 }
  89
  90 sub load_xapian_writable () {
  91         return 1 if $X->{WritableDatabase};
  92         PublicInbox::Search::load_xapian() or return;
  93         my $xap = $PublicInbox::Search::Xap;
  94         for (qw(Document TermGenerator WritableDatabase)) {
  95                 $X->{$_} = $xap.'::'.$_;
  96         }
  97         eval 'require '.$X->{WritableDatabase} or die;
  98         *sortable_serialise = $xap.'::sortable_serialise';
  99         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 100         $DB_OPEN = eval($xap.'::DB_OPEN()');
 101         1;
 102 }
 103
 104 sub _xdb_acquire {
 105         my ($self) = @_;
 106         my $flag;
 107         my $dir = $self->xdir;
 108         if (need_xapian($self)) {
 109                 croak 'already acquired' if $self->{xdb};
 110                 load_xapian_writable();
 111                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 112         }
 113         if ($self->{creat}) {
 114                 require File::Path;
 115                 $self->lock_acquire;
 116
 117                 # don't create empty Xapian directories if we don't need Xapian
 118                 my $is_shard = defined($self->{shard});
 119                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 120                         File::Path::mkpath($dir);
 121                 }
 122         }
 123         return unless defined $flag;
 124         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 125         if ($@) {
 126                 die "Failed opening $dir: ", $@;
 127         }
 128         $self->{xdb} = $xdb;
 129 }
 130
 131 sub add_val ($$$) {
 132         my ($doc, $col, $num) = @_;
 133         $num = sortable_serialise($num);
 134         $doc->add_value($col, $num);
 135 }
 136
 137 sub term_generator ($) { # write-only
 138         my ($self) = @_;
 139
 140         $self->{term_generator} //= do {
 141                 my $tg = $X->{TermGenerator}->new;
 142                 $tg->set_stemmer($self->stemmer);
 143                 $tg;
 144         }
 145 }
 146
 147 sub index_text ($$$$) {
 148         my ($self, $text, $wdf_inc, $prefix) = @_;
 149         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 150
 151         if ($self->{indexlevel} eq 'full') {
 152                 $tg->index_text($text, $wdf_inc, $prefix);
 153                 $tg->increase_termpos;
 154         } else {
 155                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 156         }
 157 }
 158
 159 sub index_users ($$) {
 160         my ($self, $smsg) = @_;
 161
 162         my $from = $smsg->from;
 163         my $to = $smsg->to;
 164         my $cc = $smsg->cc;
 165
 166         index_text($self, $from, 1, 'A'); # A - author
 167         index_text($self, $to, 1, 'XTO') if $to ne '';
 168         index_text($self, $cc, 1, 'XCC') if $cc ne '';
 169 }
 170
 171 sub index_diff_inc ($$$$) {
 172         my ($self, $text, $pfx, $xnq) = @_;
 173         if (@$xnq) {
 174                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 175                 @$xnq = ();
 176         }
 177         index_text($self, $text, 1, $pfx);
 178 }
 179
 180 sub index_old_diff_fn {
 181         my ($self, $seen, $fa, $fb, $xnq) = @_;
 182
 183         # no renames or space support for traditional diffs,
 184         # find the number of leading common paths to strip:
 185         my @fa = split('/', $fa);
 186         my @fb = split('/', $fb);
 187         while (scalar(@fa) && scalar(@fb)) {
 188                 $fa = join('/', @fa);
 189                 $fb = join('/', @fb);
 190                 if ($fa eq $fb) {
 191                         unless ($seen->{$fa}++) {
 192                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 193                         }
 194                         return 1;
 195                 }
 196                 shift @fa;
 197                 shift @fb;
 198         }
 199         0;
 200 }
 201
 202 sub index_diff ($$$) {
 203         my ($self, $txt, $doc) = @_;
 204         my %seen;
 205         my $in_diff;
 206         my @xnq;
 207         my $xnq = \@xnq;
 208         foreach (split(/\n/, $txt)) {
 209                 if ($in_diff && s/^ //) { # diff context
 210                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 211                 } elsif (/^-- $/) { # email signature begins
 212                         $in_diff = undef;
 213                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 214                         # wait until "---" and "+++" to capture filenames
 215                         $in_diff = 1;
 216                 # traditional diff:
 217                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 218                         my ($opt, $fa, $fb) = ($1, $2, $3);
 219                         push @xnq, $_;
 220                         # only support unified:
 221                         next unless $opt =~ /[uU]/;
 222                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 223                                                         $xnq);
 224                 } elsif (m!^--- ("?[^/]+/.+)!) {
 225                         my $fn = $1;
 226                         $fn = (split('/', git_unquote($fn), 2))[1];
 227                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 228                         $in_diff = 1;
 229                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 230                         my $fn = $1;
 231                         $fn = (split('/', git_unquote($fn), 2))[1];
 232                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 233                         $in_diff = 1;
 234                 } elsif (/^--- (\S+)/) {
 235                         $in_diff = $1;
 236                         push @xnq, $_;
 237                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 238                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 239                                                         $1, $xnq);
 240                 } elsif ($in_diff && s/^\+//) { # diff added
 241                         index_diff_inc($self, $_, 'XDFB', $xnq);
 242                 } elsif ($in_diff && s/^-//) { # diff removed
 243                         index_diff_inc($self, $_, 'XDFA', $xnq);
 244                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 245                         my ($ba, $bb) = ($1, $2);
 246                         index_git_blob_id($doc, 'XDFPRE', $ba);
 247                         index_git_blob_id($doc, 'XDFPOST', $bb);
 248                         $in_diff = 1;
 249                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 250                         # traditional diff w/o -p
 251                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 252                         # hunk header context
 253                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 254                 # ignore the following lines:
 255                 } elsif (/^(?:dis)similarity index/ ||
 256                                 /^(?:old|new) mode/ ||
 257                                 /^(?:deleted|new) file mode/ ||
 258                                 /^(?:copy|rename) (?:from|to) / ||
 259                                 /^(?:dis)?similarity index / ||
 260                                 /^\\ No newline at end of file/ ||
 261                                 /^Binary files .* differ/) {
 262                         push @xnq, $_;
 263                 } elsif ($_ eq '') {
 264                         # possible to be in diff context, some mail may be
 265                         # stripped by MUA or even GNU diff(1).  "git apply"
 266                         # treats a bare "\n" as diff context, too
 267                 } else {
 268                         push @xnq, $_;
 269                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 270                         $in_diff = undef;
 271                 }
 272         }
 273
 274         index_text($self, join("\n", @xnq), 1, 'XNQ');
 275 }
 276
 277 sub index_body ($$$) {
 278         my ($self, $txt, $doc) = @_;
 279         if ($doc) {
 280                 # does it look like a diff?
 281                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 282                         index_diff($self, $txt, $doc);
 283                 } else {
 284                         index_text($self, $txt, 1, 'XNQ');
 285                 }
 286         } else {
 287                 index_text($self, $txt, 0, 'XQUOT');
 288         }
 289 }
 290
 291 sub index_xapian { # msg_iter callback
 292         my ($part, $depth, @idx) = @{$_[0]};
 293         my ($self, $doc) = @{$_[1]};
 294         my $ct = $part->content_type || 'text/plain';
 295         my $fn = $part->filename;
 296         if (defined $fn && $fn ne '') {
 297                 index_text($self, $fn, 1, 'XFN');
 298         }
 299
 300         my ($s, undef) = msg_part_text($part, $ct);
 301         defined $s or return;
 302
 303         # split off quoted and unquoted blocks:
 304         my @sections = split(/((?:^>[^\n]*\n)+)/sm, $s);
 305         $part = $s = undef;
 306         index_body($self, $_, /\A>/ ? 0 : $doc) for @sections;
 307 }
 308
 309 sub add_xapian ($$$$$$) {
 310         my ($self, $mime, $num, $oid, $mids, $mid0) = @_;
 311         my $smsg = PublicInbox::Smsg->new($mime);
 312         my $hdr = $mime->header_obj;
 313         $smsg->{ds} = msg_datestamp($hdr, $self->{autime});
 314         $smsg->{ts} = msg_timestamp($hdr, $self->{cotime});
 315         my $doc = $X->{Document}->new;
 316         my $subj = $smsg->subject;
 317         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 318         my @ds = gmtime($smsg->{ds});
 319         my $yyyymmdd = strftime('%Y%m%d', @ds);
 320         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 321         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 322         add_val($doc, PublicInbox::Search::DT(), $dt);
 323
 324         my $tg = term_generator($self);
 325
 326         $tg->set_document($doc);
 327         index_text($self, $subj, 1, 'S') if $subj;
 328         index_users($self, $smsg);
 329
 330         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 331         foreach my $mid (@$mids) {
 332                 index_text($self, $mid, 1, 'XM');
 333
 334                 # because too many Message-IDs are prefixed with
 335                 # "Pine.LNX."...
 336                 if ($mid =~ /\w{12,}/) {
 337                         my @long = ($mid =~ /(\w{3,}+)/g);
 338                         index_text($self, join(' ', @long), 1, 'XM');
 339                 }
 340         }
 341         $smsg->{to} = $smsg->{cc} = '';
 342         PublicInbox::OverIdx::parse_references($smsg, $mid0, $mids);
 343         $smsg->{blob} = $oid;
 344         $smsg->{mid} = $mid0;
 345         my $data = $smsg->to_doc_data;
 346         $doc->set_data($data);
 347         if (my $altid = $self->{-altid}) {
 348                 foreach my $alt (@$altid) {
 349                         my $pfx = $alt->{xprefix};
 350                         foreach my $mid (@$mids) {
 351                                 my $id = $alt->mid2alt($mid);
 352                                 next unless defined $id;
 353                                 $doc->add_boolean_term($pfx . $id);
 354                         }
 355                 }
 356         }
 357         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 358         $self->{xdb}->replace_document($num, $doc);
 359 }
 360
 361 sub _msgmap_init ($) {
 362         my ($self) = @_;
 363         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 364         $self->{mm} //= eval {
 365                 require PublicInbox::Msgmap;
 366                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 367         };
 368 }
 369
 370 sub add_message {
 371         # mime = Email::MIME object
 372         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 373         my $mids = mids_for_index($mime->header_obj);
 374         $mid0 //= $mids->[0]; # v1 compatibility
 375         $num //= do { # v1
 376                 _msgmap_init($self);
 377                 index_mm($self, $mime);
 378         };
 379         eval {
 380                 if (need_xapian($self)) {
 381                         add_xapian($self, $mime, $num, $oid, $mids, $mid0);
 382                 }
 383                 if (my $over = $self->{over}) {
 384                         $over->add_overview($mime, $bytes, $num, $oid, $mid0,
 385                                                 $self);
 386                 }
 387         };
 388
 389         if ($@) {
 390                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 391                 return undef;
 392         }
 393         $num;
 394 }
 395
 396 # returns begin and end PostingIterator
 397 sub find_doc_ids {
 398         my ($self, $termval) = @_;
 399         my $db = $self->{xdb};
 400
 401         ($db->postlist_begin($termval), $db->postlist_end($termval));
 402 }
 403
 404 # v1 only
 405 sub batch_do {
 406         my ($self, $termval, $cb) = @_;
 407         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 408         while (1) {
 409                 my ($head, $tail) = $self->find_doc_ids($termval);
 410                 return if $head == $tail;
 411                 my @ids;
 412                 for (; $head != $tail && @ids < $batch_size; $head++) {
 413                         push @ids, $head->get_docid;
 414                 }
 415                 $cb->(\@ids);
 416         }
 417 }
 418
 419 # v1 only, where $mid is unique
 420 sub remove_message {
 421         my ($self, $mid) = @_;
 422         $mid = mid_clean($mid);
 423
 424         if (my $over = $self->{over}) {
 425                 my $nr = eval { $over->remove_oid(undef, $mid) };
 426                 if ($@) {
 427                         warn "failed to remove <$mid> from overview: $@\n";
 428                 } elsif ($nr == 0) {
 429                         warn "<$mid> missing for removal from overview\n";
 430                 }
 431         }
 432         return unless need_xapian($self);
 433         my $db = $self->{xdb};
 434         my $nr = 0;
 435         eval {
 436                 batch_do($self, 'Q' . $mid, sub {
 437                         my ($ids) = @_;
 438                         $db->delete_document($_) for @$ids;
 439                         $nr += scalar @$ids;
 440                 });
 441         };
 442         if ($@) {
 443                 warn "failed to remove <$mid> from Xapian: $@\n";
 444         } elsif ($nr == 0) {
 445                 warn "<$mid> missing for removal from Xapian\n";
 446         }
 447 }
 448
 449 # MID is a hint in V2
 450 sub remove_by_oid {
 451         my ($self, $oid, $mid) = @_;
 452
 453         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 454
 455         return unless need_xapian($self);
 456         my $db = $self->{xdb};
 457
 458         # XXX careful, we cannot use batch_do here since we conditionally
 459         # delete documents based on other factors, so we cannot call
 460         # find_doc_ids twice.
 461         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 462         return if $head == $tail;
 463
 464         # there is only ONE element in @delete unless we
 465         # have bugs in our v2writable deduplication check
 466         my @delete;
 467         for (; $head != $tail; $head++) {
 468                 my $docid = $head->get_docid;
 469                 my $doc = $db->get_document($docid);
 470                 my $smsg = PublicInbox::Smsg->wrap($mid);
 471                 $smsg->load_expand($doc);
 472                 if ($smsg->{blob} eq $oid) {
 473                         push(@delete, $docid);
 474                 }
 475         }
 476         $db->delete_document($_) foreach @delete;
 477         scalar(@delete);
 478 }
 479
 480 sub index_git_blob_id {
 481         my ($doc, $pfx, $objid) = @_;
 482
 483         my $len = length($objid);
 484         for (my $len = length($objid); $len >= 7; ) {
 485                 $doc->add_term($pfx.$objid);
 486                 $objid = substr($objid, 0, --$len);
 487         }
 488 }
 489
 490 sub unindex_blob {
 491         my ($self, $mime) = @_;
 492         my $mid = eval { mid_clean(mid_mime($mime)) };
 493         $self->remove_message($mid) if defined $mid;
 494 }
 495
 496 sub index_mm {
 497         my ($self, $mime) = @_;
 498         my $mid = mid_clean(mid_mime($mime));
 499         my $mm = $self->{mm};
 500         my $num;
 501
 502         if (defined $self->{regen_down}) {
 503                 $num = $mm->num_for($mid) and return $num;
 504
 505                 while (($num = $self->{regen_down}--) > 0) {
 506                         if ($mm->mid_set($num, $mid) != 0) {
 507                                 return $num;
 508                         }
 509                 }
 510         } elsif (defined $self->{regen_up}) {
 511                 $num = $mm->num_for($mid) and return $num;
 512
 513                 # this is to fixup old bugs due to add-remove-add
 514                 while (($num = ++$self->{regen_up})) {
 515                         if ($mm->mid_set($num, $mid) != 0) {
 516                                 return $num;
 517                         }
 518                 }
 519         }
 520
 521         $num = $mm->mid_insert($mid) and return $num;
 522
 523         # fallback to num_for since filters like RubyLang set the number
 524         $mm->num_for($mid);
 525 }
 526
 527 sub unindex_mm {
 528         my ($self, $mime) = @_;
 529         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 530 }
 531
 532 sub index_both {
 533         my ($self, $mime, $bytes, $blob) = @_;
 534         my $num = index_mm($self, $mime);
 535         add_message($self, $mime, $bytes, $num, $blob);
 536 }
 537
 538 sub unindex_both {
 539         my ($self, $mime) = @_;
 540         unindex_blob($self, $mime);
 541         unindex_mm($self, $mime);
 542 }
 543
 544 sub do_cat_mail {
 545         my ($git, $blob, $sizeref) = @_;
 546         my $mime = eval {
 547                 my $str = $git->cat_file($blob, $sizeref);
 548                 # fixup bugs from import:
 549                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 550                 PublicInbox::MIME->new($str);
 551         };
 552         $@ ? undef : $mime;
 553 }
 554
 555 # called by public-inbox-index
 556 sub index_sync {
 557         my ($self, $opts) = @_;
 558         delete $self->{lock_path} if $opts->{-skip_lock};
 559         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 560 }
 561
 562 sub batch_adjust ($$$$$) {
 563         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 564         $$max -= $bytes;
 565         if ($$max <= 0) {
 566                 $$max = BATCH_BYTES;
 567                 $batch_cb->($nr, $latest);
 568         }
 569 }
 570
 571 # only for v1
 572 sub read_log {
 573         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 574         my $hex = '[a-f0-9]';
 575         my $h40 = $hex .'{40}';
 576         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 577         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 578         my $git = $self->{git};
 579         my $latest;
 580         my $bytes;
 581         my $max = BATCH_BYTES;
 582         local $/ = "\n";
 583         my %D;
 584         my $line;
 585         my $newest;
 586         my $nr = 0;
 587         while (defined($line = <$log>)) {
 588                 if ($line =~ /$addmsg/o) {
 589                         my $blob = $1;
 590                         if (delete $D{$blob}) {
 591                                 if (defined $self->{regen_down}) {
 592                                         my $num = $self->{regen_down}--;
 593                                         $self->{mm}->num_highwater($num);
 594                                 }
 595                                 next;
 596                         }
 597                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 598                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 599                         $add_cb->($self, $mime, $bytes, $blob);
 600                 } elsif ($line =~ /$delmsg/o) {
 601                         my $blob = $1;
 602                         $D{$blob} = 1;
 603                 } elsif ($line =~ /^commit ($h40)/o) {
 604                         $latest = $1;
 605                         $newest ||= $latest;
 606                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 607                         $self->{over}->{autime} = $self->{autime} = $1;
 608                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 609                         $self->{over}->{cotime} = $self->{cotime} = $1;
 610                 }
 611         }
 612         close($log) or die "git log failed: \$?=$?";
 613         # get the leftovers
 614         foreach my $blob (keys %D) {
 615                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 616                 $del_cb->($self, $mime);
 617         }
 618         $batch_cb->($nr, $latest, $newest);
 619 }
 620
 621 sub _git_log {
 622         my ($self, $opts, $range) = @_;
 623         my $git = $self->{git};
 624
 625         if (index($range, '..') < 0) {
 626                 # don't show annoying git errrors to users who run -index
 627                 # on empty inboxes
 628                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 629                 if ($?) {
 630                         open my $fh, '<', '/dev/null' or
 631                                 die "failed to open /dev/null: $!\n";
 632                         return $fh;
 633                 }
 634         }
 635
 636         # Count the new files so they can be added newest to oldest
 637         # and still have numbers increasing from oldest to newest
 638         my $fcount = 0;
 639         my $pr = $opts->{-progress};
 640         $pr->("counting changes\n\t$range ... ") if $pr;
 641         # can't use 'rev-list --count' if we use --diff-filter
 642         my $fh = $git->popen(qw(log --pretty=tformat:%h
 643                              --no-notes --no-color --no-renames
 644                              --diff-filter=AM), $range);
 645         ++$fcount while <$fh>;
 646         close $fh or die "git log failed: \$?=$?";
 647         my $high = $self->{mm}->num_highwater;
 648         $pr->("$fcount\n") if $pr; # continue previous line
 649         $self->{ntodo} = $fcount;
 650
 651         if (index($range, '..') < 0) {
 652                 if ($high && $high == $fcount) {
 653                         # fix up old bugs in full indexes which caused messages to
 654                         # not appear in Msgmap
 655                         $self->{regen_up} = $high;
 656                 } else {
 657                         # normal regen is for for fresh data
 658                         $self->{regen_down} = $fcount;
 659                 }
 660         } else {
 661                 # Give oldest messages the smallest numbers
 662                 $self->{regen_down} = $high + $fcount;
 663         }
 664
 665         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 666                                 --raw -r --no-abbrev/, $range);
 667 }
 668
 669 # --is-ancestor requires git 1.8.0+
 670 sub is_ancestor ($$$) {
 671         my ($git, $cur, $tip) = @_;
 672         return 0 unless $git->check($cur);
 673         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 674                 qw(merge-base --is-ancestor), $cur, $tip ];
 675         my $pid = spawn($cmd);
 676         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 677         $? == 0;
 678 }
 679
 680 sub need_update ($$$) {
 681         my ($self, $cur, $new) = @_;
 682         my $git = $self->{git};
 683         return 1 if $cur && !is_ancestor($git, $cur, $new);
 684         my $range = $cur eq '' ? $new : "$cur..$new";
 685         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 686         ($n eq '' || $n > 0);
 687 }
 688
 689 # The last git commit we indexed with Xapian or SQLite (msgmap)
 690 # This needs to account for cases where Xapian or SQLite is
 691 # out-of-date with respect to the other.
 692 sub _last_x_commit {
 693         my ($self, $mm) = @_;
 694         my $lm = $mm->last_commit || '';
 695         my $lx = '';
 696         if (need_xapian($self)) {
 697                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 698         } else {
 699                 $lx = $lm;
 700         }
 701         # Use last_commit from msgmap if it is older or unset
 702         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 703                 $lx = $lm;
 704         }
 705         $lx;
 706 }
 707
 708 sub reindex_from ($$) {
 709         my ($reindex, $last_commit) = @_;
 710         return $last_commit unless $reindex;
 711         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 712 }
 713
 714 # indexes all unindexed messages (v1 only)
 715 sub _index_sync {
 716         my ($self, $opts) = @_;
 717         my $tip = $opts->{ref} || 'HEAD';
 718         my ($last_commit, $lx, $xlog);
 719         my $git = $self->{git};
 720         $git->batch_prepare;
 721         my $pr = $opts->{-progress};
 722
 723         my $xdb = $self->begin_txn_lazy;
 724         my $mm = _msgmap_init($self);
 725         do {
 726                 if ($xlog) {
 727                         close($xlog) or die "git log failed: \$?=$?";
 728                         $xlog = undef;
 729                 }
 730                 $last_commit = _last_x_commit($self, $mm);
 731                 $lx = reindex_from($opts->{reindex}, $last_commit);
 732
 733                 $self->{over}->rollback_lazy;
 734                 $self->{over}->disconnect;
 735                 $git->cleanup;
 736                 delete $self->{txn};
 737                 $xdb->cancel_transaction if $xdb;
 738                 $xdb = _xdb_release($self);
 739
 740                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 741                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 742                 $xlog = _git_log($self, $opts, $range);
 743
 744                 $xdb = $self->begin_txn_lazy;
 745         } while (_last_x_commit($self, $mm) ne $last_commit);
 746
 747         my $dbh = $mm->{dbh} if $mm;
 748         my $cb = sub {
 749                 my ($nr, $commit, $newest) = @_;
 750                 if ($dbh) {
 751                         if ($newest) {
 752                                 my $cur = $mm->last_commit || '';
 753                                 if (need_update($self, $cur, $newest)) {
 754                                         $mm->last_commit($newest);
 755                                 }
 756                         }
 757                         $dbh->commit;
 758                 }
 759                 if ($newest && need_xapian($self)) {
 760                         my $cur = $xdb->get_metadata('last_commit');
 761                         if (need_update($self, $cur, $newest)) {
 762                                 $xdb->set_metadata('last_commit', $newest);
 763                         }
 764                 }
 765                 $self->commit_txn_lazy;
 766                 $git->cleanup;
 767                 $xdb = _xdb_release($self);
 768                 # let another process do some work... <
 769                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 770                 if (!$newest) {
 771                         $xdb = $self->begin_txn_lazy;
 772                         $dbh->begin_work if $dbh;
 773                 }
 774         };
 775
 776         $dbh->begin_work;
 777         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 778 }
 779
 780 sub DESTROY {
 781         # order matters for unlocking
 782         $_[0]->{xdb} = undef;
 783         $_[0]->{lockfh} = undef;
 784 }
 785
 786 # remote_* subs are only used by SearchIdxPart
 787 sub remote_commit {
 788         my ($self) = @_;
 789         if (my $w = $self->{w}) {
 790                 print $w "commit\n" or die "failed to write commit: $!";
 791         } else {
 792                 $self->commit_txn_lazy;
 793         }
 794 }
 795
 796 sub remote_close {
 797         my ($self) = @_;
 798         if (my $w = delete $self->{w}) {
 799                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 800                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 801                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 802                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 803                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 804         } else {
 805                 die "transaction in progress $self\n" if $self->{txn};
 806                 $self->_xdb_release if $self->{xdb};
 807         }
 808 }
 809
 810 sub remote_remove {
 811         my ($self, $oid, $mid) = @_;
 812         if (my $w = $self->{w}) {
 813                 # triggers remove_by_oid in a shard
 814                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 815         } else {
 816                 $self->begin_txn_lazy;
 817                 $self->remove_by_oid($oid, $mid);
 818         }
 819 }
 820
 821 sub begin_txn_lazy {
 822         my ($self) = @_;
 823         return if $self->{txn};
 824
 825         $self->{-inbox}->with_umask(sub {
 826                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 827                 $self->{over}->begin_lazy if $self->{over};
 828                 $xdb->begin_transaction if $xdb;
 829                 $self->{txn} = 1;
 830                 $xdb;
 831         });
 832 }
 833
 834 sub commit_txn_lazy {
 835         my ($self) = @_;
 836         delete $self->{txn} or return;
 837         $self->{-inbox}->with_umask(sub {
 838                 if (my $xdb = $self->{xdb}) {
 839
 840                         # store 'indexlevel=medium' in v2 shard=0 and
 841                         # v1 (only one shard)
 842                         # This metadata is read by Admin::detect_indexlevel:
 843                         if (!$self->{shard} # undef or 0, not >0
 844                             && $self->{indexlevel} eq 'medium') {
 845                                 $xdb->set_metadata('indexlevel', 'medium');
 846                         }
 847
 848                         $xdb->commit_transaction;
 849                 }
 850                 $self->{over}->commit_lazy if $self->{over};
 851         });
 852 }
 853
 854 sub worker_done {
 855         my ($self) = @_;
 856         if (need_xapian($self)) {
 857                 die "$$ $0 xdb not released\n" if $self->{xdb};
 858         }
 859         die "$$ $0 still in transaction\n" if $self->{txn};
 860 }
 861
 862 1;