lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use PublicInbox::MIME;
  14 use base qw(PublicInbox::Search);
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids references/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 require PublicInbox::Git;
  20
  21 use constant {
  22         MAX_MID_SIZE => 244, # max term size (Xapian limitation) - length('Q')
  23         PERM_UMASK => 0,
  24         OLD_PERM_GROUP => 1,
  25         OLD_PERM_EVERYBODY => 2,
  26         PERM_GROUP => 0660,
  27         PERM_EVERYBODY => 0664,
  28         BATCH_BYTES => 1_000_000,
  29         DEBUG => !!$ENV{DEBUG},
  30 };
  31
  32 my %GIT_ESC = (
  33         a => "\a",
  34         b => "\b",
  35         f => "\f",
  36         n => "\n",
  37         r => "\r",
  38         t => "\t",
  39         v => "\013",
  40 );
  41
  42 sub git_unquote ($) {
  43         my ($s) = @_;
  44         return $s unless ($s =~ /\A"(.*)"\z/);
  45         $s = $1;
  46         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  47         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  48         $s;
  49 }
  50
  51 sub new {
  52         my ($class, $ibx, $creat, $part) = @_;
  53         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  54         my $git_dir = $mainrepo;
  55         my ($altid, $git);
  56         my $version = 1;
  57         if (ref $ibx) {
  58                 $mainrepo = $ibx->{mainrepo};
  59                 $altid = $ibx->{altid};
  60                 $version = $ibx->{version} || 1;
  61                 if ($altid) {
  62                         require PublicInbox::AltId;
  63                         $altid = [ map {
  64                                 PublicInbox::AltId->new($ibx, $_);
  65                         } @$altid ];
  66                 }
  67                 $git = $ibx->git;
  68         } else {
  69                 $git = PublicInbox::Git->new($git_dir); # v1 only
  70         }
  71         require Search::Xapian::WritableDatabase;
  72         my $self = bless {
  73                 mainrepo => $mainrepo,
  74                 git => $git,
  75                 -altid => $altid,
  76                 version => $version,
  77         }, $class;
  78         my $perm = $self->_git_config_perm;
  79         my $umask = _umask_for($perm);
  80         $self->{umask} = $umask;
  81         if ($version == 1) {
  82                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  83         } elsif ($version == 2) {
  84                 defined $part or die "partition is required for v2\n";
  85                 # partition is a number or "all"
  86                 $self->{partition} = $part;
  87                 $self->{lock_path} = undef;
  88                 $self->{msgmap_path} = "$mainrepo/msgmap.sqlite3";
  89         } else {
  90                 die "unsupported inbox version=$version\n";
  91         }
  92         $self->{creat} = ($creat || 0) == 1;
  93         $self;
  94 }
  95
  96 sub _xdb_release {
  97         my ($self) = @_;
  98         my $xdb = delete $self->{xdb} or croak 'not acquired';
  99         $xdb->close;
 100         _lock_release($self) if $self->{creat};
 101         undef;
 102 }
 103
 104 sub _xdb_acquire {
 105         my ($self) = @_;
 106         croak 'already acquired' if $self->{xdb};
 107         my $dir = $self->xdir;
 108         my $flag = Search::Xapian::DB_OPEN;
 109         if ($self->{creat}) {
 110                 require File::Path;
 111                 _lock_acquire($self);
 112                 File::Path::mkpath($dir);
 113                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 114         }
 115         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 116 }
 117
 118 # we only acquire the flock if creating or reindexing;
 119 # PublicInbox::Import already has the lock on its own.
 120 sub _lock_acquire {
 121         my ($self) = @_;
 122         croak 'already locked' if $self->{lockfh};
 123         my $lock_path = $self->{lock_path} or return;
 124         sysopen(my $lockfh, $lock_path, O_WRONLY|O_CREAT) or
 125                 die "failed to open lock $lock_path: $!\n";
 126         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
 127         $self->{lockfh} = $lockfh;
 128 }
 129
 130 sub _lock_release {
 131         my ($self) = @_;
 132         return unless $self->{lock_path};
 133         my $lockfh = delete $self->{lockfh} or croak 'not locked';
 134         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
 135         close $lockfh or die "close failed: $!\n";
 136 }
 137
 138 sub add_val ($$$) {
 139         my ($doc, $col, $num) = @_;
 140         $num = Search::Xapian::sortable_serialise($num);
 141         $doc->add_value($col, $num);
 142 }
 143
 144 sub add_values ($$) {
 145         my ($doc, $values) = @_;
 146
 147         my $ts = $values->[PublicInbox::Search::TS];
 148         add_val($doc, PublicInbox::Search::TS, $ts);
 149
 150         my $num = $values->[PublicInbox::Search::NUM];
 151         defined($num) and add_val($doc, PublicInbox::Search::NUM, $num);
 152
 153         my $bytes = $values->[PublicInbox::Search::BYTES];
 154         defined($bytes) and add_val($doc, PublicInbox::Search::BYTES, $bytes);
 155
 156         my $lines = $values->[PublicInbox::Search::LINES];
 157         add_val($doc, PublicInbox::Search::LINES, $lines);
 158
 159         my $yyyymmdd = strftime('%Y%m%d', gmtime($ts));
 160         add_val($doc, PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 161 }
 162
 163 sub index_users ($$) {
 164         my ($tg, $smsg) = @_;
 165
 166         my $from = $smsg->from;
 167         my $to = $smsg->to;
 168         my $cc = $smsg->cc;
 169
 170         $tg->index_text($from, 1, 'A'); # A - author
 171         $tg->increase_termpos;
 172         $tg->index_text($to, 1, 'XTO') if $to ne '';
 173         $tg->increase_termpos;
 174         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 175         $tg->increase_termpos;
 176 }
 177
 178 sub index_text_inc ($$$) {
 179         my ($tg, $text, $pfx) = @_;
 180         $tg->index_text($text, 1, $pfx);
 181         $tg->increase_termpos;
 182 }
 183
 184 sub index_old_diff_fn {
 185         my ($tg, $seen, $fa, $fb) = @_;
 186
 187         # no renames or space support for traditional diffs,
 188         # find the number of leading common paths to strip:
 189         my @fa = split('/', $fa);
 190         my @fb = split('/', $fb);
 191         while (scalar(@fa) && scalar(@fb)) {
 192                 $fa = join('/', @fa);
 193                 $fb = join('/', @fb);
 194                 if ($fa eq $fb) {
 195                         index_text_inc($tg, $fa,'XDFN') unless $seen->{$fa}++;
 196                         return 1;
 197                 }
 198                 shift @fa;
 199                 shift @fb;
 200         }
 201         0;
 202 }
 203
 204 sub index_diff ($$$) {
 205         my ($tg, $lines, $doc) = @_;
 206         my %seen;
 207         my $in_diff;
 208         foreach (@$lines) {
 209                 if ($in_diff && s/^ //) { # diff context
 210                         index_text_inc($tg, $_, 'XDFCTX');
 211                 } elsif (/^-- $/) { # email signature begins
 212                         $in_diff = undef;
 213                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 214                         my ($fa, $fb) = ($1, $2);
 215                         my $fn = (split('/', git_unquote($fa), 2))[1];
 216                         index_text_inc($tg, $fn, 'XDFN') unless $seen{$fn}++;
 217                         $fn = (split('/', git_unquote($fb), 2))[1];
 218                         index_text_inc($tg, $fn, 'XDFN') unless $seen{$fn}++;
 219                         $in_diff = 1;
 220                 # traditional diff:
 221                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 222                         my ($opt, $fa, $fb) = ($1, $2, $3);
 223                         # only support unified:
 224                         next unless $opt =~ /[uU]/;
 225                         $in_diff = index_old_diff_fn($tg, \%seen, $fa, $fb);
 226                 } elsif (m!^--- ("?a/.+)!) {
 227                         my $fn = (split('/', git_unquote($1), 2))[1];
 228                         index_text_inc($tg, $fn, 'XDFN') unless $seen{$fn}++;
 229                         $in_diff = 1;
 230                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 231                         my $fn = (split('/', git_unquote($1), 2))[1];
 232                         index_text_inc($tg, $fn, 'XDFN') unless $seen{$fn}++;
 233                         $in_diff = 1;
 234                 } elsif (/^--- (\S+)/) {
 235                         $in_diff = $1;
 236                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 237                         $in_diff = index_old_diff_fn($tg, \%seen, $in_diff, $1);
 238                 } elsif ($in_diff && s/^\+//) { # diff added
 239                         index_text_inc($tg, $_, 'XDFB');
 240                 } elsif ($in_diff && s/^-//) { # diff removed
 241                         index_text_inc($tg, $_, 'XDFA');
 242                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 243                         my ($ba, $bb) = ($1, $2);
 244                         index_git_blob_id($doc, 'XDFPRE', $ba);
 245                         index_git_blob_id($doc, 'XDFPOST', $bb);
 246                         $in_diff = 1;
 247                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 248                         # traditional diff w/o -p
 249                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 250                         # hunk header context
 251                         index_text_inc($tg, $1, 'XDFHH');
 252                 # ignore the following lines:
 253                 } elsif (/^(?:dis)similarity index/) {
 254                 } elsif (/^(?:old|new) mode/) {
 255                 } elsif (/^(?:deleted|new) file mode/) {
 256                 } elsif (/^(?:copy|rename) (?:from|to) /) {
 257                 } elsif (/^(?:dis)?similarity index /) {
 258                 } elsif (/^\\ No newline at end of file/) {
 259                 } elsif (/^Binary files .* differ/) {
 260                 } elsif ($_ eq '') {
 261                         $in_diff = undef;
 262                 } else {
 263                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 264                         $in_diff = undef;
 265                 }
 266         }
 267 }
 268
 269 sub index_body ($$$) {
 270         my ($tg, $lines, $doc) = @_;
 271         my $txt = join("\n", @$lines);
 272         $tg->index_text($txt, !!$doc, $doc ? 'XNQ' : 'XQUOT');
 273         $tg->increase_termpos;
 274         # does it look like a diff?
 275         if ($doc && $txt =~ /^(?:diff|---|\+\+\+) /ms) {
 276                 $txt = undef;
 277                 index_diff($tg, $lines, $doc);
 278         }
 279         @$lines = ();
 280 }
 281
 282 sub add_message {
 283         my ($self, $mime, $bytes, $num, $blob) = @_; # mime = Email::MIME object
 284         my $db = $self->{xdb};
 285
 286         my ($doc_id, $old_tid);
 287         my @mids = mid_mime($mime);
 288         if (@mids > 1) {
 289                 warn "Multi-MID: ( ",join(' | ', @mids)," )\n";
 290         }
 291         my $mid = mid_clean($mids[0]);
 292         my $skel = $self->{skeleton};
 293
 294         eval {
 295                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
 296                 my $smsg = $self->lookup_message($mid);
 297                 if ($smsg) {
 298                         # convert a ghost to a regular message
 299                         # it will also clobber any existing regular message
 300                         $doc_id = $smsg->{doc_id};
 301                         $old_tid = $smsg->thread_id unless $skel;
 302                 }
 303                 $smsg = PublicInbox::SearchMsg->new($mime);
 304                 my $doc = $smsg->{doc};
 305                 $doc->add_term('Q' . $mid);
 306
 307                 my $subj = $smsg->subject;
 308                 my $xpath;
 309                 if ($subj ne '') {
 310                         $xpath = $self->subject_path($subj);
 311                         $xpath = id_compress($xpath);
 312                         $doc->add_term('XPATH' . $xpath);
 313                 }
 314
 315                 my $lines = $mime->body_raw =~ tr!\n!\n!;
 316                 my @values = ($smsg->ts, $num, $bytes, $lines);
 317                 add_values($doc, \@values);
 318
 319                 my $tg = $self->term_generator;
 320
 321                 $tg->set_document($doc);
 322                 $tg->index_text($subj, 1, 'S') if $subj;
 323                 $tg->increase_termpos;
 324
 325                 index_users($tg, $smsg);
 326
 327                 msg_iter($mime, sub {
 328                         my ($part, $depth, @idx) = @{$_[0]};
 329                         my $ct = $part->content_type || 'text/plain';
 330                         my $fn = $part->filename;
 331                         if (defined $fn && $fn ne '') {
 332                                 $tg->index_text($fn, 1, 'XFN');
 333                         }
 334
 335                         return if $ct =~ m!\btext/x?html\b!i;
 336
 337                         my $s = eval { $part->body_str };
 338                         if ($@) {
 339                                 if ($ct =~ m!\btext/plain\b!i) {
 340                                         # Try to assume UTF-8 because Alpine
 341                                         # seems to do wacky things and set
 342                                         # charset=X-UNKNOWN
 343                                         $part->charset_set('UTF-8');
 344                                         $s = eval { $part->body_str };
 345                                         $s = $part->body if $@;
 346                                 }
 347                         }
 348                         defined $s or return;
 349
 350                         my (@orig, @quot);
 351                         my $body = $part->body;
 352                         my @lines = split(/\n/, $body);
 353                         while (defined(my $l = shift @lines)) {
 354                                 if ($l =~ /^>/) {
 355                                         index_body($tg, \@orig, $doc) if @orig;
 356                                         push @quot, $l;
 357                                 } else {
 358                                         index_body($tg, \@quot, 0) if @quot;
 359                                         push @orig, $l;
 360                                 }
 361                         }
 362                         index_body($tg, \@quot, 0) if @quot;
 363                         index_body($tg, \@orig, $doc) if @orig;
 364                 });
 365
 366                 # populates smsg->references for smsg->to_doc_data
 367                 my $refs = parse_references($smsg);
 368                 my $data = $smsg->to_doc_data($blob);
 369                 if ($skel) {
 370                         push @values, $mid, $xpath, $data;
 371                         $skel->index_skeleton(\@values);
 372                 } else {
 373                         link_message($self, $smsg, $refs, $old_tid);
 374                 }
 375                 $tg->index_text($mid, 1, 'XM');
 376                 $doc->set_data($data);
 377
 378                 if (my $altid = $self->{-altid}) {
 379                         foreach my $alt (@$altid) {
 380                                 my $id = $alt->mid2alt($mid);
 381                                 next unless defined $id;
 382                                 $doc->add_term($alt->{xprefix} . $id);
 383                         }
 384                 }
 385                 if (defined $doc_id) {
 386                         $db->replace_document($doc_id, $doc);
 387                 } else {
 388                         $doc_id = $db->add_document($doc);
 389                 }
 390         };
 391
 392         if ($@) {
 393                 warn "failed to index message <$mid>: $@\n";
 394                 return undef;
 395         }
 396         $doc_id;
 397 }
 398
 399 # returns deleted doc_id on success, undef on missing
 400 sub remove_message {
 401         my ($self, $mid) = @_;
 402         my $db = $self->{xdb};
 403         my $doc_id;
 404         $mid = mid_clean($mid);
 405
 406         eval {
 407                 my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 408                 if ($head->equal($tail)) {
 409                         warn "cannot remove non-existent <$mid>\n";
 410                 }
 411                 for (; $head != $tail; $head->inc) {
 412                         my $docid = $head->get_docid;
 413                         $db->delete_document($docid);
 414                 }
 415         };
 416
 417         if ($@) {
 418                 warn "failed to remove message <$mid>: $@\n";
 419                 return undef;
 420         }
 421         $doc_id;
 422 }
 423
 424 sub term_generator { # write-only
 425         my ($self) = @_;
 426
 427         my $tg = $self->{term_generator};
 428         return $tg if $tg;
 429
 430         $tg = Search::Xapian::TermGenerator->new;
 431         $tg->set_stemmer($self->stemmer);
 432
 433         $self->{term_generator} = $tg;
 434 }
 435
 436 # increments last_thread_id counter
 437 # returns a 64-bit integer represented as a decimal string
 438 sub next_thread_id {
 439         my ($self) = @_;
 440         my $db = $self->{xdb};
 441         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 442
 443         $db->set_metadata('last_thread_id', ++$last_thread_id);
 444
 445         $last_thread_id;
 446 }
 447
 448 sub parse_references ($) {
 449         my ($smsg) = @_;
 450         my $mime = $smsg->{mime};
 451         my $hdr = $mime->header_obj;
 452         my $refs = references($hdr);
 453         return $refs if scalar(@$refs) == 0;
 454
 455         # prevent circular references via References here:
 456         my %mids = map { $_ => 1 } @{mids($hdr)};
 457         my @keep;
 458         foreach my $ref (@$refs) {
 459                 # FIXME: this is an archive-prevention vector like X-No-Archive
 460                 if (length($ref) > MAX_MID_SIZE) {
 461                         warn "References: <$ref> too long, ignoring\n";
 462                 }
 463                 next if $mids{$ref};
 464                 push @keep, $ref;
 465         }
 466         $smsg->{references} = '<'.join('> <', @keep).'>' if @keep;
 467         \@keep;
 468 }
 469
 470 sub link_message {
 471         my ($self, $smsg, $refs, $old_tid) = @_;
 472         my $tid;
 473
 474         if (@$refs) {
 475
 476                 # first ref *should* be the thread root,
 477                 # but we can never trust clients to do the right thing
 478                 my $ref = shift @$refs;
 479                 $tid = $self->_resolve_mid_to_tid($ref);
 480                 $self->merge_threads($tid, $old_tid) if defined $old_tid;
 481
 482                 # the rest of the refs should point to this tid:
 483                 foreach $ref (@$refs) {
 484                         my $ptid = $self->_resolve_mid_to_tid($ref);
 485                         merge_threads($self, $tid, $ptid);
 486                 }
 487         } else {
 488                 $tid = defined $old_tid ? $old_tid : $self->next_thread_id;
 489         }
 490         $smsg->{doc}->add_term('G' . $tid);
 491 }
 492
 493 sub index_git_blob_id {
 494         my ($doc, $pfx, $objid) = @_;
 495
 496         my $len = length($objid);
 497         for (my $len = length($objid); $len >= 7; ) {
 498                 $doc->add_term($pfx.$objid);
 499                 $objid = substr($objid, 0, --$len);
 500         }
 501 }
 502
 503 sub unindex_blob {
 504         my ($self, $mime) = @_;
 505         my $mid = eval { mid_clean(mid_mime($mime)) };
 506         $self->remove_message($mid) if defined $mid;
 507 }
 508
 509 sub index_mm {
 510         my ($self, $mime) = @_;
 511         my $mid = mid_clean(mid_mime($mime));
 512         my $mm = $self->{mm};
 513         my $num = $mm->mid_insert($mid);
 514         return $num if defined $num;
 515
 516         # fallback to num_for since filters like RubyLang set the number
 517         $mm->num_for($mid);
 518 }
 519
 520 sub unindex_mm {
 521         my ($self, $mime) = @_;
 522         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 523 }
 524
 525 sub index_mm2 {
 526         my ($self, $mime, $bytes, $blob) = @_;
 527         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 528         add_message($self, $mime, $bytes, $num, $blob);
 529 }
 530
 531 sub unindex_mm2 {
 532         my ($self, $mime) = @_;
 533         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 534         unindex_blob($self, $mime);
 535 }
 536
 537 sub index_both {
 538         my ($self, $mime, $bytes, $blob) = @_;
 539         my $num = index_mm($self, $mime);
 540         add_message($self, $mime, $bytes, $num, $blob);
 541 }
 542
 543 sub unindex_both {
 544         my ($self, $mime) = @_;
 545         unindex_blob($self, $mime);
 546         unindex_mm($self, $mime);
 547 }
 548
 549 sub do_cat_mail {
 550         my ($git, $blob, $sizeref) = @_;
 551         my $mime = eval {
 552                 my $str = $git->cat_file($blob, $sizeref);
 553                 # fixup bugs from import:
 554                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 555                 PublicInbox::MIME->new($str);
 556         };
 557         $@ ? undef : $mime;
 558 }
 559
 560 sub index_sync {
 561         my ($self, $opts) = @_;
 562         with_umask($self, sub { $self->_index_sync($opts) });
 563 }
 564
 565 sub batch_adjust ($$$$) {
 566         my ($max, $bytes, $batch_cb, $latest) = @_;
 567         $$max -= $bytes;
 568         if ($$max <= 0) {
 569                 $$max = BATCH_BYTES;
 570                 $batch_cb->($latest, 1);
 571         }
 572 }
 573
 574 # only for v1
 575 sub rlog {
 576         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 577         my $hex = '[a-f0-9]';
 578         my $h40 = $hex .'{40}';
 579         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 580         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 581         my $git = $self->{git};
 582         my $latest;
 583         my $bytes;
 584         my $max = BATCH_BYTES;
 585         local $/ = "\n";
 586         my $line;
 587         while (defined($line = <$log>)) {
 588                 if ($line =~ /$addmsg/o) {
 589                         my $blob = $1;
 590                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 591                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 592                         $add_cb->($self, $mime, $bytes, $blob);
 593                 } elsif ($line =~ /$delmsg/o) {
 594                         my $blob = $1;
 595                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 596                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 597                         $del_cb->($self, $mime);
 598                 } elsif ($line =~ /^commit ($h40)/o) {
 599                         $latest = $1;
 600                 }
 601         }
 602         $batch_cb->($latest, 0);
 603 }
 604
 605 sub _msgmap_init {
 606         my ($self) = @_;
 607         $self->{mm} ||= eval {
 608                 require PublicInbox::Msgmap;
 609                 my $msgmap_path = $self->{msgmap_path};
 610                 if (defined $msgmap_path) { # v2
 611                         PublicInbox::Msgmap->new_file($msgmap_path, 1);
 612                 } else {
 613                         PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 614                 }
 615         };
 616 }
 617
 618 sub _git_log {
 619         my ($self, $range) = @_;
 620         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 621                                 --raw -r --no-abbrev/, $range);
 622 }
 623
 624 # indexes all unindexed messages
 625 sub _index_sync {
 626         my ($self, $opts) = @_;
 627         my $tip = $opts->{ref} || 'HEAD';
 628         my $reindex = $opts->{reindex};
 629         my ($mkey, $last_commit, $lx, $xlog);
 630         $self->{git}->batch_prepare;
 631         my $xdb = _xdb_acquire($self);
 632         $xdb->begin_transaction;
 633         do {
 634                 $xlog = undef;
 635                 $mkey = 'last_commit';
 636                 $last_commit = $xdb->get_metadata('last_commit');
 637                 $lx = $last_commit;
 638                 if ($reindex) {
 639                         $lx = '';
 640                         $mkey = undef if $last_commit ne '';
 641                 }
 642                 $xdb->cancel_transaction;
 643                 $xdb = _xdb_release($self);
 644
 645                 # ensure we leak no FDs to "git log"
 646                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 647                 $xlog = _git_log($self, $range);
 648
 649                 $xdb = _xdb_acquire($self);
 650                 $xdb->begin_transaction;
 651         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 652
 653         my $mm = _msgmap_init($self);
 654         my $dbh = $mm->{dbh} if $mm;
 655         my $mm_only;
 656         my $cb = sub {
 657                 my ($commit, $more) = @_;
 658                 if ($dbh) {
 659                         $mm->last_commit($commit) if $commit;
 660                         $dbh->commit;
 661                 }
 662                 if (!$mm_only) {
 663                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 664                         $xdb->commit_transaction;
 665                         $xdb = _xdb_release($self);
 666                 }
 667                 # let another process do some work... <
 668                 if ($more) {
 669                         if (!$mm_only) {
 670                                 $xdb = _xdb_acquire($self);
 671                                 $xdb->begin_transaction;
 672                         }
 673                         $dbh->begin_work if $dbh;
 674                 }
 675         };
 676
 677         if ($mm) {
 678                 $dbh->begin_work;
 679                 my $lm = $mm->last_commit || '';
 680                 if ($lm eq $lx) {
 681                         # Common case is the indexes are synced,
 682                         # we only need to run git-log once:
 683                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 684                 } else {
 685                         # Uncommon case, msgmap and xapian are out-of-sync
 686                         # do not care for performance (but git is fast :>)
 687                         # This happens if we have to reindex Xapian since
 688                         # msgmap is a frozen format and our Xapian format
 689                         # is evolving.
 690                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 691
 692                         # first, ensure msgmap is up-to-date:
 693                         my $mkey_prev = $mkey;
 694                         $mkey = undef; # ignore xapian, for now
 695                         my $mlog = _git_log($self, $r);
 696                         $mm_only = 1;
 697                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 698                         $mm_only = $mlog = undef;
 699
 700                         # now deal with Xapian
 701                         $mkey = $mkey_prev;
 702                         $dbh = undef;
 703                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 704                 }
 705         } else {
 706                 # user didn't install DBD::SQLite and DBI
 707                 rlog($self, $xlog, *add_message, *unindex_blob, $cb);
 708         }
 709 }
 710
 711 # this will create a ghost as necessary
 712 sub _resolve_mid_to_tid {
 713         my ($self, $mid) = @_;
 714
 715         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 716         $smsg->thread_id;
 717 }
 718
 719 sub create_ghost {
 720         my ($self, $mid) = @_;
 721
 722         my $tid = $self->next_thread_id;
 723         my $doc = Search::Xapian::Document->new;
 724         $doc->add_term('Q' . $mid);
 725         $doc->add_term('G' . $tid);
 726         $doc->add_term('T' . 'ghost');
 727
 728         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 729         $self->{xdb}->add_document($doc);
 730
 731         $smsg;
 732 }
 733
 734 sub merge_threads {
 735         my ($self, $winner_tid, $loser_tid) = @_;
 736         return if $winner_tid == $loser_tid;
 737         my $db = $self->{xdb};
 738
 739         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 740         while (1) {
 741                 my ($head, $tail) = $self->find_doc_ids('G' . $loser_tid);
 742                 return if $head == $tail;
 743                 my @ids;
 744                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 745                         push @ids, $head->get_docid;
 746                 }
 747                 foreach my $docid (@ids) {
 748                         my $doc = $db->get_document($docid);
 749                         $doc->remove_term('G' . $loser_tid);
 750                         $doc->add_term('G' . $winner_tid);
 751                         $db->replace_document($docid, $doc);
 752                 }
 753         }
 754 }
 755
 756 sub _read_git_config_perm {
 757         my ($self) = @_;
 758         my @cmd = qw(config);
 759         if ($self->{version} == 2) {
 760                 push @cmd, "--file=$self->{mainrepo}/inbox-config";
 761         }
 762         my $fh = $self->{git}->popen(@cmd, 'core.sharedRepository');
 763         local $/ = "\n";
 764         my $perm = <$fh>;
 765         chomp $perm if defined $perm;
 766         $perm;
 767 }
 768
 769 sub _git_config_perm {
 770         my $self = shift;
 771         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 772         return PERM_GROUP if (!defined($perm) || $perm eq '');
 773         return PERM_UMASK if ($perm eq 'umask');
 774         return PERM_GROUP if ($perm eq 'group');
 775         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 776                 return PERM_EVERYBODY;
 777         }
 778         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 779         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 780
 781         my $i = oct($perm);
 782         return PERM_UMASK if ($i == PERM_UMASK);
 783         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 784         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 785
 786         if (($i & 0600) != 0600) {
 787                 die "core.sharedRepository mode invalid: ".
 788                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 789         }
 790         ($i & 0666);
 791 }
 792
 793 sub _umask_for {
 794         my ($perm) = @_; # _git_config_perm return value
 795         my $rv = $perm;
 796         return umask if $rv == 0;
 797
 798         # set +x bit if +r or +w were set
 799         $rv |= 0100 if ($rv & 0600);
 800         $rv |= 0010 if ($rv & 0060);
 801         $rv |= 0001 if ($rv & 0006);
 802         (~$rv & 0777);
 803 }
 804
 805 sub with_umask {
 806         my ($self, $cb) = @_;
 807         my $old = umask $self->{umask};
 808         my $rv = eval { $cb->() };
 809         my $err = $@;
 810         umask $old;
 811         die $err if $err;
 812         $rv;
 813 }
 814
 815 sub DESTROY {
 816         # order matters for unlocking
 817         $_[0]->{xdb} = undef;
 818         $_[0]->{lockfh} = undef;
 819 }
 820
 821 # remote_* subs are only used by SearchIdxPart and SearchIdxSkeleton
 822 sub remote_commit {
 823         my ($self) = @_;
 824         print { $self->{w} } "commit\n" or die "failed to write commit: $!";
 825 }
 826
 827 sub remote_close {
 828         my ($self) = @_;
 829         my $pid = delete $self->{pid} or die "no process to wait on\n";
 830         my $w = delete $self->{w} or die "no pipe to write to\n";
 831         print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 832         close $w or die "failed to close pipe for pid:$pid: $!\n";
 833         waitpid($pid, 0) == $pid or die "remote process did not finish";
 834         $? == 0 or die ref($self)." pid:$pid exited with: $?";
 835 }
 836
 837 1;