lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchIdx;
   5 use strict;
   6 use warnings;
   7 use base qw(PublicInbox::Search);
   8 use PublicInbox::MID qw/mid_clean mid_compress/;
   9 *xpfx = *PublicInbox::Search::xpfx;
  10
  11 use constant {
  12         PERM_UMASK => 0,
  13         OLD_PERM_GROUP => 1,
  14         OLD_PERM_EVERYBODY => 2,
  15         PERM_GROUP => 0660,
  16         PERM_EVERYBODY => 0664,
  17 };
  18
  19 sub new {
  20         my ($class, $git_dir, $writable) = @_;
  21         my $dir = $class->xdir($git_dir);
  22         require Search::Xapian::WritableDatabase;
  23         my $flag = Search::Xapian::DB_OPEN;
  24         my $self = bless { git_dir => $git_dir }, $class;
  25         my $perm = $self->_git_config_perm;
  26         my $umask = _umask_for($perm);
  27         $self->{umask} = $umask;
  28         $self->{xdb} = $self->with_umask(sub {
  29                 if ($writable == 1) {
  30                         require File::Path;
  31                         File::Path::mkpath($dir);
  32                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  33                 }
  34                 Search::Xapian::WritableDatabase->new($dir, $flag);
  35         });
  36         $self;
  37 }
  38
  39 sub add_val {
  40         my ($doc, $col, $num) = @_;
  41         $num = Search::Xapian::sortable_serialise($num);
  42         $doc->add_value($col, $num);
  43 }
  44
  45 sub add_message {
  46         my ($self, $mime, $bytes, $num) = @_; # mime = Email::MIME object
  47         my $db = $self->{xdb};
  48
  49         my $doc_id;
  50         my $mid = mid_clean($mime->header('Message-ID'));
  51         my $was_ghost = 0;
  52         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  53
  54         eval {
  55                 my $smsg = $self->lookup_message($mid);
  56                 my $doc;
  57
  58                 if ($smsg) {
  59                         $smsg->ensure_metadata;
  60                         # convert a ghost to a regular message
  61                         # it will also clobber any existing regular message
  62                         $smsg->mime($mime);
  63                         $doc = $smsg->{doc};
  64
  65                         my $type = xpfx('type');
  66                         eval {
  67                                 $doc->remove_term($type . 'ghost');
  68                                 $was_ghost = 1;
  69                         };
  70
  71                         # probably does not exist:
  72                         eval { $doc->remove_term($type . 'mail') };
  73                         $doc->add_term($type . 'mail');
  74                 }  else {
  75                         $smsg = PublicInbox::SearchMsg->new($mime);
  76                         $doc = $smsg->{doc};
  77                         $doc->add_term(xpfx('mid') . $mid);
  78                 }
  79
  80                 my $subj = $smsg->subject;
  81
  82                 if ($subj ne '') {
  83                         $doc->add_term(xpfx('subject') . $subj);
  84
  85                         my $path = $self->subject_path($subj);
  86                         $doc->add_term(xpfx('path') . mid_compress($path));
  87                 }
  88
  89                 add_val($doc, &PublicInbox::Search::TS, $smsg->ts);
  90
  91                 defined($num) and
  92                         add_val($doc, &PublicInbox::Search::NUM, $num);
  93
  94                 defined($bytes) and
  95                         add_val($doc, &PublicInbox::Search::BYTES, $bytes);
  96
  97                 add_val($doc, &PublicInbox::Search::LINES,
  98                                 $mime->body_raw =~ tr!\n!\n!);
  99
 100                 my $tg = $self->term_generator;
 101
 102                 $tg->set_document($doc);
 103                 $tg->index_text($subj, 1, 'S') if $subj;
 104                 $tg->increase_termpos;
 105                 $tg->index_text($subj) if $subj;
 106                 $tg->increase_termpos;
 107
 108                 $tg->index_text($smsg->from);
 109                 $tg->increase_termpos;
 110
 111                 $mime->walk_parts(sub {
 112                         my ($part) = @_;
 113                         return if $part->subparts; # walk_parts already recurses
 114                         my $ct = $part->content_type || $ct_msg;
 115
 116                         # account for filter bugs...
 117                         $ct =~ m!\btext/plain\b!i or return;
 118
 119                         my (@orig, @quot);
 120                         my $body = $part->body;
 121                         $part->body_set('');
 122                         my @lines = split(/\n/, $body);
 123                         while (defined(my $l = shift @lines)) {
 124                                 if ($l =~ /^\s*>/) {
 125                                         push @quot, $l;
 126                                 } else {
 127                                         push @orig, $l;
 128                                 }
 129                         }
 130                         if (@quot) {
 131                                 $tg->index_text(join("\n", @quot), 0);
 132                                 @quot = ();
 133                                 $tg->increase_termpos;
 134                         }
 135                         if (@orig) {
 136                                 $tg->index_text(join("\n", @orig));
 137                                 @orig = ();
 138                                 $tg->increase_termpos;
 139                         }
 140                 });
 141
 142                 if ($was_ghost) {
 143                         $doc_id = $smsg->doc_id;
 144                         $self->link_message($smsg, 0);
 145                         $doc->set_data($smsg->to_doc_data);
 146                         $db->replace_document($doc_id, $doc);
 147                 } else {
 148                         $self->link_message($smsg, 0);
 149                         $doc->set_data($smsg->to_doc_data);
 150                         $doc_id = $db->add_document($doc);
 151                 }
 152         };
 153
 154         if ($@) {
 155                 warn "failed to index message <$mid>: $@\n";
 156                 return undef;
 157         }
 158         $doc_id;
 159 }
 160
 161 # returns deleted doc_id on success, undef on missing
 162 sub remove_message {
 163         my ($self, $mid) = @_;
 164         my $db = $self->{xdb};
 165         my $doc_id;
 166         $mid = mid_clean($mid);
 167
 168         eval {
 169                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 170                 $db->delete_document($doc_id) if defined $doc_id;
 171         };
 172
 173         if ($@) {
 174                 warn "failed to remove message <$mid>: $@\n";
 175                 return undef;
 176         }
 177         $doc_id;
 178 }
 179
 180 sub term_generator { # write-only
 181         my ($self) = @_;
 182
 183         my $tg = $self->{term_generator};
 184         return $tg if $tg;
 185
 186         $tg = Search::Xapian::TermGenerator->new;
 187         $tg->set_stemmer($self->stemmer);
 188
 189         $self->{term_generator} = $tg;
 190 }
 191
 192 # increments last_thread_id counter
 193 # returns a 64-bit integer represented as a hex string
 194 sub next_thread_id {
 195         my ($self) = @_;
 196         my $db = $self->{xdb};
 197         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 198
 199         $db->set_metadata('last_thread_id', ++$last_thread_id);
 200
 201         $last_thread_id;
 202 }
 203
 204 sub link_message {
 205         my ($self, $smsg, $is_ghost) = @_;
 206
 207         if ($is_ghost) {
 208                 $smsg->ensure_metadata;
 209         } else {
 210                 $self->link_message_to_parents($smsg);
 211         }
 212 }
 213
 214 sub link_message_to_parents {
 215         my ($self, $smsg) = @_;
 216         my $doc = $smsg->{doc};
 217         my $mid = $smsg->mid;
 218         my $mime = $smsg->mime;
 219         my $refs = $mime->header('References');
 220         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 221         if (my $irt = $mime->header('In-Reply-To')) {
 222                 # last References should be $irt
 223                 # we will de-dupe later
 224                 push @refs, mid_clean($irt);
 225         }
 226
 227         my $tid;
 228         if (@refs) {
 229                 my %uniq = ($mid => 1);
 230                 my @orig_refs = @refs;
 231                 @refs = ();
 232
 233                 # prevent circular references via References: here:
 234                 foreach my $ref (@orig_refs) {
 235                         next if $uniq{$ref};
 236                         $uniq{$ref} = 1;
 237                         push @refs, $ref;
 238                 }
 239         }
 240         if (@refs) {
 241                 $smsg->{references} = '<'.join('> <', @refs).'>';
 242
 243                 # first ref *should* be the thread root,
 244                 # but we can never trust clients to do the right thing
 245                 my $ref = shift @refs;
 246                 $tid = $self->_resolve_mid_to_tid($ref);
 247
 248                 # the rest of the refs should point to this tid:
 249                 foreach $ref (@refs) {
 250                         my $ptid = $self->_resolve_mid_to_tid($ref);
 251                         if ($tid ne $ptid) {
 252                                 $self->merge_threads($tid, $ptid);
 253                         }
 254                 }
 255         } else {
 256                 $tid = $self->next_thread_id;
 257         }
 258         $doc->add_term(xpfx('thread') . $tid);
 259 }
 260
 261 sub index_blob {
 262         my ($self, $git, $mime, $bytes, $num) = @_;
 263         $self->add_message($mime, $bytes, $num);
 264 }
 265
 266 sub unindex_blob {
 267         my ($self, $git, $mime) = @_;
 268         my $mid = mid_clean($mime->header('Message-ID'));
 269         $self->remove_message($mid) if defined $mid;
 270 }
 271
 272 sub index_mm {
 273         my ($self, $git, $mime) = @_;
 274         $self->{mm}->mid_insert(mid_clean($mime->header('Message-ID')));
 275 }
 276
 277 sub unindex_mm {
 278         my ($self, $git, $mime) = @_;
 279         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 280 }
 281
 282 sub index_mm2 {
 283         my ($self, $git, $mime, $bytes) = @_;
 284         my $num = $self->{mm}->num_for(mid_clean($mime->header('Message-ID')));
 285         index_blob($self, $git, $mime, $bytes, $num);
 286 }
 287
 288 sub unindex_mm2 {
 289         my ($self, $git, $mime) = @_;
 290         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 291         unindex_blob($self, $git, $mime);
 292 }
 293
 294 sub index_both {
 295         my ($self, $git, $mime, $bytes) = @_;
 296         my $num = index_mm($self, $git, $mime);
 297         index_blob($self, $git, $mime, $bytes, $num);
 298 }
 299
 300 sub unindex_both {
 301         my ($self, $git, $mime) = @_;
 302         unindex_blob($self, $git, $mime);
 303         unindex_mm($self, $git, $mime);
 304 }
 305
 306 sub do_cat_mail {
 307         my ($git, $blob, $sizeref) = @_;
 308         my $mime = eval {
 309                 my $str = $git->cat_file($blob, $sizeref);
 310                 Email::MIME->new($str);
 311         };
 312         $@ ? undef : $mime;
 313 }
 314
 315 sub index_sync {
 316         my ($self, $head) = @_;
 317         $self->with_umask(sub { $self->_index_sync($head) });
 318 }
 319
 320 sub rlog {
 321         my ($self, $range, $add_cb, $del_cb) = @_;
 322         my $hex = '[a-f0-9]';
 323         my $h40 = $hex .'{40}';
 324         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 325         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 326         my $git_dir = $self->{git_dir};
 327         require PublicInbox::GitCatFile;
 328         my $git = PublicInbox::GitCatFile->new($git_dir);
 329         my @cmd = ('git', "--git-dir=$git_dir", "log",
 330                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 331                     $range);
 332         my $latest;
 333         my $bytes;
 334         my $pid = open(my $log, '-|', @cmd) or
 335                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 336         while (my $line = <$log>) {
 337                 if ($line =~ /$addmsg/o) {
 338                         my $mime = do_cat_mail($git, $1, \$bytes) or next;
 339                         $add_cb->($self, $git, $mime, $bytes);
 340                 } elsif ($line =~ /$delmsg/o) {
 341                         my $mime = do_cat_mail($git, $1) or next;
 342                         $del_cb->($self, $git, $mime);
 343                 } elsif ($line =~ /^commit ($h40)/o) {
 344                         $latest = $1;
 345                 }
 346         }
 347         close $log;
 348         $latest;
 349 }
 350
 351 # indexes all unindexed messages
 352 sub _index_sync {
 353         my ($self, $head) = @_;
 354         my $db = $self->{xdb};
 355         $head ||= 'HEAD';
 356         my $mm = $self->{mm} = eval {
 357                 require PublicInbox::Msgmap;
 358                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 359         };
 360
 361         $db->begin_transaction;
 362         my $lx = $db->get_metadata('last_commit');
 363         my $range = $lx eq '' ? $head : "$lx..$head";
 364         if ($mm) {
 365                 $mm->{dbh}->begin_work;
 366                 my $lm = $mm->last_commit || '';
 367                 if ($lm eq $lx) {
 368                         # Common case is the indexes are synced,
 369                         # we only need to run git-log once:
 370                         $lx = $self->rlog($range, *index_both, *unindex_both);
 371                         $mm->{dbh}->commit;
 372                         if (defined $lx) {
 373                                 $db->set_metadata('last_commit', $lx);
 374                                 $mm->last_commit($lx);
 375                         }
 376                 } else {
 377                         # dumb case, msgmap and xapian are out-of-sync
 378                         # do not care for performance:
 379                         my $r = $lm eq '' ? $head : "$lm..$head";
 380                         $lm = $self->rlog($r, *index_mm, *unindex_mm);
 381                         $mm->{dbh}->commit;
 382                         $mm->last_commit($lm) if defined $lm;
 383
 384                         $lx = $self->rlog($range, *index_mm2, *unindex_mm2);
 385                         $db->set_metadata('last_commit', $lx) if defined $lx;
 386                 }
 387         } else {
 388                 # user didn't install DBD::SQLite and DBI
 389                 $lx = $self->rlog($range, *index_blob, *unindex_blob);
 390                 $db->set_metadata('last_commit', $lx) if defined $lx;
 391         }
 392         if ($@) {
 393                 $db->cancel_transaction;
 394                 $mm->{dbh}->rollback if $mm;
 395         } else {
 396                 $db->commit_transaction;
 397         }
 398 }
 399
 400 # this will create a ghost as necessary
 401 sub _resolve_mid_to_tid {
 402         my ($self, $mid) = @_;
 403
 404         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 405         $smsg->thread_id;
 406 }
 407
 408 sub create_ghost {
 409         my ($self, $mid, $tid) = @_;
 410
 411         $tid = $self->next_thread_id unless defined $tid;
 412
 413         my $doc = Search::Xapian::Document->new;
 414         $doc->add_term(xpfx('mid') . $mid);
 415         $doc->add_term(xpfx('thread') . $tid);
 416         $doc->add_term(xpfx('type') . 'ghost');
 417
 418         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 419         $self->link_message($smsg, 1);
 420         $self->{xdb}->add_document($doc);
 421
 422         $smsg;
 423 }
 424
 425 sub merge_threads {
 426         my ($self, $winner_tid, $loser_tid) = @_;
 427         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 428         my $thread_pfx = xpfx('thread');
 429         my $db = $self->{xdb};
 430
 431         for (; $head != $tail; $head->inc) {
 432                 my $docid = $head->get_docid;
 433                 my $doc = $db->get_document($docid);
 434                 $doc->remove_term($thread_pfx . $loser_tid);
 435                 $doc->add_term($thread_pfx . $winner_tid);
 436                 $db->replace_document($docid, $doc);
 437         }
 438 }
 439
 440 sub _read_git_config_perm {
 441         my ($self) = @_;
 442         my @cmd = ('git', "--git-dir=$self->{git_dir}",
 443                    qw(config core.sharedRepository));
 444         my $pid = open(my $fh, '-|', @cmd) or
 445                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 446         my $perm = <$fh>;
 447         close $fh;
 448         chomp $perm if defined $perm;
 449         $perm;
 450 }
 451
 452 sub _git_config_perm {
 453         my $self = shift;
 454         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 455         return PERM_GROUP if (!defined($perm) || $perm eq '');
 456         return PERM_UMASK if ($perm eq 'umask');
 457         return PERM_GROUP if ($perm eq 'group');
 458         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 459                 return PERM_EVERYBODY;
 460         }
 461         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 462         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 463
 464         my $i = oct($perm);
 465         return PERM_UMASK if ($i == PERM_UMASK);
 466         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 467         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 468
 469         if (($i & 0600) != 0600) {
 470                 die "core.sharedRepository mode invalid: ".
 471                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 472         }
 473         ($i & 0666);
 474 }
 475
 476 sub _umask_for {
 477         my ($perm) = @_; # _git_config_perm return value
 478         my $rv = $perm;
 479         return umask if $rv == 0;
 480
 481         # set +x bit if +r or +w were set
 482         $rv |= 0100 if ($rv & 0600);
 483         $rv |= 0010 if ($rv & 0060);
 484         $rv |= 0001 if ($rv & 0006);
 485         (~$rv & 0777);
 486 }
 487
 488 sub with_umask {
 489         my ($self, $cb) = @_;
 490         my $old = umask $self->{umask};
 491         my $rv = eval { $cb->() };
 492         my $err = $@;
 493         umask $old;
 494         die $err if $@;
 495         $rv;
 496 }
 497
 498 1;