lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchIdx;
   5 use strict;
   6 use warnings;
   7 use base qw(PublicInbox::Search);
   8 use PublicInbox::MID qw/mid_clean mid_compress/;
   9 *xpfx = *PublicInbox::Search::xpfx;
  10
  11 use constant {
  12         PERM_UMASK => 0,
  13         OLD_PERM_GROUP => 1,
  14         OLD_PERM_EVERYBODY => 2,
  15         PERM_GROUP => 0660,
  16         PERM_EVERYBODY => 0664,
  17 };
  18
  19 sub new {
  20         my ($class, $git_dir, $writable) = @_;
  21         my $dir = $class->xdir($git_dir);
  22         require Search::Xapian::WritableDatabase;
  23         my $flag = Search::Xapian::DB_OPEN;
  24         my $self = bless { git_dir => $git_dir }, $class;
  25         my $perm = $self->_git_config_perm;
  26         my $umask = _umask_for($perm);
  27         $self->{umask} = $umask;
  28         $self->{xdb} = $self->with_umask(sub {
  29                 if ($writable == 1) {
  30                         require File::Path;
  31                         File::Path::mkpath($dir);
  32                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  33                 }
  34                 Search::Xapian::WritableDatabase->new($dir, $flag);
  35         });
  36         $self;
  37 }
  38
  39 sub add_message {
  40         my ($self, $mime) = @_; # mime = Email::MIME object
  41         my $db = $self->{xdb};
  42
  43         my $doc_id;
  44         my $mid_orig = mid_clean($mime->header('Message-ID'));
  45         my $mid = mid_compress($mid_orig);
  46         my $was_ghost = 0;
  47         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  48
  49         eval {
  50                 my $smsg = $self->lookup_message($mid);
  51                 my $doc;
  52
  53                 if ($smsg) {
  54                         $smsg->ensure_metadata;
  55                         # convert a ghost to a regular message
  56                         # it will also clobber any existing regular message
  57                         $smsg->mime($mime);
  58                         $doc = $smsg->{doc};
  59
  60                         my $type = xpfx('type');
  61                         eval {
  62                                 $doc->remove_term($type . 'ghost');
  63                                 $was_ghost = 1;
  64                         };
  65
  66                         # probably does not exist:
  67                         eval { $doc->remove_term($type . 'mail') };
  68                         $doc->add_term($type . 'mail');
  69                 }  else {
  70                         $smsg = PublicInbox::SearchMsg->new($mime);
  71                         $doc = $smsg->{doc};
  72                         $doc->add_term(xpfx('mid') . $mid);
  73                 }
  74
  75                 my $subj = $smsg->subject;
  76
  77                 if ($subj ne '') {
  78                         $doc->add_term(xpfx('subject') . $subj);
  79
  80                         my $path = $self->subject_path($subj);
  81                         $doc->add_term(xpfx('path') . mid_compress($path));
  82                 }
  83
  84                 my $from = $smsg->from_name;
  85                 my $date = $smsg->date;
  86                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
  87                 $doc->add_value(PublicInbox::Search::TS, $ts);
  88
  89                 my $tg = $self->term_generator;
  90
  91                 $tg->set_document($doc);
  92                 $tg->index_text($subj, 1, 'S') if $subj;
  93                 $tg->increase_termpos;
  94                 $tg->index_text($subj) if $subj;
  95                 $tg->increase_termpos;
  96
  97                 $tg->index_text($smsg->from->format);
  98                 $tg->increase_termpos;
  99
 100                 $mime->walk_parts(sub {
 101                         my ($part) = @_;
 102                         return if $part->subparts; # walk_parts already recurses
 103                         my $ct = $part->content_type || $ct_msg;
 104
 105                         # account for filter bugs...
 106                         $ct =~ m!\btext/plain\b!i or return;
 107
 108                         my (@orig, @quot);
 109                         my $body = $part->body;
 110                         $part->body_set('');
 111                         my @lines = split(/\n/, $body);
 112                         while (defined(my $l = shift @lines)) {
 113                                 if ($l =~ /^\s*>/) {
 114                                         push @quot, $l;
 115                                 } else {
 116                                         push @orig, $l;
 117                                 }
 118                         }
 119                         if (@quot) {
 120                                 $tg->index_text(join("\n", @quot), 0);
 121                                 @quot = ();
 122                                 $tg->increase_termpos;
 123                         }
 124                         if (@orig) {
 125                                 $tg->index_text(join("\n", @orig));
 126                                 @orig = ();
 127                                 $tg->increase_termpos;
 128                         }
 129                 });
 130
 131                 if ($was_ghost) {
 132                         $doc_id = $smsg->doc_id;
 133                         $self->link_message($smsg, 0);
 134                         $doc->set_data($smsg->to_doc_data);
 135                         $db->replace_document($doc_id, $doc);
 136                 } else {
 137                         $self->link_message($smsg, 0);
 138                         $doc->set_data($smsg->to_doc_data);
 139                         $doc_id = $db->add_document($doc);
 140                 }
 141         };
 142
 143         if ($@) {
 144                 warn "failed to index message <$mid_orig>: $@\n";
 145                 return undef;
 146         }
 147         $doc_id;
 148 }
 149
 150 # returns deleted doc_id on success, undef on missing
 151 sub remove_message {
 152         my ($self, $mid_orig) = @_;
 153         my $db = $self->{xdb};
 154         my $doc_id;
 155         $mid_orig = mid_clean($mid_orig);
 156         my $mid = mid_compress($mid_orig);
 157
 158         eval {
 159                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 160                 $db->delete_document($doc_id) if defined $doc_id;
 161         };
 162
 163         if ($@) {
 164                 warn "failed to remove message <$mid_orig>: $@\n";
 165                 return undef;
 166         }
 167         $doc_id;
 168 }
 169
 170 sub term_generator { # write-only
 171         my ($self) = @_;
 172
 173         my $tg = $self->{term_generator};
 174         return $tg if $tg;
 175
 176         $tg = Search::Xapian::TermGenerator->new;
 177         $tg->set_stemmer($self->stemmer);
 178
 179         $self->{term_generator} = $tg;
 180 }
 181
 182 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 183
 184 # increments last_thread_id counter
 185 # returns a 64-bit integer represented as a hex string
 186 sub next_thread_id {
 187         my ($self) = @_;
 188         my $db = $self->{xdb};
 189         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 190
 191         $db->set_metadata('last_thread_id', ++$last_thread_id);
 192
 193         $last_thread_id;
 194 }
 195
 196 sub link_message {
 197         my ($self, $smsg, $is_ghost) = @_;
 198
 199         if ($is_ghost) {
 200                 $smsg->ensure_metadata;
 201         } else {
 202                 $self->link_message_to_parents($smsg);
 203         }
 204 }
 205
 206 sub link_message_to_parents {
 207         my ($self, $smsg) = @_;
 208         my $doc = $smsg->{doc};
 209         my $mid = mid_compress($smsg->mid);
 210         my $mime = $smsg->mime;
 211         my $refs = $mime->header('References');
 212         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 213         my $irt = $mime->header('In-Reply-To');
 214         if ($irt) {
 215                 $irt = mid_compress(mid_clean($irt));
 216
 217                 # maybe some crazies will try to make a circular reference:
 218                 if ($irt eq $mid) {
 219                         $irt = undef;
 220                 } else {
 221                         # last References should be $irt
 222                         # we will de-dupe later
 223                         push @refs, $irt;
 224                 }
 225         }
 226
 227         my $tid;
 228         if (@refs) {
 229                 my @crefs = map { mid_compress($_) } @refs;
 230                 my %uniq = ($mid => 1);
 231
 232                 # prevent circular references via References: here:
 233                 @refs = ();
 234                 foreach my $ref (@crefs) {
 235                         next if $uniq{$ref};
 236                         $uniq{$ref} = 1;
 237                         push @refs, $ref;
 238                 }
 239         }
 240         if (@refs) {
 241                 $doc->add_term(xpfx('inreplyto') . $irt) if defined $irt;
 242                 $smsg->{references_sorted} = '<'.join('><', @refs).'>';
 243
 244                 my $ref_pfx = xpfx('references');
 245
 246                 # first ref *should* be the thread root,
 247                 # but we can never trust clients to do the right thing
 248                 my $ref = shift @refs;
 249                 $doc->add_term($ref_pfx . $ref);
 250                 $tid = $self->_resolve_mid_to_tid($ref);
 251
 252                 # the rest of the refs should point to this tid:
 253                 foreach $ref (@refs) {
 254                         $doc->add_term($ref_pfx . $ref);
 255                         my $ptid = $self->_resolve_mid_to_tid($ref);
 256                         if ($tid ne $ptid) {
 257                                 $self->merge_threads($tid, $ptid);
 258                         }
 259                 }
 260         } else {
 261                 $tid = $self->next_thread_id;
 262         }
 263         $doc->add_term(xpfx('thread') . $tid);
 264 }
 265
 266 sub index_blob {
 267         my ($self, $git, $blob) = @_;
 268         my $mime = do_cat_mail($git, $blob) or return;
 269         eval { $self->add_message($mime) };
 270         warn "W: index_blob $blob: $@\n" if $@;
 271 }
 272
 273 sub unindex_blob {
 274         my ($self, $git, $blob) = @_;
 275         my $mime = do_cat_mail($git, $blob) or return;
 276         my $mid = $mime->header('Message-ID');
 277         eval { $self->remove_message($mid) } if defined $mid;
 278         warn "W: unindex_blob $blob: $@\n" if $@;
 279 }
 280
 281 sub do_cat_mail {
 282         my ($git, $blob) = @_;
 283         my $mime = eval {
 284                 my $str = $git->cat_file($blob);
 285                 Email::MIME->new($str);
 286         };
 287         $@ ? undef : $mime;
 288 }
 289
 290 sub index_sync {
 291         my ($self, $head) = @_;
 292         $self->with_umask(sub { $self->_index_sync($head) });
 293 }
 294
 295 # indexes all unindexed messages
 296 sub _index_sync {
 297         my ($self, $head) = @_;
 298         require PublicInbox::GitCatFile;
 299         my $db = $self->{xdb};
 300         my $hex = '[a-f0-9]';
 301         my $h40 = $hex .'{40}';
 302         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 303         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 304         $head ||= 'HEAD';
 305
 306         $db->begin_transaction;
 307         eval {
 308                 my $git = PublicInbox::GitCatFile->new($self->{git_dir});
 309
 310                 my $latest = $db->get_metadata('last_commit');
 311                 my $range = $latest eq '' ? $head : "$latest..$head";
 312                 $latest = undef;
 313
 314                 # get indexed messages
 315                 my @cmd = ('git', "--git-dir=$self->{git_dir}", "log",
 316                             qw/--reverse --no-notes --no-color --raw -r
 317                                --no-abbrev/, $range);
 318                 my $pid = open(my $log, '-|', @cmd) or
 319                         die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 320
 321                 while (my $line = <$log>) {
 322                         if ($line =~ /$addmsg/o) {
 323                                 $self->index_blob($git, $1);
 324                         } elsif ($line =~ /$delmsg/o) {
 325                                 $self->unindex_blob($git, $1);
 326                         } elsif ($line =~ /^commit ($h40)/o) {
 327                                 $latest = $1;
 328                         }
 329                 }
 330                 close $log;
 331                 $db->set_metadata('last_commit', $latest) if defined $latest;
 332         };
 333         if ($@) {
 334                 warn "indexing failed: $@\n";
 335                 $db->cancel_transaction;
 336         } else {
 337                 $db->commit_transaction;
 338         }
 339 }
 340
 341 # this will create a ghost as necessary
 342 sub _resolve_mid_to_tid {
 343         my ($self, $mid) = @_;
 344
 345         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 346         $smsg->thread_id;
 347 }
 348
 349 sub create_ghost {
 350         my ($self, $mid, $tid) = @_;
 351
 352         $mid = mid_compress($mid);
 353         $tid = $self->next_thread_id unless defined $tid;
 354
 355         my $doc = Search::Xapian::Document->new;
 356         $doc->add_term(xpfx('mid') . $mid);
 357         $doc->add_term(xpfx('thread') . $tid);
 358         $doc->add_term(xpfx('type') . 'ghost');
 359
 360         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 361         $self->link_message($smsg, 1);
 362         $self->{xdb}->add_document($doc);
 363
 364         $smsg;
 365 }
 366
 367 sub merge_threads {
 368         my ($self, $winner_tid, $loser_tid) = @_;
 369         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 370         my $thread_pfx = xpfx('thread');
 371         my $db = $self->{xdb};
 372
 373         for (; $head != $tail; $head->inc) {
 374                 my $docid = $head->get_docid;
 375                 my $doc = $db->get_document($docid);
 376                 $doc->remove_term($thread_pfx . $loser_tid);
 377                 $doc->add_term($thread_pfx . $winner_tid);
 378                 $db->replace_document($docid, $doc);
 379         }
 380 }
 381
 382 sub _read_git_config_perm {
 383         my ($self) = @_;
 384         my @cmd = ('git', "--git-dir=$self->{git_dir}",
 385                    qw(config core.sharedRepository));
 386         my $pid = open(my $fh, '-|', @cmd) or
 387                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 388         my $perm = <$fh>;
 389         close $fh;
 390         chomp $perm if defined $perm;
 391         $perm;
 392 }
 393
 394 sub _git_config_perm {
 395         my $self = shift;
 396         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 397         return PERM_GROUP if (!defined($perm) || $perm eq '');
 398         return PERM_UMASK if ($perm eq 'umask');
 399         return PERM_GROUP if ($perm eq 'group');
 400         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 401                 return PERM_EVERYBODY;
 402         }
 403         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 404         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 405
 406         my $i = oct($perm);
 407         return PERM_UMASK if ($i == PERM_UMASK);
 408         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 409         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 410
 411         if (($i & 0600) != 0600) {
 412                 die "core.sharedRepository mode invalid: ".
 413                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 414         }
 415         ($i & 0666);
 416 }
 417
 418 sub _umask_for {
 419         my ($perm) = @_; # _git_config_perm return value
 420         my $rv = $perm;
 421         return umask if $rv == 0;
 422
 423         # set +x bit if +r or +w were set
 424         $rv |= 0100 if ($rv & 0600);
 425         $rv |= 0010 if ($rv & 0060);
 426         $rv |= 0001 if ($rv & 0006);
 427         (~$rv & 0777);
 428 }
 429
 430 sub with_umask {
 431         my ($self, $cb) = @_;
 432         my $old = umask $self->{umask};
 433         my $rv = eval { $cb->() };
 434         my $err = $@;
 435         umask $old;
 436         die $err if $@;
 437         $rv;
 438 }
 439
 440 1;