lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak);
  19 use POSIX qw(strftime);
  20 use PublicInbox::OverIdx;
  21 use PublicInbox::Spawn qw(spawn);
  22 use PublicInbox::Git qw(git_unquote);
  23 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  24 our @EXPORT_OK = qw(crlf_adjust log2stack is_ancestor check_size nodatacow_dir);
  25 my $X = \%PublicInbox::Search::X;
  26 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  27 our $DB_NO_SYNC = 0;
  28 our $BATCH_BYTES = defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  29                         0x7fffffff : 1_000_000;
  30 use constant DEBUG => !!$ENV{DEBUG};
  31
  32 my $xapianlevels = qr/\A(?:full|medium)\z/;
  33 my $hex = '[a-f0-9]';
  34 my $OID = $hex .'{40,}';
  35
  36 sub new {
  37         my ($class, $ibx, $creat, $shard) = @_;
  38         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  39         my $levels = qr/\A(?:full|medium|basic)\z/;
  40         my $inboxdir = $ibx->{inboxdir};
  41         my $version = $ibx->version;
  42         my $indexlevel = 'full';
  43         my $altid = $ibx->{altid};
  44         if ($altid) {
  45                 require PublicInbox::AltId;
  46                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  47         }
  48         if ($ibx->{indexlevel}) {
  49                 if ($ibx->{indexlevel} =~ $levels) {
  50                         $indexlevel = $ibx->{indexlevel};
  51                 } else {
  52                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  53                 }
  54         }
  55         $ibx = PublicInbox::InboxWritable->new($ibx);
  56         my $self = bless {
  57                 ibx => $ibx,
  58                 xpfx => $inboxdir, # for xpfx_init
  59                 -altid => $altid,
  60                 ibx_ver => $version,
  61                 indexlevel => $indexlevel,
  62         }, $class;
  63         $self->xpfx_init;
  64         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  65         $ibx->umask_prepare;
  66         if ($version == 1) {
  67                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  68                 my $dir = $self->xdir;
  69                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  70                 $self->{over}->{-no_sync} = 1 if $ibx->{-no_sync};
  71                 $self->{index_max_size} = $ibx->{index_max_size};
  72         } elsif ($version == 2) {
  73                 defined $shard or die "shard is required for v2\n";
  74                 # shard is a number
  75                 $self->{shard} = $shard;
  76                 $self->{lock_path} = undef;
  77         } else {
  78                 die "unsupported inbox version=$version\n";
  79         }
  80         $self->{creat} = ($creat || 0) == 1;
  81         $self;
  82 }
  83
  84 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  85
  86 sub idx_release {
  87         my ($self, $wake) = @_;
  88         if (need_xapian($self)) {
  89                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  90                 $xdb->close;
  91         }
  92         $self->lock_release($wake) if $self->{creat};
  93         undef;
  94 }
  95
  96 sub load_xapian_writable () {
  97         return 1 if $X->{WritableDatabase};
  98         PublicInbox::Search::load_xapian() or return;
  99         my $xap = $PublicInbox::Search::Xap;
 100         for (qw(Document TermGenerator WritableDatabase)) {
 101                 $X->{$_} = $xap.'::'.$_;
 102         }
 103         eval 'require '.$X->{WritableDatabase} or die;
 104         *sortable_serialise = $xap.'::sortable_serialise';
 105         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 106         $DB_OPEN = eval($xap.'::DB_OPEN()');
 107         my $ver = (eval($xap.'::major_version()') << 16) |
 108                 (eval($xap.'::minor_version()') << 8);
 109         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 110         1;
 111 }
 112
 113 sub nodatacow_dir ($) {
 114         my ($dir) = @_;
 115         opendir my $dh, $dir or die "opendir($dir): $!\n";
 116         PublicInbox::Spawn::set_nodatacow(fileno($dh));
 117 }
 118
 119 sub idx_acquire {
 120         my ($self) = @_;
 121         my $flag;
 122         my $dir = $self->xdir;
 123         if (need_xapian($self)) {
 124                 croak 'already acquired' if $self->{xdb};
 125                 load_xapian_writable();
 126                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 127         }
 128         if ($self->{creat}) {
 129                 require File::Path;
 130                 $self->lock_acquire;
 131
 132                 # don't create empty Xapian directories if we don't need Xapian
 133                 my $is_shard = defined($self->{shard});
 134                 if (!-d $dir && (!$is_shard ||
 135                                 ($is_shard && need_xapian($self)))) {
 136                         File::Path::mkpath($dir);
 137                         nodatacow_dir($dir);
 138                 }
 139         }
 140         return unless defined $flag;
 141         $flag |= $DB_NO_SYNC if $self->{ibx}->{-no_sync};
 142         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 143         if ($@) {
 144                 die "Failed opening $dir: ", $@;
 145         }
 146         $self->{xdb} = $xdb;
 147 }
 148
 149 sub add_val ($$$) {
 150         my ($doc, $col, $num) = @_;
 151         $num = sortable_serialise($num);
 152         $doc->add_value($col, $num);
 153 }
 154
 155 sub term_generator ($) { # write-only
 156         my ($self) = @_;
 157
 158         $self->{term_generator} //= do {
 159                 my $tg = $X->{TermGenerator}->new;
 160                 $tg->set_stemmer($self->stemmer);
 161                 $tg;
 162         }
 163 }
 164
 165 sub index_text ($$$$) {
 166         my ($self, $text, $wdf_inc, $prefix) = @_;
 167         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 168
 169         if ($self->{indexlevel} eq 'full') {
 170                 $tg->index_text($text, $wdf_inc, $prefix);
 171                 $tg->increase_termpos;
 172         } else {
 173                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 174         }
 175 }
 176
 177 sub index_headers ($$) {
 178         my ($self, $smsg) = @_;
 179         my @x = (from => 'A', # Author
 180                 subject => 'S', to => 'XTO', cc => 'XCC');
 181         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 182                 my $val = $smsg->{$field};
 183                 index_text($self, $val, 1, $pfx) if $val ne '';
 184         }
 185 }
 186
 187 sub index_diff_inc ($$$$) {
 188         my ($self, $text, $pfx, $xnq) = @_;
 189         if (@$xnq) {
 190                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 191                 @$xnq = ();
 192         }
 193         index_text($self, $text, 1, $pfx);
 194 }
 195
 196 sub index_old_diff_fn {
 197         my ($self, $seen, $fa, $fb, $xnq) = @_;
 198
 199         # no renames or space support for traditional diffs,
 200         # find the number of leading common paths to strip:
 201         my @fa = split('/', $fa);
 202         my @fb = split('/', $fb);
 203         while (scalar(@fa) && scalar(@fb)) {
 204                 $fa = join('/', @fa);
 205                 $fb = join('/', @fb);
 206                 if ($fa eq $fb) {
 207                         unless ($seen->{$fa}++) {
 208                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 209                         }
 210                         return 1;
 211                 }
 212                 shift @fa;
 213                 shift @fb;
 214         }
 215         0;
 216 }
 217
 218 sub index_diff ($$$) {
 219         my ($self, $txt, $doc) = @_;
 220         my %seen;
 221         my $in_diff;
 222         my @xnq;
 223         my $xnq = \@xnq;
 224         foreach (split(/\n/, $txt)) {
 225                 if ($in_diff && s/^ //) { # diff context
 226                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 227                 } elsif (/^-- $/) { # email signature begins
 228                         $in_diff = undef;
 229                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 230                         # wait until "---" and "+++" to capture filenames
 231                         $in_diff = 1;
 232                 # traditional diff:
 233                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 234                         my ($opt, $fa, $fb) = ($1, $2, $3);
 235                         push @xnq, $_;
 236                         # only support unified:
 237                         next unless $opt =~ /[uU]/;
 238                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 239                                                         $xnq);
 240                 } elsif (m!^--- ("?[^/]+/.+)!) {
 241                         my $fn = $1;
 242                         $fn = (split('/', git_unquote($fn), 2))[1];
 243                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 244                         $in_diff = 1;
 245                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 246                         my $fn = $1;
 247                         $fn = (split('/', git_unquote($fn), 2))[1];
 248                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 249                         $in_diff = 1;
 250                 } elsif (/^--- (\S+)/) {
 251                         $in_diff = $1;
 252                         push @xnq, $_;
 253                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 254                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 255                                                         $1, $xnq);
 256                 } elsif ($in_diff && s/^\+//) { # diff added
 257                         index_diff_inc($self, $_, 'XDFB', $xnq);
 258                 } elsif ($in_diff && s/^-//) { # diff removed
 259                         index_diff_inc($self, $_, 'XDFA', $xnq);
 260                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 261                         my ($ba, $bb) = ($1, $2);
 262                         index_git_blob_id($doc, 'XDFPRE', $ba);
 263                         index_git_blob_id($doc, 'XDFPOST', $bb);
 264                         $in_diff = 1;
 265                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 266                         # traditional diff w/o -p
 267                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 268                         # hunk header context
 269                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 270                 # ignore the following lines:
 271                 } elsif (/^(?:dis)similarity index/ ||
 272                                 /^(?:old|new) mode/ ||
 273                                 /^(?:deleted|new) file mode/ ||
 274                                 /^(?:copy|rename) (?:from|to) / ||
 275                                 /^(?:dis)?similarity index / ||
 276                                 /^\\ No newline at end of file/ ||
 277                                 /^Binary files .* differ/) {
 278                         push @xnq, $_;
 279                 } elsif ($_ eq '') {
 280                         # possible to be in diff context, some mail may be
 281                         # stripped by MUA or even GNU diff(1).  "git apply"
 282                         # treats a bare "\n" as diff context, too
 283                 } else {
 284                         push @xnq, $_;
 285                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 286                         $in_diff = undef;
 287                 }
 288         }
 289
 290         index_text($self, join("\n", @xnq), 1, 'XNQ');
 291 }
 292
 293 sub index_xapian { # msg_iter callback
 294         my $part = $_[0]->[0]; # ignore $depth and $idx
 295         my ($self, $doc) = @{$_[1]};
 296         my $ct = $part->content_type || 'text/plain';
 297         my $fn = $part->filename;
 298         if (defined $fn && $fn ne '') {
 299                 index_text($self, $fn, 1, 'XFN');
 300         }
 301         if ($part->{is_submsg}) {
 302                 my $mids = mids_for_index($part);
 303                 index_ids($self, $doc, $part, $mids);
 304                 my $smsg = bless {}, 'PublicInbox::Smsg';
 305                 $smsg->populate($part);
 306                 index_headers($self, $smsg);
 307         }
 308
 309         my ($s, undef) = msg_part_text($part, $ct);
 310         defined $s or return;
 311         $_[0]->[0] = $part = undef; # free memory
 312
 313         # split off quoted and unquoted blocks:
 314         my @sections = PublicInbox::MsgIter::split_quotes($s);
 315         undef $s; # free memory
 316         for my $txt (@sections) {
 317                 if ($txt =~ /\A>/) {
 318                         index_text($self, $txt, 0, 'XQUOT');
 319                 } else {
 320                         # does it look like a diff?
 321                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 322                                 index_diff($self, $txt, $doc);
 323                         } else {
 324                                 index_text($self, $txt, 1, 'XNQ');
 325                         }
 326                 }
 327                 undef $txt; # free memory
 328         }
 329 }
 330
 331 sub index_ids ($$$$) {
 332         my ($self, $doc, $hdr, $mids) = @_;
 333         for my $mid (@$mids) {
 334                 index_text($self, $mid, 1, 'XM');
 335
 336                 # because too many Message-IDs are prefixed with
 337                 # "Pine.LNX."...
 338                 if ($mid =~ /\w{12,}/) {
 339                         my @long = ($mid =~ /(\w{3,}+)/g);
 340                         index_text($self, join(' ', @long), 1, 'XM');
 341                 }
 342         }
 343         $doc->add_boolean_term('Q' . $_) for @$mids;
 344         for my $l ($hdr->header_raw('List-Id')) {
 345                 $l =~ /<([^>]+)>/ or next;
 346                 my $lid = $1;
 347                 $doc->add_boolean_term('G' . $lid);
 348                 index_text($self, $lid, 1, 'XL'); # probabilistic
 349         }
 350 }
 351
 352 sub add_xapian ($$$$) {
 353         my ($self, $mime, $smsg, $mids) = @_;
 354         my $hdr = $mime->header_obj;
 355         my $doc = $X->{Document}->new;
 356         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 357         my @ds = gmtime($smsg->{ds});
 358         my $yyyymmdd = strftime('%Y%m%d', @ds);
 359         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 360         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 361         add_val($doc, PublicInbox::Search::DT(), $dt);
 362         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 363         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 364
 365         my $tg = term_generator($self);
 366         $tg->set_document($doc);
 367         index_headers($self, $smsg);
 368
 369         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 370         index_ids($self, $doc, $hdr, $mids);
 371         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 372         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 373         my $data = $smsg->to_doc_data;
 374         $doc->set_data($data);
 375         if (my $altid = $self->{-altid}) {
 376                 foreach my $alt (@$altid) {
 377                         my $pfx = $alt->{xprefix};
 378                         foreach my $mid (@$mids) {
 379                                 my $id = $alt->mid2alt($mid);
 380                                 next unless defined $id;
 381                                 $doc->add_boolean_term($pfx . $id);
 382                         }
 383                 }
 384         }
 385         $self->{xdb}->replace_document($smsg->{num}, $doc);
 386 }
 387
 388 sub _msgmap_init ($) {
 389         my ($self) = @_;
 390         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 391         $self->{mm} //= eval {
 392                 require PublicInbox::Msgmap;
 393                 my $rw = $self->{ibx}->{-no_sync} ? 2 : 1;
 394                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 395         };
 396 }
 397
 398 sub add_message {
 399         # mime = PublicInbox::Eml or Email::MIME object
 400         my ($self, $mime, $smsg, $sync) = @_;
 401         my $hdr = $mime->header_obj;
 402         my $mids = mids_for_index($hdr);
 403         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 404         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 405         $smsg->{num} //= do { # v1
 406                 _msgmap_init($self);
 407                 index_mm($self, $mime, $smsg->{blob}, $sync);
 408         };
 409
 410         # v1 and tests only:
 411         $smsg->populate($hdr, $sync);
 412         $smsg->{bytes} //= length($mime->as_string);
 413
 414         eval {
 415                 # order matters, overview stores every possible piece of
 416                 # data in doc_data (deflated).  Xapian only stores a subset
 417                 # of the fields which exist in over.sqlite3.  We may stop
 418                 # storing doc_data in Xapian sometime after we get multi-inbox
 419                 # search working.
 420                 if (my $over = $self->{over}) { # v1 only
 421                         $over->add_overview($mime, $smsg);
 422                 }
 423                 if (need_xapian($self)) {
 424                         add_xapian($self, $mime, $smsg, $mids);
 425                 }
 426         };
 427
 428         if ($@) {
 429                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 430                 return undef;
 431         }
 432         $smsg->{num};
 433 }
 434
 435 sub xdb_remove {
 436         my ($self, $oid, @removed) = @_;
 437         my $xdb = $self->{xdb} or return;
 438         for my $num (@removed) {
 439                 my $doc = eval { $xdb->get_document($num) };
 440                 unless ($doc) {
 441                         warn "E: $@\n" if $@;
 442                         warn "E: #$num $oid missing in Xapian\n";
 443                         next;
 444                 }
 445                 my $smsg = bless {}, 'PublicInbox::Smsg';
 446                 $smsg->load_expand($doc);
 447                 my $blob = $smsg->{blob} // '(unset)';
 448                 if ($blob eq $oid) {
 449                         $xdb->delete_document($num);
 450                 } else {
 451                         warn "E: #$num $oid != $blob in Xapian\n";
 452                 }
 453         }
 454 }
 455
 456 sub remove_by_oid {
 457         my ($self, $oid, $num) = @_;
 458         die "BUG: remove_by_oid is v2-only\n" if $self->{over};
 459         $self->begin_txn_lazy;
 460         xdb_remove($self, $oid, $num) if need_xapian($self);
 461 }
 462
 463 sub index_git_blob_id {
 464         my ($doc, $pfx, $objid) = @_;
 465
 466         my $len = length($objid);
 467         for (my $len = length($objid); $len >= 7; ) {
 468                 $doc->add_term($pfx.$objid);
 469                 $objid = substr($objid, 0, --$len);
 470         }
 471 }
 472
 473 # v1 only
 474 sub unindex_eml {
 475         my ($self, $oid, $eml) = @_;
 476         my $mids = mids($eml);
 477         my $nr = 0;
 478         my %tmp;
 479         for my $mid (@$mids) {
 480                 my @removed = eval { $self->{over}->remove_oid($oid, $mid) };
 481                 if ($@) {
 482                         warn "E: failed to remove <$mid> from overview: $@\n";
 483                 } else {
 484                         $nr += scalar @removed;
 485                         $tmp{$_}++ for @removed;
 486                 }
 487         }
 488         if (!$nr) {
 489                 $mids = join('> <', @$mids);
 490                 warn "W: <$mids> missing for removal from overview\n";
 491         }
 492         while (my ($num, $nr) = each %tmp) {
 493                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 494         }
 495         if ($nr) {
 496                 $self->{mm}->num_delete($_) for (keys %tmp);
 497         } else { # just in case msgmap and over.sqlite3 become desynched:
 498                 $self->{mm}->mid_delete($mids->[0]);
 499         }
 500         xdb_remove($self, $oid, keys %tmp) if need_xapian($self);
 501 }
 502
 503 sub index_mm {
 504         my ($self, $mime, $oid, $sync) = @_;
 505         my $mids = mids($mime);
 506         my $mm = $self->{mm};
 507         if ($sync->{reindex}) {
 508                 my $over = $self->{over};
 509                 for my $mid (@$mids) {
 510                         my ($num, undef) = $over->num_mid0_for_oid($oid, $mid);
 511                         return $num if defined $num;
 512                 }
 513                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 514         } else {
 515                 # fallback to num_for since filters like RubyLang set the number
 516                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 517         }
 518 }
 519
 520 # returns the number of bytes to add if given a non-CRLF arg
 521 sub crlf_adjust ($) {
 522         if (index($_[0], "\r\n") < 0) {
 523                 # common case is LF-only, every \n needs an \r;
 524                 # so favor a cheap tr// over an expensive m//g
 525                 $_[0] =~ tr/\n/\n/;
 526         } else { # count number of '\n' w/o '\r', expensive:
 527                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 528         }
 529 }
 530
 531 sub index_both { # git->cat_async callback
 532         my ($bref, $oid, $type, $size, $sync) = @_;
 533         my ($nr, $max) = @$sync{qw(nr max)};
 534         ++$$nr;
 535         $$max -= $size;
 536         $size += crlf_adjust($$bref);
 537         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 538         my $self = $sync->{sidx};
 539         my $eml = PublicInbox::Eml->new($bref);
 540         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 541                 die "E: could not generate NNTP article number for $oid";
 542         add_message($self, $eml, $smsg, $sync);
 543 }
 544
 545 sub unindex_both { # git->cat_async callback
 546         my ($bref, $oid, $type, $size, $self) = @_;
 547         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 548 }
 549
 550 # called by public-inbox-index
 551 sub index_sync {
 552         my ($self, $opts) = @_;
 553         delete $self->{lock_path} if $opts->{-skip_lock};
 554         $self->{ibx}->with_umask(\&_index_sync, $self, $opts);
 555         if ($opts->{reindex}) {
 556                 my %again = %$opts;
 557                 delete @again{qw(rethread reindex)};
 558                 index_sync($self, \%again);
 559         }
 560 }
 561
 562 sub check_size { # check_async cb for -index --max-size=...
 563         my ($oid, $type, $size, $arg, $git) = @_;
 564         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 565         if ($size <= $arg->{index_max_size}) {
 566                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 567         } else {
 568                 warn "W: skipping $oid ($size > $arg->{index_max_size})\n";
 569         }
 570 }
 571
 572 sub v1_checkpoint ($$;$) {
 573         my ($self, $sync, $stk) = @_;
 574         $self->{ibx}->git->check_async_wait;
 575         $self->{ibx}->git->cat_async_wait;
 576
 577         # latest_cmt may be undef
 578         my $newest = $stk ? $stk->{latest_cmt} : undef;
 579         if ($newest) {
 580                 my $cur = $self->{mm}->last_commit || '';
 581                 if (need_update($self, $cur, $newest)) {
 582                         $self->{mm}->last_commit($newest);
 583                 }
 584         } else {
 585                 ${$sync->{max}} = $BATCH_BYTES;
 586         }
 587
 588         $self->{mm}->{dbh}->commit;
 589         if ($newest && need_xapian($self)) {
 590                 my $cur = $self->{xdb}->get_metadata('last_commit');
 591                 if (need_update($self, $cur, $newest)) {
 592                         $self->{xdb}->set_metadata('last_commit', $newest);
 593                 }
 594         }
 595
 596         $self->{over}->rethread_done($sync->{-opt}) if $newest; # all done
 597         commit_txn_lazy($self);
 598         $self->{ibx}->git->cleanup;
 599         my $nr = ${$sync->{nr}};
 600         idx_release($self, $nr);
 601         # let another process do some work...
 602         if (my $pr = $sync->{-opt}->{-progress}) {
 603                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 604         }
 605         if (!$stk) { # more to come
 606                 begin_txn_lazy($self);
 607                 $self->{mm}->{dbh}->begin_work;
 608         }
 609 }
 610
 611 # only for v1
 612 sub process_stack {
 613         my ($self, $sync, $stk) = @_;
 614         my $git = $self->{ibx}->git;
 615         my $max = $BATCH_BYTES;
 616         my $nr = 0;
 617         $sync->{nr} = \$nr;
 618         $sync->{max} = \$max;
 619         $sync->{sidx} = $self;
 620
 621         $self->{mm}->{dbh}->begin_work;
 622         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 623                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 624                 for my $oid (@leftovers) {
 625                         $oid = unpack('H*', $oid);
 626                         $git->cat_async($oid, \&unindex_both, $self);
 627                 }
 628         }
 629         if ($sync->{index_max_size} = $self->{ibx}->{index_max_size}) {
 630                 $sync->{index_oid} = \&index_both;
 631         }
 632         while (my ($f, $at, $ct, $oid) = $stk->pop_rec) {
 633                 if ($f eq 'm') {
 634                         my $arg = { %$sync, autime => $at, cotime => $ct };
 635                         if ($sync->{index_max_size}) {
 636                                 $git->check_async($oid, \&check_size, $arg);
 637                         } else {
 638                                 $git->cat_async($oid, \&index_both, $arg);
 639                         }
 640                         v1_checkpoint($self, $sync) if $max <= 0;
 641                 } elsif ($f eq 'd') {
 642                         $git->cat_async($oid, \&unindex_both, $self);
 643                 }
 644         }
 645         v1_checkpoint($self, $sync, $stk);
 646 }
 647
 648 sub log2stack ($$$$) {
 649         my ($sync, $git, $range, $ibx) = @_;
 650         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 651         my ($add, $del);
 652         if ($ibx->version == 1) {
 653                 my $path = $hex.'{2}/'.$hex.'{38}';
 654                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 655                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 656         } else {
 657                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 658                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 659         }
 660
 661         # Count the new files so they can be added newest to oldest
 662         # and still have numbers increasing from oldest to newest
 663         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 664                                 --no-notes --no-color --no-renames --no-abbrev),
 665                                 $range);
 666         my ($at, $ct, $stk);
 667         while (<$fh>) {
 668                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 669                         ($at, $ct) = ($1 + 0, $2 + 0);
 670                         $stk //= PublicInbox::IdxStack->new($3);
 671                 } elsif (/$del/) {
 672                         my $oid = $1;
 673                         if ($D) { # reindex case
 674                                 $D->{pack('H*', $oid)}++;
 675                         } else { # non-reindex case:
 676                                 $stk->push_rec('d', $at, $ct, $oid);
 677                         }
 678                 } elsif (/$add/) {
 679                         my $oid = $1;
 680                         if ($D) {
 681                                 my $oid_bin = pack('H*', $oid);
 682                                 my $nr = --$D->{$oid_bin};
 683                                 delete($D->{$oid_bin}) if $nr <= 0;
 684
 685                                 # nr < 0 (-1) means it never existed
 686                                 $stk->push_rec('m', $at, $ct, $oid) if $nr < 0;
 687                         } else {
 688                                 $stk->push_rec('m', $at, $ct, $oid);
 689                         }
 690                 }
 691         }
 692         close $fh or die "git log failed: \$?=$?";
 693         $stk //= PublicInbox::IdxStack->new;
 694         $stk->read_prepare;
 695 }
 696
 697 sub prepare_stack ($$$) {
 698         my ($self, $sync, $range) = @_;
 699         my $git = $self->{ibx}->git;
 700
 701         if (index($range, '..') < 0) {
 702                 # don't show annoying git errors to users who run -index
 703                 # on empty inboxes
 704                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 705                 return PublicInbox::IdxStack->new->read_prepare if $?;
 706         }
 707         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 708         log2stack($sync, $git, $range, $self->{ibx});
 709 }
 710
 711 # --is-ancestor requires git 1.8.0+
 712 sub is_ancestor ($$$) {
 713         my ($git, $cur, $tip) = @_;
 714         return 0 unless $git->check($cur);
 715         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 716                 qw(merge-base --is-ancestor), $cur, $tip ];
 717         my $pid = spawn($cmd);
 718         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 719         $? == 0;
 720 }
 721
 722 sub need_update ($$$) {
 723         my ($self, $cur, $new) = @_;
 724         my $git = $self->{ibx}->git;
 725         return 1 if $cur && !is_ancestor($git, $cur, $new);
 726         my $range = $cur eq '' ? $new : "$cur..$new";
 727         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 728         ($n eq '' || $n > 0);
 729 }
 730
 731 # The last git commit we indexed with Xapian or SQLite (msgmap)
 732 # This needs to account for cases where Xapian or SQLite is
 733 # out-of-date with respect to the other.
 734 sub _last_x_commit {
 735         my ($self, $mm) = @_;
 736         my $lm = $mm->last_commit || '';
 737         my $lx = '';
 738         if (need_xapian($self)) {
 739                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 740         } else {
 741                 $lx = $lm;
 742         }
 743         # Use last_commit from msgmap if it is older or unset
 744         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 745                 $lx = $lm;
 746         }
 747         $lx;
 748 }
 749
 750 sub reindex_from ($$) {
 751         my ($reindex, $last_commit) = @_;
 752         return $last_commit unless $reindex;
 753         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 754 }
 755
 756 # indexes all unindexed messages (v1 only)
 757 sub _index_sync {
 758         my ($self, $opts) = @_;
 759         my $tip = $opts->{ref} || 'HEAD';
 760         my $git = $self->{ibx}->git;
 761         $git->batch_prepare;
 762         my $pr = $opts->{-progress};
 763         my $sync = { reindex => $opts->{reindex}, -opt => $opts };
 764         my $xdb = $self->begin_txn_lazy;
 765         $self->{over}->rethread_prepare($opts);
 766         my $mm = _msgmap_init($self);
 767         if ($sync->{reindex}) {
 768                 my $last = $mm->last_commit;
 769                 if ($last) {
 770                         $tip = $last;
 771                 } else {
 772                         # somebody just blindly added --reindex when indexing
 773                         # for the first time, allow it:
 774                         undef $sync->{reindex};
 775                 }
 776         }
 777         my $last_commit = _last_x_commit($self, $mm);
 778         my $lx = reindex_from($sync->{reindex}, $last_commit);
 779         my $range = $lx eq '' ? $tip : "$lx..$tip";
 780         $pr->("counting changes\n\t$range ... ") if $pr;
 781         my $stk = prepare_stack($self, $sync, $range);
 782         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 783         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 784         process_stack($self, $sync, $stk);
 785 }
 786
 787 sub DESTROY {
 788         # order matters for unlocking
 789         $_[0]->{xdb} = undef;
 790         $_[0]->{lockfh} = undef;
 791 }
 792
 793 # remote_* subs are only used by SearchIdxPart
 794 sub remote_commit {
 795         my ($self) = @_;
 796         if (my $w = $self->{w}) {
 797                 print $w "commit\n" or die "failed to write commit: $!";
 798         } else {
 799                 $self->commit_txn_lazy;
 800         }
 801 }
 802
 803 sub remote_close {
 804         my ($self) = @_;
 805         if (my $w = delete $self->{w}) {
 806                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 807                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 808                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 809                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 810                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 811         } else {
 812                 die "transaction in progress $self\n" if $self->{txn};
 813                 idx_release($self) if $self->{xdb};
 814         }
 815 }
 816
 817 sub remote_remove {
 818         my ($self, $oid, $num) = @_;
 819         if (my $w = $self->{w}) {
 820                 # triggers remove_by_oid in a shard
 821                 print $w "D $oid $num\n" or die "failed to write remove $!";
 822         } else {
 823                 $self->remove_by_oid($oid, $num);
 824         }
 825 }
 826
 827 sub _begin_txn {
 828         my ($self) = @_;
 829         my $xdb = $self->{xdb} || idx_acquire($self);
 830         $self->{over}->begin_lazy if $self->{over};
 831         $xdb->begin_transaction if $xdb;
 832         $self->{txn} = 1;
 833         $xdb;
 834 }
 835
 836 sub begin_txn_lazy {
 837         my ($self) = @_;
 838         $self->{ibx}->with_umask(\&_begin_txn, $self) if !$self->{txn};
 839 }
 840
 841 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 842 # This metadata is read by Admin::detect_indexlevel:
 843 sub set_indexlevel {
 844         my ($self) = @_;
 845
 846         if (!$self->{shard} && # undef or 0, not >0
 847                         delete($self->{-set_indexlevel_once})) {
 848                 my $xdb = $self->{xdb};
 849                 my $level = $xdb->get_metadata('indexlevel');
 850                 if (!$level || $level ne 'medium') {
 851                         $xdb->set_metadata('indexlevel', 'medium');
 852                 }
 853         }
 854 }
 855
 856 sub _commit_txn {
 857         my ($self) = @_;
 858         if (my $xdb = $self->{xdb}) {
 859                 set_indexlevel($self);
 860                 $xdb->commit_transaction;
 861         }
 862         $self->{over}->commit_lazy if $self->{over};
 863 }
 864
 865 sub commit_txn_lazy {
 866         my ($self) = @_;
 867         delete($self->{txn}) and
 868                 $self->{ibx}->with_umask(\&_commit_txn, $self);
 869 }
 870
 871 sub worker_done {
 872         my ($self) = @_;
 873         if (need_xapian($self)) {
 874                 die "$$ $0 xdb not released\n" if $self->{xdb};
 875         }
 876         die "$$ $0 still in transaction\n" if $self->{txn};
 877 }
 878
 879 1;