lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 my $X = \%PublicInbox::Search::X;
  23 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  24 use constant {
  25         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000,
  27         DEBUG => !!$ENV{DEBUG},
  28 };
  29
  30 my $xapianlevels = qr/\A(?:full|medium)\z/;
  31
  32 sub new {
  33         my ($class, $ibx, $creat, $shard) = @_;
  34         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  35         my $levels = qr/\A(?:full|medium|basic)\z/;
  36         my $inboxdir = $ibx->{inboxdir};
  37         my $version = $ibx->{version} || 1;
  38         my $indexlevel = 'full';
  39         my $altid = $ibx->{altid};
  40         if ($altid) {
  41                 require PublicInbox::AltId;
  42                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  43         }
  44         if ($ibx->{indexlevel}) {
  45                 if ($ibx->{indexlevel} =~ $levels) {
  46                         $indexlevel = $ibx->{indexlevel};
  47                 } else {
  48                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  49                 }
  50         }
  51         $ibx = PublicInbox::InboxWritable->new($ibx);
  52         my $self = bless {
  53                 inboxdir => $inboxdir,
  54                 -inbox => $ibx,
  55                 git => $ibx->git,
  56                 -altid => $altid,
  57                 version => $version,
  58                 indexlevel => $indexlevel,
  59         }, $class;
  60         $ibx->umask_prepare;
  61         if ($version == 1) {
  62                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  63                 my $dir = $self->xdir;
  64                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  65         } elsif ($version == 2) {
  66                 defined $shard or die "shard is required for v2\n";
  67                 # shard is a number
  68                 $self->{shard} = $shard;
  69                 $self->{lock_path} = undef;
  70         } else {
  71                 die "unsupported inbox version=$version\n";
  72         }
  73         $self->{creat} = ($creat || 0) == 1;
  74         $self;
  75 }
  76
  77 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  78
  79 sub _xdb_release {
  80         my ($self) = @_;
  81         if (need_xapian($self)) {
  82                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  83                 $xdb->close;
  84         }
  85         $self->lock_release if $self->{creat};
  86         undef;
  87 }
  88
  89 sub load_xapian_writable () {
  90         return 1 if $X->{WritableDatabase};
  91         PublicInbox::Search::load_xapian() or return;
  92         my $xap = $PublicInbox::Search::Xap;
  93         for (qw(Document TermGenerator WritableDatabase)) {
  94                 $X->{$_} = $xap.'::'.$_;
  95         }
  96         eval 'require '.$X->{WritableDatabase} or die;
  97         *sortable_serialise = $xap.'::sortable_serialise';
  98         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
  99         $DB_OPEN = eval($xap.'::DB_OPEN()');
 100         1;
 101 }
 102
 103 sub _xdb_acquire {
 104         my ($self) = @_;
 105         my $flag;
 106         my $dir = $self->xdir;
 107         if (need_xapian($self)) {
 108                 croak 'already acquired' if $self->{xdb};
 109                 load_xapian_writable();
 110                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 111         }
 112         if ($self->{creat}) {
 113                 require File::Path;
 114                 $self->lock_acquire;
 115
 116                 # don't create empty Xapian directories if we don't need Xapian
 117                 my $is_shard = defined($self->{shard});
 118                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 119                         File::Path::mkpath($dir);
 120                 }
 121         }
 122         return unless defined $flag;
 123         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 124         if ($@) {
 125                 die "Failed opening $dir: ", $@;
 126         }
 127         $self->{xdb} = $xdb;
 128 }
 129
 130 sub add_val ($$$) {
 131         my ($doc, $col, $num) = @_;
 132         $num = sortable_serialise($num);
 133         $doc->add_value($col, $num);
 134 }
 135
 136 sub index_text ($$$$)
 137 {
 138         my ($self, $field, $n, $text) = @_;
 139         my $tg = $self->term_generator;
 140
 141         if ($self->{indexlevel} eq 'full') {
 142                 $tg->index_text($field, $n, $text);
 143                 $tg->increase_termpos;
 144         } else {
 145                 $tg->index_text_without_positions($field, $n, $text);
 146         }
 147 }
 148
 149 sub index_users ($$) {
 150         my ($self, $smsg) = @_;
 151
 152         my $from = $smsg->from;
 153         my $to = $smsg->to;
 154         my $cc = $smsg->cc;
 155
 156         $self->index_text($from, 1, 'A'); # A - author
 157         $self->index_text($to, 1, 'XTO') if $to ne '';
 158         $self->index_text($cc, 1, 'XCC') if $cc ne '';
 159 }
 160
 161 sub index_diff_inc ($$$$) {
 162         my ($self, $text, $pfx, $xnq) = @_;
 163         if (@$xnq) {
 164                 $self->index_text(join("\n", @$xnq), 1, 'XNQ');
 165                 @$xnq = ();
 166         }
 167         $self->index_text($text, 1, $pfx);
 168 }
 169
 170 sub index_old_diff_fn {
 171         my ($self, $seen, $fa, $fb, $xnq) = @_;
 172
 173         # no renames or space support for traditional diffs,
 174         # find the number of leading common paths to strip:
 175         my @fa = split('/', $fa);
 176         my @fb = split('/', $fb);
 177         while (scalar(@fa) && scalar(@fb)) {
 178                 $fa = join('/', @fa);
 179                 $fb = join('/', @fb);
 180                 if ($fa eq $fb) {
 181                         unless ($seen->{$fa}++) {
 182                                 $self->index_diff_inc($fa, 'XDFN', $xnq);
 183                         }
 184                         return 1;
 185                 }
 186                 shift @fa;
 187                 shift @fb;
 188         }
 189         0;
 190 }
 191
 192 sub index_diff ($$$) {
 193         my ($self, $lines, $doc) = @_;
 194         my %seen;
 195         my $in_diff;
 196         my @xnq;
 197         my $xnq = \@xnq;
 198         foreach (@$lines) {
 199                 if ($in_diff && s/^ //) { # diff context
 200                         $self->index_diff_inc($_, 'XDFCTX', $xnq);
 201                 } elsif (/^-- $/) { # email signature begins
 202                         $in_diff = undef;
 203                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 204                         my ($fa, $fb) = ($1, $2);
 205                         my $fn = (split('/', git_unquote($fa), 2))[1];
 206                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 207                         $fn = (split('/', git_unquote($fb), 2))[1];
 208                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 209                         $in_diff = 1;
 210                 # traditional diff:
 211                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 212                         my ($opt, $fa, $fb) = ($1, $2, $3);
 213                         push @xnq, $_;
 214                         # only support unified:
 215                         next unless $opt =~ /[uU]/;
 216                         $in_diff = $self->index_old_diff_fn(\%seen, $fa, $fb,
 217                                                         $xnq);
 218                 } elsif (m!^--- ("?a/.+)!) {
 219                         my $fn = $1;
 220                         $fn = (split('/', git_unquote($fn), 2))[1];
 221                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 222                         $in_diff = 1;
 223                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 224                         my $fn = $1;
 225                         $fn = (split('/', git_unquote($fn), 2))[1];
 226                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 227                         $in_diff = 1;
 228                 } elsif (/^--- (\S+)/) {
 229                         $in_diff = $1;
 230                         push @xnq, $_;
 231                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 232                         $in_diff = $self->index_old_diff_fn(\%seen, $in_diff, $1,
 233                                                         $xnq);
 234                 } elsif ($in_diff && s/^\+//) { # diff added
 235                         $self->index_diff_inc($_, 'XDFB', $xnq);
 236                 } elsif ($in_diff && s/^-//) { # diff removed
 237                         $self->index_diff_inc($_, 'XDFA', $xnq);
 238                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 239                         my ($ba, $bb) = ($1, $2);
 240                         index_git_blob_id($doc, 'XDFPRE', $ba);
 241                         index_git_blob_id($doc, 'XDFPOST', $bb);
 242                         $in_diff = 1;
 243                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 244                         # traditional diff w/o -p
 245                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 246                         # hunk header context
 247                         $self->index_diff_inc($1, 'XDFHH', $xnq);
 248                 # ignore the following lines:
 249                 } elsif (/^(?:dis)similarity index/ ||
 250                                 /^(?:old|new) mode/ ||
 251                                 /^(?:deleted|new) file mode/ ||
 252                                 /^(?:copy|rename) (?:from|to) / ||
 253                                 /^(?:dis)?similarity index / ||
 254                                 /^\\ No newline at end of file/ ||
 255                                 /^Binary files .* differ/) {
 256                         push @xnq, $_;
 257                 } elsif ($_ eq '') {
 258                         # possible to be in diff context, some mail may be
 259                         # stripped by MUA or even GNU diff(1).  "git apply"
 260                         # treats a bare "\n" as diff context, too
 261                 } else {
 262                         push @xnq, $_;
 263                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 264                         $in_diff = undef;
 265                 }
 266         }
 267
 268         $self->index_text(join("\n", @xnq), 1, 'XNQ');
 269 }
 270
 271 sub index_body ($$$) {
 272         my ($self, $lines, $doc) = @_;
 273         my $txt = join("\n", @$lines);
 274         if ($doc) {
 275                 # does it look like a diff?
 276                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 277                         $txt = undef;
 278                         $self->index_diff($lines, $doc);
 279                 } else {
 280                         $self->index_text($txt, 1, 'XNQ');
 281                 }
 282         } else {
 283                 $self->index_text($txt, 0, 'XQUOT');
 284         }
 285         @$lines = ();
 286 }
 287
 288 sub add_xapian ($$$$$) {
 289         my ($self, $mime, $num, $oid, $mids, $mid0) = @_;
 290         my $smsg = PublicInbox::SearchMsg->new($mime);
 291         my $doc = $X->{Document}->new;
 292         my $subj = $smsg->subject;
 293         add_val($doc, PublicInbox::Search::TS(), $smsg->ts);
 294         my @ds = gmtime($smsg->ds);
 295         my $yyyymmdd = strftime('%Y%m%d', @ds);
 296         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 297         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 298         add_val($doc, PublicInbox::Search::DT(), $dt);
 299
 300         my $tg = $self->term_generator;
 301
 302         $tg->set_document($doc);
 303         $self->index_text($subj, 1, 'S') if $subj;
 304         $self->index_users($smsg);
 305
 306         msg_iter($mime, sub {
 307                 my ($part, $depth, @idx) = @{$_[0]};
 308                 my $ct = $part->content_type || 'text/plain';
 309                 my $fn = $part->filename;
 310                 if (defined $fn && $fn ne '') {
 311                         $self->index_text($fn, 1, 'XFN');
 312                 }
 313
 314                 my ($s, undef) = msg_part_text($part, $ct);
 315                 defined $s or return;
 316
 317                 my (@orig, @quot);
 318                 my @lines = split(/\n/, $s);
 319                 while (defined(my $l = shift @lines)) {
 320                         if ($l =~ /^>/) {
 321                                 $self->index_body(\@orig, $doc) if @orig;
 322                                 push @quot, $l;
 323                         } else {
 324                                 $self->index_body(\@quot, 0) if @quot;
 325                                 push @orig, $l;
 326                         }
 327                 }
 328                 $self->index_body(\@quot, 0) if @quot;
 329                 $self->index_body(\@orig, $doc) if @orig;
 330         });
 331
 332         foreach my $mid (@$mids) {
 333                 $self->index_text($mid, 1, 'XM');
 334
 335                 # because too many Message-IDs are prefixed with
 336                 # "Pine.LNX."...
 337                 if ($mid =~ /\w{12,}/) {
 338                         my @long = ($mid =~ /(\w{3,}+)/g);
 339                         $self->index_text(join(' ', @long), 1, 'XM');
 340                 }
 341         }
 342         $smsg->{to} = $smsg->{cc} = '';
 343         PublicInbox::OverIdx::parse_references($smsg, $mid0, $mids);
 344         my $data = $smsg->to_doc_data($oid, $mid0);
 345         $doc->set_data($data);
 346         if (my $altid = $self->{-altid}) {
 347                 foreach my $alt (@$altid) {
 348                         my $pfx = $alt->{xprefix};
 349                         foreach my $mid (@$mids) {
 350                                 my $id = $alt->mid2alt($mid);
 351                                 next unless defined $id;
 352                                 $doc->add_boolean_term($pfx . $id);
 353                         }
 354                 }
 355         }
 356         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 357         $self->{xdb}->replace_document($num, $doc);
 358 }
 359
 360 sub add_message {
 361         # mime = Email::MIME object
 362         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 363         my $mids = mids_for_index($mime->header_obj);
 364         $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 365         unless (defined $num) { # v1
 366                 $self->_msgmap_init;
 367                 $num = index_mm($self, $mime);
 368         }
 369         eval {
 370                 if (need_xapian($self)) {
 371                         $self->add_xapian($mime, $num, $oid, $mids, $mid0)
 372                 }
 373                 if (my $over = $self->{over}) {
 374                         $over->add_overview($mime, $bytes, $num, $oid, $mid0);
 375                 }
 376         };
 377
 378         if ($@) {
 379                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 380                 return undef;
 381         }
 382         $num;
 383 }
 384
 385 # returns begin and end PostingIterator
 386 sub find_doc_ids {
 387         my ($self, $termval) = @_;
 388         my $db = $self->{xdb};
 389
 390         ($db->postlist_begin($termval), $db->postlist_end($termval));
 391 }
 392
 393 # v1 only
 394 sub batch_do {
 395         my ($self, $termval, $cb) = @_;
 396         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 397         while (1) {
 398                 my ($head, $tail) = $self->find_doc_ids($termval);
 399                 return if $head == $tail;
 400                 my @ids;
 401                 for (; $head != $tail && @ids < $batch_size; $head++) {
 402                         push @ids, $head->get_docid;
 403                 }
 404                 $cb->(\@ids);
 405         }
 406 }
 407
 408 # v1 only, where $mid is unique
 409 sub remove_message {
 410         my ($self, $mid) = @_;
 411         $mid = mid_clean($mid);
 412
 413         if (my $over = $self->{over}) {
 414                 my $nr = eval { $over->remove_oid(undef, $mid) };
 415                 if ($@) {
 416                         warn "failed to remove <$mid> from overview: $@\n";
 417                 } elsif ($nr == 0) {
 418                         warn "<$mid> missing for removal from overview\n";
 419                 }
 420         }
 421         return unless need_xapian($self);
 422         my $db = $self->{xdb};
 423         my $nr = 0;
 424         eval {
 425                 batch_do($self, 'Q' . $mid, sub {
 426                         my ($ids) = @_;
 427                         $db->delete_document($_) for @$ids;
 428                         $nr = scalar @$ids;
 429                 });
 430         };
 431         if ($@) {
 432                 warn "failed to remove <$mid> from Xapian: $@\n";
 433         } elsif ($nr == 0) {
 434                 warn "<$mid> missing for removal from Xapian\n";
 435         }
 436 }
 437
 438 # MID is a hint in V2
 439 sub remove_by_oid {
 440         my ($self, $oid, $mid) = @_;
 441
 442         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 443
 444         return unless need_xapian($self);
 445         my $db = $self->{xdb};
 446
 447         # XXX careful, we cannot use batch_do here since we conditionally
 448         # delete documents based on other factors, so we cannot call
 449         # find_doc_ids twice.
 450         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 451         return if $head == $tail;
 452
 453         # there is only ONE element in @delete unless we
 454         # have bugs in our v2writable deduplication check
 455         my @delete;
 456         for (; $head != $tail; $head++) {
 457                 my $docid = $head->get_docid;
 458                 my $doc = $db->get_document($docid);
 459                 my $smsg = PublicInbox::SearchMsg->wrap($mid);
 460                 $smsg->load_expand($doc);
 461                 if ($smsg->{blob} eq $oid) {
 462                         push(@delete, $docid);
 463                 }
 464         }
 465         $db->delete_document($_) foreach @delete;
 466         scalar(@delete);
 467 }
 468
 469 sub term_generator { # write-only
 470         my ($self) = @_;
 471
 472         my $tg = $self->{term_generator};
 473         return $tg if $tg;
 474
 475         $tg = $X->{TermGenerator}->new;
 476         $tg->set_stemmer($self->stemmer);
 477
 478         $self->{term_generator} = $tg;
 479 }
 480
 481 sub index_git_blob_id {
 482         my ($doc, $pfx, $objid) = @_;
 483
 484         my $len = length($objid);
 485         for (my $len = length($objid); $len >= 7; ) {
 486                 $doc->add_term($pfx.$objid);
 487                 $objid = substr($objid, 0, --$len);
 488         }
 489 }
 490
 491 sub unindex_blob {
 492         my ($self, $mime) = @_;
 493         my $mid = eval { mid_clean(mid_mime($mime)) };
 494         $self->remove_message($mid) if defined $mid;
 495 }
 496
 497 sub index_mm {
 498         my ($self, $mime) = @_;
 499         my $mid = mid_clean(mid_mime($mime));
 500         my $mm = $self->{mm};
 501         my $num;
 502
 503         if (defined $self->{regen_down}) {
 504                 $num = $mm->num_for($mid) and return $num;
 505
 506                 while (($num = $self->{regen_down}--) > 0) {
 507                         if ($mm->mid_set($num, $mid) != 0) {
 508                                 return $num;
 509                         }
 510                 }
 511         } elsif (defined $self->{regen_up}) {
 512                 $num = $mm->num_for($mid) and return $num;
 513
 514                 # this is to fixup old bugs due to add-remove-add
 515                 while (($num = ++$self->{regen_up})) {
 516                         if ($mm->mid_set($num, $mid) != 0) {
 517                                 return $num;
 518                         }
 519                 }
 520         }
 521
 522         $num = $mm->mid_insert($mid) and return $num;
 523
 524         # fallback to num_for since filters like RubyLang set the number
 525         $mm->num_for($mid);
 526 }
 527
 528 sub unindex_mm {
 529         my ($self, $mime) = @_;
 530         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 531 }
 532
 533 sub index_both {
 534         my ($self, $mime, $bytes, $blob) = @_;
 535         my $num = index_mm($self, $mime);
 536         add_message($self, $mime, $bytes, $num, $blob);
 537 }
 538
 539 sub unindex_both {
 540         my ($self, $mime) = @_;
 541         unindex_blob($self, $mime);
 542         unindex_mm($self, $mime);
 543 }
 544
 545 sub do_cat_mail {
 546         my ($git, $blob, $sizeref) = @_;
 547         my $mime = eval {
 548                 my $str = $git->cat_file($blob, $sizeref);
 549                 # fixup bugs from import:
 550                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 551                 PublicInbox::MIME->new($str);
 552         };
 553         $@ ? undef : $mime;
 554 }
 555
 556 # called by public-inbox-index
 557 sub index_sync {
 558         my ($self, $opts) = @_;
 559         delete $self->{lock_path} if $opts->{-skip_lock};
 560         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 561 }
 562
 563 sub batch_adjust ($$$$$) {
 564         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 565         $$max -= $bytes;
 566         if ($$max <= 0) {
 567                 $$max = BATCH_BYTES;
 568                 $batch_cb->($nr, $latest);
 569         }
 570 }
 571
 572 # only for v1
 573 sub read_log {
 574         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 575         my $hex = '[a-f0-9]';
 576         my $h40 = $hex .'{40}';
 577         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 578         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 579         my $git = $self->{git};
 580         my $latest;
 581         my $bytes;
 582         my $max = BATCH_BYTES;
 583         local $/ = "\n";
 584         my %D;
 585         my $line;
 586         my $newest;
 587         my $nr = 0;
 588         while (defined($line = <$log>)) {
 589                 if ($line =~ /$addmsg/o) {
 590                         my $blob = $1;
 591                         if (delete $D{$blob}) {
 592                                 if (defined $self->{regen_down}) {
 593                                         my $num = $self->{regen_down}--;
 594                                         $self->{mm}->num_highwater($num);
 595                                 }
 596                                 next;
 597                         }
 598                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 599                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 600                         $add_cb->($self, $mime, $bytes, $blob);
 601                 } elsif ($line =~ /$delmsg/o) {
 602                         my $blob = $1;
 603                         $D{$blob} = 1;
 604                 } elsif ($line =~ /^commit ($h40)/o) {
 605                         $latest = $1;
 606                         $newest ||= $latest;
 607                 }
 608         }
 609         close($log) or die "git log failed: \$?=$?";
 610         # get the leftovers
 611         foreach my $blob (keys %D) {
 612                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 613                 $del_cb->($self, $mime);
 614         }
 615         $batch_cb->($nr, $latest, $newest);
 616 }
 617
 618 sub _msgmap_init {
 619         my ($self) = @_;
 620         die "BUG: _msgmap_init is only for v1\n" if $self->{version} != 1;
 621         $self->{mm} ||= eval {
 622                 require PublicInbox::Msgmap;
 623                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 624         };
 625 }
 626
 627 sub _git_log {
 628         my ($self, $opts, $range) = @_;
 629         my $git = $self->{git};
 630
 631         if (index($range, '..') < 0) {
 632                 # don't show annoying git errrors to users who run -index
 633                 # on empty inboxes
 634                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 635                 if ($?) {
 636                         open my $fh, '<', '/dev/null' or
 637                                 die "failed to open /dev/null: $!\n";
 638                         return $fh;
 639                 }
 640         }
 641
 642         # Count the new files so they can be added newest to oldest
 643         # and still have numbers increasing from oldest to newest
 644         my $fcount = 0;
 645         my $pr = $opts->{-progress};
 646         $pr->("counting changes\n\t$range ... ") if $pr;
 647         # can't use 'rev-list --count' if we use --diff-filter
 648         my $fh = $git->popen(qw(log --pretty=tformat:%h
 649                              --no-notes --no-color --no-renames
 650                              --diff-filter=AM), $range);
 651         ++$fcount while <$fh>;
 652         close $fh or die "git log failed: \$?=$?";
 653         my $high = $self->{mm}->num_highwater;
 654         $pr->("$fcount\n") if $pr; # continue previous line
 655         $self->{ntodo} = $fcount;
 656
 657         if (index($range, '..') < 0) {
 658                 if ($high && $high == $fcount) {
 659                         # fix up old bugs in full indexes which caused messages to
 660                         # not appear in Msgmap
 661                         $self->{regen_up} = $high;
 662                 } else {
 663                         # normal regen is for for fresh data
 664                         $self->{regen_down} = $fcount;
 665                 }
 666         } else {
 667                 # Give oldest messages the smallest numbers
 668                 $self->{regen_down} = $high + $fcount;
 669         }
 670
 671         $git->popen(qw/log --no-notes --no-color --no-renames
 672                                 --raw -r --no-abbrev/, $range);
 673 }
 674
 675 # --is-ancestor requires git 1.8.0+
 676 sub is_ancestor ($$$) {
 677         my ($git, $cur, $tip) = @_;
 678         return 0 unless $git->check($cur);
 679         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 680                 qw(merge-base --is-ancestor), $cur, $tip ];
 681         my $pid = spawn($cmd);
 682         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 683         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 684         $? == 0;
 685 }
 686
 687 sub need_update ($$$) {
 688         my ($self, $cur, $new) = @_;
 689         my $git = $self->{git};
 690         return 1 if $cur && !is_ancestor($git, $cur, $new);
 691         my $range = $cur eq '' ? $new : "$cur..$new";
 692         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 693         ($n eq '' || $n > 0);
 694 }
 695
 696 # The last git commit we indexed with Xapian or SQLite (msgmap)
 697 # This needs to account for cases where Xapian or SQLite is
 698 # out-of-date with respect to the other.
 699 sub _last_x_commit {
 700         my ($self, $mm) = @_;
 701         my $lm = $mm->last_commit || '';
 702         my $lx = '';
 703         if (need_xapian($self)) {
 704                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 705         } else {
 706                 $lx = $lm;
 707         }
 708         # Use last_commit from msgmap if it is older or unset
 709         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 710                 $lx = $lm;
 711         }
 712         $lx;
 713 }
 714
 715 sub reindex_from ($$) {
 716         my ($reindex, $last_commit) = @_;
 717         return $last_commit unless $reindex;
 718         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 719 }
 720
 721 # indexes all unindexed messages (v1 only)
 722 sub _index_sync {
 723         my ($self, $opts) = @_;
 724         my $tip = $opts->{ref} || 'HEAD';
 725         my ($last_commit, $lx, $xlog);
 726         my $git = $self->{git};
 727         $git->batch_prepare;
 728         my $pr = $opts->{-progress};
 729
 730         my $xdb = $self->begin_txn_lazy;
 731         my $mm = _msgmap_init($self);
 732         do {
 733                 if ($xlog) {
 734                         close($xlog) or die "git log failed: \$?=$?";
 735                         $xlog = undef;
 736                 }
 737                 $last_commit = _last_x_commit($self, $mm);
 738                 $lx = reindex_from($opts->{reindex}, $last_commit);
 739
 740                 $self->{over}->rollback_lazy;
 741                 $self->{over}->disconnect;
 742                 $git->cleanup;
 743                 delete $self->{txn};
 744                 $xdb->cancel_transaction if $xdb;
 745                 $xdb = _xdb_release($self);
 746
 747                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 748                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 749                 $xlog = _git_log($self, $opts, $range);
 750
 751                 $xdb = $self->begin_txn_lazy;
 752         } while (_last_x_commit($self, $mm) ne $last_commit);
 753
 754         my $dbh = $mm->{dbh} if $mm;
 755         my $cb = sub {
 756                 my ($nr, $commit, $newest) = @_;
 757                 if ($dbh) {
 758                         if ($newest) {
 759                                 my $cur = $mm->last_commit || '';
 760                                 if (need_update($self, $cur, $newest)) {
 761                                         $mm->last_commit($newest);
 762                                 }
 763                         }
 764                         $dbh->commit;
 765                 }
 766                 if ($newest && need_xapian($self)) {
 767                         my $cur = $xdb->get_metadata('last_commit');
 768                         if (need_update($self, $cur, $newest)) {
 769                                 $xdb->set_metadata('last_commit', $newest);
 770                         }
 771                 }
 772                 $self->commit_txn_lazy;
 773                 $git->cleanup;
 774                 $xdb = _xdb_release($self);
 775                 # let another process do some work... <
 776                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 777                 if (!$newest) {
 778                         $xdb = $self->begin_txn_lazy;
 779                         $dbh->begin_work if $dbh;
 780                 }
 781         };
 782
 783         $dbh->begin_work;
 784         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 785 }
 786
 787 sub DESTROY {
 788         # order matters for unlocking
 789         $_[0]->{xdb} = undef;
 790         $_[0]->{lockfh} = undef;
 791 }
 792
 793 # remote_* subs are only used by SearchIdxPart
 794 sub remote_commit {
 795         my ($self) = @_;
 796         if (my $w = $self->{w}) {
 797                 print $w "commit\n" or die "failed to write commit: $!";
 798         } else {
 799                 $self->commit_txn_lazy;
 800         }
 801 }
 802
 803 sub remote_close {
 804         my ($self) = @_;
 805         if (my $w = delete $self->{w}) {
 806                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 807                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 808                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 809                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 810                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 811         } else {
 812                 die "transaction in progress $self\n" if $self->{txn};
 813                 $self->_xdb_release if $self->{xdb};
 814         }
 815 }
 816
 817 sub remote_remove {
 818         my ($self, $oid, $mid) = @_;
 819         if (my $w = $self->{w}) {
 820                 # triggers remove_by_oid in a shard
 821                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 822         } else {
 823                 $self->begin_txn_lazy;
 824                 $self->remove_by_oid($oid, $mid);
 825         }
 826 }
 827
 828 sub begin_txn_lazy {
 829         my ($self) = @_;
 830         return if $self->{txn};
 831
 832         $self->{-inbox}->with_umask(sub {
 833                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 834                 $self->{over}->begin_lazy if $self->{over};
 835                 $xdb->begin_transaction if $xdb;
 836                 $self->{txn} = 1;
 837                 $xdb;
 838         });
 839 }
 840
 841 sub commit_txn_lazy {
 842         my ($self) = @_;
 843         delete $self->{txn} or return;
 844         $self->{-inbox}->with_umask(sub {
 845                 if (my $xdb = $self->{xdb}) {
 846
 847                         # store 'indexlevel=medium' in v2 shard=0 and
 848                         # v1 (only one shard)
 849                         # This metadata is read by Admin::detect_indexlevel:
 850                         if (!$self->{shard} # undef or 0, not >0
 851                             && $self->{indexlevel} eq 'medium') {
 852                                 $xdb->set_metadata('indexlevel', 'medium');
 853                         }
 854
 855                         $xdb->commit_transaction;
 856                 }
 857                 $self->{over}->commit_lazy if $self->{over};
 858         });
 859 }
 860
 861 sub worker_done {
 862         my ($self) = @_;
 863         if (need_xapian($self)) {
 864                 die "$$ $0 xdb not released\n" if $self->{xdb};
 865         }
 866         die "$$ $0 still in transaction\n" if $self->{txn};
 867 }
 868
 869 1;