lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use PublicInbox::MIME;
  14 use base qw(PublicInbox::Search);
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids references/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 require PublicInbox::Git;
  20
  21 use constant {
  22         PERM_UMASK => 0,
  23         OLD_PERM_GROUP => 1,
  24         OLD_PERM_EVERYBODY => 2,
  25         PERM_GROUP => 0660,
  26         PERM_EVERYBODY => 0664,
  27         BATCH_BYTES => 1_000_000,
  28         DEBUG => !!$ENV{DEBUG},
  29 };
  30
  31 my %GIT_ESC = (
  32         a => "\a",
  33         b => "\b",
  34         f => "\f",
  35         n => "\n",
  36         r => "\r",
  37         t => "\t",
  38         v => "\013",
  39 );
  40
  41 sub git_unquote ($) {
  42         my ($s) = @_;
  43         return $s unless ($s =~ /\A"(.*)"\z/);
  44         $s = $1;
  45         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  46         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  47         $s;
  48 }
  49
  50 sub new {
  51         my ($class, $ibx, $creat, $part) = @_;
  52         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  53         my $git_dir = $mainrepo;
  54         my ($altid, $git);
  55         my $version = 1;
  56         if (ref $ibx) {
  57                 $mainrepo = $ibx->{mainrepo};
  58                 $altid = $ibx->{altid};
  59                 $version = $ibx->{version} || 1;
  60                 if ($altid) {
  61                         require PublicInbox::AltId;
  62                         $altid = [ map {
  63                                 PublicInbox::AltId->new($ibx, $_);
  64                         } @$altid ];
  65                 }
  66                 $git = $ibx->git;
  67         } else {
  68                 $git = PublicInbox::Git->new($git_dir); # v1 only
  69         }
  70         require Search::Xapian::WritableDatabase;
  71         my $self = bless {
  72                 mainrepo => $mainrepo,
  73                 git => $git,
  74                 -altid => $altid,
  75                 version => $version,
  76         }, $class;
  77         my $perm = $self->_git_config_perm;
  78         my $umask = _umask_for($perm);
  79         $self->{umask} = $umask;
  80         if ($version == 1) {
  81                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  82         } elsif ($version == 2) {
  83                 defined $part or die "partition is required for v2\n";
  84                 # partition is a number or "all"
  85                 $self->{partition} = $part;
  86                 $self->{lock_path} = undef;
  87                 $self->{msgmap_path} = "$mainrepo/msgmap.sqlite3";
  88         } else {
  89                 die "unsupported inbox version=$version\n";
  90         }
  91         $self->{creat} = ($creat || 0) == 1;
  92         $self;
  93 }
  94
  95 sub _xdb_release {
  96         my ($self) = @_;
  97         my $xdb = delete $self->{xdb} or croak 'not acquired';
  98         $xdb->close;
  99         _lock_release($self) if $self->{creat};
 100         undef;
 101 }
 102
 103 sub _xdb_acquire {
 104         my ($self) = @_;
 105         croak 'already acquired' if $self->{xdb};
 106         my $dir = $self->xdir;
 107         my $flag = Search::Xapian::DB_OPEN;
 108         if ($self->{creat}) {
 109                 require File::Path;
 110                 _lock_acquire($self);
 111                 File::Path::mkpath($dir);
 112                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 113         }
 114         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 115 }
 116
 117 # we only acquire the flock if creating or reindexing;
 118 # PublicInbox::Import already has the lock on its own.
 119 sub _lock_acquire {
 120         my ($self) = @_;
 121         croak 'already locked' if $self->{lockfh};
 122         my $lock_path = $self->{lock_path} or return;
 123         sysopen(my $lockfh, $lock_path, O_WRONLY|O_CREAT) or
 124                 die "failed to open lock $lock_path: $!\n";
 125         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
 126         $self->{lockfh} = $lockfh;
 127 }
 128
 129 sub _lock_release {
 130         my ($self) = @_;
 131         return unless $self->{lock_path};
 132         my $lockfh = delete $self->{lockfh} or croak 'not locked';
 133         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
 134         close $lockfh or die "close failed: $!\n";
 135 }
 136
 137 sub add_val ($$$) {
 138         my ($doc, $col, $num) = @_;
 139         $num = Search::Xapian::sortable_serialise($num);
 140         $doc->add_value($col, $num);
 141 }
 142
 143 sub add_values ($$) {
 144         my ($doc, $values) = @_;
 145
 146         my $ts = $values->[PublicInbox::Search::TS];
 147         add_val($doc, PublicInbox::Search::TS, $ts);
 148
 149         my $num = $values->[PublicInbox::Search::NUM];
 150         defined($num) and add_val($doc, PublicInbox::Search::NUM, $num);
 151
 152         my $bytes = $values->[PublicInbox::Search::BYTES];
 153         defined($bytes) and add_val($doc, PublicInbox::Search::BYTES, $bytes);
 154
 155         my $lines = $values->[PublicInbox::Search::LINES];
 156         add_val($doc, PublicInbox::Search::LINES, $lines);
 157
 158         my $yyyymmdd = strftime('%Y%m%d', gmtime($ts));
 159         add_val($doc, PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 160 }
 161
 162 sub index_users ($$) {
 163         my ($tg, $smsg) = @_;
 164
 165         my $from = $smsg->from;
 166         my $to = $smsg->to;
 167         my $cc = $smsg->cc;
 168
 169         $tg->index_text($from, 1, 'A'); # A - author
 170         $tg->increase_termpos;
 171         $tg->index_text($to, 1, 'XTO') if $to ne '';
 172         $tg->increase_termpos;
 173         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 174         $tg->increase_termpos;
 175 }
 176
 177 sub index_diff_inc ($$$$) {
 178         my ($tg, $text, $pfx, $xnq) = @_;
 179         if (@$xnq) {
 180                 $tg->index_text(join("\n", @$xnq), 1, 'XNQ');
 181                 $tg->increase_termpos;
 182                 @$xnq = ();
 183         }
 184         $tg->index_text($text, 1, $pfx);
 185         $tg->increase_termpos;
 186 }
 187
 188 sub index_old_diff_fn {
 189         my ($tg, $seen, $fa, $fb, $xnq) = @_;
 190
 191         # no renames or space support for traditional diffs,
 192         # find the number of leading common paths to strip:
 193         my @fa = split('/', $fa);
 194         my @fb = split('/', $fb);
 195         while (scalar(@fa) && scalar(@fb)) {
 196                 $fa = join('/', @fa);
 197                 $fb = join('/', @fb);
 198                 if ($fa eq $fb) {
 199                         unless ($seen->{$fa}++) {
 200                                 index_diff_inc($tg, $fa, 'XDFN', $xnq);
 201                         }
 202                         return 1;
 203                 }
 204                 shift @fa;
 205                 shift @fb;
 206         }
 207         0;
 208 }
 209
 210 sub index_diff ($$$) {
 211         my ($tg, $lines, $doc) = @_;
 212         my %seen;
 213         my $in_diff;
 214         my @xnq;
 215         my $xnq = \@xnq;
 216         foreach (@$lines) {
 217                 if ($in_diff && s/^ //) { # diff context
 218                         index_diff_inc($tg, $_, 'XDFCTX', $xnq);
 219                 } elsif (/^-- $/) { # email signature begins
 220                         $in_diff = undef;
 221                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 222                         my ($fa, $fb) = ($1, $2);
 223                         my $fn = (split('/', git_unquote($fa), 2))[1];
 224                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 225                         $fn = (split('/', git_unquote($fb), 2))[1];
 226                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 227                         $in_diff = 1;
 228                 # traditional diff:
 229                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 230                         my ($opt, $fa, $fb) = ($1, $2, $3);
 231                         push @xnq, $_;
 232                         # only support unified:
 233                         next unless $opt =~ /[uU]/;
 234                         $in_diff = index_old_diff_fn($tg, \%seen, $fa, $fb,
 235                                                         $xnq);
 236                 } elsif (m!^--- ("?a/.+)!) {
 237                         my $fn = (split('/', git_unquote($1), 2))[1];
 238                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 239                         $in_diff = 1;
 240                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 241                         my $fn = (split('/', git_unquote($1), 2))[1];
 242                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 243                         $in_diff = 1;
 244                 } elsif (/^--- (\S+)/) {
 245                         $in_diff = $1;
 246                         push @xnq, $_;
 247                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 248                         $in_diff = index_old_diff_fn($tg, \%seen, $in_diff, $1,
 249                                                         $xnq);
 250                 } elsif ($in_diff && s/^\+//) { # diff added
 251                         index_diff_inc($tg, $_, 'XDFB', $xnq);
 252                 } elsif ($in_diff && s/^-//) { # diff removed
 253                         index_diff_inc($tg, $_, 'XDFA', $xnq);
 254                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 255                         my ($ba, $bb) = ($1, $2);
 256                         index_git_blob_id($doc, 'XDFPRE', $ba);
 257                         index_git_blob_id($doc, 'XDFPOST', $bb);
 258                         $in_diff = 1;
 259                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 260                         # traditional diff w/o -p
 261                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 262                         # hunk header context
 263                         index_diff_inc($tg, $1, 'XDFHH', $xnq);
 264                 # ignore the following lines:
 265                 } elsif (/^(?:dis)similarity index/ ||
 266                                 /^(?:old|new) mode/ ||
 267                                 /^(?:deleted|new) file mode/ ||
 268                                 /^(?:copy|rename) (?:from|to) / ||
 269                                 /^(?:dis)?similarity index / ||
 270                                 /^\\ No newline at end of file/ ||
 271                                 /^Binary files .* differ/) {
 272                         push @xnq, $_;
 273                 } elsif ($_ eq '') {
 274                         $in_diff = undef;
 275                 } else {
 276                         push @xnq, $_;
 277                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 278                         $in_diff = undef;
 279                 }
 280         }
 281
 282         $tg->index_text(join("\n", @xnq), 1, 'XNQ');
 283         $tg->increase_termpos;
 284 }
 285
 286 sub index_body ($$$) {
 287         my ($tg, $lines, $doc) = @_;
 288         my $txt = join("\n", @$lines);
 289         if ($doc) {
 290                 # does it look like a diff?
 291                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 292                         $txt = undef;
 293                         index_diff($tg, $lines, $doc);
 294                 } else {
 295                         $tg->index_text($txt, 1, 'XNQ');
 296                 }
 297         } else {
 298                 $tg->index_text($txt, 0, 'XQUOT');
 299         }
 300         $tg->increase_termpos;
 301         @$lines = ();
 302 }
 303
 304 sub add_message {
 305         # mime = Email::MIME object
 306         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 307         my $doc_id;
 308         my $mids = mids($mime->header_obj);
 309         my $skel = $self->{skeleton};
 310
 311         eval {
 312                 my $smsg = PublicInbox::SearchMsg->new($mime);
 313                 my $doc = $smsg->{doc};
 314                 my $subj = $smsg->subject;
 315                 my $xpath;
 316                 if ($subj ne '') {
 317                         $xpath = $self->subject_path($subj);
 318                         $xpath = id_compress($xpath);
 319                 }
 320
 321                 my $lines = $mime->body_raw =~ tr!\n!\n!;
 322                 my @values = ($smsg->ts, $num, $bytes, $lines);
 323                 add_values($doc, \@values);
 324
 325                 my $tg = $self->term_generator;
 326
 327                 $tg->set_document($doc);
 328                 $tg->index_text($subj, 1, 'S') if $subj;
 329                 $tg->increase_termpos;
 330
 331                 index_users($tg, $smsg);
 332
 333                 msg_iter($mime, sub {
 334                         my ($part, $depth, @idx) = @{$_[0]};
 335                         my $ct = $part->content_type || 'text/plain';
 336                         my $fn = $part->filename;
 337                         if (defined $fn && $fn ne '') {
 338                                 $tg->index_text($fn, 1, 'XFN');
 339                         }
 340
 341                         return if $ct =~ m!\btext/x?html\b!i;
 342
 343                         my $s = eval { $part->body_str };
 344                         if ($@) {
 345                                 if ($ct =~ m!\btext/plain\b!i) {
 346                                         # Try to assume UTF-8 because Alpine
 347                                         # seems to do wacky things and set
 348                                         # charset=X-UNKNOWN
 349                                         $part->charset_set('UTF-8');
 350                                         $s = eval { $part->body_str };
 351                                         $s = $part->body if $@;
 352                                 }
 353                         }
 354                         defined $s or return;
 355
 356                         my (@orig, @quot);
 357                         my $body = $part->body;
 358                         my @lines = split(/\n/, $body);
 359                         while (defined(my $l = shift @lines)) {
 360                                 if ($l =~ /^>/) {
 361                                         index_body($tg, \@orig, $doc) if @orig;
 362                                         push @quot, $l;
 363                                 } else {
 364                                         index_body($tg, \@quot, 0) if @quot;
 365                                         push @orig, $l;
 366                                 }
 367                         }
 368                         index_body($tg, \@quot, 0) if @quot;
 369                         index_body($tg, \@orig, $doc) if @orig;
 370                 });
 371
 372                 # populates smsg->references for smsg->to_doc_data
 373                 my $refs = parse_references($smsg);
 374                 $mid0 = $mids->[0] unless defined $mid0;
 375                 my $data = $smsg->to_doc_data($oid, $mid0);
 376                 foreach my $mid (@$mids) {
 377                         $tg->index_text($mid, 1, 'XM');
 378                 }
 379                 $doc->set_data($data);
 380                 if (my $altid = $self->{-altid}) {
 381                         foreach my $alt (@$altid) {
 382                                 my $pfx = $alt->{xprefix};
 383                                 foreach my $mid (@$mids) {
 384                                         my $id = $alt->mid2alt($mid);
 385                                         next unless defined $id;
 386                                         $doc->add_boolean_term($pfx . $id);
 387                                 }
 388                         }
 389                 }
 390
 391                 if ($skel) {
 392                         push @values, $mids, $xpath, $data;
 393                         $skel->index_skeleton(\@values);
 394                         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 395                         $doc_id = $self->{xdb}->add_document($doc);
 396                 } else {
 397                         $doc_id = link_and_save($self, $doc, $mids, $refs,
 398                                                 $num, $xpath);
 399                 }
 400         };
 401
 402         if ($@) {
 403                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 404                 return undef;
 405         }
 406         $doc_id;
 407 }
 408
 409 sub batch_do {
 410         my ($self, $termval, $cb) = @_;
 411         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 412         while (1) {
 413                 my ($head, $tail) = $self->find_doc_ids($termval);
 414                 return if $head == $tail;
 415                 my @ids;
 416                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 417                         push @ids, $head->get_docid;
 418                 }
 419                 $cb->(\@ids);
 420         }
 421 }
 422
 423 sub remove_message {
 424         my ($self, $mid) = @_;
 425         my $db = $self->{xdb};
 426         my $called;
 427         $mid = mid_clean($mid);
 428
 429         eval {
 430                 batch_do($self, 'Q' . $mid, sub {
 431                         my ($ids) = @_;
 432                         $db->delete_document($_) for @$ids;
 433                         $called = 1;
 434                 });
 435         };
 436         if ($@) {
 437                 warn "failed to remove message <$mid>: $@\n";
 438         } elsif (!$called) {
 439                 warn "cannot remove non-existent <$mid>\n";
 440         }
 441 }
 442
 443 sub term_generator { # write-only
 444         my ($self) = @_;
 445
 446         my $tg = $self->{term_generator};
 447         return $tg if $tg;
 448
 449         $tg = Search::Xapian::TermGenerator->new;
 450         $tg->set_stemmer($self->stemmer);
 451
 452         $self->{term_generator} = $tg;
 453 }
 454
 455 # increments last_thread_id counter
 456 # returns a 64-bit integer represented as a decimal string
 457 sub next_thread_id {
 458         my ($self) = @_;
 459         my $db = $self->{xdb};
 460         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 461
 462         $db->set_metadata('last_thread_id', ++$last_thread_id);
 463
 464         $last_thread_id;
 465 }
 466
 467 sub parse_references ($) {
 468         my ($smsg) = @_;
 469         my $mime = $smsg->{mime};
 470         my $hdr = $mime->header_obj;
 471         my $refs = references($hdr);
 472         return $refs if scalar(@$refs) == 0;
 473
 474         # prevent circular references via References here:
 475         my %mids = map { $_ => 1 } @{mids($hdr)};
 476         my @keep;
 477         foreach my $ref (@$refs) {
 478                 if (length($ref) > PublicInbox::MID::MAX_MID_SIZE) {
 479                         warn "References: <$ref> too long, ignoring\n";
 480                         next;
 481                 }
 482                 next if $mids{$ref};
 483                 push @keep, $ref;
 484         }
 485         $smsg->{references} = '<'.join('> <', @keep).'>' if @keep;
 486         \@keep;
 487 }
 488
 489 sub link_doc {
 490         my ($self, $doc, $refs, $old_tid) = @_;
 491         my $tid;
 492
 493         if (@$refs) {
 494                 # first ref *should* be the thread root,
 495                 # but we can never trust clients to do the right thing
 496                 my $ref = shift @$refs;
 497                 $tid = resolve_mid_to_tid($self, $ref);
 498                 merge_threads($self, $tid, $old_tid) if defined $old_tid;
 499
 500                 # the rest of the refs should point to this tid:
 501                 foreach $ref (@$refs) {
 502                         my $ptid = resolve_mid_to_tid($self, $ref);
 503                         merge_threads($self, $tid, $ptid);
 504                 }
 505         } else {
 506                 $tid = defined $old_tid ? $old_tid : $self->next_thread_id;
 507         }
 508         $doc->add_boolean_term('G' . $tid);
 509         $tid;
 510 }
 511
 512 sub link_and_save {
 513         my ($self, $doc, $mids, $refs, $num, $xpath) = @_;
 514         my $db = $self->{xdb};
 515         my $old_tid;
 516         my $doc_id;
 517         $doc->add_boolean_term('XNUM' . $num) if defined $num;
 518         $doc->add_boolean_term('XPATH' . $xpath) if defined $xpath;
 519         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 520
 521         my $vivified = 0;
 522         foreach my $mid (@$mids) {
 523                 $self->each_smsg_by_mid($mid, sub {
 524                         my ($cur) = @_;
 525                         my $type = $cur->type;
 526                         my $cur_tid = $cur->thread_id;
 527                         $old_tid = $cur_tid unless defined $old_tid;
 528                         if ($type eq 'mail') {
 529                                 # do not break existing mail messages,
 530                                 # just merge the threads
 531                                 merge_threads($self, $old_tid, $cur_tid);
 532                                 return 1;
 533                         }
 534                         if ($type ne 'ghost') {
 535                                 die "<$mid> has a bad type: $type\n";
 536                         }
 537                         my $tid = link_doc($self, $doc, $refs, $old_tid);
 538                         $old_tid = $tid unless defined $old_tid;
 539                         $doc_id = $cur->{doc_id};
 540                         $self->{xdb}->replace_document($doc_id, $doc);
 541                         ++$vivified;
 542                         1;
 543                 });
 544         }
 545         # not really important, but we return any vivified ghost docid, here:
 546         return $doc_id if defined $doc_id;
 547         link_doc($self, $doc, $refs, $old_tid);
 548         $self->{xdb}->add_document($doc);
 549 }
 550
 551 sub index_git_blob_id {
 552         my ($doc, $pfx, $objid) = @_;
 553
 554         my $len = length($objid);
 555         for (my $len = length($objid); $len >= 7; ) {
 556                 $doc->add_term($pfx.$objid);
 557                 $objid = substr($objid, 0, --$len);
 558         }
 559 }
 560
 561 sub unindex_blob {
 562         my ($self, $mime) = @_;
 563         my $mid = eval { mid_clean(mid_mime($mime)) };
 564         $self->remove_message($mid) if defined $mid;
 565 }
 566
 567 sub index_mm {
 568         my ($self, $mime) = @_;
 569         my $mid = mid_clean(mid_mime($mime));
 570         my $mm = $self->{mm};
 571         my $num = $mm->mid_insert($mid);
 572         return $num if defined $num;
 573
 574         # fallback to num_for since filters like RubyLang set the number
 575         $mm->num_for($mid);
 576 }
 577
 578 sub unindex_mm {
 579         my ($self, $mime) = @_;
 580         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 581 }
 582
 583 sub index_mm2 {
 584         my ($self, $mime, $bytes, $blob) = @_;
 585         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 586         add_message($self, $mime, $bytes, $num, $blob);
 587 }
 588
 589 sub unindex_mm2 {
 590         my ($self, $mime) = @_;
 591         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 592         unindex_blob($self, $mime);
 593 }
 594
 595 sub index_both {
 596         my ($self, $mime, $bytes, $blob) = @_;
 597         my $num = index_mm($self, $mime);
 598         add_message($self, $mime, $bytes, $num, $blob);
 599 }
 600
 601 sub unindex_both {
 602         my ($self, $mime) = @_;
 603         unindex_blob($self, $mime);
 604         unindex_mm($self, $mime);
 605 }
 606
 607 sub do_cat_mail {
 608         my ($git, $blob, $sizeref) = @_;
 609         my $mime = eval {
 610                 my $str = $git->cat_file($blob, $sizeref);
 611                 # fixup bugs from import:
 612                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 613                 PublicInbox::MIME->new($str);
 614         };
 615         $@ ? undef : $mime;
 616 }
 617
 618 sub index_sync {
 619         my ($self, $opts) = @_;
 620         with_umask($self, sub { $self->_index_sync($opts) });
 621 }
 622
 623 sub batch_adjust ($$$$) {
 624         my ($max, $bytes, $batch_cb, $latest) = @_;
 625         $$max -= $bytes;
 626         if ($$max <= 0) {
 627                 $$max = BATCH_BYTES;
 628                 $batch_cb->($latest, 1);
 629         }
 630 }
 631
 632 # only for v1
 633 sub rlog {
 634         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 635         my $hex = '[a-f0-9]';
 636         my $h40 = $hex .'{40}';
 637         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 638         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 639         my $git = $self->{git};
 640         my $latest;
 641         my $bytes;
 642         my $max = BATCH_BYTES;
 643         local $/ = "\n";
 644         my $line;
 645         while (defined($line = <$log>)) {
 646                 if ($line =~ /$addmsg/o) {
 647                         my $blob = $1;
 648                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 649                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 650                         $add_cb->($self, $mime, $bytes, $blob);
 651                 } elsif ($line =~ /$delmsg/o) {
 652                         my $blob = $1;
 653                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 654                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 655                         $del_cb->($self, $mime);
 656                 } elsif ($line =~ /^commit ($h40)/o) {
 657                         $latest = $1;
 658                 }
 659         }
 660         $batch_cb->($latest, 0);
 661 }
 662
 663 sub _msgmap_init {
 664         my ($self) = @_;
 665         $self->{mm} ||= eval {
 666                 require PublicInbox::Msgmap;
 667                 my $msgmap_path = $self->{msgmap_path};
 668                 if (defined $msgmap_path) { # v2
 669                         PublicInbox::Msgmap->new_file($msgmap_path, 1);
 670                 } else {
 671                         PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 672                 }
 673         };
 674 }
 675
 676 sub _git_log {
 677         my ($self, $range) = @_;
 678         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 679                                 --raw -r --no-abbrev/, $range);
 680 }
 681
 682 # indexes all unindexed messages
 683 sub _index_sync {
 684         my ($self, $opts) = @_;
 685         my $tip = $opts->{ref} || 'HEAD';
 686         my $reindex = $opts->{reindex};
 687         my ($mkey, $last_commit, $lx, $xlog);
 688         $self->{git}->batch_prepare;
 689         my $xdb = _xdb_acquire($self);
 690         $xdb->begin_transaction;
 691         do {
 692                 $xlog = undef;
 693                 $mkey = 'last_commit';
 694                 $last_commit = $xdb->get_metadata('last_commit');
 695                 $lx = $last_commit;
 696                 if ($reindex) {
 697                         $lx = '';
 698                         $mkey = undef if $last_commit ne '';
 699                 }
 700                 $xdb->cancel_transaction;
 701                 $xdb = _xdb_release($self);
 702
 703                 # ensure we leak no FDs to "git log"
 704                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 705                 $xlog = _git_log($self, $range);
 706
 707                 $xdb = _xdb_acquire($self);
 708                 $xdb->begin_transaction;
 709         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 710
 711         my $mm = _msgmap_init($self);
 712         my $dbh = $mm->{dbh} if $mm;
 713         my $mm_only;
 714         my $cb = sub {
 715                 my ($commit, $more) = @_;
 716                 if ($dbh) {
 717                         $mm->last_commit($commit) if $commit;
 718                         $dbh->commit;
 719                 }
 720                 if (!$mm_only) {
 721                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 722                         $xdb->commit_transaction;
 723                         $xdb = _xdb_release($self);
 724                 }
 725                 # let another process do some work... <
 726                 if ($more) {
 727                         if (!$mm_only) {
 728                                 $xdb = _xdb_acquire($self);
 729                                 $xdb->begin_transaction;
 730                         }
 731                         $dbh->begin_work if $dbh;
 732                 }
 733         };
 734
 735         if ($mm) {
 736                 $dbh->begin_work;
 737                 my $lm = $mm->last_commit || '';
 738                 if ($lm eq $lx) {
 739                         # Common case is the indexes are synced,
 740                         # we only need to run git-log once:
 741                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 742                 } else {
 743                         # Uncommon case, msgmap and xapian are out-of-sync
 744                         # do not care for performance (but git is fast :>)
 745                         # This happens if we have to reindex Xapian since
 746                         # msgmap is a frozen format and our Xapian format
 747                         # is evolving.
 748                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 749
 750                         # first, ensure msgmap is up-to-date:
 751                         my $mkey_prev = $mkey;
 752                         $mkey = undef; # ignore xapian, for now
 753                         my $mlog = _git_log($self, $r);
 754                         $mm_only = 1;
 755                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 756                         $mm_only = $mlog = undef;
 757
 758                         # now deal with Xapian
 759                         $mkey = $mkey_prev;
 760                         $dbh = undef;
 761                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 762                 }
 763         } else {
 764                 # user didn't install DBD::SQLite and DBI
 765                 rlog($self, $xlog, *add_message, *unindex_blob, $cb);
 766         }
 767 }
 768
 769 # this will create a ghost as necessary
 770 sub resolve_mid_to_tid {
 771         my ($self, $mid) = @_;
 772         my $tid;
 773         $self->each_smsg_by_mid($mid, sub {
 774                 my ($smsg) = @_;
 775                 my $cur_tid = $smsg->thread_id;
 776                 if (defined $tid) {
 777                         merge_threads($self, $tid, $cur_tid);
 778                 } else {
 779                         $tid = $smsg->thread_id;
 780                 }
 781                 1;
 782         });
 783         return $tid if defined $tid;
 784
 785         $self->create_ghost($mid)->thread_id;
 786 }
 787
 788 sub create_ghost {
 789         my ($self, $mid) = @_;
 790
 791         my $tid = $self->next_thread_id;
 792         my $doc = Search::Xapian::Document->new;
 793         $doc->add_boolean_term('Q' . $mid);
 794         $doc->add_boolean_term('G' . $tid);
 795         $doc->add_boolean_term('T' . 'ghost');
 796
 797         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 798         $self->{xdb}->add_document($doc);
 799
 800         $smsg;
 801 }
 802
 803 sub merge_threads {
 804         my ($self, $winner_tid, $loser_tid) = @_;
 805         return if $winner_tid == $loser_tid;
 806         my $db = $self->{xdb};
 807         batch_do($self, 'G' . $loser_tid, sub {
 808                 my ($ids) = @_;
 809                 foreach my $docid (@$ids) {
 810                         my $doc = $db->get_document($docid);
 811                         $doc->remove_term('G' . $loser_tid);
 812                         $doc->add_boolean_term('G' . $winner_tid);
 813                         $db->replace_document($docid, $doc);
 814                 }
 815         });
 816 }
 817
 818 sub _read_git_config_perm {
 819         my ($self) = @_;
 820         my @cmd = qw(config);
 821         if ($self->{version} == 2) {
 822                 push @cmd, "--file=$self->{mainrepo}/all.git/config";
 823         }
 824         my $fh = $self->{git}->popen(@cmd, 'core.sharedRepository');
 825         local $/ = "\n";
 826         my $perm = <$fh>;
 827         chomp $perm if defined $perm;
 828         $perm;
 829 }
 830
 831 sub _git_config_perm {
 832         my $self = shift;
 833         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 834         return PERM_GROUP if (!defined($perm) || $perm eq '');
 835         return PERM_UMASK if ($perm eq 'umask');
 836         return PERM_GROUP if ($perm eq 'group');
 837         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 838                 return PERM_EVERYBODY;
 839         }
 840         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 841         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 842
 843         my $i = oct($perm);
 844         return PERM_UMASK if ($i == PERM_UMASK);
 845         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 846         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 847
 848         if (($i & 0600) != 0600) {
 849                 die "core.sharedRepository mode invalid: ".
 850                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 851         }
 852         ($i & 0666);
 853 }
 854
 855 sub _umask_for {
 856         my ($perm) = @_; # _git_config_perm return value
 857         my $rv = $perm;
 858         return umask if $rv == 0;
 859
 860         # set +x bit if +r or +w were set
 861         $rv |= 0100 if ($rv & 0600);
 862         $rv |= 0010 if ($rv & 0060);
 863         $rv |= 0001 if ($rv & 0006);
 864         (~$rv & 0777);
 865 }
 866
 867 sub with_umask {
 868         my ($self, $cb) = @_;
 869         my $old = umask $self->{umask};
 870         my $rv = eval { $cb->() };
 871         my $err = $@;
 872         umask $old;
 873         die $err if $err;
 874         $rv;
 875 }
 876
 877 sub DESTROY {
 878         # order matters for unlocking
 879         $_[0]->{xdb} = undef;
 880         $_[0]->{lockfh} = undef;
 881 }
 882
 883 # remote_* subs are only used by SearchIdxPart and SearchIdxSkeleton
 884 sub remote_commit {
 885         my ($self) = @_;
 886         print { $self->{w} } "commit\n" or die "failed to write commit: $!";
 887 }
 888
 889 sub remote_close {
 890         my ($self) = @_;
 891         my $pid = delete $self->{pid} or die "no process to wait on\n";
 892         my $w = delete $self->{w} or die "no pipe to write to\n";
 893         print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 894         close $w or die "failed to close pipe for pid:$pid: $!\n";
 895         waitpid($pid, 0) == $pid or die "remote process did not finish";
 896         $? == 0 or die ref($self)." pid:$pid exited with: $?";
 897 }
 898
 899 1;