lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak carp);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::OverIdx;
  22 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  23 use PublicInbox::Git qw(git_unquote);
  24 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  25 our @EXPORT_OK = qw(crlf_adjust log2stack is_ancestor check_size prepare_stack
  26         index_text term_generator add_val is_bad_blob);
  27 my $X = \%PublicInbox::Search::X;
  28 our ($DB_CREATE_OR_OPEN, $DB_OPEN);
  29 our $DB_NO_SYNC = 0;
  30 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  31 use constant DEBUG => !!$ENV{DEBUG};
  32
  33 my $xapianlevels = qr/\A(?:full|medium)\z/;
  34 my $hex = '[a-f0-9]';
  35 my $OID = $hex .'{40,}';
  36 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  37
  38 sub new {
  39         my ($class, $ibx, $creat, $shard) = @_;
  40         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  41         my $inboxdir = $ibx->{inboxdir};
  42         my $version = $ibx->version;
  43         my $indexlevel = 'full';
  44         my $altid = $ibx->{altid};
  45         if ($altid) {
  46                 require PublicInbox::AltId;
  47                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  48         }
  49         if ($ibx->{indexlevel}) {
  50                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  51                         $indexlevel = $ibx->{indexlevel};
  52                 } else {
  53                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  54                 }
  55         }
  56         $ibx = PublicInbox::InboxWritable->new($ibx);
  57         my $self = bless {
  58                 ibx => $ibx,
  59                 xpfx => $inboxdir, # for xpfx_init
  60                 -altid => $altid,
  61                 ibx_ver => $version,
  62                 indexlevel => $indexlevel,
  63         }, $class;
  64         $self->xpfx_init;
  65         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  66         if ($ibx->{-skip_docdata}) {
  67                 $self->{-set_skip_docdata_once} = 1;
  68                 $self->{-skip_docdata} = 1;
  69         }
  70         $ibx->umask_prepare;
  71         if ($version == 1) {
  72                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  73                 my $dir = $self->xdir;
  74                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  75                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  76         } elsif ($version == 2) {
  77                 defined $shard or die "shard is required for v2\n";
  78                 # shard is a number
  79                 $self->{shard} = $shard;
  80                 $self->{lock_path} = undef;
  81         } else {
  82                 die "unsupported inbox version=$version\n";
  83         }
  84         $self->{creat} = ($creat || 0) == 1;
  85         $self;
  86 }
  87
  88 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  89
  90 sub idx_release {
  91         my ($self, $wake) = @_;
  92         if (need_xapian($self)) {
  93                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  94                 $xdb->close;
  95         }
  96         $self->lock_release($wake) if $self->{creat};
  97         undef;
  98 }
  99
 100 sub load_xapian_writable () {
 101         return 1 if $X->{WritableDatabase};
 102         PublicInbox::Search::load_xapian() or return;
 103         my $xap = $PublicInbox::Search::Xap;
 104         for (qw(Document TermGenerator WritableDatabase)) {
 105                 $X->{$_} = $xap.'::'.$_;
 106         }
 107         eval 'require '.$X->{WritableDatabase} or die;
 108         *sortable_serialise = $xap.'::sortable_serialise';
 109         *sortable_unserialise = $xap.'::sortable_unserialise';
 110         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 111         $DB_OPEN = eval($xap.'::DB_OPEN()');
 112         my $ver = (eval($xap.'::major_version()') << 16) |
 113                 (eval($xap.'::minor_version()') << 8);
 114         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 115         1;
 116 }
 117
 118 sub idx_acquire {
 119         my ($self) = @_;
 120         my $flag;
 121         my $dir = $self->xdir;
 122         if (need_xapian($self)) {
 123                 croak 'already acquired' if $self->{xdb};
 124                 load_xapian_writable();
 125                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 126         }
 127         if ($self->{creat}) {
 128                 require File::Path;
 129                 $self->lock_acquire;
 130
 131                 # don't create empty Xapian directories if we don't need Xapian
 132                 my $is_shard = defined($self->{shard});
 133                 if (!-d $dir && (!$is_shard ||
 134                                 ($is_shard && need_xapian($self)))) {
 135                         File::Path::mkpath($dir);
 136                         nodatacow_dir($dir);
 137                         $self->{-set_has_threadid_once} = 1;
 138                 }
 139         }
 140         return unless defined $flag;
 141         $flag |= $DB_NO_SYNC if ($self->{ibx} // $self->{eidx})->{-no_fsync};
 142         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 143         croak "Failed opening $dir: $@" if $@;
 144         $self->{xdb} = $xdb;
 145 }
 146
 147 sub add_val ($$$) {
 148         my ($doc, $col, $num) = @_;
 149         $num = sortable_serialise($num);
 150         $doc->add_value($col, $num);
 151 }
 152
 153 sub term_generator ($) { # write-only
 154         my ($self) = @_;
 155
 156         $self->{term_generator} //= do {
 157                 my $tg = $X->{TermGenerator}->new;
 158                 $tg->set_stemmer(PublicInbox::Search::stemmer($self));
 159                 $tg;
 160         }
 161 }
 162
 163 sub index_text ($$$$) {
 164         my ($self, $text, $wdf_inc, $prefix) = @_;
 165         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 166
 167         if ($self->{indexlevel} eq 'full') {
 168                 $tg->index_text($text, $wdf_inc, $prefix);
 169                 $tg->increase_termpos;
 170         } else {
 171                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 172         }
 173 }
 174
 175 sub index_headers ($$) {
 176         my ($self, $smsg) = @_;
 177         my @x = (from => 'A', # Author
 178                 subject => 'S', to => 'XTO', cc => 'XCC');
 179         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 180                 my $val = $smsg->{$field};
 181                 index_text($self, $val, 1, $pfx) if $val ne '';
 182         }
 183 }
 184
 185 sub index_diff_inc ($$$$) {
 186         my ($self, $text, $pfx, $xnq) = @_;
 187         if (@$xnq) {
 188                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 189                 @$xnq = ();
 190         }
 191         index_text($self, $text, 1, $pfx);
 192 }
 193
 194 sub index_old_diff_fn {
 195         my ($self, $seen, $fa, $fb, $xnq) = @_;
 196
 197         # no renames or space support for traditional diffs,
 198         # find the number of leading common paths to strip:
 199         my @fa = split('/', $fa);
 200         my @fb = split('/', $fb);
 201         while (scalar(@fa) && scalar(@fb)) {
 202                 $fa = join('/', @fa);
 203                 $fb = join('/', @fb);
 204                 if ($fa eq $fb) {
 205                         unless ($seen->{$fa}++) {
 206                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 207                         }
 208                         return 1;
 209                 }
 210                 shift @fa;
 211                 shift @fb;
 212         }
 213         0;
 214 }
 215
 216 sub index_diff ($$$) {
 217         my ($self, $txt, $doc) = @_;
 218         my %seen;
 219         my $in_diff;
 220         my @xnq;
 221         my $xnq = \@xnq;
 222         foreach (split(/\n/, $txt)) {
 223                 if ($in_diff && s/^ //) { # diff context
 224                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 225                 } elsif (/^-- $/) { # email signature begins
 226                         $in_diff = undef;
 227                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 228                         # wait until "---" and "+++" to capture filenames
 229                         $in_diff = 1;
 230                 # traditional diff:
 231                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 232                         my ($opt, $fa, $fb) = ($1, $2, $3);
 233                         push @xnq, $_;
 234                         # only support unified:
 235                         next unless $opt =~ /[uU]/;
 236                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 237                                                         $xnq);
 238                 } elsif (m!^--- ("?[^/]+/.+)!) {
 239                         my $fn = $1;
 240                         $fn = (split('/', git_unquote($fn), 2))[1];
 241                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 242                         $in_diff = 1;
 243                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 244                         my $fn = $1;
 245                         $fn = (split('/', git_unquote($fn), 2))[1];
 246                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 247                         $in_diff = 1;
 248                 } elsif (/^--- (\S+)/) {
 249                         $in_diff = $1;
 250                         push @xnq, $_;
 251                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 252                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 253                                                         $1, $xnq);
 254                 } elsif ($in_diff && s/^\+//) { # diff added
 255                         index_diff_inc($self, $_, 'XDFB', $xnq);
 256                 } elsif ($in_diff && s/^-//) { # diff removed
 257                         index_diff_inc($self, $_, 'XDFA', $xnq);
 258                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 259                         my ($ba, $bb) = ($1, $2);
 260                         index_git_blob_id($doc, 'XDFPRE', $ba);
 261                         index_git_blob_id($doc, 'XDFPOST', $bb);
 262                         $in_diff = 1;
 263                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 264                         # traditional diff w/o -p
 265                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 266                         # hunk header context
 267                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 268                 # ignore the following lines:
 269                 } elsif (/^(?:dis)similarity index/ ||
 270                                 /^(?:old|new) mode/ ||
 271                                 /^(?:deleted|new) file mode/ ||
 272                                 /^(?:copy|rename) (?:from|to) / ||
 273                                 /^(?:dis)?similarity index / ||
 274                                 /^\\ No newline at end of file/ ||
 275                                 /^Binary files .* differ/) {
 276                         push @xnq, $_;
 277                 } elsif ($_ eq '') {
 278                         # possible to be in diff context, some mail may be
 279                         # stripped by MUA or even GNU diff(1).  "git apply"
 280                         # treats a bare "\n" as diff context, too
 281                 } else {
 282                         push @xnq, $_;
 283                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 284                         $in_diff = undef;
 285                 }
 286         }
 287
 288         index_text($self, join("\n", @xnq), 1, 'XNQ');
 289 }
 290
 291 sub index_xapian { # msg_iter callback
 292         my $part = $_[0]->[0]; # ignore $depth and $idx
 293         my ($self, $doc) = @{$_[1]};
 294         my $ct = $part->content_type || 'text/plain';
 295         my $fn = $part->filename;
 296         if (defined $fn && $fn ne '') {
 297                 index_text($self, $fn, 1, 'XFN');
 298         }
 299         if ($part->{is_submsg}) {
 300                 my $mids = mids_for_index($part);
 301                 index_ids($self, $doc, $part, $mids);
 302                 my $smsg = bless {}, 'PublicInbox::Smsg';
 303                 $smsg->populate($part);
 304                 index_headers($self, $smsg);
 305         }
 306
 307         my ($s, undef) = msg_part_text($part, $ct);
 308         defined $s or return;
 309         $_[0]->[0] = $part = undef; # free memory
 310
 311         # split off quoted and unquoted blocks:
 312         my @sections = PublicInbox::MsgIter::split_quotes($s);
 313         undef $s; # free memory
 314         for my $txt (@sections) {
 315                 if ($txt =~ /\A>/) {
 316                         index_text($self, $txt, 0, 'XQUOT');
 317                 } else {
 318                         # does it look like a diff?
 319                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 320                                 index_diff($self, $txt, $doc);
 321                         } else {
 322                                 index_text($self, $txt, 1, 'XNQ');
 323                         }
 324                 }
 325                 undef $txt; # free memory
 326         }
 327 }
 328
 329 sub index_list_id ($$$) {
 330         my ($self, $doc, $hdr) = @_;
 331         for my $l ($hdr->header_raw('List-Id')) {
 332                 $l =~ /<([^>]+)>/ or next;
 333                 my $lid = lc $1;
 334                 $doc->add_boolean_term('G' . $lid);
 335                 index_text($self, $lid, 1, 'XL'); # probabilistic
 336         }
 337 }
 338
 339 sub index_ids ($$$$) {
 340         my ($self, $doc, $hdr, $mids) = @_;
 341         for my $mid (@$mids) {
 342                 index_text($self, $mid, 1, 'XM');
 343
 344                 # because too many Message-IDs are prefixed with
 345                 # "Pine.LNX."...
 346                 if ($mid =~ /\w{12,}/) {
 347                         my @long = ($mid =~ /(\w{3,}+)/g);
 348                         index_text($self, join(' ', @long), 1, 'XM');
 349                 }
 350         }
 351         $doc->add_boolean_term('Q' . $_) for @$mids;
 352         index_list_id($self, $doc, $hdr);
 353 }
 354
 355 sub eml2doc ($$$;$) {
 356         my ($self, $eml, $smsg, $mids) = @_;
 357         $mids //= mids_for_index($eml);
 358         my $doc = $X->{Document}->new;
 359         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 360         my @ds = gmtime($smsg->{ds});
 361         my $yyyymmdd = strftime('%Y%m%d', @ds);
 362         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 363         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 364         add_val($doc, PublicInbox::Search::DT(), $dt);
 365         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 366         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 367         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 368
 369         my $tg = term_generator($self);
 370         $tg->set_document($doc);
 371         index_headers($self, $smsg);
 372
 373         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 374                 $doc->add_boolean_term('O'.$eidx_key);
 375         }
 376         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 377         index_ids($self, $doc, $eml, $mids);
 378
 379         # by default, we maintain compatibility with v1.5.0 and earlier
 380         # by writing to docdata.glass, users who never exect to downgrade can
 381         # use --skip-docdata
 382         if (!$self->{-skip_docdata}) {
 383                 # WWW doesn't need {to} or {cc}, only NNTP
 384                 $smsg->{to} = $smsg->{cc} = '';
 385                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 386                 my $data = $smsg->to_doc_data;
 387                 $doc->set_data($data);
 388         }
 389
 390         if (my $altid = $self->{-altid}) {
 391                 foreach my $alt (@$altid) {
 392                         my $pfx = $alt->{xprefix};
 393                         foreach my $mid (@$mids) {
 394                                 my $id = $alt->mid2alt($mid);
 395                                 next unless defined $id;
 396                                 $doc->add_boolean_term($pfx . $id);
 397                         }
 398                 }
 399         }
 400         $doc;
 401 }
 402
 403 sub add_xapian ($$$$) {
 404         my ($self, $eml, $smsg, $mids) = @_;
 405         my $doc = eml2doc($self, $eml, $smsg, $mids);
 406         $self->{xdb}->replace_document($smsg->{num}, $doc);
 407 }
 408
 409 sub _msgmap_init ($) {
 410         my ($self) = @_;
 411         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 412         $self->{mm} //= eval {
 413                 require PublicInbox::Msgmap;
 414                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 415                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 416         };
 417 }
 418
 419 sub add_message {
 420         # mime = PublicInbox::Eml or Email::MIME object
 421         my ($self, $mime, $smsg, $sync) = @_;
 422         my $mids = mids_for_index($mime);
 423         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 424         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 425         $smsg->{num} //= do { # v1
 426                 _msgmap_init($self);
 427                 index_mm($self, $mime, $smsg->{blob}, $sync);
 428         };
 429
 430         # v1 and tests only:
 431         $smsg->populate($mime, $sync);
 432         $smsg->{bytes} //= length($mime->as_string);
 433
 434         eval {
 435                 # order matters, overview stores every possible piece of
 436                 # data in doc_data (deflated).  Xapian only stores a subset
 437                 # of the fields which exist in over.sqlite3.  We may stop
 438                 # storing doc_data in Xapian sometime after we get multi-inbox
 439                 # search working.
 440                 if (my $oidx = $self->{oidx}) { # v1 only
 441                         $oidx->add_overview($mime, $smsg);
 442                 }
 443                 if (need_xapian($self)) {
 444                         add_xapian($self, $mime, $smsg, $mids);
 445                 }
 446         };
 447
 448         if ($@) {
 449                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 450                 return undef;
 451         }
 452         $smsg->{num};
 453 }
 454
 455 sub _get_doc ($$) {
 456         my ($self, $docid) = @_;
 457         my $doc = eval { $self->{xdb}->get_document($docid) };
 458         $doc // do {
 459                 warn "E: $@\n" if $@;
 460                 warn "E: #$docid missing in Xapian\n";
 461                 undef;
 462         }
 463 }
 464
 465 sub add_eidx_info {
 466         my ($self, $docid, $eidx_key, $eml) = @_;
 467         begin_txn_lazy($self);
 468         my $doc = _get_doc($self, $docid) or return;
 469         term_generator($self)->set_document($doc);
 470         $doc->add_boolean_term('O'.$eidx_key);
 471         index_list_id($self, $doc, $eml);
 472         $self->{xdb}->replace_document($docid, $doc);
 473 }
 474
 475 sub remove_eidx_info {
 476         my ($self, $docid, $eidx_key, $eml) = @_;
 477         begin_txn_lazy($self);
 478         my $doc = _get_doc($self, $docid) or return;
 479         eval { $doc->remove_term('O'.$eidx_key) };
 480         warn "W: ->remove_term O$eidx_key: $@\n" if $@;
 481         for my $l ($eml ? $eml->header_raw('List-Id') : ()) {
 482                 $l =~ /<([^>]+)>/ or next;
 483                 my $lid = lc $1;
 484                 eval { $doc->remove_term('G' . $lid) };
 485                 warn "W: ->remove_term G$lid: $@\n" if $@;
 486
 487                 # nb: we don't remove the XL probabilistic terms
 488                 # since terms may overlap if cross-posted.
 489                 #
 490                 # IOW, a message which has both <foo.example.com>
 491                 # and <bar.example.com> would have overlapping
 492                 # "XLexample" and "XLcom" as terms and which we
 493                 # wouldn't know if they're safe to remove if we just
 494                 # unindex <foo.example.com> while preserving
 495                 # <bar.example.com>.
 496                 #
 497                 # In any case, this entire sub is will likely never
 498                 # be needed and users using the "l:" prefix are probably
 499                 # rarer.
 500         }
 501         $self->{xdb}->replace_document($docid, $doc);
 502 }
 503
 504 sub int_val ($$) {
 505         my ($doc, $col) = @_;
 506         my $val = $doc->get_value($col) or return; # undefined is '' in Xapian
 507         sortable_unserialise($val) + 0; # PV => IV conversion
 508 }
 509
 510 sub smsg_from_doc ($) {
 511         my ($doc) = @_;
 512         my $data = $doc->get_data or return;
 513         my $smsg = bless {}, 'PublicInbox::Smsg';
 514         $smsg->{ts} = int_val($doc, PublicInbox::Search::TS());
 515         my $dt = int_val($doc, PublicInbox::Search::DT());
 516         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
 517         $smsg->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
 518         $smsg->load_from_data($data);
 519         $smsg;
 520 }
 521
 522 sub xdb_remove {
 523         my ($self, @docids) = @_;
 524         my $xdb = $self->{xdb} or return;
 525         for my $docid (@docids) {
 526                 eval { $xdb->delete_document($docid) };
 527                 warn "E: #$docid not in in Xapian? $@\n" if $@;
 528         }
 529 }
 530
 531 sub remove_by_docid {
 532         my ($self, $num) = @_;
 533         die "BUG: remove_by_docid is v2-only\n" if $self->{oidx};
 534         $self->begin_txn_lazy;
 535         xdb_remove($self, $num) if need_xapian($self);
 536 }
 537
 538 sub index_git_blob_id {
 539         my ($doc, $pfx, $objid) = @_;
 540
 541         my $len = length($objid);
 542         for (my $len = length($objid); $len >= 7; ) {
 543                 $doc->add_term($pfx.$objid);
 544                 $objid = substr($objid, 0, --$len);
 545         }
 546 }
 547
 548 # v1 only
 549 sub unindex_eml {
 550         my ($self, $oid, $eml) = @_;
 551         my $mids = mids($eml);
 552         my $nr = 0;
 553         my %tmp;
 554         for my $mid (@$mids) {
 555                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 556                 $nr += scalar @removed;
 557                 $tmp{$_}++ for @removed;
 558         }
 559         if (!$nr) {
 560                 my $m = join('> <', @$mids);
 561                 warn "W: <$m> missing for removal from overview\n";
 562         }
 563         while (my ($num, $nr) = each %tmp) {
 564                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 565         }
 566         if ($nr) {
 567                 $self->{mm}->num_delete($_) for (keys %tmp);
 568         } else { # just in case msgmap and over.sqlite3 become desynched:
 569                 $self->{mm}->mid_delete($mids->[0]);
 570         }
 571         xdb_remove($self, keys %tmp) if need_xapian($self);
 572 }
 573
 574 sub index_mm {
 575         my ($self, $mime, $oid, $sync) = @_;
 576         my $mids = mids($mime);
 577         my $mm = $self->{mm};
 578         if ($sync->{reindex}) {
 579                 my $oidx = $self->{oidx};
 580                 for my $mid (@$mids) {
 581                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 582                         return $num if defined $num;
 583                 }
 584                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 585         } else {
 586                 # fallback to num_for since filters like RubyLang set the number
 587                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 588         }
 589 }
 590
 591 # returns the number of bytes to add if given a non-CRLF arg
 592 sub crlf_adjust ($) {
 593         if (index($_[0], "\r\n") < 0) {
 594                 # common case is LF-only, every \n needs an \r;
 595                 # so favor a cheap tr// over an expensive m//g
 596                 $_[0] =~ tr/\n/\n/;
 597         } else { # count number of '\n' w/o '\r', expensive:
 598                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 599         }
 600 }
 601
 602 sub is_bad_blob ($$$$) {
 603         my ($oid, $type, $size, $expect_oid) = @_;
 604         if ($type ne 'blob') {
 605                 carp "W: $expect_oid is not a blob (type=$type)";
 606                 return 1;
 607         }
 608         croak "BUG: $oid != $expect_oid" if $oid ne $expect_oid;
 609         $size == 0 ? 1 : 0; # size == 0 means purged
 610 }
 611
 612 sub index_both { # git->cat_async callback
 613         my ($bref, $oid, $type, $size, $sync) = @_;
 614         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 615         my ($nr, $max) = @$sync{qw(nr max)};
 616         ++$$nr;
 617         $$max -= $size;
 618         $size += crlf_adjust($$bref);
 619         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 620         my $self = $sync->{sidx};
 621         local $self->{current_info} = "$self->{current_info}: $oid";
 622         my $eml = PublicInbox::Eml->new($bref);
 623         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 624                 die "E: could not generate NNTP article number for $oid";
 625         add_message($self, $eml, $smsg, $sync);
 626         my $cur_cmt = $sync->{cur_cmt} // die 'BUG: {cur_cmt} missing';
 627         ${$sync->{latest_cmt}} = $cur_cmt;
 628 }
 629
 630 sub unindex_both { # git->cat_async callback
 631         my ($bref, $oid, $type, $size, $sync) = @_;
 632         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 633         my $self = $sync->{sidx};
 634         local $self->{current_info} = "$self->{current_info}: $oid";
 635         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 636         # may be undef if leftover
 637         if (defined(my $cur_cmt = $sync->{cur_cmt})) {
 638                 ${$sync->{latest_cmt}} = $cur_cmt;
 639         }
 640 }
 641
 642 sub with_umask {
 643         my $self = shift;
 644         ($self->{ibx} // $self->{eidx})->with_umask(@_);
 645 }
 646
 647 # called by public-inbox-index
 648 sub index_sync {
 649         my ($self, $opt) = @_;
 650         delete $self->{lock_path} if $opt->{-skip_lock};
 651         $self->with_umask(\&_index_sync, $self, $opt);
 652         if ($opt->{reindex} && !$opt->{quit}) {
 653                 my %again = %$opt;
 654                 delete @again{qw(rethread reindex)};
 655                 index_sync($self, \%again);
 656                 $opt->{quit} = $again{quit}; # propagate to caller
 657         }
 658 }
 659
 660 sub check_size { # check_async cb for -index --max-size=...
 661         my ($oid, $type, $size, $arg, $git) = @_;
 662         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 663         if ($size <= $arg->{max_size}) {
 664                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 665         } else {
 666                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 667         }
 668 }
 669
 670 sub v1_checkpoint ($$;$) {
 671         my ($self, $sync, $stk) = @_;
 672         $self->{ibx}->git->async_wait_all;
 673
 674         # $newest may be undef
 675         my $newest = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 676         if (defined($newest)) {
 677                 my $cur = $self->{mm}->last_commit || '';
 678                 if (need_update($self, $cur, $newest)) {
 679                         $self->{mm}->last_commit($newest);
 680                 }
 681         }
 682         ${$sync->{max}} = $self->{batch_bytes};
 683
 684         $self->{mm}->{dbh}->commit;
 685         my $xdb = need_xapian($self) ? $self->{xdb} : undef;
 686         if ($newest && $xdb) {
 687                 my $cur = $xdb->get_metadata('last_commit');
 688                 if (need_update($self, $cur, $newest)) {
 689                         $xdb->set_metadata('last_commit', $newest);
 690                 }
 691         }
 692         if ($stk) { # all done if $stk is passed
 693                 # let SearchView know a full --reindex was done so it can
 694                 # generate ->has_threadid-dependent links
 695                 if ($xdb && $sync->{reindex} && !ref($sync->{reindex})) {
 696                         my $n = $xdb->get_metadata('has_threadid');
 697                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 698                 }
 699                 $self->{oidx}->rethread_done($sync->{-opt}); # all done
 700         }
 701         commit_txn_lazy($self);
 702         $sync->{ibx}->git->cleanup;
 703         my $nr = ${$sync->{nr}};
 704         idx_release($self, $nr);
 705         # let another process do some work...
 706         if (my $pr = $sync->{-opt}->{-progress}) {
 707                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 708         }
 709         if (!$stk && !$sync->{quit}) { # more to come
 710                 begin_txn_lazy($self);
 711                 $self->{mm}->{dbh}->begin_work;
 712         }
 713 }
 714
 715 # only for v1
 716 sub process_stack {
 717         my ($self, $sync, $stk) = @_;
 718         my $git = $sync->{ibx}->git;
 719         my $max = $self->{batch_bytes};
 720         my $nr = 0;
 721         $sync->{nr} = \$nr;
 722         $sync->{max} = \$max;
 723         $sync->{sidx} = $self;
 724         $sync->{latest_cmt} = \(my $latest_cmt);
 725
 726         $self->{mm}->{dbh}->begin_work;
 727         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 728                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 729                 for my $oid (@leftovers) {
 730                         last if $sync->{quit};
 731                         $oid = unpack('H*', $oid);
 732                         $git->cat_async($oid, \&unindex_both, $sync);
 733                 }
 734         }
 735         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 736                 $sync->{index_oid} = \&index_both;
 737         }
 738         while (my ($f, $at, $ct, $oid, $cur_cmt) = $stk->pop_rec) {
 739                 my $arg = { %$sync, cur_cmt => $cur_cmt, oid => $oid };
 740                 last if $sync->{quit};
 741                 if ($f eq 'm') {
 742                         $arg->{autime} = $at;
 743                         $arg->{cotime} = $ct;
 744                         if ($sync->{max_size}) {
 745                                 $git->check_async($oid, \&check_size, $arg);
 746                         } else {
 747                                 $git->cat_async($oid, \&index_both, $arg);
 748                         }
 749                         v1_checkpoint($self, $sync) if $max <= 0;
 750                 } elsif ($f eq 'd') {
 751                         $git->cat_async($oid, \&unindex_both, $arg);
 752                 }
 753         }
 754         v1_checkpoint($self, $sync, $sync->{quit} ? undef : $stk);
 755 }
 756
 757 sub log2stack ($$$) {
 758         my ($sync, $git, $range) = @_;
 759         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 760         my ($add, $del);
 761         if ($sync->{ibx}->version == 1) {
 762                 my $path = $hex.'{2}/'.$hex.'{38}';
 763                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 764                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 765         } else {
 766                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 767                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 768         }
 769
 770         # Count the new files so they can be added newest to oldest
 771         # and still have numbers increasing from oldest to newest
 772         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 773                                 --no-notes --no-color --no-renames --no-abbrev),
 774                                 $range);
 775         my ($at, $ct, $stk, $cmt);
 776         while (<$fh>) {
 777                 return if $sync->{quit};
 778                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 779                         ($at, $ct, $cmt) = ($1 + 0, $2 + 0, $3);
 780                         $stk //= PublicInbox::IdxStack->new($cmt);
 781                 } elsif (/$del/) {
 782                         my $oid = $1;
 783                         if ($D) { # reindex case
 784                                 $D->{pack('H*', $oid)}++;
 785                         } else { # non-reindex case:
 786                                 $stk->push_rec('d', $at, $ct, $oid, $cmt);
 787                         }
 788                 } elsif (/$add/) {
 789                         my $oid = $1;
 790                         if ($D) {
 791                                 my $oid_bin = pack('H*', $oid);
 792                                 my $nr = --$D->{$oid_bin};
 793                                 delete($D->{$oid_bin}) if $nr <= 0;
 794                                 # nr < 0 (-1) means it never existed
 795                                 next if $nr >= 0;
 796                         }
 797                         $stk->push_rec('m', $at, $ct, $oid, $cmt);
 798                 }
 799         }
 800         close $fh or die "git log failed: \$?=$?";
 801         $stk //= PublicInbox::IdxStack->new;
 802         $stk->read_prepare;
 803 }
 804
 805 sub prepare_stack ($$) {
 806         my ($sync, $range) = @_;
 807         my $git = $sync->{ibx}->git;
 808
 809         if (index($range, '..') < 0) {
 810                 # don't show annoying git errors to users who run -index
 811                 # on empty inboxes
 812                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 813                 return PublicInbox::IdxStack->new->read_prepare if $?;
 814         }
 815         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 816         log2stack($sync, $git, $range);
 817 }
 818
 819 # --is-ancestor requires git 1.8.0+
 820 sub is_ancestor ($$$) {
 821         my ($git, $cur, $tip) = @_;
 822         return 0 unless $git->check($cur);
 823         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 824                 qw(merge-base --is-ancestor), $cur, $tip ];
 825         my $pid = spawn($cmd);
 826         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 827         $? == 0;
 828 }
 829
 830 sub need_update ($$$) {
 831         my ($self, $cur, $new) = @_;
 832         my $git = $self->{ibx}->git;
 833         return 1 if $cur && !is_ancestor($git, $cur, $new);
 834         my $range = $cur eq '' ? $new : "$cur..$new";
 835         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 836         ($n eq '' || $n > 0);
 837 }
 838
 839 # The last git commit we indexed with Xapian or SQLite (msgmap)
 840 # This needs to account for cases where Xapian or SQLite is
 841 # out-of-date with respect to the other.
 842 sub _last_x_commit {
 843         my ($self, $mm) = @_;
 844         my $lm = $mm->last_commit || '';
 845         my $lx = '';
 846         if (need_xapian($self)) {
 847                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 848         } else {
 849                 $lx = $lm;
 850         }
 851         # Use last_commit from msgmap if it is older or unset
 852         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 853                 $lx = $lm;
 854         }
 855         $lx;
 856 }
 857
 858 sub reindex_from ($$) {
 859         my ($reindex, $last_commit) = @_;
 860         return $last_commit unless $reindex;
 861         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 862 }
 863
 864 sub quit_cb ($) {
 865         my ($sync) = @_;
 866         sub {
 867                 # we set {-opt}->{quit} too, so ->index_sync callers
 868                 # can abort multi-inbox loops this way
 869                 $sync->{quit} = $sync->{-opt}->{quit} = 1;
 870                 warn "gracefully quitting\n";
 871         }
 872 }
 873
 874 # indexes all unindexed messages (v1 only)
 875 sub _index_sync {
 876         my ($self, $opt) = @_;
 877         my $tip = $opt->{ref} || 'HEAD';
 878         my $ibx = $self->{ibx};
 879         local $self->{current_info} = "$ibx->{inboxdir}";
 880         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 881         $ibx->git->batch_prepare;
 882         my $pr = $opt->{-progress};
 883         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
 884         my $quit = quit_cb($sync);
 885         local $SIG{QUIT} = $quit;
 886         local $SIG{INT} = $quit;
 887         local $SIG{TERM} = $quit;
 888         my $xdb = $self->begin_txn_lazy;
 889         $self->{oidx}->rethread_prepare($opt);
 890         my $mm = _msgmap_init($self);
 891         if ($sync->{reindex}) {
 892                 my $last = $mm->last_commit;
 893                 if ($last) {
 894                         $tip = $last;
 895                 } else {
 896                         # somebody just blindly added --reindex when indexing
 897                         # for the first time, allow it:
 898                         undef $sync->{reindex};
 899                 }
 900         }
 901         my $last_commit = _last_x_commit($self, $mm);
 902         my $lx = reindex_from($sync->{reindex}, $last_commit);
 903         my $range = $lx eq '' ? $tip : "$lx..$tip";
 904         $pr->("counting changes\n\t$range ... ") if $pr;
 905         my $stk = prepare_stack($sync, $range);
 906         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 907         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 908         process_stack($self, $sync, $stk) if !$sync->{quit};
 909 }
 910
 911 sub DESTROY {
 912         # order matters for unlocking
 913         $_[0]->{xdb} = undef;
 914         $_[0]->{lockfh} = undef;
 915 }
 916
 917 sub _begin_txn {
 918         my ($self) = @_;
 919         my $xdb = $self->{xdb} || idx_acquire($self);
 920         $self->{oidx}->begin_lazy if $self->{oidx};
 921         $xdb->begin_transaction if $xdb;
 922         $self->{txn} = 1;
 923         $xdb;
 924 }
 925
 926 sub begin_txn_lazy {
 927         my ($self) = @_;
 928         $self->with_umask(\&_begin_txn, $self) if !$self->{txn};
 929 }
 930
 931 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 932 # This metadata is read by Admin::detect_indexlevel:
 933 sub set_metadata_once {
 934         my ($self) = @_;
 935
 936         return if $self->{shard}; # only continue if undef or 0, not >0
 937         my $xdb = $self->{xdb};
 938
 939         if (delete($self->{-set_has_threadid_once})) {
 940                 $xdb->set_metadata('has_threadid', '1');
 941         }
 942         if (delete($self->{-set_indexlevel_once})) {
 943                 my $level = $xdb->get_metadata('indexlevel');
 944                 if (!$level || $level ne 'medium') {
 945                         $xdb->set_metadata('indexlevel', 'medium');
 946                 }
 947         }
 948         if (delete($self->{-set_skip_docdata_once})) {
 949                 $xdb->get_metadata('skip_docdata') or
 950                         $xdb->set_metadata('skip_docdata', '1');
 951         }
 952 }
 953
 954 sub _commit_txn {
 955         my ($self) = @_;
 956         if (my $eidx = $self->{eidx}) {
 957                 $eidx->git->async_wait_all;
 958                 $eidx->{transact_bytes} = 0;
 959         }
 960         if (my $xdb = $self->{xdb}) {
 961                 set_metadata_once($self);
 962                 $xdb->commit_transaction;
 963         }
 964         $self->{oidx}->commit_lazy if $self->{oidx};
 965 }
 966
 967 sub commit_txn_lazy {
 968         my ($self) = @_;
 969         delete($self->{txn}) and
 970                 $self->with_umask(\&_commit_txn, $self);
 971 }
 972
 973 sub worker_done {
 974         my ($self) = @_;
 975         if (need_xapian($self)) {
 976                 die "$$ $0 xdb not released\n" if $self->{xdb};
 977         }
 978         die "$$ $0 still in transaction\n" if $self->{txn};
 979 }
 980
 981 sub eidx_shard_new {
 982         my ($class, $eidx, $shard) = @_;
 983         my $self = bless {
 984                 eidx => $eidx,
 985                 xpfx => $eidx->{xpfx},
 986                 indexlevel => $eidx->{indexlevel},
 987                 -skip_docdata => 1,
 988                 shard => $shard,
 989                 creat => 1,
 990         }, $class;
 991         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
 992         $self;
 993 }
 994
 995 # ensure there's no stale Xapian docs by treating $over as canonical
 996 sub over_check {
 997         my ($self, $over) = @_;
 998         begin_txn_lazy($self);
 999         my $sth = $over->dbh->prepare(<<'');
1000 SELECT COUNT(*) FROM over WHERE num = ?
1001
1002         my $xdb = $self->{xdb};
1003         my $cur = $xdb->postlist_begin('');
1004         my $end = $xdb->postlist_end('');
1005         my $xdir = $self->xdir;
1006         for (; $cur != $end; $cur++) {
1007                 my $docid = $cur->get_docid;
1008                 $sth->execute($docid);
1009                 my $x = $sth->fetchrow_array;
1010                 next if $x > 0;
1011                 warn "I: removing $xdir #$docid, not in `over'\n";
1012                 $xdb->delete_document($docid);
1013         }
1014 }
1015
1016 1;