lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use PublicInbox::MIME;
  14 use base qw(PublicInbox::Search);
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 require PublicInbox::Git;
  20
  21 use constant {
  22         MAX_MID_SIZE => 244, # max term size - 1 in Xapian
  23         PERM_UMASK => 0,
  24         OLD_PERM_GROUP => 1,
  25         OLD_PERM_EVERYBODY => 2,
  26         PERM_GROUP => 0660,
  27         PERM_EVERYBODY => 0664,
  28         BATCH_BYTES => 1_000_000,
  29         DEBUG => !!$ENV{DEBUG},
  30 };
  31
  32 my %GIT_ESC = (
  33         a => "\a",
  34         b => "\b",
  35         f => "\f",
  36         n => "\n",
  37         r => "\r",
  38         t => "\t",
  39         v => "\013",
  40 );
  41
  42 sub git_unquote ($) {
  43         my ($s) = @_;
  44         return $s unless ($s =~ /\A"(.*)"\z/);
  45         $s = $1;
  46         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  47         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  48         $s;
  49 }
  50
  51 sub new {
  52         my ($class, $ibx, $creat, $part) = @_;
  53         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  54         my $git_dir = $mainrepo;
  55         my ($altid, $git);
  56         my $version = 1;
  57         if (ref $ibx) {
  58                 $mainrepo = $ibx->{mainrepo};
  59                 $altid = $ibx->{altid};
  60                 $version = $ibx->{version} || 1;
  61                 if ($altid) {
  62                         require PublicInbox::AltId;
  63                         $altid = [ map {
  64                                 PublicInbox::AltId->new($ibx, $_);
  65                         } @$altid ];
  66                 }
  67                 $git = $ibx->git;
  68         } else {
  69                 $git = PublicInbox::Git->new($git_dir); # v1 only
  70         }
  71         require Search::Xapian::WritableDatabase;
  72         my $self = bless {
  73                 mainrepo => $mainrepo,
  74                 git => $git,
  75                 -altid => $altid,
  76                 version => $version,
  77         }, $class;
  78         my $perm = $self->_git_config_perm;
  79         my $umask = _umask_for($perm);
  80         $self->{umask} = $umask;
  81         if ($version == 1) {
  82                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  83         } elsif ($version == 2) {
  84                 defined $part or die "partition is required for v2\n";
  85                 # partition is a number or "all"
  86                 $self->{partition} = $part;
  87                 $self->{lock_path} = undef;
  88                 $self->{msgmap_path} = "$mainrepo/msgmap.sqlite3";
  89         } else {
  90                 die "unsupported inbox version=$version\n";
  91         }
  92         $self->{creat} = ($creat || 0) == 1;
  93         $self;
  94 }
  95
  96 sub _xdb_release {
  97         my ($self) = @_;
  98         my $xdb = delete $self->{xdb} or croak 'not acquired';
  99         $xdb->close;
 100         _lock_release($self) if $self->{creat};
 101         undef;
 102 }
 103
 104 sub _xdb_acquire {
 105         my ($self) = @_;
 106         croak 'already acquired' if $self->{xdb};
 107         my $dir = $self->xdir;
 108         my $flag = Search::Xapian::DB_OPEN;
 109         if ($self->{creat}) {
 110                 require File::Path;
 111                 _lock_acquire($self);
 112                 File::Path::mkpath($dir);
 113                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 114         }
 115         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 116 }
 117
 118 # we only acquire the flock if creating or reindexing;
 119 # PublicInbox::Import already has the lock on its own.
 120 sub _lock_acquire {
 121         my ($self) = @_;
 122         croak 'already locked' if $self->{lockfh};
 123         my $lock_path = $self->{lock_path} or return;
 124         sysopen(my $lockfh, $lock_path, O_WRONLY|O_CREAT) or
 125                 die "failed to open lock $lock_path: $!\n";
 126         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
 127         $self->{lockfh} = $lockfh;
 128 }
 129
 130 sub _lock_release {
 131         my ($self) = @_;
 132         return unless $self->{lock_path};
 133         my $lockfh = delete $self->{lockfh} or croak 'not locked';
 134         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
 135         close $lockfh or die "close failed: $!\n";
 136 }
 137
 138 sub add_val ($$$) {
 139         my ($doc, $col, $num) = @_;
 140         $num = Search::Xapian::sortable_serialise($num);
 141         $doc->add_value($col, $num);
 142 }
 143
 144 sub add_values ($$) {
 145         my ($doc, $values) = @_;
 146
 147         my $ts = $values->[PublicInbox::Search::TS];
 148         add_val($doc, PublicInbox::Search::TS, $ts);
 149
 150         my $num = $values->[PublicInbox::Search::NUM];
 151         defined($num) and add_val($doc, PublicInbox::Search::NUM, $num);
 152
 153         my $bytes = $values->[PublicInbox::Search::BYTES];
 154         defined($bytes) and add_val($doc, PublicInbox::Search::BYTES, $bytes);
 155
 156         my $lines = $values->[PublicInbox::Search::LINES];
 157         add_val($doc, PublicInbox::Search::LINES, $lines);
 158
 159         my $yyyymmdd = strftime('%Y%m%d', gmtime($ts));
 160         add_val($doc, PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 161 }
 162
 163 sub index_users ($$) {
 164         my ($tg, $smsg) = @_;
 165
 166         my $from = $smsg->from;
 167         my $to = $smsg->to;
 168         my $cc = $smsg->cc;
 169
 170         $tg->index_text($from, 1, 'A'); # A - author
 171         $tg->increase_termpos;
 172         $tg->index_text($to, 1, 'XTO') if $to ne '';
 173         $tg->increase_termpos;
 174         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 175         $tg->increase_termpos;
 176 }
 177
 178 sub index_text_inc ($$$) {
 179         my ($tg, $text, $pfx) = @_;
 180         $tg->index_text($text, 1, $pfx);
 181         $tg->increase_termpos;
 182 }
 183
 184 sub index_old_diff_fn {
 185         my ($tg, $seen, $fa, $fb) = @_;
 186
 187         # no renames or space support for traditional diffs,
 188         # find the number of leading common paths to strip:
 189         my @fa = split('/', $fa);
 190         my @fb = split('/', $fb);
 191         while (scalar(@fa) && scalar(@fb)) {
 192                 $fa = join('/', @fa);
 193                 $fb = join('/', @fb);
 194                 if ($fa eq $fb) {
 195                         index_text_inc($tg, $fa,'XDFN') unless $seen->{$fa}++;
 196                         return 1;
 197                 }
 198                 shift @fa;
 199                 shift @fb;
 200         }
 201         0;
 202 }
 203
 204 sub index_diff ($$$) {
 205         my ($tg, $lines, $doc) = @_;
 206         my %seen;
 207         my $in_diff;
 208         foreach (@$lines) {
 209                 if ($in_diff && s/^ //) { # diff context
 210                         index_text_inc($tg, $_, 'XDFCTX');
 211                 } elsif (/^-- $/) { # email signature begins
 212                         $in_diff = undef;
 213                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 214                         my ($fa, $fb) = ($1, $2);
 215                         my $fn = (split('/', git_unquote($fa), 2))[1];
 216                         index_text_inc($tg, $fn, 'XDFN') unless $seen{$fn}++;
 217                         $fn = (split('/', git_unquote($fb), 2))[1];
 218                         index_text_inc($tg, $fn, 'XDFN') unless $seen{$fn}++;
 219                         $in_diff = 1;
 220                 # traditional diff:
 221                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 222                         my ($opt, $fa, $fb) = ($1, $2, $3);
 223                         # only support unified:
 224                         next unless $opt =~ /[uU]/;
 225                         $in_diff = index_old_diff_fn($tg, \%seen, $fa, $fb);
 226                 } elsif (m!^--- ("?a/.+)!) {
 227                         my $fn = (split('/', git_unquote($1), 2))[1];
 228                         index_text_inc($tg, $fn, 'XDFN') unless $seen{$fn}++;
 229                         $in_diff = 1;
 230                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 231                         my $fn = (split('/', git_unquote($1), 2))[1];
 232                         index_text_inc($tg, $fn, 'XDFN') unless $seen{$fn}++;
 233                         $in_diff = 1;
 234                 } elsif (/^--- (\S+)/) {
 235                         $in_diff = $1;
 236                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 237                         $in_diff = index_old_diff_fn($tg, \%seen, $in_diff, $1);
 238                 } elsif ($in_diff && s/^\+//) { # diff added
 239                         index_text_inc($tg, $_, 'XDFB');
 240                 } elsif ($in_diff && s/^-//) { # diff removed
 241                         index_text_inc($tg, $_, 'XDFA');
 242                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 243                         my ($ba, $bb) = ($1, $2);
 244                         index_git_blob_id($doc, 'XDFPRE', $ba);
 245                         index_git_blob_id($doc, 'XDFPOST', $bb);
 246                         $in_diff = 1;
 247                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 248                         # traditional diff w/o -p
 249                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 250                         # hunk header context
 251                         index_text_inc($tg, $1, 'XDFHH');
 252                 # ignore the following lines:
 253                 } elsif (/^(?:dis)similarity index/) {
 254                 } elsif (/^(?:old|new) mode/) {
 255                 } elsif (/^(?:deleted|new) file mode/) {
 256                 } elsif (/^(?:copy|rename) (?:from|to) /) {
 257                 } elsif (/^(?:dis)?similarity index /) {
 258                 } elsif (/^\\ No newline at end of file/) {
 259                 } elsif (/^Binary files .* differ/) {
 260                 } elsif ($_ eq '') {
 261                         $in_diff = undef;
 262                 } else {
 263                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 264                         $in_diff = undef;
 265                 }
 266         }
 267 }
 268
 269 sub index_body ($$$) {
 270         my ($tg, $lines, $doc) = @_;
 271         my $txt = join("\n", @$lines);
 272         $tg->index_text($txt, !!$doc, $doc ? 'XNQ' : 'XQUOT');
 273         $tg->increase_termpos;
 274         # does it look like a diff?
 275         if ($doc && $txt =~ /^(?:diff|---|\+\+\+) /ms) {
 276                 $txt = undef;
 277                 index_diff($tg, $lines, $doc);
 278         }
 279         @$lines = ();
 280 }
 281
 282 sub add_message {
 283         my ($self, $mime, $bytes, $num, $blob) = @_; # mime = Email::MIME object
 284         my $db = $self->{xdb};
 285
 286         my ($doc_id, $old_tid);
 287         my $mid = mid_clean(mid_mime($mime));
 288         my $skel = $self->{skeleton};
 289
 290         eval {
 291                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
 292                 my $smsg = $self->lookup_message($mid);
 293                 if ($smsg) {
 294                         # convert a ghost to a regular message
 295                         # it will also clobber any existing regular message
 296                         $doc_id = $smsg->{doc_id};
 297                         $old_tid = $smsg->thread_id unless $skel;
 298                 }
 299                 $smsg = PublicInbox::SearchMsg->new($mime);
 300                 my $doc = $smsg->{doc};
 301                 $doc->add_term('XMID' . $mid);
 302
 303                 my $subj = $smsg->subject;
 304                 my $xpath;
 305                 if ($subj ne '') {
 306                         $xpath = $self->subject_path($subj);
 307                         $xpath = id_compress($xpath);
 308                         $doc->add_term('XPATH' . $xpath);
 309                 }
 310
 311                 my $lines = $mime->body_raw =~ tr!\n!\n!;
 312                 my @values = ($smsg->ts, $num, $bytes, $lines);
 313                 add_values($doc, \@values);
 314
 315                 my $tg = $self->term_generator;
 316
 317                 $tg->set_document($doc);
 318                 $tg->index_text($subj, 1, 'S') if $subj;
 319                 $tg->increase_termpos;
 320
 321                 index_users($tg, $smsg);
 322
 323                 msg_iter($mime, sub {
 324                         my ($part, $depth, @idx) = @{$_[0]};
 325                         my $ct = $part->content_type || 'text/plain';
 326                         my $fn = $part->filename;
 327                         if (defined $fn && $fn ne '') {
 328                                 $tg->index_text($fn, 1, 'XFN');
 329                         }
 330
 331                         return if $ct =~ m!\btext/x?html\b!i;
 332
 333                         my $s = eval { $part->body_str };
 334                         if ($@) {
 335                                 if ($ct =~ m!\btext/plain\b!i) {
 336                                         # Try to assume UTF-8 because Alpine
 337                                         # seems to do wacky things and set
 338                                         # charset=X-UNKNOWN
 339                                         $part->charset_set('UTF-8');
 340                                         $s = eval { $part->body_str };
 341                                         $s = $part->body if $@;
 342                                 }
 343                         }
 344                         defined $s or return;
 345
 346                         my (@orig, @quot);
 347                         my $body = $part->body;
 348                         my @lines = split(/\n/, $body);
 349                         while (defined(my $l = shift @lines)) {
 350                                 if ($l =~ /^>/) {
 351                                         index_body($tg, \@orig, $doc) if @orig;
 352                                         push @quot, $l;
 353                                 } else {
 354                                         index_body($tg, \@quot, 0) if @quot;
 355                                         push @orig, $l;
 356                                 }
 357                         }
 358                         index_body($tg, \@quot, 0) if @quot;
 359                         index_body($tg, \@orig, $doc) if @orig;
 360                 });
 361
 362                 # populates smsg->references for smsg->to_doc_data
 363                 my $refs = parse_references($smsg);
 364                 my $data = $smsg->to_doc_data($blob);
 365                 if ($skel) {
 366                         push @values, $mid, $xpath, $data;
 367                         $skel->index_skeleton(\@values);
 368                 } else {
 369                         link_message($self, $smsg, $refs, $old_tid);
 370                 }
 371                 $tg->index_text($mid, 1, 'XM');
 372                 $doc->set_data($data);
 373
 374                 if (my $altid = $self->{-altid}) {
 375                         foreach my $alt (@$altid) {
 376                                 my $id = $alt->mid2alt($mid);
 377                                 next unless defined $id;
 378                                 $doc->add_term($alt->{xprefix} . $id);
 379                         }
 380                 }
 381                 if (defined $doc_id) {
 382                         $db->replace_document($doc_id, $doc);
 383                 } else {
 384                         $doc_id = $db->add_document($doc);
 385                 }
 386         };
 387
 388         if ($@) {
 389                 warn "failed to index message <$mid>: $@\n";
 390                 return undef;
 391         }
 392         $doc_id;
 393 }
 394
 395 # returns deleted doc_id on success, undef on missing
 396 sub remove_message {
 397         my ($self, $mid) = @_;
 398         my $db = $self->{xdb};
 399         my $doc_id;
 400         $mid = mid_clean($mid);
 401
 402         eval {
 403                 my ($head, $tail) = $self->find_doc_ids('XMID' . $mid);
 404                 if ($head->equal($tail)) {
 405                         warn "cannot remove non-existent <$mid>\n";
 406                 }
 407                 for (; $head != $tail; $head->inc) {
 408                         my $docid = $head->get_docid;
 409                         $db->delete_document($docid);
 410                 }
 411         };
 412
 413         if ($@) {
 414                 warn "failed to remove message <$mid>: $@\n";
 415                 return undef;
 416         }
 417         $doc_id;
 418 }
 419
 420 sub term_generator { # write-only
 421         my ($self) = @_;
 422
 423         my $tg = $self->{term_generator};
 424         return $tg if $tg;
 425
 426         $tg = Search::Xapian::TermGenerator->new;
 427         $tg->set_stemmer($self->stemmer);
 428
 429         $self->{term_generator} = $tg;
 430 }
 431
 432 # increments last_thread_id counter
 433 # returns a 64-bit integer represented as a decimal string
 434 sub next_thread_id {
 435         my ($self) = @_;
 436         my $db = $self->{xdb};
 437         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 438
 439         $db->set_metadata('last_thread_id', ++$last_thread_id);
 440
 441         $last_thread_id;
 442 }
 443
 444 sub parse_references ($) {
 445         my ($smsg) = @_;
 446         my $doc = $smsg->{doc};
 447         my $mid = $smsg->mid;
 448         my $mime = $smsg->{mime};
 449         my $hdr = $mime->header_obj;
 450
 451         # last References should be IRT, but some mail clients do things
 452         # out of order, so trust IRT over References iff IRT exists
 453         my @refs = (($hdr->header_raw('References') || '') =~ /<([^>]+)>/g);
 454         push(@refs, (($hdr->header_raw('In-Reply-To') || '') =~ /<([^>]+)>/g));
 455
 456         if (@refs) {
 457                 my %uniq = ($mid => 1);
 458                 my @orig_refs = @refs;
 459                 @refs = ();
 460
 461                 # prevent circular references via References: here:
 462                 foreach my $ref (@orig_refs) {
 463                         if (length($ref) > MAX_MID_SIZE) {
 464                                 warn "References: <$ref> too long, ignoring\n";
 465                         }
 466                         next if $uniq{$ref};
 467                         $uniq{$ref} = 1;
 468                         push @refs, $ref;
 469                 }
 470         }
 471         $smsg->{references} = '<'.join('> <', @refs).'>' if @refs;
 472         \@refs
 473 }
 474
 475 sub link_message {
 476         my ($self, $smsg, $refs, $old_tid) = @_;
 477         my $tid;
 478
 479         if (@$refs) {
 480
 481                 # first ref *should* be the thread root,
 482                 # but we can never trust clients to do the right thing
 483                 my $ref = shift @$refs;
 484                 $tid = $self->_resolve_mid_to_tid($ref);
 485                 $self->merge_threads($tid, $old_tid) if defined $old_tid;
 486
 487                 # the rest of the refs should point to this tid:
 488                 foreach $ref (@$refs) {
 489                         my $ptid = $self->_resolve_mid_to_tid($ref);
 490                         merge_threads($self, $tid, $ptid);
 491                 }
 492         } else {
 493                 $tid = defined $old_tid ? $old_tid : $self->next_thread_id;
 494         }
 495         $smsg->{doc}->add_term('G' . $tid);
 496 }
 497
 498 sub index_git_blob_id {
 499         my ($doc, $pfx, $objid) = @_;
 500
 501         my $len = length($objid);
 502         for (my $len = length($objid); $len >= 7; ) {
 503                 $doc->add_term($pfx.$objid);
 504                 $objid = substr($objid, 0, --$len);
 505         }
 506 }
 507
 508 sub unindex_blob {
 509         my ($self, $mime) = @_;
 510         my $mid = eval { mid_clean(mid_mime($mime)) };
 511         $self->remove_message($mid) if defined $mid;
 512 }
 513
 514 sub index_mm {
 515         my ($self, $mime, $warn_existing) = @_;
 516         my $mid = mid_clean(mid_mime($mime));
 517         my $mm = $self->{mm};
 518         my $num = $mm->mid_insert($mid);
 519         return $num if defined $num;
 520
 521         warn "<$mid> reused\n" if $warn_existing;
 522         # fallback to num_for since filters like RubyLang set the number
 523         $mm->num_for($mid);
 524 }
 525
 526 sub unindex_mm {
 527         my ($self, $mime) = @_;
 528         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 529 }
 530
 531 sub index_mm2 {
 532         my ($self, $mime, $bytes, $blob) = @_;
 533         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 534         add_message($self, $mime, $bytes, $num, $blob);
 535 }
 536
 537 sub unindex_mm2 {
 538         my ($self, $mime) = @_;
 539         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 540         unindex_blob($self, $mime);
 541 }
 542
 543 sub index_both {
 544         my ($self, $mime, $bytes, $blob) = @_;
 545         my $num = index_mm($self, $mime);
 546         add_message($self, $mime, $bytes, $num, $blob);
 547 }
 548
 549 sub unindex_both {
 550         my ($self, $mime) = @_;
 551         unindex_blob($self, $mime);
 552         unindex_mm($self, $mime);
 553 }
 554
 555 sub do_cat_mail {
 556         my ($git, $blob, $sizeref) = @_;
 557         my $mime = eval {
 558                 my $str = $git->cat_file($blob, $sizeref);
 559                 # fixup bugs from import:
 560                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 561                 PublicInbox::MIME->new($str);
 562         };
 563         $@ ? undef : $mime;
 564 }
 565
 566 sub index_sync {
 567         my ($self, $opts) = @_;
 568         with_umask($self, sub { $self->_index_sync($opts) });
 569 }
 570
 571 sub batch_adjust ($$$$) {
 572         my ($max, $bytes, $batch_cb, $latest) = @_;
 573         $$max -= $bytes;
 574         if ($$max <= 0) {
 575                 $$max = BATCH_BYTES;
 576                 $batch_cb->($latest, 1);
 577         }
 578 }
 579
 580 # only for v1
 581 sub rlog {
 582         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 583         my $hex = '[a-f0-9]';
 584         my $h40 = $hex .'{40}';
 585         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 586         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 587         my $git = $self->{git};
 588         my $latest;
 589         my $bytes;
 590         my $max = BATCH_BYTES;
 591         local $/ = "\n";
 592         my $line;
 593         while (defined($line = <$log>)) {
 594                 if ($line =~ /$addmsg/o) {
 595                         my $blob = $1;
 596                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 597                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 598                         $add_cb->($self, $mime, $bytes, $blob);
 599                 } elsif ($line =~ /$delmsg/o) {
 600                         my $blob = $1;
 601                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 602                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 603                         $del_cb->($self, $mime);
 604                 } elsif ($line =~ /^commit ($h40)/o) {
 605                         $latest = $1;
 606                 }
 607         }
 608         $batch_cb->($latest, 0);
 609 }
 610
 611 sub _msgmap_init {
 612         my ($self) = @_;
 613         $self->{mm} ||= eval {
 614                 require PublicInbox::Msgmap;
 615                 my $msgmap_path = $self->{msgmap_path};
 616                 if (defined $msgmap_path) { # v2
 617                         PublicInbox::Msgmap->new_file($msgmap_path, 1);
 618                 } else {
 619                         PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 620                 }
 621         };
 622 }
 623
 624 sub _git_log {
 625         my ($self, $range) = @_;
 626         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 627                                 --raw -r --no-abbrev/, $range);
 628 }
 629
 630 # indexes all unindexed messages
 631 sub _index_sync {
 632         my ($self, $opts) = @_;
 633         my $tip = $opts->{ref} || 'HEAD';
 634         my $reindex = $opts->{reindex};
 635         my ($mkey, $last_commit, $lx, $xlog);
 636         $self->{git}->batch_prepare;
 637         my $xdb = _xdb_acquire($self);
 638         $xdb->begin_transaction;
 639         do {
 640                 $xlog = undef;
 641                 $mkey = 'last_commit';
 642                 $last_commit = $xdb->get_metadata('last_commit');
 643                 $lx = $last_commit;
 644                 if ($reindex) {
 645                         $lx = '';
 646                         $mkey = undef if $last_commit ne '';
 647                 }
 648                 $xdb->cancel_transaction;
 649                 $xdb = _xdb_release($self);
 650
 651                 # ensure we leak no FDs to "git log"
 652                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 653                 $xlog = _git_log($self, $range);
 654
 655                 $xdb = _xdb_acquire($self);
 656                 $xdb->begin_transaction;
 657         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 658
 659         my $mm = _msgmap_init($self);
 660         my $dbh = $mm->{dbh} if $mm;
 661         my $mm_only;
 662         my $cb = sub {
 663                 my ($commit, $more) = @_;
 664                 if ($dbh) {
 665                         $mm->last_commit($commit) if $commit;
 666                         $dbh->commit;
 667                 }
 668                 if (!$mm_only) {
 669                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 670                         $xdb->commit_transaction;
 671                         $xdb = _xdb_release($self);
 672                 }
 673                 # let another process do some work... <
 674                 if ($more) {
 675                         if (!$mm_only) {
 676                                 $xdb = _xdb_acquire($self);
 677                                 $xdb->begin_transaction;
 678                         }
 679                         $dbh->begin_work if $dbh;
 680                 }
 681         };
 682
 683         if ($mm) {
 684                 $dbh->begin_work;
 685                 my $lm = $mm->last_commit || '';
 686                 if ($lm eq $lx) {
 687                         # Common case is the indexes are synced,
 688                         # we only need to run git-log once:
 689                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 690                 } else {
 691                         # Uncommon case, msgmap and xapian are out-of-sync
 692                         # do not care for performance (but git is fast :>)
 693                         # This happens if we have to reindex Xapian since
 694                         # msgmap is a frozen format and our Xapian format
 695                         # is evolving.
 696                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 697
 698                         # first, ensure msgmap is up-to-date:
 699                         my $mkey_prev = $mkey;
 700                         $mkey = undef; # ignore xapian, for now
 701                         my $mlog = _git_log($self, $r);
 702                         $mm_only = 1;
 703                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 704                         $mm_only = $mlog = undef;
 705
 706                         # now deal with Xapian
 707                         $mkey = $mkey_prev;
 708                         $dbh = undef;
 709                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 710                 }
 711         } else {
 712                 # user didn't install DBD::SQLite and DBI
 713                 rlog($self, $xlog, *add_message, *unindex_blob, $cb);
 714         }
 715 }
 716
 717 # this will create a ghost as necessary
 718 sub _resolve_mid_to_tid {
 719         my ($self, $mid) = @_;
 720
 721         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 722         $smsg->thread_id;
 723 }
 724
 725 sub create_ghost {
 726         my ($self, $mid) = @_;
 727
 728         my $tid = $self->next_thread_id;
 729         my $doc = Search::Xapian::Document->new;
 730         $doc->add_term('XMID' . $mid);
 731         $doc->add_term('G' . $tid);
 732         $doc->add_term('T' . 'ghost');
 733
 734         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 735         $self->{xdb}->add_document($doc);
 736
 737         $smsg;
 738 }
 739
 740 sub merge_threads {
 741         my ($self, $winner_tid, $loser_tid) = @_;
 742         return if $winner_tid == $loser_tid;
 743         my $db = $self->{xdb};
 744
 745         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 746         while (1) {
 747                 my ($head, $tail) = $self->find_doc_ids('G' . $loser_tid);
 748                 return if $head == $tail;
 749                 my @ids;
 750                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 751                         push @ids, $head->get_docid;
 752                 }
 753                 foreach my $docid (@ids) {
 754                         my $doc = $db->get_document($docid);
 755                         $doc->remove_term('G' . $loser_tid);
 756                         $doc->add_term('G' . $winner_tid);
 757                         $db->replace_document($docid, $doc);
 758                 }
 759         }
 760 }
 761
 762 sub _read_git_config_perm {
 763         my ($self) = @_;
 764         my @cmd = qw(config);
 765         if ($self->{version} == 2) {
 766                 push @cmd, "--file=$self->{mainrepo}/inbox-config";
 767         }
 768         my $fh = $self->{git}->popen(@cmd, 'core.sharedRepository');
 769         local $/ = "\n";
 770         my $perm = <$fh>;
 771         chomp $perm if defined $perm;
 772         $perm;
 773 }
 774
 775 sub _git_config_perm {
 776         my $self = shift;
 777         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 778         return PERM_GROUP if (!defined($perm) || $perm eq '');
 779         return PERM_UMASK if ($perm eq 'umask');
 780         return PERM_GROUP if ($perm eq 'group');
 781         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 782                 return PERM_EVERYBODY;
 783         }
 784         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 785         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 786
 787         my $i = oct($perm);
 788         return PERM_UMASK if ($i == PERM_UMASK);
 789         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 790         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 791
 792         if (($i & 0600) != 0600) {
 793                 die "core.sharedRepository mode invalid: ".
 794                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 795         }
 796         ($i & 0666);
 797 }
 798
 799 sub _umask_for {
 800         my ($perm) = @_; # _git_config_perm return value
 801         my $rv = $perm;
 802         return umask if $rv == 0;
 803
 804         # set +x bit if +r or +w were set
 805         $rv |= 0100 if ($rv & 0600);
 806         $rv |= 0010 if ($rv & 0060);
 807         $rv |= 0001 if ($rv & 0006);
 808         (~$rv & 0777);
 809 }
 810
 811 sub with_umask {
 812         my ($self, $cb) = @_;
 813         my $old = umask $self->{umask};
 814         my $rv = eval { $cb->() };
 815         my $err = $@;
 816         umask $old;
 817         die $err if $err;
 818         $rv;
 819 }
 820
 821 sub DESTROY {
 822         # order matters for unlocking
 823         $_[0]->{xdb} = undef;
 824         $_[0]->{lockfh} = undef;
 825 }
 826
 827 # remote_* subs are only used by SearchIdxPart and SearchIdxSkeleton
 828 sub remote_commit {
 829         my ($self) = @_;
 830         print { $self->{w} } "commit\n" or die "failed to write commit: $!";
 831 }
 832
 833 sub remote_close {
 834         my ($self) = @_;
 835         my $pid = delete $self->{pid} or die "no process to wait on\n";
 836         my $w = delete $self->{w} or die "no pipe to write to\n";
 837         print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 838         close $w or die "failed to close pipe for pid:$pid: $!\n";
 839         waitpid($pid, 0) == $pid or die "remote process did not finish";
 840         $? == 0 or die ref($self)." exited with: $?";
 841 }
 842
 843 1;