lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 use constant {
  26         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  27                         0x7fffffff : 1_000_000,
  28         DEBUG => !!$ENV{DEBUG},
  29 };
  30
  31 my $xapianlevels = qr/\A(?:full|medium)\z/;
  32
  33 sub new {
  34         my ($class, $ibx, $creat, $shard) = @_;
  35         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  36         my $levels = qr/\A(?:full|medium|basic)\z/;
  37         my $inboxdir = $ibx->{inboxdir};
  38         my $version = $ibx->version;
  39         my $indexlevel = 'full';
  40         my $altid = $ibx->{altid};
  41         if ($altid) {
  42                 require PublicInbox::AltId;
  43                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  44         }
  45         if ($ibx->{indexlevel}) {
  46                 if ($ibx->{indexlevel} =~ $levels) {
  47                         $indexlevel = $ibx->{indexlevel};
  48                 } else {
  49                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  50                 }
  51         }
  52         $ibx = PublicInbox::InboxWritable->new($ibx);
  53         my $self = bless {
  54                 inboxdir => $inboxdir,
  55                 -inbox => $ibx,
  56                 git => $ibx->git,
  57                 -altid => $altid,
  58                 ibx_ver => $version,
  59                 indexlevel => $indexlevel,
  60         }, $class;
  61         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  62         $ibx->umask_prepare;
  63         if ($version == 1) {
  64                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  65                 my $dir = $self->xdir;
  66                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  67         } elsif ($version == 2) {
  68                 defined $shard or die "shard is required for v2\n";
  69                 # shard is a number
  70                 $self->{shard} = $shard;
  71                 $self->{lock_path} = undef;
  72         } else {
  73                 die "unsupported inbox version=$version\n";
  74         }
  75         $self->{creat} = ($creat || 0) == 1;
  76         $self;
  77 }
  78
  79 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  80
  81 sub _xdb_release {
  82         my ($self) = @_;
  83         if (need_xapian($self)) {
  84                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  85                 $xdb->close;
  86         }
  87         $self->lock_release if $self->{creat};
  88         undef;
  89 }
  90
  91 sub load_xapian_writable () {
  92         return 1 if $X->{WritableDatabase};
  93         PublicInbox::Search::load_xapian() or return;
  94         my $xap = $PublicInbox::Search::Xap;
  95         for (qw(Document TermGenerator WritableDatabase)) {
  96                 $X->{$_} = $xap.'::'.$_;
  97         }
  98         eval 'require '.$X->{WritableDatabase} or die;
  99         *sortable_serialise = $xap.'::sortable_serialise';
 100         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 101         $DB_OPEN = eval($xap.'::DB_OPEN()');
 102         1;
 103 }
 104
 105 sub _xdb_acquire {
 106         my ($self) = @_;
 107         my $flag;
 108         my $dir = $self->xdir;
 109         if (need_xapian($self)) {
 110                 croak 'already acquired' if $self->{xdb};
 111                 load_xapian_writable();
 112                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 113         }
 114         if ($self->{creat}) {
 115                 require File::Path;
 116                 $self->lock_acquire;
 117
 118                 # don't create empty Xapian directories if we don't need Xapian
 119                 my $is_shard = defined($self->{shard});
 120                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 121                         File::Path::mkpath($dir);
 122                 }
 123         }
 124         return unless defined $flag;
 125         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 126         if ($@) {
 127                 die "Failed opening $dir: ", $@;
 128         }
 129         $self->{xdb} = $xdb;
 130 }
 131
 132 sub add_val ($$$) {
 133         my ($doc, $col, $num) = @_;
 134         $num = sortable_serialise($num);
 135         $doc->add_value($col, $num);
 136 }
 137
 138 sub term_generator ($) { # write-only
 139         my ($self) = @_;
 140
 141         $self->{term_generator} //= do {
 142                 my $tg = $X->{TermGenerator}->new;
 143                 $tg->set_stemmer($self->stemmer);
 144                 $tg;
 145         }
 146 }
 147
 148 sub index_text ($$$$) {
 149         my ($self, $text, $wdf_inc, $prefix) = @_;
 150         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 151
 152         if ($self->{indexlevel} eq 'full') {
 153                 $tg->index_text($text, $wdf_inc, $prefix);
 154                 $tg->increase_termpos;
 155         } else {
 156                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 157         }
 158 }
 159
 160 sub index_users ($$) {
 161         my ($self, $smsg) = @_;
 162
 163         my $from = $smsg->from;
 164         my $to = $smsg->to;
 165         my $cc = $smsg->cc;
 166
 167         index_text($self, $from, 1, 'A'); # A - author
 168         index_text($self, $to, 1, 'XTO') if $to ne '';
 169         index_text($self, $cc, 1, 'XCC') if $cc ne '';
 170 }
 171
 172 sub index_diff_inc ($$$$) {
 173         my ($self, $text, $pfx, $xnq) = @_;
 174         if (@$xnq) {
 175                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 176                 @$xnq = ();
 177         }
 178         index_text($self, $text, 1, $pfx);
 179 }
 180
 181 sub index_old_diff_fn {
 182         my ($self, $seen, $fa, $fb, $xnq) = @_;
 183
 184         # no renames or space support for traditional diffs,
 185         # find the number of leading common paths to strip:
 186         my @fa = split('/', $fa);
 187         my @fb = split('/', $fb);
 188         while (scalar(@fa) && scalar(@fb)) {
 189                 $fa = join('/', @fa);
 190                 $fb = join('/', @fb);
 191                 if ($fa eq $fb) {
 192                         unless ($seen->{$fa}++) {
 193                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 194                         }
 195                         return 1;
 196                 }
 197                 shift @fa;
 198                 shift @fb;
 199         }
 200         0;
 201 }
 202
 203 sub index_diff ($$$) {
 204         my ($self, $txt, $doc) = @_;
 205         my %seen;
 206         my $in_diff;
 207         my @xnq;
 208         my $xnq = \@xnq;
 209         foreach (split(/\n/, $txt)) {
 210                 if ($in_diff && s/^ //) { # diff context
 211                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 212                 } elsif (/^-- $/) { # email signature begins
 213                         $in_diff = undef;
 214                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 215                         # wait until "---" and "+++" to capture filenames
 216                         $in_diff = 1;
 217                 # traditional diff:
 218                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 219                         my ($opt, $fa, $fb) = ($1, $2, $3);
 220                         push @xnq, $_;
 221                         # only support unified:
 222                         next unless $opt =~ /[uU]/;
 223                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 224                                                         $xnq);
 225                 } elsif (m!^--- ("?[^/]+/.+)!) {
 226                         my $fn = $1;
 227                         $fn = (split('/', git_unquote($fn), 2))[1];
 228                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 229                         $in_diff = 1;
 230                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 231                         my $fn = $1;
 232                         $fn = (split('/', git_unquote($fn), 2))[1];
 233                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 234                         $in_diff = 1;
 235                 } elsif (/^--- (\S+)/) {
 236                         $in_diff = $1;
 237                         push @xnq, $_;
 238                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 239                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 240                                                         $1, $xnq);
 241                 } elsif ($in_diff && s/^\+//) { # diff added
 242                         index_diff_inc($self, $_, 'XDFB', $xnq);
 243                 } elsif ($in_diff && s/^-//) { # diff removed
 244                         index_diff_inc($self, $_, 'XDFA', $xnq);
 245                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 246                         my ($ba, $bb) = ($1, $2);
 247                         index_git_blob_id($doc, 'XDFPRE', $ba);
 248                         index_git_blob_id($doc, 'XDFPOST', $bb);
 249                         $in_diff = 1;
 250                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 251                         # traditional diff w/o -p
 252                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 253                         # hunk header context
 254                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 255                 # ignore the following lines:
 256                 } elsif (/^(?:dis)similarity index/ ||
 257                                 /^(?:old|new) mode/ ||
 258                                 /^(?:deleted|new) file mode/ ||
 259                                 /^(?:copy|rename) (?:from|to) / ||
 260                                 /^(?:dis)?similarity index / ||
 261                                 /^\\ No newline at end of file/ ||
 262                                 /^Binary files .* differ/) {
 263                         push @xnq, $_;
 264                 } elsif ($_ eq '') {
 265                         # possible to be in diff context, some mail may be
 266                         # stripped by MUA or even GNU diff(1).  "git apply"
 267                         # treats a bare "\n" as diff context, too
 268                 } else {
 269                         push @xnq, $_;
 270                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 271                         $in_diff = undef;
 272                 }
 273         }
 274
 275         index_text($self, join("\n", @xnq), 1, 'XNQ');
 276 }
 277
 278 sub index_xapian { # msg_iter callback
 279         my $part = $_[0]->[0]; # ignore $depth and @idx
 280         my ($self, $doc) = @{$_[1]};
 281         my $ct = $part->content_type || 'text/plain';
 282         my $fn = $part->filename;
 283         if (defined $fn && $fn ne '') {
 284                 index_text($self, $fn, 1, 'XFN');
 285         }
 286
 287         my ($s, undef) = msg_part_text($part, $ct);
 288         defined $s or return;
 289         $_[0]->[0] = $part = undef; # free memory
 290
 291         # split off quoted and unquoted blocks:
 292         my @sections = PublicInbox::MsgIter::split_quotes($s);
 293         undef $s; # free memory
 294         for my $txt (@sections) {
 295                 if ($txt =~ /\A>/) {
 296                         index_text($self, $txt, 0, 'XQUOT');
 297                 } else {
 298                         # does it look like a diff?
 299                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 300                                 index_diff($self, $txt, $doc);
 301                         } else {
 302                                 index_text($self, $txt, 1, 'XNQ');
 303                         }
 304                 }
 305                 undef $txt; # free memory
 306         }
 307 }
 308
 309 sub add_xapian ($$$$) {
 310         my ($self, $mime, $smsg, $mids) = @_;
 311         $smsg->{mime} = $mime; # XXX dangerous
 312         my $hdr = $mime->header_obj;
 313         my $doc = $X->{Document}->new;
 314         my $subj = $smsg->subject;
 315         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 316         my @ds = gmtime($smsg->{ds});
 317         my $yyyymmdd = strftime('%Y%m%d', @ds);
 318         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 319         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 320         add_val($doc, PublicInbox::Search::DT(), $dt);
 321
 322         my $tg = term_generator($self);
 323
 324         $tg->set_document($doc);
 325         index_text($self, $subj, 1, 'S') if $subj;
 326         index_users($self, $smsg);
 327
 328         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 329         foreach my $mid (@$mids) {
 330                 index_text($self, $mid, 1, 'XM');
 331
 332                 # because too many Message-IDs are prefixed with
 333                 # "Pine.LNX."...
 334                 if ($mid =~ /\w{12,}/) {
 335                         my @long = ($mid =~ /(\w{3,}+)/g);
 336                         index_text($self, join(' ', @long), 1, 'XM');
 337                 }
 338         }
 339         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 340         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 341         my $data = $smsg->to_doc_data;
 342         $doc->set_data($data);
 343         if (my $altid = $self->{-altid}) {
 344                 foreach my $alt (@$altid) {
 345                         my $pfx = $alt->{xprefix};
 346                         foreach my $mid (@$mids) {
 347                                 my $id = $alt->mid2alt($mid);
 348                                 next unless defined $id;
 349                                 $doc->add_boolean_term($pfx . $id);
 350                         }
 351                 }
 352         }
 353         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 354         $self->{xdb}->replace_document($smsg->{num}, $doc);
 355 }
 356
 357 sub _msgmap_init ($) {
 358         my ($self) = @_;
 359         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 360         $self->{mm} //= eval {
 361                 require PublicInbox::Msgmap;
 362                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 363         };
 364 }
 365
 366 sub add_message {
 367         # mime = Email::MIME object
 368         my ($self, $mime, $smsg) = @_;
 369         my $hdr = $mime->header_obj;
 370         my $mids = mids_for_index($hdr);
 371         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 372         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 373         $smsg->{num} //= do { # v1
 374                 _msgmap_init($self);
 375                 index_mm($self, $mime);
 376         };
 377
 378         # v1 and tests only:
 379         $smsg->{ds} //= msg_datestamp($hdr, $self->{autime});
 380         $smsg->{ts} //= msg_timestamp($hdr, $self->{cotime});
 381
 382         eval {
 383                 # order matters, overview stores every possible piece of
 384                 # data in doc_data (deflated).  Xapian only stores a subset
 385                 # of the fields which exist in over.sqlite3.  We may stop
 386                 # storing doc_data in Xapian sometime after we get multi-inbox
 387                 # search working.
 388                 if (my $over = $self->{over}) { # v1 only
 389                         $over->add_overview($mime, $smsg);
 390                 }
 391                 if (need_xapian($self)) {
 392                         add_xapian($self, $mime, $smsg, $mids);
 393                 }
 394         };
 395
 396         if ($@) {
 397                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 398                 return undef;
 399         }
 400         $smsg->{num};
 401 }
 402
 403 # returns begin and end PostingIterator
 404 sub find_doc_ids {
 405         my ($self, $termval) = @_;
 406         my $db = $self->{xdb};
 407
 408         ($db->postlist_begin($termval), $db->postlist_end($termval));
 409 }
 410
 411 # v1 only
 412 sub batch_do {
 413         my ($self, $termval, $cb) = @_;
 414         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 415         while (1) {
 416                 my ($head, $tail) = $self->find_doc_ids($termval);
 417                 return if $head == $tail;
 418                 my @ids;
 419                 for (; $head != $tail && @ids < $batch_size; $head++) {
 420                         push @ids, $head->get_docid;
 421                 }
 422                 $cb->(\@ids);
 423         }
 424 }
 425
 426 # v1 only, where $mid is unique
 427 sub remove_message {
 428         my ($self, $mid) = @_;
 429         $mid = mid_clean($mid);
 430
 431         if (my $over = $self->{over}) {
 432                 my $nr = eval { $over->remove_oid(undef, $mid) };
 433                 if ($@) {
 434                         warn "failed to remove <$mid> from overview: $@\n";
 435                 } elsif ($nr == 0) {
 436                         warn "<$mid> missing for removal from overview\n";
 437                 }
 438         }
 439         return unless need_xapian($self);
 440         my $db = $self->{xdb};
 441         my $nr = 0;
 442         eval {
 443                 batch_do($self, 'Q' . $mid, sub {
 444                         my ($ids) = @_;
 445                         $db->delete_document($_) for @$ids;
 446                         $nr += scalar @$ids;
 447                 });
 448         };
 449         if ($@) {
 450                 warn "failed to remove <$mid> from Xapian: $@\n";
 451         } elsif ($nr == 0) {
 452                 warn "<$mid> missing for removal from Xapian\n";
 453         }
 454 }
 455
 456 # MID is a hint in V2
 457 sub remove_by_oid {
 458         my ($self, $oid, $mid) = @_;
 459
 460         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 461
 462         return unless need_xapian($self);
 463         my $db = $self->{xdb};
 464
 465         # XXX careful, we cannot use batch_do here since we conditionally
 466         # delete documents based on other factors, so we cannot call
 467         # find_doc_ids twice.
 468         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 469         return if $head == $tail;
 470
 471         # there is only ONE element in @delete unless we
 472         # have bugs in our v2writable deduplication check
 473         my @delete;
 474         for (; $head != $tail; $head++) {
 475                 my $docid = $head->get_docid;
 476                 my $doc = $db->get_document($docid);
 477                 my $smsg = PublicInbox::Smsg->wrap($mid);
 478                 $smsg->load_expand($doc);
 479                 if ($smsg->{blob} eq $oid) {
 480                         push(@delete, $docid);
 481                 }
 482         }
 483         $db->delete_document($_) foreach @delete;
 484         scalar(@delete);
 485 }
 486
 487 sub index_git_blob_id {
 488         my ($doc, $pfx, $objid) = @_;
 489
 490         my $len = length($objid);
 491         for (my $len = length($objid); $len >= 7; ) {
 492                 $doc->add_term($pfx.$objid);
 493                 $objid = substr($objid, 0, --$len);
 494         }
 495 }
 496
 497 sub unindex_blob {
 498         my ($self, $mime) = @_;
 499         my $mid = eval { mid_mime($mime) };
 500         $self->remove_message($mid) if defined $mid;
 501 }
 502
 503 sub index_mm {
 504         my ($self, $mime) = @_;
 505         my $mid = mid_mime($mime);
 506         my $mm = $self->{mm};
 507         my $num;
 508
 509         if (defined $self->{regen_down}) {
 510                 $num = $mm->num_for($mid) and return $num;
 511
 512                 while (($num = $self->{regen_down}--) > 0) {
 513                         if ($mm->mid_set($num, $mid) != 0) {
 514                                 return $num;
 515                         }
 516                 }
 517         } elsif (defined $self->{regen_up}) {
 518                 $num = $mm->num_for($mid) and return $num;
 519
 520                 # this is to fixup old bugs due to add-remove-add
 521                 while (($num = ++$self->{regen_up})) {
 522                         if ($mm->mid_set($num, $mid) != 0) {
 523                                 return $num;
 524                         }
 525                 }
 526         }
 527
 528         $num = $mm->mid_insert($mid) and return $num;
 529
 530         # fallback to num_for since filters like RubyLang set the number
 531         $mm->num_for($mid);
 532 }
 533
 534 sub unindex_mm {
 535         my ($self, $mime) = @_;
 536         $self->{mm}->mid_delete(mid_mime($mime));
 537 }
 538
 539 sub index_both {
 540         my ($self, $mime, $smsg) = @_;
 541         my $num = index_mm($self, $mime);
 542         $smsg->{num} = $num;
 543         add_message($self, $mime, $smsg);
 544 }
 545
 546 sub unindex_both {
 547         my ($self, $mime) = @_;
 548         unindex_blob($self, $mime);
 549         unindex_mm($self, $mime);
 550 }
 551
 552 sub do_cat_mail {
 553         my ($git, $blob, $sizeref) = @_;
 554         my $str = $git->cat_file($blob, $sizeref) or
 555                 die "BUG: $blob not found in $git->{git_dir}";
 556         # fixup bugs from import:
 557         $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 558         PublicInbox::MIME->new($str);
 559 }
 560
 561 # called by public-inbox-index
 562 sub index_sync {
 563         my ($self, $opts) = @_;
 564         delete $self->{lock_path} if $opts->{-skip_lock};
 565         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 566 }
 567
 568 sub batch_adjust ($$$$$) {
 569         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 570         $$max -= $bytes;
 571         if ($$max <= 0) {
 572                 $$max = BATCH_BYTES;
 573                 $batch_cb->($nr, $latest);
 574         }
 575 }
 576
 577 # only for v1
 578 sub read_log {
 579         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 580         my $hex = '[a-f0-9]';
 581         my $h40 = $hex .'{40}';
 582         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 583         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 584         my $git = $self->{git};
 585         my $latest;
 586         my $bytes;
 587         my $max = BATCH_BYTES;
 588         local $/ = "\n";
 589         my %D;
 590         my $line;
 591         my $newest;
 592         my $nr = 0;
 593         while (defined($line = <$log>)) {
 594                 if ($line =~ /$addmsg/o) {
 595                         my $blob = $1;
 596                         if (delete $D{$blob}) {
 597                                 if (defined $self->{regen_down}) {
 598                                         my $num = $self->{regen_down}--;
 599                                         $self->{mm}->num_highwater($num);
 600                                 }
 601                                 next;
 602                         }
 603                         my $mime = do_cat_mail($git, $blob, \$bytes);
 604                         my $smsg = bless {}, 'PublicInbox::Smsg';
 605                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 606                         $smsg->{blob} = $blob;
 607                         $smsg->{bytes} = $bytes;
 608                         $add_cb->($self, $mime, $smsg);
 609                 } elsif ($line =~ /$delmsg/o) {
 610                         my $blob = $1;
 611                         $D{$blob} = 1;
 612                 } elsif ($line =~ /^commit ($h40)/o) {
 613                         $latest = $1;
 614                         $newest ||= $latest;
 615                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 616                         $self->{autime} = $1;
 617                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 618                         $self->{cotime} = $1;
 619                 }
 620         }
 621         close($log) or die "git log failed: \$?=$?";
 622         # get the leftovers
 623         foreach my $blob (keys %D) {
 624                 my $mime = do_cat_mail($git, $blob, \$bytes);
 625                 $del_cb->($self, $mime);
 626         }
 627         $batch_cb->($nr, $latest, $newest);
 628 }
 629
 630 sub _git_log {
 631         my ($self, $opts, $range) = @_;
 632         my $git = $self->{git};
 633
 634         if (index($range, '..') < 0) {
 635                 # don't show annoying git errors to users who run -index
 636                 # on empty inboxes
 637                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 638                 if ($?) {
 639                         open my $fh, '<', '/dev/null' or
 640                                 die "failed to open /dev/null: $!\n";
 641                         return $fh;
 642                 }
 643         }
 644
 645         # Count the new files so they can be added newest to oldest
 646         # and still have numbers increasing from oldest to newest
 647         my $fcount = 0;
 648         my $pr = $opts->{-progress};
 649         $pr->("counting changes\n\t$range ... ") if $pr;
 650         # can't use 'rev-list --count' if we use --diff-filter
 651         my $fh = $git->popen(qw(log --pretty=tformat:%h
 652                              --no-notes --no-color --no-renames
 653                              --diff-filter=AM), $range);
 654         ++$fcount while <$fh>;
 655         close $fh or die "git log failed: \$?=$?";
 656         my $high = $self->{mm}->num_highwater;
 657         $pr->("$fcount\n") if $pr; # continue previous line
 658         $self->{ntodo} = $fcount;
 659
 660         if (index($range, '..') < 0) {
 661                 if ($high && $high == $fcount) {
 662                         # fix up old bugs in full indexes which caused messages to
 663                         # not appear in Msgmap
 664                         $self->{regen_up} = $high;
 665                 } else {
 666                         # normal regen is for for fresh data
 667                         $self->{regen_down} = $fcount;
 668                 }
 669         } else {
 670                 # Give oldest messages the smallest numbers
 671                 $self->{regen_down} = $high + $fcount;
 672         }
 673
 674         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 675                                 --raw -r --no-abbrev/, $range);
 676 }
 677
 678 # --is-ancestor requires git 1.8.0+
 679 sub is_ancestor ($$$) {
 680         my ($git, $cur, $tip) = @_;
 681         return 0 unless $git->check($cur);
 682         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 683                 qw(merge-base --is-ancestor), $cur, $tip ];
 684         my $pid = spawn($cmd);
 685         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 686         $? == 0;
 687 }
 688
 689 sub need_update ($$$) {
 690         my ($self, $cur, $new) = @_;
 691         my $git = $self->{git};
 692         return 1 if $cur && !is_ancestor($git, $cur, $new);
 693         my $range = $cur eq '' ? $new : "$cur..$new";
 694         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 695         ($n eq '' || $n > 0);
 696 }
 697
 698 # The last git commit we indexed with Xapian or SQLite (msgmap)
 699 # This needs to account for cases where Xapian or SQLite is
 700 # out-of-date with respect to the other.
 701 sub _last_x_commit {
 702         my ($self, $mm) = @_;
 703         my $lm = $mm->last_commit || '';
 704         my $lx = '';
 705         if (need_xapian($self)) {
 706                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 707         } else {
 708                 $lx = $lm;
 709         }
 710         # Use last_commit from msgmap if it is older or unset
 711         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 712                 $lx = $lm;
 713         }
 714         $lx;
 715 }
 716
 717 sub reindex_from ($$) {
 718         my ($reindex, $last_commit) = @_;
 719         return $last_commit unless $reindex;
 720         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 721 }
 722
 723 # indexes all unindexed messages (v1 only)
 724 sub _index_sync {
 725         my ($self, $opts) = @_;
 726         my $tip = $opts->{ref} || 'HEAD';
 727         my ($last_commit, $lx, $xlog);
 728         my $git = $self->{git};
 729         $git->batch_prepare;
 730         my $pr = $opts->{-progress};
 731
 732         my $xdb = $self->begin_txn_lazy;
 733         my $mm = _msgmap_init($self);
 734         do {
 735                 if ($xlog) {
 736                         close($xlog) or die "git log failed: \$?=$?";
 737                         $xlog = undef;
 738                 }
 739                 $last_commit = _last_x_commit($self, $mm);
 740                 $lx = reindex_from($opts->{reindex}, $last_commit);
 741
 742                 $self->{over}->rollback_lazy;
 743                 $self->{over}->disconnect;
 744                 $git->cleanup;
 745                 delete $self->{txn};
 746                 $xdb->cancel_transaction if $xdb;
 747                 $xdb = _xdb_release($self);
 748
 749                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 750                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 751                 $xlog = _git_log($self, $opts, $range);
 752
 753                 $xdb = $self->begin_txn_lazy;
 754         } while (_last_x_commit($self, $mm) ne $last_commit);
 755
 756         my $dbh = $mm->{dbh} if $mm;
 757         my $cb = sub {
 758                 my ($nr, $commit, $newest) = @_;
 759                 if ($dbh) {
 760                         if ($newest) {
 761                                 my $cur = $mm->last_commit || '';
 762                                 if (need_update($self, $cur, $newest)) {
 763                                         $mm->last_commit($newest);
 764                                 }
 765                         }
 766                         $dbh->commit;
 767                 }
 768                 if ($newest && need_xapian($self)) {
 769                         my $cur = $xdb->get_metadata('last_commit');
 770                         if (need_update($self, $cur, $newest)) {
 771                                 $xdb->set_metadata('last_commit', $newest);
 772                         }
 773                 }
 774                 $self->commit_txn_lazy;
 775                 $git->cleanup;
 776                 $xdb = _xdb_release($self);
 777                 # let another process do some work... <
 778                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 779                 if (!$newest) {
 780                         $xdb = $self->begin_txn_lazy;
 781                         $dbh->begin_work if $dbh;
 782                 }
 783         };
 784
 785         $dbh->begin_work;
 786         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 787 }
 788
 789 sub DESTROY {
 790         # order matters for unlocking
 791         $_[0]->{xdb} = undef;
 792         $_[0]->{lockfh} = undef;
 793 }
 794
 795 # remote_* subs are only used by SearchIdxPart
 796 sub remote_commit {
 797         my ($self) = @_;
 798         if (my $w = $self->{w}) {
 799                 print $w "commit\n" or die "failed to write commit: $!";
 800         } else {
 801                 $self->commit_txn_lazy;
 802         }
 803 }
 804
 805 sub remote_close {
 806         my ($self) = @_;
 807         if (my $w = delete $self->{w}) {
 808                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 809                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 810                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 811                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 812                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 813         } else {
 814                 die "transaction in progress $self\n" if $self->{txn};
 815                 $self->_xdb_release if $self->{xdb};
 816         }
 817 }
 818
 819 sub remote_remove {
 820         my ($self, $oid, $mid) = @_;
 821         if (my $w = $self->{w}) {
 822                 # triggers remove_by_oid in a shard
 823                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 824         } else {
 825                 $self->begin_txn_lazy;
 826                 $self->remove_by_oid($oid, $mid);
 827         }
 828 }
 829
 830 sub begin_txn_lazy {
 831         my ($self) = @_;
 832         return if $self->{txn};
 833
 834         $self->{-inbox}->with_umask(sub {
 835                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 836                 $self->{over}->begin_lazy if $self->{over};
 837                 $xdb->begin_transaction if $xdb;
 838                 $self->{txn} = 1;
 839                 $xdb;
 840         });
 841 }
 842
 843 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 844 # This metadata is read by Admin::detect_indexlevel:
 845 sub set_indexlevel {
 846         my ($self) = @_;
 847
 848         if (!$self->{shard} && # undef or 0, not >0
 849                         delete($self->{-set_indexlevel_once})) {
 850                 my $xdb = $self->{xdb};
 851                 my $level = $xdb->get_metadata('indexlevel');
 852                 if (!$level || $level ne 'medium') {
 853                         $xdb->set_metadata('indexlevel', 'medium');
 854                 }
 855         }
 856 }
 857
 858 sub commit_txn_lazy {
 859         my ($self) = @_;
 860         delete $self->{txn} or return;
 861         $self->{-inbox}->with_umask(sub {
 862                 if (my $xdb = $self->{xdb}) {
 863                         set_indexlevel($self);
 864                         $xdb->commit_transaction;
 865                 }
 866                 $self->{over}->commit_lazy if $self->{over};
 867         });
 868 }
 869
 870 sub worker_done {
 871         my ($self) = @_;
 872         if (need_xapian($self)) {
 873                 die "$$ $0 xdb not released\n" if $self->{xdb};
 874         }
 875         die "$$ $0 still in transaction\n" if $self->{txn};
 876 }
 877
 878 1;