lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::OverIdx;
  22 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  23 use PublicInbox::Git qw(git_unquote);
  24 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  25 our @EXPORT_OK = qw(crlf_adjust log2stack is_ancestor check_size);
  26 my $X = \%PublicInbox::Search::X;
  27 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  28 our $DB_NO_SYNC = 0;
  29 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  30 use constant DEBUG => !!$ENV{DEBUG};
  31
  32 my $xapianlevels = qr/\A(?:full|medium)\z/;
  33 my $hex = '[a-f0-9]';
  34 my $OID = $hex .'{40,}';
  35 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  36
  37 sub new {
  38         my ($class, $ibx, $creat, $shard) = @_;
  39         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  40         my $inboxdir = $ibx->{inboxdir};
  41         my $version = $ibx->version;
  42         my $indexlevel = 'full';
  43         my $altid = $ibx->{altid};
  44         if ($altid) {
  45                 require PublicInbox::AltId;
  46                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  47         }
  48         if ($ibx->{indexlevel}) {
  49                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  50                         $indexlevel = $ibx->{indexlevel};
  51                 } else {
  52                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  53                 }
  54         }
  55         $ibx = PublicInbox::InboxWritable->new($ibx);
  56         my $self = bless {
  57                 ibx => $ibx,
  58                 xpfx => $inboxdir, # for xpfx_init
  59                 -altid => $altid,
  60                 ibx_ver => $version,
  61                 indexlevel => $indexlevel,
  62         }, $class;
  63         $self->xpfx_init;
  64         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  65         if ($ibx->{-skip_docdata}) {
  66                 $self->{-set_skip_docdata_once} = 1;
  67                 $self->{-skip_docdata} = 1;
  68         }
  69         $ibx->umask_prepare;
  70         if ($version == 1) {
  71                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  72                 my $dir = $self->xdir;
  73                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  74                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  75         } elsif ($version == 2) {
  76                 defined $shard or die "shard is required for v2\n";
  77                 # shard is a number
  78                 $self->{shard} = $shard;
  79                 $self->{lock_path} = undef;
  80         } else {
  81                 die "unsupported inbox version=$version\n";
  82         }
  83         $self->{creat} = ($creat || 0) == 1;
  84         $self;
  85 }
  86
  87 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  88
  89 sub idx_release {
  90         my ($self, $wake) = @_;
  91         if (need_xapian($self)) {
  92                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  93                 $xdb->close;
  94         }
  95         $self->lock_release($wake) if $self->{creat};
  96         undef;
  97 }
  98
  99 sub load_xapian_writable () {
 100         return 1 if $X->{WritableDatabase};
 101         PublicInbox::Search::load_xapian() or return;
 102         my $xap = $PublicInbox::Search::Xap;
 103         for (qw(Document TermGenerator WritableDatabase)) {
 104                 $X->{$_} = $xap.'::'.$_;
 105         }
 106         eval 'require '.$X->{WritableDatabase} or die;
 107         *sortable_serialise = $xap.'::sortable_serialise';
 108         *sortable_unserialise = $xap.'::sortable_unserialise';
 109         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 110         $DB_OPEN = eval($xap.'::DB_OPEN()');
 111         my $ver = (eval($xap.'::major_version()') << 16) |
 112                 (eval($xap.'::minor_version()') << 8);
 113         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 114         1;
 115 }
 116
 117 sub idx_acquire {
 118         my ($self) = @_;
 119         my $flag;
 120         my $dir = $self->xdir;
 121         if (need_xapian($self)) {
 122                 croak 'already acquired' if $self->{xdb};
 123                 load_xapian_writable();
 124                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 125         }
 126         if ($self->{creat}) {
 127                 require File::Path;
 128                 $self->lock_acquire;
 129
 130                 # don't create empty Xapian directories if we don't need Xapian
 131                 my $is_shard = defined($self->{shard});
 132                 if (!-d $dir && (!$is_shard ||
 133                                 ($is_shard && need_xapian($self)))) {
 134                         File::Path::mkpath($dir);
 135                         nodatacow_dir($dir);
 136                         $self->{-set_has_threadid_once} = 1;
 137                 }
 138         }
 139         return unless defined $flag;
 140         $flag |= $DB_NO_SYNC if $self->{ibx}->{-no_fsync};
 141         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 142         croak "Failed opening $dir: $@" if $@;
 143         $self->{xdb} = $xdb;
 144 }
 145
 146 sub add_val ($$$) {
 147         my ($doc, $col, $num) = @_;
 148         $num = sortable_serialise($num);
 149         $doc->add_value($col, $num);
 150 }
 151
 152 sub term_generator ($) { # write-only
 153         my ($self) = @_;
 154
 155         $self->{term_generator} //= do {
 156                 my $tg = $X->{TermGenerator}->new;
 157                 $tg->set_stemmer($self->stemmer);
 158                 $tg;
 159         }
 160 }
 161
 162 sub index_text ($$$$) {
 163         my ($self, $text, $wdf_inc, $prefix) = @_;
 164         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 165
 166         if ($self->{indexlevel} eq 'full') {
 167                 $tg->index_text($text, $wdf_inc, $prefix);
 168                 $tg->increase_termpos;
 169         } else {
 170                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 171         }
 172 }
 173
 174 sub index_headers ($$) {
 175         my ($self, $smsg) = @_;
 176         my @x = (from => 'A', # Author
 177                 subject => 'S', to => 'XTO', cc => 'XCC');
 178         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 179                 my $val = $smsg->{$field};
 180                 index_text($self, $val, 1, $pfx) if $val ne '';
 181         }
 182 }
 183
 184 sub index_diff_inc ($$$$) {
 185         my ($self, $text, $pfx, $xnq) = @_;
 186         if (@$xnq) {
 187                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 188                 @$xnq = ();
 189         }
 190         index_text($self, $text, 1, $pfx);
 191 }
 192
 193 sub index_old_diff_fn {
 194         my ($self, $seen, $fa, $fb, $xnq) = @_;
 195
 196         # no renames or space support for traditional diffs,
 197         # find the number of leading common paths to strip:
 198         my @fa = split('/', $fa);
 199         my @fb = split('/', $fb);
 200         while (scalar(@fa) && scalar(@fb)) {
 201                 $fa = join('/', @fa);
 202                 $fb = join('/', @fb);
 203                 if ($fa eq $fb) {
 204                         unless ($seen->{$fa}++) {
 205                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 206                         }
 207                         return 1;
 208                 }
 209                 shift @fa;
 210                 shift @fb;
 211         }
 212         0;
 213 }
 214
 215 sub index_diff ($$$) {
 216         my ($self, $txt, $doc) = @_;
 217         my %seen;
 218         my $in_diff;
 219         my @xnq;
 220         my $xnq = \@xnq;
 221         foreach (split(/\n/, $txt)) {
 222                 if ($in_diff && s/^ //) { # diff context
 223                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 224                 } elsif (/^-- $/) { # email signature begins
 225                         $in_diff = undef;
 226                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 227                         # wait until "---" and "+++" to capture filenames
 228                         $in_diff = 1;
 229                 # traditional diff:
 230                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 231                         my ($opt, $fa, $fb) = ($1, $2, $3);
 232                         push @xnq, $_;
 233                         # only support unified:
 234                         next unless $opt =~ /[uU]/;
 235                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 236                                                         $xnq);
 237                 } elsif (m!^--- ("?[^/]+/.+)!) {
 238                         my $fn = $1;
 239                         $fn = (split('/', git_unquote($fn), 2))[1];
 240                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 241                         $in_diff = 1;
 242                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 243                         my $fn = $1;
 244                         $fn = (split('/', git_unquote($fn), 2))[1];
 245                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 246                         $in_diff = 1;
 247                 } elsif (/^--- (\S+)/) {
 248                         $in_diff = $1;
 249                         push @xnq, $_;
 250                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 251                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 252                                                         $1, $xnq);
 253                 } elsif ($in_diff && s/^\+//) { # diff added
 254                         index_diff_inc($self, $_, 'XDFB', $xnq);
 255                 } elsif ($in_diff && s/^-//) { # diff removed
 256                         index_diff_inc($self, $_, 'XDFA', $xnq);
 257                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 258                         my ($ba, $bb) = ($1, $2);
 259                         index_git_blob_id($doc, 'XDFPRE', $ba);
 260                         index_git_blob_id($doc, 'XDFPOST', $bb);
 261                         $in_diff = 1;
 262                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 263                         # traditional diff w/o -p
 264                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 265                         # hunk header context
 266                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 267                 # ignore the following lines:
 268                 } elsif (/^(?:dis)similarity index/ ||
 269                                 /^(?:old|new) mode/ ||
 270                                 /^(?:deleted|new) file mode/ ||
 271                                 /^(?:copy|rename) (?:from|to) / ||
 272                                 /^(?:dis)?similarity index / ||
 273                                 /^\\ No newline at end of file/ ||
 274                                 /^Binary files .* differ/) {
 275                         push @xnq, $_;
 276                 } elsif ($_ eq '') {
 277                         # possible to be in diff context, some mail may be
 278                         # stripped by MUA or even GNU diff(1).  "git apply"
 279                         # treats a bare "\n" as diff context, too
 280                 } else {
 281                         push @xnq, $_;
 282                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 283                         $in_diff = undef;
 284                 }
 285         }
 286
 287         index_text($self, join("\n", @xnq), 1, 'XNQ');
 288 }
 289
 290 sub index_xapian { # msg_iter callback
 291         my $part = $_[0]->[0]; # ignore $depth and $idx
 292         my ($self, $doc) = @{$_[1]};
 293         my $ct = $part->content_type || 'text/plain';
 294         my $fn = $part->filename;
 295         if (defined $fn && $fn ne '') {
 296                 index_text($self, $fn, 1, 'XFN');
 297         }
 298         if ($part->{is_submsg}) {
 299                 my $mids = mids_for_index($part);
 300                 index_ids($self, $doc, $part, $mids);
 301                 my $smsg = bless {}, 'PublicInbox::Smsg';
 302                 $smsg->populate($part);
 303                 index_headers($self, $smsg);
 304         }
 305
 306         my ($s, undef) = msg_part_text($part, $ct);
 307         defined $s or return;
 308         $_[0]->[0] = $part = undef; # free memory
 309
 310         # split off quoted and unquoted blocks:
 311         my @sections = PublicInbox::MsgIter::split_quotes($s);
 312         undef $s; # free memory
 313         for my $txt (@sections) {
 314                 if ($txt =~ /\A>/) {
 315                         index_text($self, $txt, 0, 'XQUOT');
 316                 } else {
 317                         # does it look like a diff?
 318                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 319                                 index_diff($self, $txt, $doc);
 320                         } else {
 321                                 index_text($self, $txt, 1, 'XNQ');
 322                         }
 323                 }
 324                 undef $txt; # free memory
 325         }
 326 }
 327
 328 sub index_list_id ($$$) {
 329         my ($self, $doc, $hdr) = @_;
 330         for my $l ($hdr->header_raw('List-Id')) {
 331                 $l =~ /<([^>]+)>/ or next;
 332                 my $lid = lc $1;
 333                 $doc->add_boolean_term('G' . $lid);
 334                 index_text($self, $lid, 1, 'XL'); # probabilistic
 335         }
 336 }
 337
 338 sub index_ids ($$$$) {
 339         my ($self, $doc, $hdr, $mids) = @_;
 340         for my $mid (@$mids) {
 341                 index_text($self, $mid, 1, 'XM');
 342
 343                 # because too many Message-IDs are prefixed with
 344                 # "Pine.LNX."...
 345                 if ($mid =~ /\w{12,}/) {
 346                         my @long = ($mid =~ /(\w{3,}+)/g);
 347                         index_text($self, join(' ', @long), 1, 'XM');
 348                 }
 349         }
 350         $doc->add_boolean_term('Q' . $_) for @$mids;
 351         index_list_id($self, $doc, $hdr);
 352 }
 353
 354 sub add_xapian ($$$$) {
 355         my ($self, $eml, $smsg, $mids) = @_;
 356         my $doc = $X->{Document}->new;
 357         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 358         my @ds = gmtime($smsg->{ds});
 359         my $yyyymmdd = strftime('%Y%m%d', @ds);
 360         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 361         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 362         add_val($doc, PublicInbox::Search::DT(), $dt);
 363         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 364         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 365         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 366
 367         my $tg = term_generator($self);
 368         $tg->set_document($doc);
 369         index_headers($self, $smsg);
 370
 371         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 372                 $doc->add_boolean_term('P'.
 373                                 "$eidx_key:$smsg->{num}:$smsg->{blob}");
 374         }
 375         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 376         index_ids($self, $doc, $eml, $mids);
 377
 378         # by default, we maintain compatibility with v1.5.0 and earlier
 379         # by writing to docdata.glass, users who never exect to downgrade can
 380         # use --skip-docdata
 381         if (!$self->{-skip_docdata}) {
 382                 # WWW doesn't need {to} or {cc}, only NNTP
 383                 $smsg->{to} = $smsg->{cc} = '';
 384                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 385                 my $data = $smsg->to_doc_data;
 386                 $doc->set_data($data);
 387         }
 388
 389         if (my $altid = $self->{-altid}) {
 390                 foreach my $alt (@$altid) {
 391                         my $pfx = $alt->{xprefix};
 392                         foreach my $mid (@$mids) {
 393                                 my $id = $alt->mid2alt($mid);
 394                                 next unless defined $id;
 395                                 $doc->add_boolean_term($pfx . $id);
 396                         }
 397                 }
 398         }
 399         $self->{xdb}->replace_document($smsg->{num}, $doc);
 400 }
 401
 402 sub _msgmap_init ($) {
 403         my ($self) = @_;
 404         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 405         $self->{mm} //= eval {
 406                 require PublicInbox::Msgmap;
 407                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 408                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 409         };
 410 }
 411
 412 sub add_message {
 413         # mime = PublicInbox::Eml or Email::MIME object
 414         my ($self, $mime, $smsg, $sync) = @_;
 415         my $mids = mids_for_index($mime);
 416         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 417         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 418         $smsg->{num} //= do { # v1
 419                 _msgmap_init($self);
 420                 index_mm($self, $mime, $smsg->{blob}, $sync);
 421         };
 422
 423         # v1 and tests only:
 424         $smsg->populate($mime, $sync);
 425         $smsg->{bytes} //= length($mime->as_string);
 426
 427         eval {
 428                 # order matters, overview stores every possible piece of
 429                 # data in doc_data (deflated).  Xapian only stores a subset
 430                 # of the fields which exist in over.sqlite3.  We may stop
 431                 # storing doc_data in Xapian sometime after we get multi-inbox
 432                 # search working.
 433                 if (my $oidx = $self->{oidx}) { # v1 only
 434                         $oidx->add_overview($mime, $smsg);
 435                 }
 436                 if (need_xapian($self)) {
 437                         add_xapian($self, $mime, $smsg, $mids);
 438                 }
 439         };
 440
 441         if ($@) {
 442                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 443                 return undef;
 444         }
 445         $smsg->{num};
 446 }
 447
 448 sub _get_doc ($$$) {
 449         my ($self, $docid, $oid) = @_;
 450         my $doc = eval { $self->{xdb}->get_document($docid) };
 451         $doc // do {
 452                 warn "E: $@\n" if $@;
 453                 warn "E: #$docid $oid missing in Xapian\n";
 454                 undef;
 455         }
 456 }
 457
 458 sub add_xref3 {
 459         my ($self, $docid, $xnum, $oid, $eidx_key, $eml) = @_;
 460         begin_txn_lazy($self);
 461         my $doc = _get_doc($self, $docid, $oid) or return;
 462         term_generator($self)->set_document($doc);
 463         $doc->add_boolean_term('P'."$eidx_key:$xnum:$oid");
 464         index_list_id($self, $doc, $eml);
 465         $self->{xdb}->replace_document($docid, $doc);
 466 }
 467
 468 sub remove_xref3 {
 469         my ($self, $docid, $oid, $eidx_key, $eml) = @_;
 470         begin_txn_lazy($self);
 471         my $doc = _get_doc($self, $docid, $oid) or return;
 472         my $xref3 = PublicInbox::Smsg::xref3(undef, $doc);
 473         for (grep(/\A\Q$eidx_key\E:[0-9]+:\Q$oid\E\z/, @$xref3)) {
 474                 $doc->remove_term('P' . $_);
 475         }
 476         for my $l ($eml->header_raw('List-Id')) {
 477                 $l =~ /<([^>]+)>/ or next;
 478                 my $lid = lc $1;
 479                 $doc->remove_term('G' . $lid);
 480
 481                 # nb: we don't remove the XL probabilistic terms
 482                 # since terms may overlap if cross-posted.
 483                 #
 484                 # IOW, a message which has both <foo.example.com>
 485                 # and <bar.example.com> would have overlapping
 486                 # "XLexample" and "XLcom" as terms and which we
 487                 # wouldn't know if they're safe to remove if we just
 488                 # unindex <foo.example.com> while preserving
 489                 # <bar.example.com>.
 490                 #
 491                 # In any case, this entire sub is will likely never
 492                 # be needed and users using the "l:" prefix are probably
 493                 # rarer.
 494         }
 495         $self->{xdb}->replace_document($docid, $doc);
 496 }
 497
 498 sub get_val ($$) {
 499         my ($doc, $col) = @_;
 500         sortable_unserialise($doc->get_value($col));
 501 }
 502
 503 sub smsg_from_doc ($) {
 504         my ($doc) = @_;
 505         my $data = $doc->get_data or return;
 506         my $smsg = bless {}, 'PublicInbox::Smsg';
 507         $smsg->{ts} = get_val($doc, PublicInbox::Search::TS());
 508         my $dt = get_val($doc, PublicInbox::Search::DT());
 509         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
 510         $smsg->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
 511         $smsg->load_from_data($data);
 512         $smsg;
 513 }
 514
 515 sub xdb_remove {
 516         my ($self, $oid, @removed) = @_;
 517         my $xdb = $self->{xdb} or return;
 518         for my $num (@removed) {
 519                 my $doc = _get_doc($self, $num, $oid) or next;
 520                 my $smsg = smsg_from_doc($doc);
 521                 my $blob = $smsg->{blob}; # may be undef if --skip-docdata
 522                 if (!defined($blob) || $blob eq $oid) {
 523                         $xdb->delete_document($num);
 524                 } else {
 525                         warn "E: #$num $oid != $blob in Xapian\n";
 526                 }
 527         }
 528 }
 529
 530 sub remove_by_oid {
 531         my ($self, $oid, $num) = @_;
 532         die "BUG: remove_by_oid is v2-only\n" if $self->{oidx};
 533         $self->begin_txn_lazy;
 534         xdb_remove($self, $oid, $num) if need_xapian($self);
 535 }
 536
 537 sub index_git_blob_id {
 538         my ($doc, $pfx, $objid) = @_;
 539
 540         my $len = length($objid);
 541         for (my $len = length($objid); $len >= 7; ) {
 542                 $doc->add_term($pfx.$objid);
 543                 $objid = substr($objid, 0, --$len);
 544         }
 545 }
 546
 547 # v1 only
 548 sub unindex_eml {
 549         my ($self, $oid, $eml) = @_;
 550         my $mids = mids($eml);
 551         my $nr = 0;
 552         my %tmp;
 553         for my $mid (@$mids) {
 554                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 555                 $nr += scalar @removed;
 556                 $tmp{$_}++ for @removed;
 557         }
 558         if (!$nr) {
 559                 $mids = join('> <', @$mids);
 560                 warn "W: <$mids> missing for removal from overview\n";
 561         }
 562         while (my ($num, $nr) = each %tmp) {
 563                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 564         }
 565         if ($nr) {
 566                 $self->{mm}->num_delete($_) for (keys %tmp);
 567         } else { # just in case msgmap and over.sqlite3 become desynched:
 568                 $self->{mm}->mid_delete($mids->[0]);
 569         }
 570         xdb_remove($self, $oid, keys %tmp) if need_xapian($self);
 571 }
 572
 573 sub index_mm {
 574         my ($self, $mime, $oid, $sync) = @_;
 575         my $mids = mids($mime);
 576         my $mm = $self->{mm};
 577         if ($sync->{reindex}) {
 578                 my $oidx = $self->{oidx};
 579                 for my $mid (@$mids) {
 580                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 581                         return $num if defined $num;
 582                 }
 583                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 584         } else {
 585                 # fallback to num_for since filters like RubyLang set the number
 586                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 587         }
 588 }
 589
 590 # returns the number of bytes to add if given a non-CRLF arg
 591 sub crlf_adjust ($) {
 592         if (index($_[0], "\r\n") < 0) {
 593                 # common case is LF-only, every \n needs an \r;
 594                 # so favor a cheap tr// over an expensive m//g
 595                 $_[0] =~ tr/\n/\n/;
 596         } else { # count number of '\n' w/o '\r', expensive:
 597                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 598         }
 599 }
 600
 601 sub index_both { # git->cat_async callback
 602         my ($bref, $oid, $type, $size, $sync) = @_;
 603         my ($nr, $max) = @$sync{qw(nr max)};
 604         ++$$nr;
 605         $$max -= $size;
 606         $size += crlf_adjust($$bref);
 607         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 608         my $self = $sync->{sidx};
 609         my $eml = PublicInbox::Eml->new($bref);
 610         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 611                 die "E: could not generate NNTP article number for $oid";
 612         add_message($self, $eml, $smsg, $sync);
 613 }
 614
 615 sub unindex_both { # git->cat_async callback
 616         my ($bref, $oid, $type, $size, $self) = @_;
 617         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 618 }
 619
 620 # called by public-inbox-index
 621 sub index_sync {
 622         my ($self, $opt) = @_;
 623         delete $self->{lock_path} if $opt->{-skip_lock};
 624         $self->{ibx}->with_umask(\&_index_sync, $self, $opt);
 625         if ($opt->{reindex}) {
 626                 my %again = %$opt;
 627                 delete @again{qw(rethread reindex)};
 628                 index_sync($self, \%again);
 629         }
 630 }
 631
 632 sub check_size { # check_async cb for -index --max-size=...
 633         my ($oid, $type, $size, $arg, $git) = @_;
 634         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 635         if ($size <= $arg->{max_size}) {
 636                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 637         } else {
 638                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 639         }
 640 }
 641
 642 sub v1_checkpoint ($$;$) {
 643         my ($self, $sync, $stk) = @_;
 644         $self->{ibx}->git->async_wait_all;
 645
 646         # latest_cmt may be undef
 647         my $newest = $stk ? $stk->{latest_cmt} : undef;
 648         if ($newest) {
 649                 my $cur = $self->{mm}->last_commit || '';
 650                 if (need_update($self, $cur, $newest)) {
 651                         $self->{mm}->last_commit($newest);
 652                 }
 653         } else {
 654                 ${$sync->{max}} = $self->{batch_bytes};
 655         }
 656
 657         $self->{mm}->{dbh}->commit;
 658         if ($newest && need_xapian($self)) {
 659                 my $xdb = $self->{xdb};
 660                 my $cur = $xdb->get_metadata('last_commit');
 661                 if (need_update($self, $cur, $newest)) {
 662                         $xdb->set_metadata('last_commit', $newest);
 663                 }
 664
 665                 # let SearchView know a full --reindex was done so it can
 666                 # generate ->has_threadid-dependent links
 667                 if ($sync->{reindex} && !ref($sync->{reindex})) {
 668                         my $n = $xdb->get_metadata('has_threadid');
 669                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 670                 }
 671         }
 672
 673         $self->{oidx}->rethread_done($sync->{-opt}) if $newest; # all done
 674         commit_txn_lazy($self);
 675         $self->{ibx}->git->cleanup;
 676         my $nr = ${$sync->{nr}};
 677         idx_release($self, $nr);
 678         # let another process do some work...
 679         if (my $pr = $sync->{-opt}->{-progress}) {
 680                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 681         }
 682         if (!$stk) { # more to come
 683                 begin_txn_lazy($self);
 684                 $self->{mm}->{dbh}->begin_work;
 685         }
 686 }
 687
 688 # only for v1
 689 sub process_stack {
 690         my ($self, $sync, $stk) = @_;
 691         my $git = $self->{ibx}->git;
 692         my $max = $self->{batch_bytes};
 693         my $nr = 0;
 694         $sync->{nr} = \$nr;
 695         $sync->{max} = \$max;
 696         $sync->{sidx} = $self;
 697
 698         $self->{mm}->{dbh}->begin_work;
 699         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 700                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 701                 for my $oid (@leftovers) {
 702                         $oid = unpack('H*', $oid);
 703                         $git->cat_async($oid, \&unindex_both, $self);
 704                 }
 705         }
 706         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 707                 $sync->{index_oid} = \&index_both;
 708         }
 709         while (my ($f, $at, $ct, $oid) = $stk->pop_rec) {
 710                 if ($f eq 'm') {
 711                         my $arg = { %$sync, autime => $at, cotime => $ct };
 712                         if ($sync->{max_size}) {
 713                                 $git->check_async($oid, \&check_size, $arg);
 714                         } else {
 715                                 $git->cat_async($oid, \&index_both, $arg);
 716                         }
 717                         v1_checkpoint($self, $sync) if $max <= 0;
 718                 } elsif ($f eq 'd') {
 719                         $git->cat_async($oid, \&unindex_both, $self);
 720                 }
 721         }
 722         v1_checkpoint($self, $sync, $stk);
 723 }
 724
 725 sub log2stack ($$$$) {
 726         my ($sync, $git, $range, $ibx) = @_;
 727         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 728         my ($add, $del);
 729         if ($ibx->version == 1) {
 730                 my $path = $hex.'{2}/'.$hex.'{38}';
 731                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 732                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 733         } else {
 734                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 735                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 736         }
 737
 738         # Count the new files so they can be added newest to oldest
 739         # and still have numbers increasing from oldest to newest
 740         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 741                                 --no-notes --no-color --no-renames --no-abbrev),
 742                                 $range);
 743         my ($at, $ct, $stk);
 744         while (<$fh>) {
 745                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 746                         ($at, $ct) = ($1 + 0, $2 + 0);
 747                         $stk //= PublicInbox::IdxStack->new($3);
 748                 } elsif (/$del/) {
 749                         my $oid = $1;
 750                         if ($D) { # reindex case
 751                                 $D->{pack('H*', $oid)}++;
 752                         } else { # non-reindex case:
 753                                 $stk->push_rec('d', $at, $ct, $oid);
 754                         }
 755                 } elsif (/$add/) {
 756                         my $oid = $1;
 757                         if ($D) {
 758                                 my $oid_bin = pack('H*', $oid);
 759                                 my $nr = --$D->{$oid_bin};
 760                                 delete($D->{$oid_bin}) if $nr <= 0;
 761
 762                                 # nr < 0 (-1) means it never existed
 763                                 $stk->push_rec('m', $at, $ct, $oid) if $nr < 0;
 764                         } else {
 765                                 $stk->push_rec('m', $at, $ct, $oid);
 766                         }
 767                 }
 768         }
 769         close $fh or die "git log failed: \$?=$?";
 770         $stk //= PublicInbox::IdxStack->new;
 771         $stk->read_prepare;
 772 }
 773
 774 sub prepare_stack ($$$) {
 775         my ($self, $sync, $range) = @_;
 776         my $git = $self->{ibx}->git;
 777
 778         if (index($range, '..') < 0) {
 779                 # don't show annoying git errors to users who run -index
 780                 # on empty inboxes
 781                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 782                 return PublicInbox::IdxStack->new->read_prepare if $?;
 783         }
 784         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 785         log2stack($sync, $git, $range, $self->{ibx});
 786 }
 787
 788 # --is-ancestor requires git 1.8.0+
 789 sub is_ancestor ($$$) {
 790         my ($git, $cur, $tip) = @_;
 791         return 0 unless $git->check($cur);
 792         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 793                 qw(merge-base --is-ancestor), $cur, $tip ];
 794         my $pid = spawn($cmd);
 795         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 796         $? == 0;
 797 }
 798
 799 sub need_update ($$$) {
 800         my ($self, $cur, $new) = @_;
 801         my $git = $self->{ibx}->git;
 802         return 1 if $cur && !is_ancestor($git, $cur, $new);
 803         my $range = $cur eq '' ? $new : "$cur..$new";
 804         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 805         ($n eq '' || $n > 0);
 806 }
 807
 808 # The last git commit we indexed with Xapian or SQLite (msgmap)
 809 # This needs to account for cases where Xapian or SQLite is
 810 # out-of-date with respect to the other.
 811 sub _last_x_commit {
 812         my ($self, $mm) = @_;
 813         my $lm = $mm->last_commit || '';
 814         my $lx = '';
 815         if (need_xapian($self)) {
 816                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 817         } else {
 818                 $lx = $lm;
 819         }
 820         # Use last_commit from msgmap if it is older or unset
 821         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 822                 $lx = $lm;
 823         }
 824         $lx;
 825 }
 826
 827 sub reindex_from ($$) {
 828         my ($reindex, $last_commit) = @_;
 829         return $last_commit unless $reindex;
 830         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 831 }
 832
 833 # indexes all unindexed messages (v1 only)
 834 sub _index_sync {
 835         my ($self, $opt) = @_;
 836         my $tip = $opt->{ref} || 'HEAD';
 837         my $git = $self->{ibx}->git;
 838         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 839         $git->batch_prepare;
 840         my $pr = $opt->{-progress};
 841         my $sync = { reindex => $opt->{reindex}, -opt => $opt };
 842         my $xdb = $self->begin_txn_lazy;
 843         $self->{oidx}->rethread_prepare($opt);
 844         my $mm = _msgmap_init($self);
 845         if ($sync->{reindex}) {
 846                 my $last = $mm->last_commit;
 847                 if ($last) {
 848                         $tip = $last;
 849                 } else {
 850                         # somebody just blindly added --reindex when indexing
 851                         # for the first time, allow it:
 852                         undef $sync->{reindex};
 853                 }
 854         }
 855         my $last_commit = _last_x_commit($self, $mm);
 856         my $lx = reindex_from($sync->{reindex}, $last_commit);
 857         my $range = $lx eq '' ? $tip : "$lx..$tip";
 858         $pr->("counting changes\n\t$range ... ") if $pr;
 859         my $stk = prepare_stack($self, $sync, $range);
 860         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 861         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 862         process_stack($self, $sync, $stk);
 863 }
 864
 865 sub DESTROY {
 866         # order matters for unlocking
 867         $_[0]->{xdb} = undef;
 868         $_[0]->{lockfh} = undef;
 869 }
 870
 871 sub _begin_txn {
 872         my ($self) = @_;
 873         my $xdb = $self->{xdb} || idx_acquire($self);
 874         $self->{oidx}->begin_lazy if $self->{oidx};
 875         $xdb->begin_transaction if $xdb;
 876         $self->{txn} = 1;
 877         $xdb;
 878 }
 879
 880 sub begin_txn_lazy {
 881         my ($self) = @_;
 882         $self->{ibx}->with_umask(\&_begin_txn, $self) if !$self->{txn};
 883 }
 884
 885 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 886 # This metadata is read by Admin::detect_indexlevel:
 887 sub set_metadata_once {
 888         my ($self) = @_;
 889
 890         return if $self->{shard}; # only continue if undef or 0, not >0
 891         my $xdb = $self->{xdb};
 892
 893         if (delete($self->{-set_has_threadid_once})) {
 894                 $xdb->set_metadata('has_threadid', '1');
 895         }
 896         if (delete($self->{-set_indexlevel_once})) {
 897                 my $level = $xdb->get_metadata('indexlevel');
 898                 if (!$level || $level ne 'medium') {
 899                         $xdb->set_metadata('indexlevel', 'medium');
 900                 }
 901         }
 902         if (delete($self->{-set_skip_docdata_once})) {
 903                 $xdb->get_metadata('skip_docdata') or
 904                         $xdb->set_metadata('skip_docdata', '1');
 905         }
 906 }
 907
 908 sub _commit_txn {
 909         my ($self) = @_;
 910         if (my $xdb = $self->{xdb}) {
 911                 set_metadata_once($self);
 912                 $xdb->commit_transaction;
 913         }
 914         $self->{oidx}->commit_lazy if $self->{oidx};
 915 }
 916
 917 sub commit_txn_lazy {
 918         my ($self) = @_;
 919         delete($self->{txn}) and
 920                 $self->{ibx}->with_umask(\&_commit_txn, $self);
 921 }
 922
 923 sub worker_done {
 924         my ($self) = @_;
 925         if (need_xapian($self)) {
 926                 die "$$ $0 xdb not released\n" if $self->{xdb};
 927         }
 928         die "$$ $0 still in transaction\n" if $self->{txn};
 929 }
 930
 931 1;