lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by Mail::Thread.  This writes to the search
   8 # index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Email::MIME;
  13 use Email::MIME::ContentType;
  14 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  15 use base qw(PublicInbox::Search);
  16 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  17 use PublicInbox::MsgIter;
  18 require PublicInbox::Git;
  19 *xpfx = *PublicInbox::Search::xpfx;
  20
  21 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  22 use constant {
  23         PERM_UMASK => 0,
  24         OLD_PERM_GROUP => 1,
  25         OLD_PERM_EVERYBODY => 2,
  26         PERM_GROUP => 0660,
  27         PERM_EVERYBODY => 0664,
  28 };
  29
  30 sub new {
  31         my ($class, $git_dir, $writable) = @_;
  32         my $dir = $class->xdir($git_dir);
  33         require Search::Xapian::WritableDatabase;
  34         my $flag = Search::Xapian::DB_OPEN;
  35         my $self = bless { git_dir => $git_dir }, $class;
  36         my $perm = $self->_git_config_perm;
  37         my $umask = _umask_for($perm);
  38         $self->{umask} = $umask;
  39         $self->{xdb} = $self->with_umask(sub {
  40                 if ($writable == 1) {
  41                         require File::Path;
  42                         File::Path::mkpath($dir);
  43                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  44                 }
  45                 Search::Xapian::WritableDatabase->new($dir, $flag);
  46         });
  47         $self;
  48 }
  49
  50 sub add_val {
  51         my ($doc, $col, $num) = @_;
  52         $num = Search::Xapian::sortable_serialise($num);
  53         $doc->add_value($col, $num);
  54 }
  55
  56 sub add_message {
  57         my ($self, $mime, $bytes, $num) = @_; # mime = Email::MIME object
  58         my $db = $self->{xdb};
  59
  60         my $doc_id;
  61         my $mid = mid_clean(mid_mime($mime));
  62         my $was_ghost = 0;
  63         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  64
  65         eval {
  66                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
  67                 my $smsg = $self->lookup_message($mid);
  68                 my $doc;
  69
  70                 if ($smsg) {
  71                         $smsg->ensure_metadata;
  72                         # convert a ghost to a regular message
  73                         # it will also clobber any existing regular message
  74                         $smsg->mime($mime);
  75                         $doc = $smsg->{doc};
  76
  77                         my $type = xpfx('type');
  78                         eval {
  79                                 $doc->remove_term($type . 'ghost');
  80                                 $was_ghost = 1;
  81                         };
  82
  83                         # probably does not exist:
  84                         eval { $doc->remove_term($type . 'mail') };
  85                         $doc->add_term($type . 'mail');
  86                 }  else {
  87                         $smsg = PublicInbox::SearchMsg->new($mime);
  88                         $doc = $smsg->{doc};
  89                         $doc->add_term(xpfx('mid') . $mid);
  90                 }
  91
  92                 my $subj = $smsg->subject;
  93
  94                 if ($subj ne '') {
  95                         my $path = $self->subject_path($subj);
  96                         $doc->add_term(xpfx('path') . id_compress($path));
  97                 }
  98
  99                 add_val($doc, &PublicInbox::Search::TS, $smsg->ts);
 100
 101                 defined($num) and
 102                         add_val($doc, &PublicInbox::Search::NUM, $num);
 103
 104                 defined($bytes) and
 105                         add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 106
 107                 add_val($doc, &PublicInbox::Search::LINES,
 108                                 $mime->body_raw =~ tr!\n!\n!);
 109
 110                 my $tg = $self->term_generator;
 111
 112                 $tg->set_document($doc);
 113                 $tg->index_text($subj, 1, 'S') if $subj;
 114                 $tg->increase_termpos;
 115                 $tg->index_text($subj) if $subj;
 116                 $tg->increase_termpos;
 117
 118                 $tg->index_text($smsg->from);
 119                 $tg->increase_termpos;
 120
 121                 msg_iter($mime, sub {
 122                         my ($part, $depth, @idx) = @{$_[0]};
 123                         my $ct = $part->content_type || $ct_msg;
 124
 125                         # account for filter bugs...
 126                         $ct =~ m!\btext/plain\b!i or return;
 127
 128                         my (@orig, @quot);
 129                         my $body = $part->body;
 130                         $part->body_set('');
 131                         my @lines = split(/\n/, $body);
 132                         while (defined(my $l = shift @lines)) {
 133                                 if ($l =~ /^\s*>/) {
 134                                         push @quot, $l;
 135                                 } else {
 136                                         push @orig, $l;
 137                                 }
 138                         }
 139                         if (@quot) {
 140                                 $tg->index_text(join("\n", @quot), 0);
 141                                 @quot = ();
 142                                 $tg->increase_termpos;
 143                         }
 144                         if (@orig) {
 145                                 $tg->index_text(join("\n", @orig));
 146                                 @orig = ();
 147                                 $tg->increase_termpos;
 148                         }
 149                 });
 150
 151                 if ($was_ghost) {
 152                         $doc_id = $smsg->doc_id;
 153                         $self->link_message($smsg, 0);
 154                         $doc->set_data($smsg->to_doc_data);
 155                         $db->replace_document($doc_id, $doc);
 156                 } else {
 157                         $self->link_message($smsg, 0);
 158                         $doc->set_data($smsg->to_doc_data);
 159                         $doc_id = $db->add_document($doc);
 160                 }
 161         };
 162
 163         if ($@) {
 164                 warn "failed to index message <$mid>: $@\n";
 165                 return undef;
 166         }
 167         $doc_id;
 168 }
 169
 170 # returns deleted doc_id on success, undef on missing
 171 sub remove_message {
 172         my ($self, $mid) = @_;
 173         my $db = $self->{xdb};
 174         my $doc_id;
 175         $mid = mid_clean($mid);
 176
 177         eval {
 178                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 179                 $db->delete_document($doc_id) if defined $doc_id;
 180         };
 181
 182         if ($@) {
 183                 warn "failed to remove message <$mid>: $@\n";
 184                 return undef;
 185         }
 186         $doc_id;
 187 }
 188
 189 sub term_generator { # write-only
 190         my ($self) = @_;
 191
 192         my $tg = $self->{term_generator};
 193         return $tg if $tg;
 194
 195         $tg = Search::Xapian::TermGenerator->new;
 196         $tg->set_stemmer($self->stemmer);
 197
 198         $self->{term_generator} = $tg;
 199 }
 200
 201 # increments last_thread_id counter
 202 # returns a 64-bit integer represented as a hex string
 203 sub next_thread_id {
 204         my ($self) = @_;
 205         my $db = $self->{xdb};
 206         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 207
 208         $db->set_metadata('last_thread_id', ++$last_thread_id);
 209
 210         $last_thread_id;
 211 }
 212
 213 sub link_message {
 214         my ($self, $smsg, $is_ghost) = @_;
 215
 216         if ($is_ghost) {
 217                 $smsg->ensure_metadata;
 218         } else {
 219                 $self->link_message_to_parents($smsg);
 220         }
 221 }
 222
 223 sub link_message_to_parents {
 224         my ($self, $smsg) = @_;
 225         my $doc = $smsg->{doc};
 226         my $mid = $smsg->mid;
 227         my $mime = $smsg->mime;
 228         my $hdr = $mime->header_obj;
 229         my $refs = $hdr->header_raw('References');
 230         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 231         if (my $irt = $hdr->header_raw('In-Reply-To')) {
 232                 # last References should be $irt
 233                 # we will de-dupe later
 234                 push @refs, mid_clean($irt);
 235         }
 236
 237         my $tid;
 238         if (@refs) {
 239                 my %uniq = ($mid => 1);
 240                 my @orig_refs = @refs;
 241                 @refs = ();
 242
 243                 # prevent circular references via References: here:
 244                 foreach my $ref (@orig_refs) {
 245                         if (length($ref) > MAX_MID_SIZE) {
 246                                 warn "References: <$ref> too long, ignoring\n";
 247                         }
 248                         next if $uniq{$ref};
 249                         $uniq{$ref} = 1;
 250                         push @refs, $ref;
 251                 }
 252         }
 253         if (@refs) {
 254                 $smsg->{references} = '<'.join('> <', @refs).'>';
 255
 256                 # first ref *should* be the thread root,
 257                 # but we can never trust clients to do the right thing
 258                 my $ref = shift @refs;
 259                 $tid = $self->_resolve_mid_to_tid($ref);
 260
 261                 # the rest of the refs should point to this tid:
 262                 foreach $ref (@refs) {
 263                         my $ptid = $self->_resolve_mid_to_tid($ref);
 264                         if ($tid ne $ptid) {
 265                                 $self->merge_threads($tid, $ptid);
 266                         }
 267                 }
 268         } else {
 269                 $tid = $self->next_thread_id;
 270         }
 271         $doc->add_term(xpfx('thread') . $tid);
 272 }
 273
 274 sub index_blob {
 275         my ($self, $git, $mime, $bytes, $num) = @_;
 276         $self->add_message($mime, $bytes, $num);
 277 }
 278
 279 sub unindex_blob {
 280         my ($self, $git, $mime) = @_;
 281         my $mid = eval { mid_clean(mid_mime($mime)) };
 282         $self->remove_message($mid) if defined $mid;
 283 }
 284
 285 sub index_mm {
 286         my ($self, $git, $mime) = @_;
 287         $self->{mm}->mid_insert(mid_clean(mid_mime($mime)));
 288 }
 289
 290 sub unindex_mm {
 291         my ($self, $git, $mime) = @_;
 292         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 293 }
 294
 295 sub index_mm2 {
 296         my ($self, $git, $mime, $bytes) = @_;
 297         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 298         index_blob($self, $git, $mime, $bytes, $num);
 299 }
 300
 301 sub unindex_mm2 {
 302         my ($self, $git, $mime) = @_;
 303         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 304         unindex_blob($self, $git, $mime);
 305 }
 306
 307 sub index_both {
 308         my ($self, $git, $mime, $bytes) = @_;
 309         my $num = index_mm($self, $git, $mime);
 310         index_blob($self, $git, $mime, $bytes, $num);
 311 }
 312
 313 sub unindex_both {
 314         my ($self, $git, $mime) = @_;
 315         unindex_blob($self, $git, $mime);
 316         unindex_mm($self, $git, $mime);
 317 }
 318
 319 sub do_cat_mail {
 320         my ($git, $blob, $sizeref) = @_;
 321         my $mime = eval {
 322                 my $str = $git->cat_file($blob, $sizeref);
 323                 Email::MIME->new($str);
 324         };
 325         $@ ? undef : $mime;
 326 }
 327
 328 sub index_sync {
 329         my ($self, $head) = @_;
 330         $self->with_umask(sub { $self->_index_sync($head) });
 331 }
 332
 333 sub rlog {
 334         my ($self, $range, $add_cb, $del_cb) = @_;
 335         my $hex = '[a-f0-9]';
 336         my $h40 = $hex .'{40}';
 337         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 338         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 339         my $git = PublicInbox::Git->new($self->{git_dir});
 340         my $log = $git->popen(qw/log --reverse --no-notes --no-color
 341                                 --raw -r --no-abbrev/, $range);
 342         my $latest;
 343         my $bytes;
 344         local $/ = "\n";
 345         while (defined(my $line = <$log>)) {
 346                 if ($line =~ /$addmsg/o) {
 347                         my $mime = do_cat_mail($git, $1, \$bytes) or next;
 348                         $add_cb->($self, $git, $mime, $bytes);
 349                 } elsif ($line =~ /$delmsg/o) {
 350                         my $mime = do_cat_mail($git, $1) or next;
 351                         $del_cb->($self, $git, $mime);
 352                 } elsif ($line =~ /^commit ($h40)/o) {
 353                         $latest = $1;
 354                 }
 355         }
 356         $latest;
 357 }
 358
 359 # indexes all unindexed messages
 360 sub _index_sync {
 361         my ($self, $head) = @_;
 362         my $db = $self->{xdb};
 363         $head ||= 'HEAD';
 364         my $mm = $self->{mm} = eval {
 365                 require PublicInbox::Msgmap;
 366                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 367         };
 368
 369         $db->begin_transaction;
 370         my $lx = $db->get_metadata('last_commit');
 371         my $range = $lx eq '' ? $head : "$lx..$head";
 372         if ($mm) {
 373                 $mm->{dbh}->begin_work;
 374                 my $lm = $mm->last_commit || '';
 375                 if ($lm eq $lx) {
 376                         # Common case is the indexes are synced,
 377                         # we only need to run git-log once:
 378                         $lx = $self->rlog($range, *index_both, *unindex_both);
 379                         $mm->{dbh}->commit;
 380                         if (defined $lx) {
 381                                 $db->set_metadata('last_commit', $lx);
 382                                 $mm->last_commit($lx);
 383                         }
 384                 } else {
 385                         # dumb case, msgmap and xapian are out-of-sync
 386                         # do not care for performance:
 387                         my $r = $lm eq '' ? $head : "$lm..$head";
 388                         $lm = $self->rlog($r, *index_mm, *unindex_mm);
 389                         $mm->{dbh}->commit;
 390                         $mm->last_commit($lm) if defined $lm;
 391
 392                         $lx = $self->rlog($range, *index_mm2, *unindex_mm2);
 393                         $db->set_metadata('last_commit', $lx) if defined $lx;
 394                 }
 395         } else {
 396                 # user didn't install DBD::SQLite and DBI
 397                 $lx = $self->rlog($range, *index_blob, *unindex_blob);
 398                 $db->set_metadata('last_commit', $lx) if defined $lx;
 399         }
 400         if ($@) {
 401                 $db->cancel_transaction;
 402                 $mm->{dbh}->rollback if $mm;
 403         } else {
 404                 $db->commit_transaction;
 405         }
 406 }
 407
 408 # this will create a ghost as necessary
 409 sub _resolve_mid_to_tid {
 410         my ($self, $mid) = @_;
 411
 412         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 413         $smsg->thread_id;
 414 }
 415
 416 sub create_ghost {
 417         my ($self, $mid, $tid) = @_;
 418
 419         $tid = $self->next_thread_id unless defined $tid;
 420
 421         my $doc = Search::Xapian::Document->new;
 422         $doc->add_term(xpfx('mid') . $mid);
 423         $doc->add_term(xpfx('thread') . $tid);
 424         $doc->add_term(xpfx('type') . 'ghost');
 425
 426         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 427         $self->link_message($smsg, 1);
 428         $self->{xdb}->add_document($doc);
 429
 430         $smsg;
 431 }
 432
 433 sub merge_threads {
 434         my ($self, $winner_tid, $loser_tid) = @_;
 435         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 436         my $thread_pfx = xpfx('thread');
 437         my $db = $self->{xdb};
 438
 439         for (; $head != $tail; $head->inc) {
 440                 my $docid = $head->get_docid;
 441                 my $doc = $db->get_document($docid);
 442                 $doc->remove_term($thread_pfx . $loser_tid);
 443                 $doc->add_term($thread_pfx . $winner_tid);
 444                 $db->replace_document($docid, $doc);
 445         }
 446 }
 447
 448 sub _read_git_config_perm {
 449         my ($self) = @_;
 450         my @cmd = qw(config core.sharedRepository);
 451         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 452         local $/ = "\n";
 453         my $perm = <$fh>;
 454         chomp $perm if defined $perm;
 455         $perm;
 456 }
 457
 458 sub _git_config_perm {
 459         my $self = shift;
 460         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 461         return PERM_GROUP if (!defined($perm) || $perm eq '');
 462         return PERM_UMASK if ($perm eq 'umask');
 463         return PERM_GROUP if ($perm eq 'group');
 464         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 465                 return PERM_EVERYBODY;
 466         }
 467         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 468         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 469
 470         my $i = oct($perm);
 471         return PERM_UMASK if ($i == PERM_UMASK);
 472         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 473         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 474
 475         if (($i & 0600) != 0600) {
 476                 die "core.sharedRepository mode invalid: ".
 477                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 478         }
 479         ($i & 0666);
 480 }
 481
 482 sub _umask_for {
 483         my ($perm) = @_; # _git_config_perm return value
 484         my $rv = $perm;
 485         return umask if $rv == 0;
 486
 487         # set +x bit if +r or +w were set
 488         $rv |= 0100 if ($rv & 0600);
 489         $rv |= 0010 if ($rv & 0060);
 490         $rv |= 0001 if ($rv & 0006);
 491         (~$rv & 0777);
 492 }
 493
 494 sub with_umask {
 495         my ($self, $cb) = @_;
 496         my $old = umask $self->{umask};
 497         my $rv = eval { $cb->() };
 498         my $err = $@;
 499         umask $old;
 500         die $err if $@;
 501         $rv;
 502 }
 503
 504 1;