lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::OverIdx;
  22 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  23 use PublicInbox::Git qw(git_unquote);
  24 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  25 our @EXPORT_OK = qw(crlf_adjust log2stack is_ancestor check_size);
  26 my $X = \%PublicInbox::Search::X;
  27 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  28 our $DB_NO_SYNC = 0;
  29 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  30 use constant DEBUG => !!$ENV{DEBUG};
  31
  32 my $xapianlevels = qr/\A(?:full|medium)\z/;
  33 my $hex = '[a-f0-9]';
  34 my $OID = $hex .'{40,}';
  35
  36 sub new {
  37         my ($class, $ibx, $creat, $shard) = @_;
  38         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  39         my $levels = qr/\A(?:full|medium|basic)\z/;
  40         my $inboxdir = $ibx->{inboxdir};
  41         my $version = $ibx->version;
  42         my $indexlevel = 'full';
  43         my $altid = $ibx->{altid};
  44         if ($altid) {
  45                 require PublicInbox::AltId;
  46                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  47         }
  48         if ($ibx->{indexlevel}) {
  49                 if ($ibx->{indexlevel} =~ $levels) {
  50                         $indexlevel = $ibx->{indexlevel};
  51                 } else {
  52                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  53                 }
  54         }
  55         $ibx = PublicInbox::InboxWritable->new($ibx);
  56         my $self = bless {
  57                 ibx => $ibx,
  58                 xpfx => $inboxdir, # for xpfx_init
  59                 -altid => $altid,
  60                 ibx_ver => $version,
  61                 indexlevel => $indexlevel,
  62         }, $class;
  63         $self->xpfx_init;
  64         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  65         if ($ibx->{-skip_docdata}) {
  66                 $self->{-set_skip_docdata_once} = 1;
  67                 $self->{-skip_docdata} = 1;
  68         }
  69         $ibx->umask_prepare;
  70         if ($version == 1) {
  71                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  72                 my $dir = $self->xdir;
  73                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  74                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  75         } elsif ($version == 2) {
  76                 defined $shard or die "shard is required for v2\n";
  77                 # shard is a number
  78                 $self->{shard} = $shard;
  79                 $self->{lock_path} = undef;
  80         } else {
  81                 die "unsupported inbox version=$version\n";
  82         }
  83         $self->{creat} = ($creat || 0) == 1;
  84         $self;
  85 }
  86
  87 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  88
  89 sub idx_release {
  90         my ($self, $wake) = @_;
  91         if (need_xapian($self)) {
  92                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  93                 $xdb->close;
  94         }
  95         $self->lock_release($wake) if $self->{creat};
  96         undef;
  97 }
  98
  99 sub load_xapian_writable () {
 100         return 1 if $X->{WritableDatabase};
 101         PublicInbox::Search::load_xapian() or return;
 102         my $xap = $PublicInbox::Search::Xap;
 103         for (qw(Document TermGenerator WritableDatabase)) {
 104                 $X->{$_} = $xap.'::'.$_;
 105         }
 106         eval 'require '.$X->{WritableDatabase} or die;
 107         *sortable_serialise = $xap.'::sortable_serialise';
 108         *sortable_unserialise = $xap.'::sortable_unserialise';
 109         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 110         $DB_OPEN = eval($xap.'::DB_OPEN()');
 111         my $ver = (eval($xap.'::major_version()') << 16) |
 112                 (eval($xap.'::minor_version()') << 8);
 113         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 114         1;
 115 }
 116
 117 sub idx_acquire {
 118         my ($self) = @_;
 119         my $flag;
 120         my $dir = $self->xdir;
 121         if (need_xapian($self)) {
 122                 croak 'already acquired' if $self->{xdb};
 123                 load_xapian_writable();
 124                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 125         }
 126         if ($self->{creat}) {
 127                 require File::Path;
 128                 $self->lock_acquire;
 129
 130                 # don't create empty Xapian directories if we don't need Xapian
 131                 my $is_shard = defined($self->{shard});
 132                 if (!-d $dir && (!$is_shard ||
 133                                 ($is_shard && need_xapian($self)))) {
 134                         File::Path::mkpath($dir);
 135                         nodatacow_dir($dir);
 136                         $self->{-set_has_threadid_once} = 1;
 137                 }
 138         }
 139         return unless defined $flag;
 140         $flag |= $DB_NO_SYNC if $self->{ibx}->{-no_fsync};
 141         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 142         croak "Failed opening $dir: $@" if $@;
 143         $self->{xdb} = $xdb;
 144 }
 145
 146 sub add_val ($$$) {
 147         my ($doc, $col, $num) = @_;
 148         $num = sortable_serialise($num);
 149         $doc->add_value($col, $num);
 150 }
 151
 152 sub term_generator ($) { # write-only
 153         my ($self) = @_;
 154
 155         $self->{term_generator} //= do {
 156                 my $tg = $X->{TermGenerator}->new;
 157                 $tg->set_stemmer($self->stemmer);
 158                 $tg;
 159         }
 160 }
 161
 162 sub index_text ($$$$) {
 163         my ($self, $text, $wdf_inc, $prefix) = @_;
 164         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 165
 166         if ($self->{indexlevel} eq 'full') {
 167                 $tg->index_text($text, $wdf_inc, $prefix);
 168                 $tg->increase_termpos;
 169         } else {
 170                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 171         }
 172 }
 173
 174 sub index_headers ($$) {
 175         my ($self, $smsg) = @_;
 176         my @x = (from => 'A', # Author
 177                 subject => 'S', to => 'XTO', cc => 'XCC');
 178         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 179                 my $val = $smsg->{$field};
 180                 index_text($self, $val, 1, $pfx) if $val ne '';
 181         }
 182 }
 183
 184 sub index_diff_inc ($$$$) {
 185         my ($self, $text, $pfx, $xnq) = @_;
 186         if (@$xnq) {
 187                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 188                 @$xnq = ();
 189         }
 190         index_text($self, $text, 1, $pfx);
 191 }
 192
 193 sub index_old_diff_fn {
 194         my ($self, $seen, $fa, $fb, $xnq) = @_;
 195
 196         # no renames or space support for traditional diffs,
 197         # find the number of leading common paths to strip:
 198         my @fa = split('/', $fa);
 199         my @fb = split('/', $fb);
 200         while (scalar(@fa) && scalar(@fb)) {
 201                 $fa = join('/', @fa);
 202                 $fb = join('/', @fb);
 203                 if ($fa eq $fb) {
 204                         unless ($seen->{$fa}++) {
 205                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 206                         }
 207                         return 1;
 208                 }
 209                 shift @fa;
 210                 shift @fb;
 211         }
 212         0;
 213 }
 214
 215 sub index_diff ($$$) {
 216         my ($self, $txt, $doc) = @_;
 217         my %seen;
 218         my $in_diff;
 219         my @xnq;
 220         my $xnq = \@xnq;
 221         foreach (split(/\n/, $txt)) {
 222                 if ($in_diff && s/^ //) { # diff context
 223                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 224                 } elsif (/^-- $/) { # email signature begins
 225                         $in_diff = undef;
 226                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 227                         # wait until "---" and "+++" to capture filenames
 228                         $in_diff = 1;
 229                 # traditional diff:
 230                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 231                         my ($opt, $fa, $fb) = ($1, $2, $3);
 232                         push @xnq, $_;
 233                         # only support unified:
 234                         next unless $opt =~ /[uU]/;
 235                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 236                                                         $xnq);
 237                 } elsif (m!^--- ("?[^/]+/.+)!) {
 238                         my $fn = $1;
 239                         $fn = (split('/', git_unquote($fn), 2))[1];
 240                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 241                         $in_diff = 1;
 242                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 243                         my $fn = $1;
 244                         $fn = (split('/', git_unquote($fn), 2))[1];
 245                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 246                         $in_diff = 1;
 247                 } elsif (/^--- (\S+)/) {
 248                         $in_diff = $1;
 249                         push @xnq, $_;
 250                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 251                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 252                                                         $1, $xnq);
 253                 } elsif ($in_diff && s/^\+//) { # diff added
 254                         index_diff_inc($self, $_, 'XDFB', $xnq);
 255                 } elsif ($in_diff && s/^-//) { # diff removed
 256                         index_diff_inc($self, $_, 'XDFA', $xnq);
 257                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 258                         my ($ba, $bb) = ($1, $2);
 259                         index_git_blob_id($doc, 'XDFPRE', $ba);
 260                         index_git_blob_id($doc, 'XDFPOST', $bb);
 261                         $in_diff = 1;
 262                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 263                         # traditional diff w/o -p
 264                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 265                         # hunk header context
 266                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 267                 # ignore the following lines:
 268                 } elsif (/^(?:dis)similarity index/ ||
 269                                 /^(?:old|new) mode/ ||
 270                                 /^(?:deleted|new) file mode/ ||
 271                                 /^(?:copy|rename) (?:from|to) / ||
 272                                 /^(?:dis)?similarity index / ||
 273                                 /^\\ No newline at end of file/ ||
 274                                 /^Binary files .* differ/) {
 275                         push @xnq, $_;
 276                 } elsif ($_ eq '') {
 277                         # possible to be in diff context, some mail may be
 278                         # stripped by MUA or even GNU diff(1).  "git apply"
 279                         # treats a bare "\n" as diff context, too
 280                 } else {
 281                         push @xnq, $_;
 282                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 283                         $in_diff = undef;
 284                 }
 285         }
 286
 287         index_text($self, join("\n", @xnq), 1, 'XNQ');
 288 }
 289
 290 sub index_xapian { # msg_iter callback
 291         my $part = $_[0]->[0]; # ignore $depth and $idx
 292         my ($self, $doc) = @{$_[1]};
 293         my $ct = $part->content_type || 'text/plain';
 294         my $fn = $part->filename;
 295         if (defined $fn && $fn ne '') {
 296                 index_text($self, $fn, 1, 'XFN');
 297         }
 298         if ($part->{is_submsg}) {
 299                 my $mids = mids_for_index($part);
 300                 index_ids($self, $doc, $part, $mids);
 301                 my $smsg = bless {}, 'PublicInbox::Smsg';
 302                 $smsg->populate($part);
 303                 index_headers($self, $smsg);
 304         }
 305
 306         my ($s, undef) = msg_part_text($part, $ct);
 307         defined $s or return;
 308         $_[0]->[0] = $part = undef; # free memory
 309
 310         # split off quoted and unquoted blocks:
 311         my @sections = PublicInbox::MsgIter::split_quotes($s);
 312         undef $s; # free memory
 313         for my $txt (@sections) {
 314                 if ($txt =~ /\A>/) {
 315                         index_text($self, $txt, 0, 'XQUOT');
 316                 } else {
 317                         # does it look like a diff?
 318                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 319                                 index_diff($self, $txt, $doc);
 320                         } else {
 321                                 index_text($self, $txt, 1, 'XNQ');
 322                         }
 323                 }
 324                 undef $txt; # free memory
 325         }
 326 }
 327
 328 sub index_ids ($$$$) {
 329         my ($self, $doc, $hdr, $mids) = @_;
 330         for my $mid (@$mids) {
 331                 index_text($self, $mid, 1, 'XM');
 332
 333                 # because too many Message-IDs are prefixed with
 334                 # "Pine.LNX."...
 335                 if ($mid =~ /\w{12,}/) {
 336                         my @long = ($mid =~ /(\w{3,}+)/g);
 337                         index_text($self, join(' ', @long), 1, 'XM');
 338                 }
 339         }
 340         $doc->add_boolean_term('Q' . $_) for @$mids;
 341         for my $l ($hdr->header_raw('List-Id')) {
 342                 $l =~ /<([^>]+)>/ or next;
 343                 my $lid = lc $1;
 344                 $doc->add_boolean_term('G' . $lid);
 345                 index_text($self, $lid, 1, 'XL'); # probabilistic
 346         }
 347 }
 348
 349 sub add_xapian ($$$$) {
 350         my ($self, $eml, $smsg, $mids) = @_;
 351         my $doc = $X->{Document}->new;
 352         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 353         my @ds = gmtime($smsg->{ds});
 354         my $yyyymmdd = strftime('%Y%m%d', @ds);
 355         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 356         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 357         add_val($doc, PublicInbox::Search::DT(), $dt);
 358         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 359         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 360         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 361
 362         my $tg = term_generator($self);
 363         $tg->set_document($doc);
 364         index_headers($self, $smsg);
 365
 366         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 367         index_ids($self, $doc, $eml, $mids);
 368
 369         # by default, we maintain compatibility with v1.5.0 and earlier
 370         # by writing to docdata.glass, users who never exect to downgrade can
 371         # use --skip-docdata
 372         if (!$self->{-skip_docdata}) {
 373                 # WWW doesn't need {to} or {cc}, only NNTP
 374                 $smsg->{to} = $smsg->{cc} = '';
 375                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 376                 my $data = $smsg->to_doc_data;
 377                 $doc->set_data($data);
 378         }
 379
 380         if (my $altid = $self->{-altid}) {
 381                 foreach my $alt (@$altid) {
 382                         my $pfx = $alt->{xprefix};
 383                         foreach my $mid (@$mids) {
 384                                 my $id = $alt->mid2alt($mid);
 385                                 next unless defined $id;
 386                                 $doc->add_boolean_term($pfx . $id);
 387                         }
 388                 }
 389         }
 390         $self->{xdb}->replace_document($smsg->{num}, $doc);
 391 }
 392
 393 sub _msgmap_init ($) {
 394         my ($self) = @_;
 395         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 396         $self->{mm} //= eval {
 397                 require PublicInbox::Msgmap;
 398                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 399                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 400         };
 401 }
 402
 403 sub add_message {
 404         # mime = PublicInbox::Eml or Email::MIME object
 405         my ($self, $mime, $smsg, $sync) = @_;
 406         my $mids = mids_for_index($mime);
 407         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 408         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 409         $smsg->{num} //= do { # v1
 410                 _msgmap_init($self);
 411                 index_mm($self, $mime, $smsg->{blob}, $sync);
 412         };
 413
 414         # v1 and tests only:
 415         $smsg->populate($mime, $sync);
 416         $smsg->{bytes} //= length($mime->as_string);
 417
 418         eval {
 419                 # order matters, overview stores every possible piece of
 420                 # data in doc_data (deflated).  Xapian only stores a subset
 421                 # of the fields which exist in over.sqlite3.  We may stop
 422                 # storing doc_data in Xapian sometime after we get multi-inbox
 423                 # search working.
 424                 if (my $oidx = $self->{oidx}) { # v1 only
 425                         $oidx->add_overview($mime, $smsg);
 426                 }
 427                 if (need_xapian($self)) {
 428                         add_xapian($self, $mime, $smsg, $mids);
 429                 }
 430         };
 431
 432         if ($@) {
 433                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 434                 return undef;
 435         }
 436         $smsg->{num};
 437 }
 438
 439 sub get_val ($$) {
 440         my ($doc, $col) = @_;
 441         sortable_unserialise($doc->get_value($col));
 442 }
 443
 444 sub smsg_from_doc ($) {
 445         my ($doc) = @_;
 446         my $data = $doc->get_data or return;
 447         my $smsg = bless {}, 'PublicInbox::Smsg';
 448         $smsg->{ts} = get_val($doc, PublicInbox::Search::TS());
 449         my $dt = get_val($doc, PublicInbox::Search::DT());
 450         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
 451         $smsg->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
 452         $smsg->load_from_data($data);
 453         $smsg;
 454 }
 455
 456 sub xdb_remove {
 457         my ($self, $oid, @removed) = @_;
 458         my $xdb = $self->{xdb} or return;
 459         for my $num (@removed) {
 460                 my $doc = eval { $xdb->get_document($num) };
 461                 unless ($doc) {
 462                         warn "E: $@\n" if $@;
 463                         warn "E: #$num $oid missing in Xapian\n";
 464                         next;
 465                 }
 466                 my $smsg = smsg_from_doc($doc);
 467                 my $blob = $smsg->{blob}; # may be undef if --skip-docdata
 468                 if (!defined($blob) || $blob eq $oid) {
 469                         $xdb->delete_document($num);
 470                 } else {
 471                         warn "E: #$num $oid != $blob in Xapian\n";
 472                 }
 473         }
 474 }
 475
 476 sub remove_by_oid {
 477         my ($self, $oid, $num) = @_;
 478         die "BUG: remove_by_oid is v2-only\n" if $self->{oidx};
 479         $self->begin_txn_lazy;
 480         xdb_remove($self, $oid, $num) if need_xapian($self);
 481 }
 482
 483 sub index_git_blob_id {
 484         my ($doc, $pfx, $objid) = @_;
 485
 486         my $len = length($objid);
 487         for (my $len = length($objid); $len >= 7; ) {
 488                 $doc->add_term($pfx.$objid);
 489                 $objid = substr($objid, 0, --$len);
 490         }
 491 }
 492
 493 # v1 only
 494 sub unindex_eml {
 495         my ($self, $oid, $eml) = @_;
 496         my $mids = mids($eml);
 497         my $nr = 0;
 498         my %tmp;
 499         for my $mid (@$mids) {
 500                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 501                 $nr += scalar @removed;
 502                 $tmp{$_}++ for @removed;
 503         }
 504         if (!$nr) {
 505                 $mids = join('> <', @$mids);
 506                 warn "W: <$mids> missing for removal from overview\n";
 507         }
 508         while (my ($num, $nr) = each %tmp) {
 509                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 510         }
 511         if ($nr) {
 512                 $self->{mm}->num_delete($_) for (keys %tmp);
 513         } else { # just in case msgmap and over.sqlite3 become desynched:
 514                 $self->{mm}->mid_delete($mids->[0]);
 515         }
 516         xdb_remove($self, $oid, keys %tmp) if need_xapian($self);
 517 }
 518
 519 sub index_mm {
 520         my ($self, $mime, $oid, $sync) = @_;
 521         my $mids = mids($mime);
 522         my $mm = $self->{mm};
 523         if ($sync->{reindex}) {
 524                 my $oidx = $self->{oidx};
 525                 for my $mid (@$mids) {
 526                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 527                         return $num if defined $num;
 528                 }
 529                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 530         } else {
 531                 # fallback to num_for since filters like RubyLang set the number
 532                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 533         }
 534 }
 535
 536 # returns the number of bytes to add if given a non-CRLF arg
 537 sub crlf_adjust ($) {
 538         if (index($_[0], "\r\n") < 0) {
 539                 # common case is LF-only, every \n needs an \r;
 540                 # so favor a cheap tr// over an expensive m//g
 541                 $_[0] =~ tr/\n/\n/;
 542         } else { # count number of '\n' w/o '\r', expensive:
 543                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 544         }
 545 }
 546
 547 sub index_both { # git->cat_async callback
 548         my ($bref, $oid, $type, $size, $sync) = @_;
 549         my ($nr, $max) = @$sync{qw(nr max)};
 550         ++$$nr;
 551         $$max -= $size;
 552         $size += crlf_adjust($$bref);
 553         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 554         my $self = $sync->{sidx};
 555         my $eml = PublicInbox::Eml->new($bref);
 556         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 557                 die "E: could not generate NNTP article number for $oid";
 558         add_message($self, $eml, $smsg, $sync);
 559 }
 560
 561 sub unindex_both { # git->cat_async callback
 562         my ($bref, $oid, $type, $size, $self) = @_;
 563         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 564 }
 565
 566 # called by public-inbox-index
 567 sub index_sync {
 568         my ($self, $opt) = @_;
 569         delete $self->{lock_path} if $opt->{-skip_lock};
 570         $self->{ibx}->with_umask(\&_index_sync, $self, $opt);
 571         if ($opt->{reindex}) {
 572                 my %again = %$opt;
 573                 delete @again{qw(rethread reindex)};
 574                 index_sync($self, \%again);
 575         }
 576 }
 577
 578 sub check_size { # check_async cb for -index --max-size=...
 579         my ($oid, $type, $size, $arg, $git) = @_;
 580         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 581         if ($size <= $arg->{max_size}) {
 582                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 583         } else {
 584                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 585         }
 586 }
 587
 588 sub v1_checkpoint ($$;$) {
 589         my ($self, $sync, $stk) = @_;
 590         $self->{ibx}->git->check_async_wait;
 591         $self->{ibx}->git->cat_async_wait;
 592
 593         # latest_cmt may be undef
 594         my $newest = $stk ? $stk->{latest_cmt} : undef;
 595         if ($newest) {
 596                 my $cur = $self->{mm}->last_commit || '';
 597                 if (need_update($self, $cur, $newest)) {
 598                         $self->{mm}->last_commit($newest);
 599                 }
 600         } else {
 601                 ${$sync->{max}} = $self->{batch_bytes};
 602         }
 603
 604         $self->{mm}->{dbh}->commit;
 605         if ($newest && need_xapian($self)) {
 606                 my $xdb = $self->{xdb};
 607                 my $cur = $xdb->get_metadata('last_commit');
 608                 if (need_update($self, $cur, $newest)) {
 609                         $xdb->set_metadata('last_commit', $newest);
 610                 }
 611
 612                 # let SearchView know a full --reindex was done so it can
 613                 # generate ->has_threadid-dependent links
 614                 if ($sync->{reindex} && !ref($sync->{reindex})) {
 615                         my $n = $xdb->get_metadata('has_threadid');
 616                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 617                 }
 618         }
 619
 620         $self->{oidx}->rethread_done($sync->{-opt}) if $newest; # all done
 621         commit_txn_lazy($self);
 622         $self->{ibx}->git->cleanup;
 623         my $nr = ${$sync->{nr}};
 624         idx_release($self, $nr);
 625         # let another process do some work...
 626         if (my $pr = $sync->{-opt}->{-progress}) {
 627                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 628         }
 629         if (!$stk) { # more to come
 630                 begin_txn_lazy($self);
 631                 $self->{mm}->{dbh}->begin_work;
 632         }
 633 }
 634
 635 # only for v1
 636 sub process_stack {
 637         my ($self, $sync, $stk) = @_;
 638         my $git = $self->{ibx}->git;
 639         my $max = $self->{batch_bytes};
 640         my $nr = 0;
 641         $sync->{nr} = \$nr;
 642         $sync->{max} = \$max;
 643         $sync->{sidx} = $self;
 644
 645         $self->{mm}->{dbh}->begin_work;
 646         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 647                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 648                 for my $oid (@leftovers) {
 649                         $oid = unpack('H*', $oid);
 650                         $git->cat_async($oid, \&unindex_both, $self);
 651                 }
 652         }
 653         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 654                 $sync->{index_oid} = \&index_both;
 655         }
 656         while (my ($f, $at, $ct, $oid) = $stk->pop_rec) {
 657                 if ($f eq 'm') {
 658                         my $arg = { %$sync, autime => $at, cotime => $ct };
 659                         if ($sync->{max_size}) {
 660                                 $git->check_async($oid, \&check_size, $arg);
 661                         } else {
 662                                 $git->cat_async($oid, \&index_both, $arg);
 663                         }
 664                         v1_checkpoint($self, $sync) if $max <= 0;
 665                 } elsif ($f eq 'd') {
 666                         $git->cat_async($oid, \&unindex_both, $self);
 667                 }
 668         }
 669         v1_checkpoint($self, $sync, $stk);
 670 }
 671
 672 sub log2stack ($$$$) {
 673         my ($sync, $git, $range, $ibx) = @_;
 674         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 675         my ($add, $del);
 676         if ($ibx->version == 1) {
 677                 my $path = $hex.'{2}/'.$hex.'{38}';
 678                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 679                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 680         } else {
 681                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 682                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 683         }
 684
 685         # Count the new files so they can be added newest to oldest
 686         # and still have numbers increasing from oldest to newest
 687         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 688                                 --no-notes --no-color --no-renames --no-abbrev),
 689                                 $range);
 690         my ($at, $ct, $stk);
 691         while (<$fh>) {
 692                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 693                         ($at, $ct) = ($1 + 0, $2 + 0);
 694                         $stk //= PublicInbox::IdxStack->new($3);
 695                 } elsif (/$del/) {
 696                         my $oid = $1;
 697                         if ($D) { # reindex case
 698                                 $D->{pack('H*', $oid)}++;
 699                         } else { # non-reindex case:
 700                                 $stk->push_rec('d', $at, $ct, $oid);
 701                         }
 702                 } elsif (/$add/) {
 703                         my $oid = $1;
 704                         if ($D) {
 705                                 my $oid_bin = pack('H*', $oid);
 706                                 my $nr = --$D->{$oid_bin};
 707                                 delete($D->{$oid_bin}) if $nr <= 0;
 708
 709                                 # nr < 0 (-1) means it never existed
 710                                 $stk->push_rec('m', $at, $ct, $oid) if $nr < 0;
 711                         } else {
 712                                 $stk->push_rec('m', $at, $ct, $oid);
 713                         }
 714                 }
 715         }
 716         close $fh or die "git log failed: \$?=$?";
 717         $stk //= PublicInbox::IdxStack->new;
 718         $stk->read_prepare;
 719 }
 720
 721 sub prepare_stack ($$$) {
 722         my ($self, $sync, $range) = @_;
 723         my $git = $self->{ibx}->git;
 724
 725         if (index($range, '..') < 0) {
 726                 # don't show annoying git errors to users who run -index
 727                 # on empty inboxes
 728                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 729                 return PublicInbox::IdxStack->new->read_prepare if $?;
 730         }
 731         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 732         log2stack($sync, $git, $range, $self->{ibx});
 733 }
 734
 735 # --is-ancestor requires git 1.8.0+
 736 sub is_ancestor ($$$) {
 737         my ($git, $cur, $tip) = @_;
 738         return 0 unless $git->check($cur);
 739         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 740                 qw(merge-base --is-ancestor), $cur, $tip ];
 741         my $pid = spawn($cmd);
 742         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 743         $? == 0;
 744 }
 745
 746 sub need_update ($$$) {
 747         my ($self, $cur, $new) = @_;
 748         my $git = $self->{ibx}->git;
 749         return 1 if $cur && !is_ancestor($git, $cur, $new);
 750         my $range = $cur eq '' ? $new : "$cur..$new";
 751         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 752         ($n eq '' || $n > 0);
 753 }
 754
 755 # The last git commit we indexed with Xapian or SQLite (msgmap)
 756 # This needs to account for cases where Xapian or SQLite is
 757 # out-of-date with respect to the other.
 758 sub _last_x_commit {
 759         my ($self, $mm) = @_;
 760         my $lm = $mm->last_commit || '';
 761         my $lx = '';
 762         if (need_xapian($self)) {
 763                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 764         } else {
 765                 $lx = $lm;
 766         }
 767         # Use last_commit from msgmap if it is older or unset
 768         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 769                 $lx = $lm;
 770         }
 771         $lx;
 772 }
 773
 774 sub reindex_from ($$) {
 775         my ($reindex, $last_commit) = @_;
 776         return $last_commit unless $reindex;
 777         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 778 }
 779
 780 # indexes all unindexed messages (v1 only)
 781 sub _index_sync {
 782         my ($self, $opt) = @_;
 783         my $tip = $opt->{ref} || 'HEAD';
 784         my $git = $self->{ibx}->git;
 785         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 786         $git->batch_prepare;
 787         my $pr = $opt->{-progress};
 788         my $sync = { reindex => $opt->{reindex}, -opt => $opt };
 789         my $xdb = $self->begin_txn_lazy;
 790         $self->{oidx}->rethread_prepare($opt);
 791         my $mm = _msgmap_init($self);
 792         if ($sync->{reindex}) {
 793                 my $last = $mm->last_commit;
 794                 if ($last) {
 795                         $tip = $last;
 796                 } else {
 797                         # somebody just blindly added --reindex when indexing
 798                         # for the first time, allow it:
 799                         undef $sync->{reindex};
 800                 }
 801         }
 802         my $last_commit = _last_x_commit($self, $mm);
 803         my $lx = reindex_from($sync->{reindex}, $last_commit);
 804         my $range = $lx eq '' ? $tip : "$lx..$tip";
 805         $pr->("counting changes\n\t$range ... ") if $pr;
 806         my $stk = prepare_stack($self, $sync, $range);
 807         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 808         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 809         process_stack($self, $sync, $stk);
 810 }
 811
 812 sub DESTROY {
 813         # order matters for unlocking
 814         $_[0]->{xdb} = undef;
 815         $_[0]->{lockfh} = undef;
 816 }
 817
 818 sub _begin_txn {
 819         my ($self) = @_;
 820         my $xdb = $self->{xdb} || idx_acquire($self);
 821         $self->{oidx}->begin_lazy if $self->{oidx};
 822         $xdb->begin_transaction if $xdb;
 823         $self->{txn} = 1;
 824         $xdb;
 825 }
 826
 827 sub begin_txn_lazy {
 828         my ($self) = @_;
 829         $self->{ibx}->with_umask(\&_begin_txn, $self) if !$self->{txn};
 830 }
 831
 832 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 833 # This metadata is read by Admin::detect_indexlevel:
 834 sub set_metadata_once {
 835         my ($self) = @_;
 836
 837         return if $self->{shard}; # only continue if undef or 0, not >0
 838         my $xdb = $self->{xdb};
 839
 840         if (delete($self->{-set_has_threadid_once})) {
 841                 $xdb->set_metadata('has_threadid', '1');
 842         }
 843         if (delete($self->{-set_indexlevel_once})) {
 844                 my $level = $xdb->get_metadata('indexlevel');
 845                 if (!$level || $level ne 'medium') {
 846                         $xdb->set_metadata('indexlevel', 'medium');
 847                 }
 848         }
 849         if (delete($self->{-set_skip_docdata_once})) {
 850                 $xdb->get_metadata('skip_docdata') or
 851                         $xdb->set_metadata('skip_docdata', '1');
 852         }
 853 }
 854
 855 sub _commit_txn {
 856         my ($self) = @_;
 857         if (my $xdb = $self->{xdb}) {
 858                 set_metadata_once($self);
 859                 $xdb->commit_transaction;
 860         }
 861         $self->{oidx}->commit_lazy if $self->{oidx};
 862 }
 863
 864 sub commit_txn_lazy {
 865         my ($self) = @_;
 866         delete($self->{txn}) and
 867                 $self->{ibx}->with_umask(\&_commit_txn, $self);
 868 }
 869
 870 sub worker_done {
 871         my ($self) = @_;
 872         if (need_xapian($self)) {
 873                 die "$$ $0 xdb not released\n" if $self->{xdb};
 874         }
 875         die "$$ $0 still in transaction\n" if $self->{txn};
 876 }
 877
 878 1;