lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchIdx;
   5 use strict;
   6 use warnings;
   7 use base qw(PublicInbox::Search);
   8 use PublicInbox::MID qw/mid_clean mid_compress/;
   9 *xpfx = *PublicInbox::Search::xpfx;
  10
  11 use constant {
  12         PERM_UMASK => 0,
  13         OLD_PERM_GROUP => 1,
  14         OLD_PERM_EVERYBODY => 2,
  15         PERM_GROUP => 0660,
  16         PERM_EVERYBODY => 0664,
  17 };
  18
  19 sub new {
  20         my ($class, $git_dir, $writable) = @_;
  21         my $dir = $class->xdir($git_dir);
  22         require Search::Xapian::WritableDatabase;
  23         my $flag = Search::Xapian::DB_OPEN;
  24         my $self = bless { git_dir => $git_dir }, $class;
  25         my $perm = $self->_git_config_perm;
  26         my $umask = _umask_for($perm);
  27         $self->{umask} = $umask;
  28         $self->{xdb} = $self->with_umask(sub {
  29                 if ($writable == 1) {
  30                         require File::Path;
  31                         File::Path::mkpath($dir);
  32                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  33                 }
  34                 Search::Xapian::WritableDatabase->new($dir, $flag);
  35         });
  36         $self;
  37 }
  38
  39 sub add_message {
  40         my ($self, $mime) = @_; # mime = Email::MIME object
  41         my $db = $self->{xdb};
  42
  43         my $doc_id;
  44         my $mid = mid_clean($mime->header('Message-ID'));
  45         my $was_ghost = 0;
  46         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  47
  48         eval {
  49                 my $smsg = $self->lookup_message($mid);
  50                 my $doc;
  51
  52                 if ($smsg) {
  53                         $smsg->ensure_metadata;
  54                         # convert a ghost to a regular message
  55                         # it will also clobber any existing regular message
  56                         $smsg->mime($mime);
  57                         $doc = $smsg->{doc};
  58
  59                         my $type = xpfx('type');
  60                         eval {
  61                                 $doc->remove_term($type . 'ghost');
  62                                 $was_ghost = 1;
  63                         };
  64
  65                         # probably does not exist:
  66                         eval { $doc->remove_term($type . 'mail') };
  67                         $doc->add_term($type . 'mail');
  68                 }  else {
  69                         $smsg = PublicInbox::SearchMsg->new($mime);
  70                         $doc = $smsg->{doc};
  71                         $doc->add_term(xpfx('mid') . $mid);
  72                 }
  73
  74                 my $subj = $smsg->subject;
  75
  76                 if ($subj ne '') {
  77                         $doc->add_term(xpfx('subject') . $subj);
  78
  79                         my $path = $self->subject_path($subj);
  80                         $doc->add_term(xpfx('path') . mid_compress($path));
  81                 }
  82
  83                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
  84                 $doc->add_value(PublicInbox::Search::TS, $ts);
  85
  86                 my $tg = $self->term_generator;
  87
  88                 $tg->set_document($doc);
  89                 $tg->index_text($subj, 1, 'S') if $subj;
  90                 $tg->increase_termpos;
  91                 $tg->index_text($subj) if $subj;
  92                 $tg->increase_termpos;
  93
  94                 $tg->index_text($smsg->from->format);
  95                 $tg->increase_termpos;
  96
  97                 $mime->walk_parts(sub {
  98                         my ($part) = @_;
  99                         return if $part->subparts; # walk_parts already recurses
 100                         my $ct = $part->content_type || $ct_msg;
 101
 102                         # account for filter bugs...
 103                         $ct =~ m!\btext/plain\b!i or return;
 104
 105                         my (@orig, @quot);
 106                         my $body = $part->body;
 107                         $part->body_set('');
 108                         my @lines = split(/\n/, $body);
 109                         while (defined(my $l = shift @lines)) {
 110                                 if ($l =~ /^\s*>/) {
 111                                         push @quot, $l;
 112                                 } else {
 113                                         push @orig, $l;
 114                                 }
 115                         }
 116                         if (@quot) {
 117                                 $tg->index_text(join("\n", @quot), 0);
 118                                 @quot = ();
 119                                 $tg->increase_termpos;
 120                         }
 121                         if (@orig) {
 122                                 $tg->index_text(join("\n", @orig));
 123                                 @orig = ();
 124                                 $tg->increase_termpos;
 125                         }
 126                 });
 127
 128                 if ($was_ghost) {
 129                         $doc_id = $smsg->doc_id;
 130                         $self->link_message($smsg, 0);
 131                         $doc->set_data($smsg->to_doc_data);
 132                         $db->replace_document($doc_id, $doc);
 133                 } else {
 134                         $self->link_message($smsg, 0);
 135                         $doc->set_data($smsg->to_doc_data);
 136                         $doc_id = $db->add_document($doc);
 137                 }
 138         };
 139
 140         if ($@) {
 141                 warn "failed to index message <$mid>: $@\n";
 142                 return undef;
 143         }
 144         $doc_id;
 145 }
 146
 147 # returns deleted doc_id on success, undef on missing
 148 sub remove_message {
 149         my ($self, $mid) = @_;
 150         my $db = $self->{xdb};
 151         my $doc_id;
 152         $mid = mid_clean($mid);
 153
 154         eval {
 155                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 156                 $db->delete_document($doc_id) if defined $doc_id;
 157         };
 158
 159         if ($@) {
 160                 warn "failed to remove message <$mid>: $@\n";
 161                 return undef;
 162         }
 163         $doc_id;
 164 }
 165
 166 sub term_generator { # write-only
 167         my ($self) = @_;
 168
 169         my $tg = $self->{term_generator};
 170         return $tg if $tg;
 171
 172         $tg = Search::Xapian::TermGenerator->new;
 173         $tg->set_stemmer($self->stemmer);
 174
 175         $self->{term_generator} = $tg;
 176 }
 177
 178 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 179
 180 # increments last_thread_id counter
 181 # returns a 64-bit integer represented as a hex string
 182 sub next_thread_id {
 183         my ($self) = @_;
 184         my $db = $self->{xdb};
 185         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 186
 187         $db->set_metadata('last_thread_id', ++$last_thread_id);
 188
 189         $last_thread_id;
 190 }
 191
 192 sub link_message {
 193         my ($self, $smsg, $is_ghost) = @_;
 194
 195         if ($is_ghost) {
 196                 $smsg->ensure_metadata;
 197         } else {
 198                 $self->link_message_to_parents($smsg);
 199         }
 200 }
 201
 202 sub link_message_to_parents {
 203         my ($self, $smsg) = @_;
 204         my $doc = $smsg->{doc};
 205         my $mid = $smsg->mid;
 206         my $mime = $smsg->mime;
 207         my $refs = $mime->header('References');
 208         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 209         if (my $irt = $mime->header('In-Reply-To')) {
 210                 # last References should be $irt
 211                 # we will de-dupe later
 212                 push @refs, mid_clean($irt);
 213         }
 214
 215         my $tid;
 216         if (@refs) {
 217                 my %uniq = ($mid => 1);
 218                 my @orig_refs = @refs;
 219                 @refs = ();
 220
 221                 # prevent circular references via References: here:
 222                 foreach my $ref (@orig_refs) {
 223                         next if $uniq{$ref};
 224                         $uniq{$ref} = 1;
 225                         push @refs, $ref;
 226                 }
 227         }
 228         if (@refs) {
 229                 $smsg->{references_sorted} = '<'.join('><', @refs).'>';
 230
 231                 # first ref *should* be the thread root,
 232                 # but we can never trust clients to do the right thing
 233                 my $ref = shift @refs;
 234                 $tid = $self->_resolve_mid_to_tid($ref);
 235
 236                 # the rest of the refs should point to this tid:
 237                 foreach $ref (@refs) {
 238                         my $ptid = $self->_resolve_mid_to_tid($ref);
 239                         if ($tid ne $ptid) {
 240                                 $self->merge_threads($tid, $ptid);
 241                         }
 242                 }
 243         } else {
 244                 $tid = $self->next_thread_id;
 245         }
 246         $doc->add_term(xpfx('thread') . $tid);
 247 }
 248
 249 sub index_blob {
 250         my ($self, $git, $mime) = @_;
 251         $self->add_message($mime);
 252 }
 253
 254 sub unindex_blob {
 255         my ($self, $git, $mime) = @_;
 256         my $mid = mid_clean($mime->header('Message-ID'));
 257         $self->remove_message($mid) if defined $mid;
 258 }
 259
 260 sub index_mm {
 261         my ($self, $git, $mime) = @_;
 262         $self->{mm}->mid_insert(mid_clean($mime->header('Message-ID')));
 263 }
 264
 265 sub unindex_mm {
 266         my ($self, $git, $mime) = @_;
 267         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 268 }
 269
 270 sub index_both {
 271         my ($self, $git, $mime) = @_;
 272         index_blob($self, $git, $mime);
 273         index_mm($self, $git, $mime);
 274 }
 275
 276 sub unindex_both {
 277         my ($self, $git, $mime) = @_;
 278         unindex_blob($self, $git, $mime);
 279         unindex_mm($self, $git, $mime);
 280 }
 281
 282 sub do_cat_mail {
 283         my ($git, $blob) = @_;
 284         my $mime = eval {
 285                 my $str = $git->cat_file($blob);
 286                 Email::MIME->new($str);
 287         };
 288         $@ ? undef : $mime;
 289 }
 290
 291 sub index_sync {
 292         my ($self, $head) = @_;
 293         $self->with_umask(sub { $self->_index_sync($head) });
 294 }
 295
 296 sub rlog {
 297         my ($self, $range, $add_cb, $del_cb) = @_;
 298         my $hex = '[a-f0-9]';
 299         my $h40 = $hex .'{40}';
 300         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 301         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 302         my $git_dir = $self->{git_dir};
 303         require PublicInbox::GitCatFile;
 304         my $git = PublicInbox::GitCatFile->new($git_dir);
 305         my @cmd = ('git', "--git-dir=$git_dir", "log",
 306                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 307                     $range);
 308         my $latest;
 309         my $pid = open(my $log, '-|', @cmd) or
 310                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 311         while (my $line = <$log>) {
 312                 if ($line =~ /$addmsg/o) {
 313                         my $mime = do_cat_mail($git, $1) or next;
 314                         $add_cb->($self, $git, $mime);
 315                 } elsif ($line =~ /$delmsg/o) {
 316                         my $mime = do_cat_mail($git, $1) or next;
 317                         $del_cb->($self, $git, $mime);
 318                 } elsif ($line =~ /^commit ($h40)/o) {
 319                         $latest = $1;
 320                 }
 321         }
 322         close $log;
 323         $latest;
 324 }
 325
 326 # indexes all unindexed messages
 327 sub _index_sync {
 328         my ($self, $head) = @_;
 329         my $db = $self->{xdb};
 330         $head ||= 'HEAD';
 331         my $mm = $self->{mm} = eval {
 332                 require PublicInbox::Msgmap;
 333                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 334         };
 335
 336         $db->begin_transaction;
 337         my $lx = $db->get_metadata('last_commit');
 338         my $range = $lx eq '' ? $head : "$lx..$head";
 339         if ($mm) {
 340                 $mm->{dbh}->begin_work;
 341                 my $lm = $mm->last_commit || '';
 342                 if ($lm eq $lx) {
 343                         # Common case is the indexes are synced,
 344                         # we only need to run git-log once:
 345                         $lx = $self->rlog($range, *index_both, *unindex_both);
 346                         $mm->{dbh}->commit;
 347                         if (defined $lx) {
 348                                 $db->set_metadata('last_commit', $lx);
 349                                 $mm->last_commit($lx);
 350                         }
 351                 } else {
 352                         # dumb case, msgmap and xapian are out-of-sync
 353                         # do not care for performance:
 354                         my $r = $lm eq '' ? $head : "$lm..$head";
 355                         $lm = $self->rlog($r, *index_mm, *unindex_mm);
 356                         $mm->{dbh}->commit;
 357                         $mm->last_commit($lm) if defined $lm;
 358
 359                         goto xapian_only;
 360                 }
 361         } else {
 362                 # user didn't install DBD::SQLite and DBI
 363 xapian_only:
 364                 $lx = $self->rlog($range, *index_blob, *unindex_blob);
 365                 $db->set_metadata('last_commit', $lx) if defined $lx;
 366         }
 367         if ($@) {
 368                 $db->cancel_transaction;
 369                 $mm->{dbh}->rollback if $mm;
 370         } else {
 371                 $db->commit_transaction;
 372         }
 373 }
 374
 375 # this will create a ghost as necessary
 376 sub _resolve_mid_to_tid {
 377         my ($self, $mid) = @_;
 378
 379         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 380         $smsg->thread_id;
 381 }
 382
 383 sub create_ghost {
 384         my ($self, $mid, $tid) = @_;
 385
 386         $tid = $self->next_thread_id unless defined $tid;
 387
 388         my $doc = Search::Xapian::Document->new;
 389         $doc->add_term(xpfx('mid') . $mid);
 390         $doc->add_term(xpfx('thread') . $tid);
 391         $doc->add_term(xpfx('type') . 'ghost');
 392
 393         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 394         $self->link_message($smsg, 1);
 395         $self->{xdb}->add_document($doc);
 396
 397         $smsg;
 398 }
 399
 400 sub merge_threads {
 401         my ($self, $winner_tid, $loser_tid) = @_;
 402         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 403         my $thread_pfx = xpfx('thread');
 404         my $db = $self->{xdb};
 405
 406         for (; $head != $tail; $head->inc) {
 407                 my $docid = $head->get_docid;
 408                 my $doc = $db->get_document($docid);
 409                 $doc->remove_term($thread_pfx . $loser_tid);
 410                 $doc->add_term($thread_pfx . $winner_tid);
 411                 $db->replace_document($docid, $doc);
 412         }
 413 }
 414
 415 sub _read_git_config_perm {
 416         my ($self) = @_;
 417         my @cmd = ('git', "--git-dir=$self->{git_dir}",
 418                    qw(config core.sharedRepository));
 419         my $pid = open(my $fh, '-|', @cmd) or
 420                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 421         my $perm = <$fh>;
 422         close $fh;
 423         chomp $perm if defined $perm;
 424         $perm;
 425 }
 426
 427 sub _git_config_perm {
 428         my $self = shift;
 429         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 430         return PERM_GROUP if (!defined($perm) || $perm eq '');
 431         return PERM_UMASK if ($perm eq 'umask');
 432         return PERM_GROUP if ($perm eq 'group');
 433         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 434                 return PERM_EVERYBODY;
 435         }
 436         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 437         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 438
 439         my $i = oct($perm);
 440         return PERM_UMASK if ($i == PERM_UMASK);
 441         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 442         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 443
 444         if (($i & 0600) != 0600) {
 445                 die "core.sharedRepository mode invalid: ".
 446                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 447         }
 448         ($i & 0666);
 449 }
 450
 451 sub _umask_for {
 452         my ($perm) = @_; # _git_config_perm return value
 453         my $rv = $perm;
 454         return umask if $rv == 0;
 455
 456         # set +x bit if +r or +w were set
 457         $rv |= 0100 if ($rv & 0600);
 458         $rv |= 0010 if ($rv & 0060);
 459         $rv |= 0001 if ($rv & 0006);
 460         (~$rv & 0777);
 461 }
 462
 463 sub with_umask {
 464         my ($self, $cb) = @_;
 465         my $old = umask $self->{umask};
 466         my $rv = eval { $cb->() };
 467         my $err = $@;
 468         umask $old;
 469         die $err if $@;
 470         $rv;
 471 }
 472
 473 1;