lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by Mail::Thread.  This writes to the search
   8 # index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Email::MIME;
  13 use Email::MIME::ContentType;
  14 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  15 use base qw(PublicInbox::Search);
  16 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  17 use PublicInbox::MsgIter;
  18 require PublicInbox::Git;
  19 *xpfx = *PublicInbox::Search::xpfx;
  20
  21 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  22 use constant {
  23         PERM_UMASK => 0,
  24         OLD_PERM_GROUP => 1,
  25         OLD_PERM_EVERYBODY => 2,
  26         PERM_GROUP => 0660,
  27         PERM_EVERYBODY => 0664,
  28 };
  29
  30 sub new {
  31         my ($class, $git_dir, $writable) = @_;
  32         my $dir = $class->xdir($git_dir);
  33         require Search::Xapian::WritableDatabase;
  34         my $flag = Search::Xapian::DB_OPEN;
  35         my $self = bless { git_dir => $git_dir }, $class;
  36         my $perm = $self->_git_config_perm;
  37         my $umask = _umask_for($perm);
  38         $self->{umask} = $umask;
  39         $self->{xdb} = $self->with_umask(sub {
  40                 if ($writable == 1) {
  41                         require File::Path;
  42                         File::Path::mkpath($dir);
  43                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  44                 }
  45                 Search::Xapian::WritableDatabase->new($dir, $flag);
  46         });
  47         $self;
  48 }
  49
  50 sub add_val {
  51         my ($doc, $col, $num) = @_;
  52         $num = Search::Xapian::sortable_serialise($num);
  53         $doc->add_value($col, $num);
  54 }
  55
  56 sub add_message {
  57         my ($self, $mime, $bytes, $num) = @_; # mime = Email::MIME object
  58         my $db = $self->{xdb};
  59
  60         my $doc_id;
  61         my $mid = mid_clean(mid_mime($mime));
  62         my $was_ghost = 0;
  63         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  64
  65         eval {
  66                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
  67                 my $smsg = $self->lookup_message($mid);
  68                 my $doc;
  69
  70                 if ($smsg) {
  71                         $smsg->ensure_metadata;
  72                         # convert a ghost to a regular message
  73                         # it will also clobber any existing regular message
  74                         $smsg->mime($mime);
  75                         $doc = $smsg->{doc};
  76
  77                         my $type = xpfx('type');
  78                         eval {
  79                                 $doc->remove_term($type . 'ghost');
  80                                 $was_ghost = 1;
  81                         };
  82
  83                         # probably does not exist:
  84                         eval { $doc->remove_term($type . 'mail') };
  85                         $doc->add_term($type . 'mail');
  86                 }  else {
  87                         $smsg = PublicInbox::SearchMsg->new($mime);
  88                         $doc = $smsg->{doc};
  89                         $doc->add_term(xpfx('mid') . $mid);
  90                 }
  91
  92                 my $subj = $smsg->subject;
  93
  94                 if ($subj ne '') {
  95                         my $path = $self->subject_path($subj);
  96                         $doc->add_term(xpfx('path') . id_compress($path));
  97                 }
  98
  99                 add_val($doc, &PublicInbox::Search::TS, $smsg->ts);
 100
 101                 defined($num) and
 102                         add_val($doc, &PublicInbox::Search::NUM, $num);
 103
 104                 defined($bytes) and
 105                         add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 106
 107                 add_val($doc, &PublicInbox::Search::LINES,
 108                                 $mime->body_raw =~ tr!\n!\n!);
 109
 110                 my $tg = $self->term_generator;
 111
 112                 $tg->set_document($doc);
 113                 $tg->index_text($subj, 1, 'S') if $subj;
 114                 $tg->increase_termpos;
 115                 $tg->index_text($subj) if $subj;
 116                 $tg->increase_termpos;
 117
 118                 $tg->index_text($smsg->from);
 119                 $tg->increase_termpos;
 120
 121                 msg_iter($mime, sub {
 122                         my ($part, $depth, @idx) = @{$_[0]};
 123                         my $ct = $part->content_type || $ct_msg;
 124
 125                         # account for filter bugs...
 126                         $ct =~ m!\btext/plain\b!i or return;
 127
 128                         my (@orig, @quot);
 129                         my $body = $part->body;
 130                         $part->body_set('');
 131                         my @lines = split(/\n/, $body);
 132                         while (defined(my $l = shift @lines)) {
 133                                 if ($l =~ /^\s*>/) {
 134                                         push @quot, $l;
 135                                 } else {
 136                                         push @orig, $l;
 137                                 }
 138                         }
 139                         if (@quot) {
 140                                 $tg->index_text(join("\n", @quot), 0);
 141                                 @quot = ();
 142                                 $tg->increase_termpos;
 143                         }
 144                         if (@orig) {
 145                                 $tg->index_text(join("\n", @orig));
 146                                 @orig = ();
 147                                 $tg->increase_termpos;
 148                         }
 149                 });
 150
 151                 if ($was_ghost) {
 152                         $doc_id = $smsg->doc_id;
 153                         $self->link_message($smsg);
 154                         $doc->set_data($smsg->to_doc_data);
 155                         $db->replace_document($doc_id, $doc);
 156                 } else {
 157                         $self->link_message($smsg);
 158                         $doc->set_data($smsg->to_doc_data);
 159                         $doc_id = $db->add_document($doc);
 160                 }
 161         };
 162
 163         if ($@) {
 164                 warn "failed to index message <$mid>: $@\n";
 165                 return undef;
 166         }
 167         $doc_id;
 168 }
 169
 170 # returns deleted doc_id on success, undef on missing
 171 sub remove_message {
 172         my ($self, $mid) = @_;
 173         my $db = $self->{xdb};
 174         my $doc_id;
 175         $mid = mid_clean($mid);
 176
 177         eval {
 178                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 179                 $db->delete_document($doc_id) if defined $doc_id;
 180         };
 181
 182         if ($@) {
 183                 warn "failed to remove message <$mid>: $@\n";
 184                 return undef;
 185         }
 186         $doc_id;
 187 }
 188
 189 sub term_generator { # write-only
 190         my ($self) = @_;
 191
 192         my $tg = $self->{term_generator};
 193         return $tg if $tg;
 194
 195         $tg = Search::Xapian::TermGenerator->new;
 196         $tg->set_stemmer($self->stemmer);
 197
 198         $self->{term_generator} = $tg;
 199 }
 200
 201 # increments last_thread_id counter
 202 # returns a 64-bit integer represented as a hex string
 203 sub next_thread_id {
 204         my ($self) = @_;
 205         my $db = $self->{xdb};
 206         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 207
 208         $db->set_metadata('last_thread_id', ++$last_thread_id);
 209
 210         $last_thread_id;
 211 }
 212
 213 sub link_message {
 214         my ($self, $smsg) = @_;
 215         my $doc = $smsg->{doc};
 216         my $mid = $smsg->mid;
 217         my $mime = $smsg->mime;
 218         my $hdr = $mime->header_obj;
 219         my $refs = $hdr->header_raw('References');
 220         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 221         if (my $irt = $hdr->header_raw('In-Reply-To')) {
 222                 # last References should be $irt
 223                 # we will de-dupe later
 224                 push @refs, mid_clean($irt);
 225         }
 226
 227         my $tid;
 228         if (@refs) {
 229                 my %uniq = ($mid => 1);
 230                 my @orig_refs = @refs;
 231                 @refs = ();
 232
 233                 # prevent circular references via References: here:
 234                 foreach my $ref (@orig_refs) {
 235                         if (length($ref) > MAX_MID_SIZE) {
 236                                 warn "References: <$ref> too long, ignoring\n";
 237                         }
 238                         next if $uniq{$ref};
 239                         $uniq{$ref} = 1;
 240                         push @refs, $ref;
 241                 }
 242         }
 243         if (@refs) {
 244                 $smsg->{references} = '<'.join('> <', @refs).'>';
 245
 246                 # first ref *should* be the thread root,
 247                 # but we can never trust clients to do the right thing
 248                 my $ref = shift @refs;
 249                 $tid = $self->_resolve_mid_to_tid($ref);
 250
 251                 # the rest of the refs should point to this tid:
 252                 foreach $ref (@refs) {
 253                         my $ptid = $self->_resolve_mid_to_tid($ref);
 254                         if ($tid ne $ptid) {
 255                                 $self->merge_threads($tid, $ptid);
 256                         }
 257                 }
 258         } else {
 259                 $tid = $self->next_thread_id;
 260         }
 261         $doc->add_term(xpfx('thread') . $tid);
 262 }
 263
 264 sub index_blob {
 265         my ($self, $git, $mime, $bytes, $num) = @_;
 266         $self->add_message($mime, $bytes, $num);
 267 }
 268
 269 sub unindex_blob {
 270         my ($self, $git, $mime) = @_;
 271         my $mid = eval { mid_clean(mid_mime($mime)) };
 272         $self->remove_message($mid) if defined $mid;
 273 }
 274
 275 sub index_mm {
 276         my ($self, $git, $mime) = @_;
 277         $self->{mm}->mid_insert(mid_clean(mid_mime($mime)));
 278 }
 279
 280 sub unindex_mm {
 281         my ($self, $git, $mime) = @_;
 282         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 283 }
 284
 285 sub index_mm2 {
 286         my ($self, $git, $mime, $bytes) = @_;
 287         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 288         index_blob($self, $git, $mime, $bytes, $num);
 289 }
 290
 291 sub unindex_mm2 {
 292         my ($self, $git, $mime) = @_;
 293         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 294         unindex_blob($self, $git, $mime);
 295 }
 296
 297 sub index_both {
 298         my ($self, $git, $mime, $bytes) = @_;
 299         my $num = index_mm($self, $git, $mime);
 300         index_blob($self, $git, $mime, $bytes, $num);
 301 }
 302
 303 sub unindex_both {
 304         my ($self, $git, $mime) = @_;
 305         unindex_blob($self, $git, $mime);
 306         unindex_mm($self, $git, $mime);
 307 }
 308
 309 sub do_cat_mail {
 310         my ($git, $blob, $sizeref) = @_;
 311         my $mime = eval {
 312                 my $str = $git->cat_file($blob, $sizeref);
 313                 Email::MIME->new($str);
 314         };
 315         $@ ? undef : $mime;
 316 }
 317
 318 sub index_sync {
 319         my ($self, $head) = @_;
 320         $self->with_umask(sub { $self->_index_sync($head) });
 321 }
 322
 323 sub rlog {
 324         my ($self, $range, $add_cb, $del_cb) = @_;
 325         my $hex = '[a-f0-9]';
 326         my $h40 = $hex .'{40}';
 327         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 328         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 329         my $git = PublicInbox::Git->new($self->{git_dir});
 330         my $log = $git->popen(qw/log --reverse --no-notes --no-color
 331                                 --raw -r --no-abbrev/, $range);
 332         my $latest;
 333         my $bytes;
 334         local $/ = "\n";
 335         while (defined(my $line = <$log>)) {
 336                 if ($line =~ /$addmsg/o) {
 337                         my $mime = do_cat_mail($git, $1, \$bytes) or next;
 338                         $add_cb->($self, $git, $mime, $bytes);
 339                 } elsif ($line =~ /$delmsg/o) {
 340                         my $mime = do_cat_mail($git, $1) or next;
 341                         $del_cb->($self, $git, $mime);
 342                 } elsif ($line =~ /^commit ($h40)/o) {
 343                         $latest = $1;
 344                 }
 345         }
 346         $latest;
 347 }
 348
 349 # indexes all unindexed messages
 350 sub _index_sync {
 351         my ($self, $head) = @_;
 352         my $db = $self->{xdb};
 353         $head ||= 'HEAD';
 354         my $mm = $self->{mm} = eval {
 355                 require PublicInbox::Msgmap;
 356                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 357         };
 358
 359         $db->begin_transaction;
 360         my $lx = $db->get_metadata('last_commit');
 361         my $range = $lx eq '' ? $head : "$lx..$head";
 362         if ($mm) {
 363                 $mm->{dbh}->begin_work;
 364                 my $lm = $mm->last_commit || '';
 365                 if ($lm eq $lx) {
 366                         # Common case is the indexes are synced,
 367                         # we only need to run git-log once:
 368                         $lx = $self->rlog($range, *index_both, *unindex_both);
 369                         $mm->{dbh}->commit;
 370                         if (defined $lx) {
 371                                 $db->set_metadata('last_commit', $lx);
 372                                 $mm->last_commit($lx);
 373                         }
 374                 } else {
 375                         # dumb case, msgmap and xapian are out-of-sync
 376                         # do not care for performance:
 377                         my $r = $lm eq '' ? $head : "$lm..$head";
 378                         $lm = $self->rlog($r, *index_mm, *unindex_mm);
 379                         $mm->{dbh}->commit;
 380                         $mm->last_commit($lm) if defined $lm;
 381
 382                         $lx = $self->rlog($range, *index_mm2, *unindex_mm2);
 383                         $db->set_metadata('last_commit', $lx) if defined $lx;
 384                 }
 385         } else {
 386                 # user didn't install DBD::SQLite and DBI
 387                 $lx = $self->rlog($range, *index_blob, *unindex_blob);
 388                 $db->set_metadata('last_commit', $lx) if defined $lx;
 389         }
 390         if ($@) {
 391                 $db->cancel_transaction;
 392                 $mm->{dbh}->rollback if $mm;
 393         } else {
 394                 $db->commit_transaction;
 395         }
 396 }
 397
 398 # this will create a ghost as necessary
 399 sub _resolve_mid_to_tid {
 400         my ($self, $mid) = @_;
 401
 402         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 403         $smsg->thread_id;
 404 }
 405
 406 sub create_ghost {
 407         my ($self, $mid) = @_;
 408
 409         my $tid = $self->next_thread_id;
 410         my $doc = Search::Xapian::Document->new;
 411         $doc->add_term(xpfx('mid') . $mid);
 412         $doc->add_term(xpfx('thread') . $tid);
 413         $doc->add_term(xpfx('type') . 'ghost');
 414
 415         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 416         $self->{xdb}->add_document($doc);
 417
 418         $smsg;
 419 }
 420
 421 sub merge_threads {
 422         my ($self, $winner_tid, $loser_tid) = @_;
 423         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 424         my $thread_pfx = xpfx('thread');
 425         my $db = $self->{xdb};
 426
 427         for (; $head != $tail; $head->inc) {
 428                 my $docid = $head->get_docid;
 429                 my $doc = $db->get_document($docid);
 430                 $doc->remove_term($thread_pfx . $loser_tid);
 431                 $doc->add_term($thread_pfx . $winner_tid);
 432                 $db->replace_document($docid, $doc);
 433         }
 434 }
 435
 436 sub _read_git_config_perm {
 437         my ($self) = @_;
 438         my @cmd = qw(config core.sharedRepository);
 439         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 440         local $/ = "\n";
 441         my $perm = <$fh>;
 442         chomp $perm if defined $perm;
 443         $perm;
 444 }
 445
 446 sub _git_config_perm {
 447         my $self = shift;
 448         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 449         return PERM_GROUP if (!defined($perm) || $perm eq '');
 450         return PERM_UMASK if ($perm eq 'umask');
 451         return PERM_GROUP if ($perm eq 'group');
 452         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 453                 return PERM_EVERYBODY;
 454         }
 455         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 456         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 457
 458         my $i = oct($perm);
 459         return PERM_UMASK if ($i == PERM_UMASK);
 460         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 461         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 462
 463         if (($i & 0600) != 0600) {
 464                 die "core.sharedRepository mode invalid: ".
 465                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 466         }
 467         ($i & 0666);
 468 }
 469
 470 sub _umask_for {
 471         my ($perm) = @_; # _git_config_perm return value
 472         my $rv = $perm;
 473         return umask if $rv == 0;
 474
 475         # set +x bit if +r or +w were set
 476         $rv |= 0100 if ($rv & 0600);
 477         $rv |= 0010 if ($rv & 0060);
 478         $rv |= 0001 if ($rv & 0006);
 479         (~$rv & 0777);
 480 }
 481
 482 sub with_umask {
 483         my ($self, $cb) = @_;
 484         my $old = umask $self->{umask};
 485         my $rv = eval { $cb->() };
 486         my $err = $@;
 487         umask $old;
 488         die $err if $@;
 489         $rv;
 490 }
 491
 492 1;