lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by Mail::Thread.  This writes to the search
   8 # index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use Email::MIME;
  14 use Email::MIME::ContentType;
  15 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  16 use base qw(PublicInbox::Search);
  17 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  18 use PublicInbox::MsgIter;
  19 use Carp qw(croak);
  20 use POSIX qw(strftime);
  21 require PublicInbox::Git;
  22 *xpfx = *PublicInbox::Search::xpfx;
  23
  24 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  25 use constant {
  26         PERM_UMASK => 0,
  27         OLD_PERM_GROUP => 1,
  28         OLD_PERM_EVERYBODY => 2,
  29         PERM_GROUP => 0660,
  30         PERM_EVERYBODY => 0664,
  31 };
  32
  33 sub new {
  34         my ($class, $inbox, $creat) = @_;
  35         my $git_dir = $inbox;
  36         my $altid;
  37         if (ref $inbox) {
  38                 $git_dir = $inbox->{mainrepo};
  39                 $altid = $inbox->{altid};
  40                 if ($altid) {
  41                         require PublicInbox::AltId;
  42                         $altid = [ map {
  43                                 PublicInbox::AltId->new($inbox, $_);
  44                         } @$altid ];
  45                 }
  46         }
  47         require Search::Xapian::WritableDatabase;
  48         my $self = bless { git_dir => $git_dir, -altid => $altid }, $class;
  49         my $perm = $self->_git_config_perm;
  50         my $umask = _umask_for($perm);
  51         $self->{umask} = $umask;
  52         $self->{lock_path} = "$git_dir/ssoma.lock";
  53         $self->{git} = PublicInbox::Git->new($git_dir);
  54         $self->{creat} = ($creat || 0) == 1;
  55         $self;
  56 }
  57
  58 sub _xdb_release {
  59         my ($self) = @_;
  60         my $xdb = delete $self->{xdb} or croak 'not acquired';
  61         $xdb->close;
  62         _lock_release($self) if $self->{creat};
  63         undef;
  64 }
  65
  66 sub _xdb_acquire {
  67         my ($self) = @_;
  68         croak 'already acquired' if $self->{xdb};
  69         my $dir = PublicInbox::Search->xdir($self->{git_dir});
  70         my $flag = Search::Xapian::DB_OPEN;
  71         if ($self->{creat}) {
  72                 require File::Path;
  73                 _lock_acquire($self);
  74                 File::Path::mkpath($dir);
  75                 $self->{batch_size} = 100;
  76                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  77         }
  78         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
  79 }
  80
  81 # we only acquire the flock if creating or reindexing;
  82 # PublicInbox::Import already has the lock on its own.
  83 sub _lock_acquire {
  84         my ($self) = @_;
  85         croak 'already locked' if $self->{lockfh};
  86         sysopen(my $lockfh, $self->{lock_path}, O_WRONLY|O_CREAT) or
  87                 die "failed to open lock $self->{lock_path}: $!\n";
  88         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
  89         $self->{lockfh} = $lockfh;
  90 }
  91
  92 sub _lock_release {
  93         my ($self) = @_;
  94         my $lockfh = delete $self->{lockfh} or croak 'not locked';
  95         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
  96         close $lockfh or die "close failed: $!\n";
  97 }
  98
  99 sub add_val ($$$) {
 100         my ($doc, $col, $num) = @_;
 101         $num = Search::Xapian::sortable_serialise($num);
 102         $doc->add_value($col, $num);
 103 }
 104
 105 sub add_values ($$$) {
 106         my ($smsg, $bytes, $num) = @_;
 107
 108         my $ts = $smsg->ts;
 109         my $doc = $smsg->{doc};
 110         add_val($doc, &PublicInbox::Search::TS, $ts);
 111
 112         defined($num) and add_val($doc, &PublicInbox::Search::NUM, $num);
 113
 114         defined($bytes) and add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 115
 116         add_val($doc, &PublicInbox::Search::LINES,
 117                         $smsg->{mime}->body_raw =~ tr!\n!\n!);
 118
 119         my $yyyymmdd = strftime('%Y%m%d', gmtime($ts));
 120         $doc->add_value(&PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 121 }
 122
 123 sub index_users ($$) {
 124         my ($tg, $smsg) = @_;
 125
 126         my $from = $smsg->from;
 127         my $to = $smsg->to;
 128         my $cc = $smsg->cc;
 129
 130         $tg->index_text($from, 1, 'A'); # A - author
 131         $tg->increase_termpos;
 132         $tg->index_text($to, 1, 'XTO') if $to ne '';
 133         $tg->increase_termpos;
 134         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 135         $tg->increase_termpos;
 136 }
 137
 138 sub index_body ($$$) {
 139         my ($tg, $lines, $inc) = @_;
 140         $tg->index_text(join("\n", @$lines), $inc, $inc ? 'XNQ' : 'XQUOT');
 141         @$lines = ();
 142         $tg->increase_termpos;
 143 }
 144
 145 sub add_message {
 146         my ($self, $mime, $bytes, $num, $blob) = @_; # mime = Email::MIME object
 147         my $db = $self->{xdb};
 148
 149         my ($doc_id, $old_tid);
 150         my $mid = mid_clean(mid_mime($mime));
 151         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
 152
 153         eval {
 154                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
 155                 my $smsg = $self->lookup_message($mid);
 156                 if ($smsg) {
 157                         # convert a ghost to a regular message
 158                         # it will also clobber any existing regular message
 159                         $doc_id = $smsg->doc_id;
 160                         $old_tid = $smsg->thread_id;
 161                 }
 162                 $smsg = PublicInbox::SearchMsg->new($mime);
 163                 my $doc = $smsg->{doc};
 164                 $doc->add_term(xpfx('mid') . $mid);
 165
 166                 my $subj = $smsg->subject;
 167                 if ($subj ne '') {
 168                         my $path = $self->subject_path($subj);
 169                         $doc->add_term(xpfx('path') . id_compress($path));
 170                 }
 171
 172                 add_values($smsg, $bytes, $num);
 173
 174                 my $tg = $self->term_generator;
 175
 176                 $tg->set_document($doc);
 177                 $tg->index_text($subj, 1, 'S') if $subj;
 178                 $tg->increase_termpos;
 179
 180                 index_users($tg, $smsg);
 181
 182                 msg_iter($mime, sub {
 183                         my ($part, $depth, @idx) = @{$_[0]};
 184                         my $ct = $part->content_type || $ct_msg;
 185
 186                         # account for filter bugs...
 187                         $ct =~ m!\btext/plain\b!i or return;
 188
 189                         my (@orig, @quot);
 190                         my $body = $part->body;
 191                         $part->body_set('');
 192                         my @lines = split(/\n/, $body);
 193                         while (defined(my $l = shift @lines)) {
 194                                 if ($l =~ /^>/) {
 195                                         index_body($tg, \@orig, 1) if @orig;
 196                                         push @quot, $l;
 197                                 } else {
 198                                         index_body($tg, \@quot, 0) if @quot;
 199                                         push @orig, $l;
 200                                 }
 201                         }
 202                         index_body($tg, \@quot, 0) if @quot;
 203                         index_body($tg, \@orig, 1) if @orig;
 204                 });
 205
 206                 link_message($self, $smsg, $old_tid);
 207                 $tg->index_text($mid, 1, 'XMID');
 208                 $doc->set_data($smsg->to_doc_data($blob));
 209
 210                 if (my $altid = $self->{-altid}) {
 211                         foreach my $alt (@$altid) {
 212                                 my $id = $alt->mid2alt($mid);
 213                                 next unless defined $id;
 214                                 $doc->add_term($alt->{xprefix} . $id);
 215                         }
 216                 }
 217                 if (defined $doc_id) {
 218                         $db->replace_document($doc_id, $doc);
 219                 } else {
 220                         $doc_id = $db->add_document($doc);
 221                 }
 222         };
 223
 224         if ($@) {
 225                 warn "failed to index message <$mid>: $@\n";
 226                 return undef;
 227         }
 228         $doc_id;
 229 }
 230
 231 # returns deleted doc_id on success, undef on missing
 232 sub remove_message {
 233         my ($self, $mid) = @_;
 234         my $db = $self->{xdb};
 235         my $doc_id;
 236         $mid = mid_clean($mid);
 237
 238         eval {
 239                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 240                 $db->delete_document($doc_id) if defined $doc_id;
 241         };
 242
 243         if ($@) {
 244                 warn "failed to remove message <$mid>: $@\n";
 245                 return undef;
 246         }
 247         $doc_id;
 248 }
 249
 250 sub term_generator { # write-only
 251         my ($self) = @_;
 252
 253         my $tg = $self->{term_generator};
 254         return $tg if $tg;
 255
 256         $tg = Search::Xapian::TermGenerator->new;
 257         $tg->set_stemmer($self->stemmer);
 258
 259         $self->{term_generator} = $tg;
 260 }
 261
 262 # increments last_thread_id counter
 263 # returns a 64-bit integer represented as a hex string
 264 sub next_thread_id {
 265         my ($self) = @_;
 266         my $db = $self->{xdb};
 267         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 268
 269         $db->set_metadata('last_thread_id', ++$last_thread_id);
 270
 271         $last_thread_id;
 272 }
 273
 274 sub link_message {
 275         my ($self, $smsg, $old_tid) = @_;
 276         my $doc = $smsg->{doc};
 277         my $mid = $smsg->mid;
 278         my $mime = $smsg->mime;
 279         my $hdr = $mime->header_obj;
 280         my $refs = $hdr->header_raw('References');
 281         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 282         if (my $irt = $hdr->header_raw('In-Reply-To')) {
 283                 # last References should be $irt
 284                 # we will de-dupe later
 285                 push @refs, mid_clean($irt);
 286         }
 287
 288         my $tid;
 289         if (@refs) {
 290                 my %uniq = ($mid => 1);
 291                 my @orig_refs = @refs;
 292                 @refs = ();
 293
 294                 # prevent circular references via References: here:
 295                 foreach my $ref (@orig_refs) {
 296                         if (length($ref) > MAX_MID_SIZE) {
 297                                 warn "References: <$ref> too long, ignoring\n";
 298                         }
 299                         next if $uniq{$ref};
 300                         $uniq{$ref} = 1;
 301                         push @refs, $ref;
 302                 }
 303         }
 304         if (@refs) {
 305                 $smsg->{references} = '<'.join('> <', @refs).'>';
 306
 307                 # first ref *should* be the thread root,
 308                 # but we can never trust clients to do the right thing
 309                 my $ref = shift @refs;
 310                 $tid = $self->_resolve_mid_to_tid($ref);
 311                 $self->merge_threads($tid, $old_tid) if defined $old_tid;
 312
 313                 # the rest of the refs should point to this tid:
 314                 foreach $ref (@refs) {
 315                         my $ptid = $self->_resolve_mid_to_tid($ref);
 316                         merge_threads($self, $tid, $ptid);
 317                 }
 318         } else {
 319                 $tid = $self->next_thread_id;
 320         }
 321         $doc->add_term(xpfx('thread') . $tid);
 322 }
 323
 324 sub index_blob {
 325         my ($self, $mime, $bytes, $num, $blob) = @_;
 326         $self->add_message($mime, $bytes, $num, $blob);
 327 }
 328
 329 sub unindex_blob {
 330         my ($self, $mime) = @_;
 331         my $mid = eval { mid_clean(mid_mime($mime)) };
 332         $self->remove_message($mid) if defined $mid;
 333 }
 334
 335 sub index_mm {
 336         my ($self, $mime) = @_;
 337         $self->{mm}->mid_insert(mid_clean(mid_mime($mime)));
 338 }
 339
 340 sub unindex_mm {
 341         my ($self, $mime) = @_;
 342         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 343 }
 344
 345 sub index_mm2 {
 346         my ($self, $mime, $bytes, $blob) = @_;
 347         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 348         index_blob($self, $mime, $bytes, $num, $blob);
 349 }
 350
 351 sub unindex_mm2 {
 352         my ($self, $mime) = @_;
 353         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 354         unindex_blob($self, $mime);
 355 }
 356
 357 sub index_both {
 358         my ($self, $mime, $bytes, $blob) = @_;
 359         my $num = index_mm($self, $mime);
 360         index_blob($self, $mime, $bytes, $num, $blob);
 361 }
 362
 363 sub unindex_both {
 364         my ($self, $mime) = @_;
 365         unindex_blob($self, $mime);
 366         unindex_mm($self, $mime);
 367 }
 368
 369 sub do_cat_mail {
 370         my ($git, $blob, $sizeref) = @_;
 371         my $mime = eval {
 372                 my $str = $git->cat_file($blob, $sizeref);
 373                 # fixup bugs from import:
 374                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 375                 Email::MIME->new($str);
 376         };
 377         $@ ? undef : $mime;
 378 }
 379
 380 sub index_sync {
 381         my ($self, $opts) = @_;
 382         with_umask($self, sub { $self->_index_sync($opts) });
 383 }
 384
 385 sub rlog {
 386         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 387         my $hex = '[a-f0-9]';
 388         my $h40 = $hex .'{40}';
 389         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 390         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 391         my $git = $self->{git};
 392         my $latest;
 393         my $bytes;
 394         my $max = $self->{batch_size}; # may be undef
 395         local $/ = "\n";
 396         my $line;
 397         while (defined($line = <$log>)) {
 398                 if ($line =~ /$addmsg/o) {
 399                         my $blob = $1;
 400                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 401                         $add_cb->($self, $mime, $bytes, $blob);
 402                 } elsif ($line =~ /$delmsg/o) {
 403                         my $blob = $1;
 404                         my $mime = do_cat_mail($git, $blob) or next;
 405                         $del_cb->($self, $mime);
 406                 } elsif ($line =~ /^commit ($h40)/o) {
 407                         if (defined $max && --$max <= 0) {
 408                                 $max = $self->{batch_size};
 409                                 $batch_cb->($latest, 1);
 410                         }
 411                         $latest = $1;
 412                 }
 413         }
 414         $batch_cb->($latest, 0);
 415 }
 416
 417 sub _msgmap_init {
 418         my ($self) = @_;
 419         $self->{mm} = eval {
 420                 require PublicInbox::Msgmap;
 421                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 422         };
 423 }
 424
 425 sub _git_log {
 426         my ($self, $range) = @_;
 427         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 428                                 --raw -r --no-abbrev/, $range);
 429 }
 430
 431 # indexes all unindexed messages
 432 sub _index_sync {
 433         my ($self, $opts) = @_;
 434         my $tip = $opts->{ref} || 'HEAD';
 435         my $reindex = $opts->{reindex};
 436         my ($mkey, $last_commit, $lx, $xlog);
 437         $self->{git}->batch_prepare;
 438         my $xdb = _xdb_acquire($self);
 439         $xdb->begin_transaction;
 440         do {
 441                 $xlog = undef;
 442                 $mkey = 'last_commit';
 443                 $last_commit = $xdb->get_metadata('last_commit');
 444                 $lx = $last_commit;
 445                 if ($reindex) {
 446                         $lx = '';
 447                         $mkey = undef if $last_commit ne '';
 448                 }
 449                 $xdb->cancel_transaction;
 450                 $xdb = _xdb_release($self);
 451
 452                 # ensure we leak no FDs to "git log"
 453                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 454                 $xlog = _git_log($self, $range);
 455
 456                 $xdb = _xdb_acquire($self);
 457                 $xdb->begin_transaction;
 458         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 459
 460         my $mm = _msgmap_init($self);
 461         my $dbh = $mm->{dbh} if $mm;
 462         my $mm_only;
 463         my $cb = sub {
 464                 my ($commit, $more) = @_;
 465                 if ($dbh) {
 466                         $mm->last_commit($commit) if $commit;
 467                         $dbh->commit;
 468                 }
 469                 if (!$mm_only) {
 470                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 471                         $xdb->commit_transaction;
 472                         $xdb = _xdb_release($self);
 473                 }
 474                 # let another process do some work... <
 475                 if ($more) {
 476                         if (!$mm_only) {
 477                                 $xdb = _xdb_acquire($self);
 478                                 $xdb->begin_transaction;
 479                         }
 480                         $dbh->begin_work if $dbh;
 481                 }
 482         };
 483
 484         if ($mm) {
 485                 $dbh->begin_work;
 486                 my $lm = $mm->last_commit || '';
 487                 if ($lm eq $lx) {
 488                         # Common case is the indexes are synced,
 489                         # we only need to run git-log once:
 490                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 491                 } else {
 492                         # Uncommon case, msgmap and xapian are out-of-sync
 493                         # do not care for performance (but git is fast :>)
 494                         # This happens if we have to reindex Xapian since
 495                         # msgmap is a frozen format and our Xapian format
 496                         # is evolving.
 497                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 498
 499                         # first, ensure msgmap is up-to-date:
 500                         my $mkey_prev = $mkey;
 501                         $mkey = undef; # ignore xapian, for now
 502                         my $mlog = _git_log($self, $r);
 503                         $mm_only = 1;
 504                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 505                         $mm_only = $mlog = undef;
 506
 507                         # now deal with Xapian
 508                         $mkey = $mkey_prev;
 509                         $dbh = undef;
 510                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 511                 }
 512         } else {
 513                 # user didn't install DBD::SQLite and DBI
 514                 rlog($self, $xlog, *index_blob, *unindex_blob, $cb);
 515         }
 516 }
 517
 518 # this will create a ghost as necessary
 519 sub _resolve_mid_to_tid {
 520         my ($self, $mid) = @_;
 521
 522         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 523         $smsg->thread_id;
 524 }
 525
 526 sub create_ghost {
 527         my ($self, $mid) = @_;
 528
 529         my $tid = $self->next_thread_id;
 530         my $doc = Search::Xapian::Document->new;
 531         $doc->add_term(xpfx('mid') . $mid);
 532         $doc->add_term(xpfx('thread') . $tid);
 533         $doc->add_term(xpfx('type') . 'ghost');
 534
 535         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 536         $self->{xdb}->add_document($doc);
 537
 538         $smsg;
 539 }
 540
 541 sub merge_threads {
 542         my ($self, $winner_tid, $loser_tid) = @_;
 543         return if $winner_tid == $loser_tid;
 544         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 545         my $thread_pfx = xpfx('thread');
 546         my $db = $self->{xdb};
 547
 548         for (; $head != $tail; $head->inc) {
 549                 my $docid = $head->get_docid;
 550                 my $doc = $db->get_document($docid);
 551                 $doc->remove_term($thread_pfx . $loser_tid);
 552                 $doc->add_term($thread_pfx . $winner_tid);
 553                 $db->replace_document($docid, $doc);
 554         }
 555 }
 556
 557 sub _read_git_config_perm {
 558         my ($self) = @_;
 559         my @cmd = qw(config core.sharedRepository);
 560         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 561         local $/ = "\n";
 562         my $perm = <$fh>;
 563         chomp $perm if defined $perm;
 564         $perm;
 565 }
 566
 567 sub _git_config_perm {
 568         my $self = shift;
 569         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 570         return PERM_GROUP if (!defined($perm) || $perm eq '');
 571         return PERM_UMASK if ($perm eq 'umask');
 572         return PERM_GROUP if ($perm eq 'group');
 573         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 574                 return PERM_EVERYBODY;
 575         }
 576         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 577         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 578
 579         my $i = oct($perm);
 580         return PERM_UMASK if ($i == PERM_UMASK);
 581         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 582         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 583
 584         if (($i & 0600) != 0600) {
 585                 die "core.sharedRepository mode invalid: ".
 586                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 587         }
 588         ($i & 0666);
 589 }
 590
 591 sub _umask_for {
 592         my ($perm) = @_; # _git_config_perm return value
 593         my $rv = $perm;
 594         return umask if $rv == 0;
 595
 596         # set +x bit if +r or +w were set
 597         $rv |= 0100 if ($rv & 0600);
 598         $rv |= 0010 if ($rv & 0060);
 599         $rv |= 0001 if ($rv & 0006);
 600         (~$rv & 0777);
 601 }
 602
 603 sub with_umask {
 604         my ($self, $cb) = @_;
 605         my $old = umask $self->{umask};
 606         my $rv = eval { $cb->() };
 607         my $err = $@;
 608         umask $old;
 609         die $err if $@;
 610         $rv;
 611 }
 612
 613 sub DESTROY {
 614         # order matters for unlocking
 615         $_[0]->{xdb} = undef;
 616         $_[0]->{lockfh} = undef;
 617 }
 618
 619 1;