lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::OverIdx;
  22 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  23 use PublicInbox::Git qw(git_unquote);
  24 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  25 our @EXPORT_OK = qw(crlf_adjust log2stack is_ancestor check_size prepare_stack);
  26 my $X = \%PublicInbox::Search::X;
  27 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  28 our $DB_NO_SYNC = 0;
  29 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  30 use constant DEBUG => !!$ENV{DEBUG};
  31
  32 my $xapianlevels = qr/\A(?:full|medium)\z/;
  33 my $hex = '[a-f0-9]';
  34 my $OID = $hex .'{40,}';
  35 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  36
  37 sub new {
  38         my ($class, $ibx, $creat, $shard) = @_;
  39         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  40         my $inboxdir = $ibx->{inboxdir};
  41         my $version = $ibx->version;
  42         my $indexlevel = 'full';
  43         my $altid = $ibx->{altid};
  44         if ($altid) {
  45                 require PublicInbox::AltId;
  46                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  47         }
  48         if ($ibx->{indexlevel}) {
  49                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  50                         $indexlevel = $ibx->{indexlevel};
  51                 } else {
  52                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  53                 }
  54         }
  55         $ibx = PublicInbox::InboxWritable->new($ibx);
  56         my $self = bless {
  57                 ibx => $ibx,
  58                 xpfx => $inboxdir, # for xpfx_init
  59                 -altid => $altid,
  60                 ibx_ver => $version,
  61                 indexlevel => $indexlevel,
  62         }, $class;
  63         $self->xpfx_init;
  64         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  65         if ($ibx->{-skip_docdata}) {
  66                 $self->{-set_skip_docdata_once} = 1;
  67                 $self->{-skip_docdata} = 1;
  68         }
  69         $ibx->umask_prepare;
  70         if ($version == 1) {
  71                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  72                 my $dir = $self->xdir;
  73                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  74                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  75         } elsif ($version == 2) {
  76                 defined $shard or die "shard is required for v2\n";
  77                 # shard is a number
  78                 $self->{shard} = $shard;
  79                 $self->{lock_path} = undef;
  80         } else {
  81                 die "unsupported inbox version=$version\n";
  82         }
  83         $self->{creat} = ($creat || 0) == 1;
  84         $self;
  85 }
  86
  87 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  88
  89 sub idx_release {
  90         my ($self, $wake) = @_;
  91         if (need_xapian($self)) {
  92                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  93                 $xdb->close;
  94         }
  95         $self->lock_release($wake) if $self->{creat};
  96         undef;
  97 }
  98
  99 sub load_xapian_writable () {
 100         return 1 if $X->{WritableDatabase};
 101         PublicInbox::Search::load_xapian() or return;
 102         my $xap = $PublicInbox::Search::Xap;
 103         for (qw(Document TermGenerator WritableDatabase)) {
 104                 $X->{$_} = $xap.'::'.$_;
 105         }
 106         eval 'require '.$X->{WritableDatabase} or die;
 107         *sortable_serialise = $xap.'::sortable_serialise';
 108         *sortable_unserialise = $xap.'::sortable_unserialise';
 109         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 110         $DB_OPEN = eval($xap.'::DB_OPEN()');
 111         my $ver = (eval($xap.'::major_version()') << 16) |
 112                 (eval($xap.'::minor_version()') << 8);
 113         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 114         1;
 115 }
 116
 117 sub idx_acquire {
 118         my ($self) = @_;
 119         my $flag;
 120         my $dir = $self->xdir;
 121         if (need_xapian($self)) {
 122                 croak 'already acquired' if $self->{xdb};
 123                 load_xapian_writable();
 124                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 125         }
 126         if ($self->{creat}) {
 127                 require File::Path;
 128                 $self->lock_acquire;
 129
 130                 # don't create empty Xapian directories if we don't need Xapian
 131                 my $is_shard = defined($self->{shard});
 132                 if (!-d $dir && (!$is_shard ||
 133                                 ($is_shard && need_xapian($self)))) {
 134                         File::Path::mkpath($dir);
 135                         nodatacow_dir($dir);
 136                         $self->{-set_has_threadid_once} = 1;
 137                 }
 138         }
 139         return unless defined $flag;
 140         $flag |= $DB_NO_SYNC if ($self->{ibx} // $self->{eidx})->{-no_fsync};
 141         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 142         croak "Failed opening $dir: $@" if $@;
 143         $self->{xdb} = $xdb;
 144 }
 145
 146 sub add_val ($$$) {
 147         my ($doc, $col, $num) = @_;
 148         $num = sortable_serialise($num);
 149         $doc->add_value($col, $num);
 150 }
 151
 152 sub term_generator ($) { # write-only
 153         my ($self) = @_;
 154
 155         $self->{term_generator} //= do {
 156                 my $tg = $X->{TermGenerator}->new;
 157                 $tg->set_stemmer($self->stemmer);
 158                 $tg;
 159         }
 160 }
 161
 162 sub index_text ($$$$) {
 163         my ($self, $text, $wdf_inc, $prefix) = @_;
 164         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 165
 166         if ($self->{indexlevel} eq 'full') {
 167                 $tg->index_text($text, $wdf_inc, $prefix);
 168                 $tg->increase_termpos;
 169         } else {
 170                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 171         }
 172 }
 173
 174 sub index_headers ($$) {
 175         my ($self, $smsg) = @_;
 176         my @x = (from => 'A', # Author
 177                 subject => 'S', to => 'XTO', cc => 'XCC');
 178         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 179                 my $val = $smsg->{$field};
 180                 index_text($self, $val, 1, $pfx) if $val ne '';
 181         }
 182 }
 183
 184 sub index_diff_inc ($$$$) {
 185         my ($self, $text, $pfx, $xnq) = @_;
 186         if (@$xnq) {
 187                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 188                 @$xnq = ();
 189         }
 190         index_text($self, $text, 1, $pfx);
 191 }
 192
 193 sub index_old_diff_fn {
 194         my ($self, $seen, $fa, $fb, $xnq) = @_;
 195
 196         # no renames or space support for traditional diffs,
 197         # find the number of leading common paths to strip:
 198         my @fa = split('/', $fa);
 199         my @fb = split('/', $fb);
 200         while (scalar(@fa) && scalar(@fb)) {
 201                 $fa = join('/', @fa);
 202                 $fb = join('/', @fb);
 203                 if ($fa eq $fb) {
 204                         unless ($seen->{$fa}++) {
 205                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 206                         }
 207                         return 1;
 208                 }
 209                 shift @fa;
 210                 shift @fb;
 211         }
 212         0;
 213 }
 214
 215 sub index_diff ($$$) {
 216         my ($self, $txt, $doc) = @_;
 217         my %seen;
 218         my $in_diff;
 219         my @xnq;
 220         my $xnq = \@xnq;
 221         foreach (split(/\n/, $txt)) {
 222                 if ($in_diff && s/^ //) { # diff context
 223                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 224                 } elsif (/^-- $/) { # email signature begins
 225                         $in_diff = undef;
 226                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 227                         # wait until "---" and "+++" to capture filenames
 228                         $in_diff = 1;
 229                 # traditional diff:
 230                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 231                         my ($opt, $fa, $fb) = ($1, $2, $3);
 232                         push @xnq, $_;
 233                         # only support unified:
 234                         next unless $opt =~ /[uU]/;
 235                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 236                                                         $xnq);
 237                 } elsif (m!^--- ("?[^/]+/.+)!) {
 238                         my $fn = $1;
 239                         $fn = (split('/', git_unquote($fn), 2))[1];
 240                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 241                         $in_diff = 1;
 242                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 243                         my $fn = $1;
 244                         $fn = (split('/', git_unquote($fn), 2))[1];
 245                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 246                         $in_diff = 1;
 247                 } elsif (/^--- (\S+)/) {
 248                         $in_diff = $1;
 249                         push @xnq, $_;
 250                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 251                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 252                                                         $1, $xnq);
 253                 } elsif ($in_diff && s/^\+//) { # diff added
 254                         index_diff_inc($self, $_, 'XDFB', $xnq);
 255                 } elsif ($in_diff && s/^-//) { # diff removed
 256                         index_diff_inc($self, $_, 'XDFA', $xnq);
 257                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 258                         my ($ba, $bb) = ($1, $2);
 259                         index_git_blob_id($doc, 'XDFPRE', $ba);
 260                         index_git_blob_id($doc, 'XDFPOST', $bb);
 261                         $in_diff = 1;
 262                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 263                         # traditional diff w/o -p
 264                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 265                         # hunk header context
 266                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 267                 # ignore the following lines:
 268                 } elsif (/^(?:dis)similarity index/ ||
 269                                 /^(?:old|new) mode/ ||
 270                                 /^(?:deleted|new) file mode/ ||
 271                                 /^(?:copy|rename) (?:from|to) / ||
 272                                 /^(?:dis)?similarity index / ||
 273                                 /^\\ No newline at end of file/ ||
 274                                 /^Binary files .* differ/) {
 275                         push @xnq, $_;
 276                 } elsif ($_ eq '') {
 277                         # possible to be in diff context, some mail may be
 278                         # stripped by MUA or even GNU diff(1).  "git apply"
 279                         # treats a bare "\n" as diff context, too
 280                 } else {
 281                         push @xnq, $_;
 282                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 283                         $in_diff = undef;
 284                 }
 285         }
 286
 287         index_text($self, join("\n", @xnq), 1, 'XNQ');
 288 }
 289
 290 sub index_xapian { # msg_iter callback
 291         my $part = $_[0]->[0]; # ignore $depth and $idx
 292         my ($self, $doc) = @{$_[1]};
 293         my $ct = $part->content_type || 'text/plain';
 294         my $fn = $part->filename;
 295         if (defined $fn && $fn ne '') {
 296                 index_text($self, $fn, 1, 'XFN');
 297         }
 298         if ($part->{is_submsg}) {
 299                 my $mids = mids_for_index($part);
 300                 index_ids($self, $doc, $part, $mids);
 301                 my $smsg = bless {}, 'PublicInbox::Smsg';
 302                 $smsg->populate($part);
 303                 index_headers($self, $smsg);
 304         }
 305
 306         my ($s, undef) = msg_part_text($part, $ct);
 307         defined $s or return;
 308         $_[0]->[0] = $part = undef; # free memory
 309
 310         # split off quoted and unquoted blocks:
 311         my @sections = PublicInbox::MsgIter::split_quotes($s);
 312         undef $s; # free memory
 313         for my $txt (@sections) {
 314                 if ($txt =~ /\A>/) {
 315                         index_text($self, $txt, 0, 'XQUOT');
 316                 } else {
 317                         # does it look like a diff?
 318                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 319                                 index_diff($self, $txt, $doc);
 320                         } else {
 321                                 index_text($self, $txt, 1, 'XNQ');
 322                         }
 323                 }
 324                 undef $txt; # free memory
 325         }
 326 }
 327
 328 sub index_list_id ($$$) {
 329         my ($self, $doc, $hdr) = @_;
 330         for my $l ($hdr->header_raw('List-Id')) {
 331                 $l =~ /<([^>]+)>/ or next;
 332                 my $lid = lc $1;
 333                 $doc->add_boolean_term('G' . $lid);
 334                 index_text($self, $lid, 1, 'XL'); # probabilistic
 335         }
 336 }
 337
 338 sub index_ids ($$$$) {
 339         my ($self, $doc, $hdr, $mids) = @_;
 340         for my $mid (@$mids) {
 341                 index_text($self, $mid, 1, 'XM');
 342
 343                 # because too many Message-IDs are prefixed with
 344                 # "Pine.LNX."...
 345                 if ($mid =~ /\w{12,}/) {
 346                         my @long = ($mid =~ /(\w{3,}+)/g);
 347                         index_text($self, join(' ', @long), 1, 'XM');
 348                 }
 349         }
 350         $doc->add_boolean_term('Q' . $_) for @$mids;
 351         index_list_id($self, $doc, $hdr);
 352 }
 353
 354 sub add_xapian ($$$$) {
 355         my ($self, $eml, $smsg, $mids) = @_;
 356         my $doc = $X->{Document}->new;
 357         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 358         my @ds = gmtime($smsg->{ds});
 359         my $yyyymmdd = strftime('%Y%m%d', @ds);
 360         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 361         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 362         add_val($doc, PublicInbox::Search::DT(), $dt);
 363         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 364         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 365         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 366
 367         my $tg = term_generator($self);
 368         $tg->set_document($doc);
 369         index_headers($self, $smsg);
 370
 371         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 372                 $doc->add_boolean_term('O'.$eidx_key);
 373         }
 374         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 375         index_ids($self, $doc, $eml, $mids);
 376
 377         # by default, we maintain compatibility with v1.5.0 and earlier
 378         # by writing to docdata.glass, users who never exect to downgrade can
 379         # use --skip-docdata
 380         if (!$self->{-skip_docdata}) {
 381                 # WWW doesn't need {to} or {cc}, only NNTP
 382                 $smsg->{to} = $smsg->{cc} = '';
 383                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 384                 my $data = $smsg->to_doc_data;
 385                 $doc->set_data($data);
 386         }
 387
 388         if (my $altid = $self->{-altid}) {
 389                 foreach my $alt (@$altid) {
 390                         my $pfx = $alt->{xprefix};
 391                         foreach my $mid (@$mids) {
 392                                 my $id = $alt->mid2alt($mid);
 393                                 next unless defined $id;
 394                                 $doc->add_boolean_term($pfx . $id);
 395                         }
 396                 }
 397         }
 398         $self->{xdb}->replace_document($smsg->{num}, $doc);
 399 }
 400
 401 sub _msgmap_init ($) {
 402         my ($self) = @_;
 403         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 404         $self->{mm} //= eval {
 405                 require PublicInbox::Msgmap;
 406                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 407                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 408         };
 409 }
 410
 411 sub add_message {
 412         # mime = PublicInbox::Eml or Email::MIME object
 413         my ($self, $mime, $smsg, $sync) = @_;
 414         my $mids = mids_for_index($mime);
 415         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 416         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 417         $smsg->{num} //= do { # v1
 418                 _msgmap_init($self);
 419                 index_mm($self, $mime, $smsg->{blob}, $sync);
 420         };
 421
 422         # v1 and tests only:
 423         $smsg->populate($mime, $sync);
 424         $smsg->{bytes} //= length($mime->as_string);
 425
 426         eval {
 427                 # order matters, overview stores every possible piece of
 428                 # data in doc_data (deflated).  Xapian only stores a subset
 429                 # of the fields which exist in over.sqlite3.  We may stop
 430                 # storing doc_data in Xapian sometime after we get multi-inbox
 431                 # search working.
 432                 if (my $oidx = $self->{oidx}) { # v1 only
 433                         $oidx->add_overview($mime, $smsg);
 434                 }
 435                 if (need_xapian($self)) {
 436                         add_xapian($self, $mime, $smsg, $mids);
 437                 }
 438         };
 439
 440         if ($@) {
 441                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 442                 return undef;
 443         }
 444         $smsg->{num};
 445 }
 446
 447 sub _get_doc ($$$) {
 448         my ($self, $docid, $oid) = @_;
 449         my $doc = eval { $self->{xdb}->get_document($docid) };
 450         $doc // do {
 451                 warn "E: $@\n" if $@;
 452                 warn "E: #$docid $oid missing in Xapian\n";
 453                 undef;
 454         }
 455 }
 456
 457 sub add_eidx_info {
 458         my ($self, $docid, $oid, $eidx_key, $eml) = @_;
 459         begin_txn_lazy($self);
 460         my $doc = _get_doc($self, $docid, $oid) or return;
 461         term_generator($self)->set_document($doc);
 462         $doc->add_boolean_term('O'.$eidx_key);
 463         index_list_id($self, $doc, $eml);
 464         $self->{xdb}->replace_document($docid, $doc);
 465 }
 466
 467 sub remove_eidx_info {
 468         my ($self, $docid, $oid, $eidx_key, $eml) = @_;
 469         begin_txn_lazy($self);
 470         my $doc = _get_doc($self, $docid, $oid) or return;
 471         $doc->remove_term('O'.$eidx_key);
 472         for my $l ($eml->header_raw('List-Id')) {
 473                 $l =~ /<([^>]+)>/ or next;
 474                 my $lid = lc $1;
 475                 $doc->remove_term('G' . $lid);
 476
 477                 # nb: we don't remove the XL probabilistic terms
 478                 # since terms may overlap if cross-posted.
 479                 #
 480                 # IOW, a message which has both <foo.example.com>
 481                 # and <bar.example.com> would have overlapping
 482                 # "XLexample" and "XLcom" as terms and which we
 483                 # wouldn't know if they're safe to remove if we just
 484                 # unindex <foo.example.com> while preserving
 485                 # <bar.example.com>.
 486                 #
 487                 # In any case, this entire sub is will likely never
 488                 # be needed and users using the "l:" prefix are probably
 489                 # rarer.
 490         }
 491         $self->{xdb}->replace_document($docid, $doc);
 492 }
 493
 494 sub get_val ($$) {
 495         my ($doc, $col) = @_;
 496         sortable_unserialise($doc->get_value($col));
 497 }
 498
 499 sub smsg_from_doc ($) {
 500         my ($doc) = @_;
 501         my $data = $doc->get_data or return;
 502         my $smsg = bless {}, 'PublicInbox::Smsg';
 503         $smsg->{ts} = get_val($doc, PublicInbox::Search::TS());
 504         my $dt = get_val($doc, PublicInbox::Search::DT());
 505         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
 506         $smsg->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
 507         $smsg->load_from_data($data);
 508         $smsg;
 509 }
 510
 511 sub xdb_remove {
 512         my ($self, $oid, @removed) = @_;
 513         my $xdb = $self->{xdb} or return;
 514         for my $num (@removed) {
 515                 my $doc = _get_doc($self, $num, $oid) or next;
 516                 my $smsg = smsg_from_doc($doc);
 517                 my $blob = $smsg->{blob}; # may be undef if --skip-docdata
 518                 if (!defined($blob) || $blob eq $oid) {
 519                         $xdb->delete_document($num);
 520                 } else {
 521                         warn "E: #$num $oid != $blob in Xapian\n";
 522                 }
 523         }
 524 }
 525
 526 sub remove_by_oid {
 527         my ($self, $oid, $num) = @_;
 528         die "BUG: remove_by_oid is v2-only\n" if $self->{oidx};
 529         $self->begin_txn_lazy;
 530         xdb_remove($self, $oid, $num) if need_xapian($self);
 531 }
 532
 533 sub index_git_blob_id {
 534         my ($doc, $pfx, $objid) = @_;
 535
 536         my $len = length($objid);
 537         for (my $len = length($objid); $len >= 7; ) {
 538                 $doc->add_term($pfx.$objid);
 539                 $objid = substr($objid, 0, --$len);
 540         }
 541 }
 542
 543 # v1 only
 544 sub unindex_eml {
 545         my ($self, $oid, $eml) = @_;
 546         my $mids = mids($eml);
 547         my $nr = 0;
 548         my %tmp;
 549         for my $mid (@$mids) {
 550                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 551                 $nr += scalar @removed;
 552                 $tmp{$_}++ for @removed;
 553         }
 554         if (!$nr) {
 555                 $mids = join('> <', @$mids);
 556                 warn "W: <$mids> missing for removal from overview\n";
 557         }
 558         while (my ($num, $nr) = each %tmp) {
 559                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 560         }
 561         if ($nr) {
 562                 $self->{mm}->num_delete($_) for (keys %tmp);
 563         } else { # just in case msgmap and over.sqlite3 become desynched:
 564                 $self->{mm}->mid_delete($mids->[0]);
 565         }
 566         xdb_remove($self, $oid, keys %tmp) if need_xapian($self);
 567 }
 568
 569 sub index_mm {
 570         my ($self, $mime, $oid, $sync) = @_;
 571         my $mids = mids($mime);
 572         my $mm = $self->{mm};
 573         if ($sync->{reindex}) {
 574                 my $oidx = $self->{oidx};
 575                 for my $mid (@$mids) {
 576                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 577                         return $num if defined $num;
 578                 }
 579                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 580         } else {
 581                 # fallback to num_for since filters like RubyLang set the number
 582                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 583         }
 584 }
 585
 586 # returns the number of bytes to add if given a non-CRLF arg
 587 sub crlf_adjust ($) {
 588         if (index($_[0], "\r\n") < 0) {
 589                 # common case is LF-only, every \n needs an \r;
 590                 # so favor a cheap tr// over an expensive m//g
 591                 $_[0] =~ tr/\n/\n/;
 592         } else { # count number of '\n' w/o '\r', expensive:
 593                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 594         }
 595 }
 596
 597 sub index_both { # git->cat_async callback
 598         my ($bref, $oid, $type, $size, $sync) = @_;
 599         my ($nr, $max) = @$sync{qw(nr max)};
 600         ++$$nr;
 601         $$max -= $size;
 602         $size += crlf_adjust($$bref);
 603         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 604         my $self = $sync->{sidx};
 605         my $eml = PublicInbox::Eml->new($bref);
 606         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 607                 die "E: could not generate NNTP article number for $oid";
 608         add_message($self, $eml, $smsg, $sync);
 609 }
 610
 611 sub unindex_both { # git->cat_async callback
 612         my ($bref, $oid, $type, $size, $self) = @_;
 613         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 614 }
 615
 616 sub with_umask {
 617         my $self = shift;
 618         ($self->{ibx} // $self->{eidx})->with_umask(@_);
 619 }
 620
 621 # called by public-inbox-index
 622 sub index_sync {
 623         my ($self, $opt) = @_;
 624         delete $self->{lock_path} if $opt->{-skip_lock};
 625         $self->with_umask(\&_index_sync, $self, $opt);
 626         if ($opt->{reindex}) {
 627                 my %again = %$opt;
 628                 delete @again{qw(rethread reindex)};
 629                 index_sync($self, \%again);
 630         }
 631 }
 632
 633 sub check_size { # check_async cb for -index --max-size=...
 634         my ($oid, $type, $size, $arg, $git) = @_;
 635         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 636         if ($size <= $arg->{max_size}) {
 637                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 638         } else {
 639                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 640         }
 641 }
 642
 643 sub v1_checkpoint ($$;$) {
 644         my ($self, $sync, $stk) = @_;
 645         $self->{ibx}->git->async_wait_all;
 646
 647         # latest_cmt may be undef
 648         my $newest = $stk ? $stk->{latest_cmt} : undef;
 649         if ($newest) {
 650                 my $cur = $self->{mm}->last_commit || '';
 651                 if (need_update($self, $cur, $newest)) {
 652                         $self->{mm}->last_commit($newest);
 653                 }
 654         } else {
 655                 ${$sync->{max}} = $self->{batch_bytes};
 656         }
 657
 658         $self->{mm}->{dbh}->commit;
 659         if ($newest && need_xapian($self)) {
 660                 my $xdb = $self->{xdb};
 661                 my $cur = $xdb->get_metadata('last_commit');
 662                 if (need_update($self, $cur, $newest)) {
 663                         $xdb->set_metadata('last_commit', $newest);
 664                 }
 665
 666                 # let SearchView know a full --reindex was done so it can
 667                 # generate ->has_threadid-dependent links
 668                 if ($sync->{reindex} && !ref($sync->{reindex})) {
 669                         my $n = $xdb->get_metadata('has_threadid');
 670                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 671                 }
 672         }
 673
 674         $self->{oidx}->rethread_done($sync->{-opt}) if $newest; # all done
 675         commit_txn_lazy($self);
 676         $sync->{ibx}->git->cleanup;
 677         my $nr = ${$sync->{nr}};
 678         idx_release($self, $nr);
 679         # let another process do some work...
 680         if (my $pr = $sync->{-opt}->{-progress}) {
 681                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 682         }
 683         if (!$stk) { # more to come
 684                 begin_txn_lazy($self);
 685                 $self->{mm}->{dbh}->begin_work;
 686         }
 687 }
 688
 689 # only for v1
 690 sub process_stack {
 691         my ($self, $sync, $stk) = @_;
 692         my $git = $sync->{ibx}->git;
 693         my $max = $self->{batch_bytes};
 694         my $nr = 0;
 695         $sync->{nr} = \$nr;
 696         $sync->{max} = \$max;
 697         $sync->{sidx} = $self;
 698
 699         $self->{mm}->{dbh}->begin_work;
 700         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 701                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 702                 for my $oid (@leftovers) {
 703                         $oid = unpack('H*', $oid);
 704                         $git->cat_async($oid, \&unindex_both, $self);
 705                 }
 706         }
 707         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 708                 $sync->{index_oid} = \&index_both;
 709         }
 710         while (my ($f, $at, $ct, $oid) = $stk->pop_rec) {
 711                 if ($f eq 'm') {
 712                         my $arg = { %$sync, autime => $at, cotime => $ct };
 713                         if ($sync->{max_size}) {
 714                                 $git->check_async($oid, \&check_size, $arg);
 715                         } else {
 716                                 $git->cat_async($oid, \&index_both, $arg);
 717                         }
 718                         v1_checkpoint($self, $sync) if $max <= 0;
 719                 } elsif ($f eq 'd') {
 720                         $git->cat_async($oid, \&unindex_both, $self);
 721                 }
 722         }
 723         v1_checkpoint($self, $sync, $stk);
 724 }
 725
 726 sub log2stack ($$$) {
 727         my ($sync, $git, $range) = @_;
 728         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 729         my ($add, $del);
 730         if ($sync->{ibx}->version == 1) {
 731                 my $path = $hex.'{2}/'.$hex.'{38}';
 732                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 733                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 734         } else {
 735                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 736                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 737         }
 738
 739         # Count the new files so they can be added newest to oldest
 740         # and still have numbers increasing from oldest to newest
 741         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 742                                 --no-notes --no-color --no-renames --no-abbrev),
 743                                 $range);
 744         my ($at, $ct, $stk);
 745         while (<$fh>) {
 746                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 747                         ($at, $ct) = ($1 + 0, $2 + 0);
 748                         $stk //= PublicInbox::IdxStack->new($3);
 749                 } elsif (/$del/) {
 750                         my $oid = $1;
 751                         if ($D) { # reindex case
 752                                 $D->{pack('H*', $oid)}++;
 753                         } else { # non-reindex case:
 754                                 $stk->push_rec('d', $at, $ct, $oid);
 755                         }
 756                 } elsif (/$add/) {
 757                         my $oid = $1;
 758                         if ($D) {
 759                                 my $oid_bin = pack('H*', $oid);
 760                                 my $nr = --$D->{$oid_bin};
 761                                 delete($D->{$oid_bin}) if $nr <= 0;
 762
 763                                 # nr < 0 (-1) means it never existed
 764                                 $stk->push_rec('m', $at, $ct, $oid) if $nr < 0;
 765                         } else {
 766                                 $stk->push_rec('m', $at, $ct, $oid);
 767                         }
 768                 }
 769         }
 770         close $fh or die "git log failed: \$?=$?";
 771         $stk //= PublicInbox::IdxStack->new;
 772         $stk->read_prepare;
 773 }
 774
 775 sub prepare_stack ($$) {
 776         my ($sync, $range) = @_;
 777         my $git = $sync->{ibx}->git;
 778
 779         if (index($range, '..') < 0) {
 780                 # don't show annoying git errors to users who run -index
 781                 # on empty inboxes
 782                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 783                 return PublicInbox::IdxStack->new->read_prepare if $?;
 784         }
 785         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 786         log2stack($sync, $git, $range);
 787 }
 788
 789 # --is-ancestor requires git 1.8.0+
 790 sub is_ancestor ($$$) {
 791         my ($git, $cur, $tip) = @_;
 792         return 0 unless $git->check($cur);
 793         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 794                 qw(merge-base --is-ancestor), $cur, $tip ];
 795         my $pid = spawn($cmd);
 796         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 797         $? == 0;
 798 }
 799
 800 sub need_update ($$$) {
 801         my ($self, $cur, $new) = @_;
 802         my $git = $self->{ibx}->git;
 803         return 1 if $cur && !is_ancestor($git, $cur, $new);
 804         my $range = $cur eq '' ? $new : "$cur..$new";
 805         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 806         ($n eq '' || $n > 0);
 807 }
 808
 809 # The last git commit we indexed with Xapian or SQLite (msgmap)
 810 # This needs to account for cases where Xapian or SQLite is
 811 # out-of-date with respect to the other.
 812 sub _last_x_commit {
 813         my ($self, $mm) = @_;
 814         my $lm = $mm->last_commit || '';
 815         my $lx = '';
 816         if (need_xapian($self)) {
 817                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 818         } else {
 819                 $lx = $lm;
 820         }
 821         # Use last_commit from msgmap if it is older or unset
 822         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 823                 $lx = $lm;
 824         }
 825         $lx;
 826 }
 827
 828 sub reindex_from ($$) {
 829         my ($reindex, $last_commit) = @_;
 830         return $last_commit unless $reindex;
 831         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 832 }
 833
 834 # indexes all unindexed messages (v1 only)
 835 sub _index_sync {
 836         my ($self, $opt) = @_;
 837         my $tip = $opt->{ref} || 'HEAD';
 838         my $ibx = $self->{ibx};
 839         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 840         $ibx->git->batch_prepare;
 841         my $pr = $opt->{-progress};
 842         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
 843         my $xdb = $self->begin_txn_lazy;
 844         $self->{oidx}->rethread_prepare($opt);
 845         my $mm = _msgmap_init($self);
 846         if ($sync->{reindex}) {
 847                 my $last = $mm->last_commit;
 848                 if ($last) {
 849                         $tip = $last;
 850                 } else {
 851                         # somebody just blindly added --reindex when indexing
 852                         # for the first time, allow it:
 853                         undef $sync->{reindex};
 854                 }
 855         }
 856         my $last_commit = _last_x_commit($self, $mm);
 857         my $lx = reindex_from($sync->{reindex}, $last_commit);
 858         my $range = $lx eq '' ? $tip : "$lx..$tip";
 859         $pr->("counting changes\n\t$range ... ") if $pr;
 860         my $stk = prepare_stack($sync, $range);
 861         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 862         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 863         process_stack($self, $sync, $stk);
 864 }
 865
 866 sub DESTROY {
 867         # order matters for unlocking
 868         $_[0]->{xdb} = undef;
 869         $_[0]->{lockfh} = undef;
 870 }
 871
 872 sub _begin_txn {
 873         my ($self) = @_;
 874         my $xdb = $self->{xdb} || idx_acquire($self);
 875         $self->{oidx}->begin_lazy if $self->{oidx};
 876         $xdb->begin_transaction if $xdb;
 877         $self->{txn} = 1;
 878         $xdb;
 879 }
 880
 881 sub begin_txn_lazy {
 882         my ($self) = @_;
 883         $self->with_umask(\&_begin_txn, $self) if !$self->{txn};
 884 }
 885
 886 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 887 # This metadata is read by Admin::detect_indexlevel:
 888 sub set_metadata_once {
 889         my ($self) = @_;
 890
 891         return if $self->{shard}; # only continue if undef or 0, not >0
 892         my $xdb = $self->{xdb};
 893
 894         if (delete($self->{-set_has_threadid_once})) {
 895                 $xdb->set_metadata('has_threadid', '1');
 896         }
 897         if (delete($self->{-set_indexlevel_once})) {
 898                 my $level = $xdb->get_metadata('indexlevel');
 899                 if (!$level || $level ne 'medium') {
 900                         $xdb->set_metadata('indexlevel', 'medium');
 901                 }
 902         }
 903         if (delete($self->{-set_skip_docdata_once})) {
 904                 $xdb->get_metadata('skip_docdata') or
 905                         $xdb->set_metadata('skip_docdata', '1');
 906         }
 907 }
 908
 909 sub _commit_txn {
 910         my ($self) = @_;
 911         if (my $xdb = $self->{xdb}) {
 912                 set_metadata_once($self);
 913                 $xdb->commit_transaction;
 914         }
 915         $self->{oidx}->commit_lazy if $self->{oidx};
 916 }
 917
 918 sub commit_txn_lazy {
 919         my ($self) = @_;
 920         delete($self->{txn}) and
 921                 $self->with_umask(\&_commit_txn, $self);
 922 }
 923
 924 sub worker_done {
 925         my ($self) = @_;
 926         if (need_xapian($self)) {
 927                 die "$$ $0 xdb not released\n" if $self->{xdb};
 928         }
 929         die "$$ $0 still in transaction\n" if $self->{txn};
 930 }
 931
 932 sub eidx_shard_new {
 933         my ($class, $eidx, $shard) = @_;
 934         my $self = bless {
 935                 eidx => $eidx,
 936                 xpfx => $eidx->{xpfx},
 937                 indexlevel => $eidx->{indexlevel},
 938                 -skip_docdata => 1,
 939                 shard => $shard,
 940                 creat => 1,
 941         }, $class;
 942         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
 943         $self;
 944 }
 945
 946 1;