lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchIdx;
   5 use strict;
   6 use warnings;
   7 use base qw(PublicInbox::Search);
   8 use PublicInbox::MID qw/mid_clean mid_compressed/;
   9 *xpfx = *PublicInbox::Search::xpfx;
  10
  11 sub new {
  12         my ($class, $git_dir, $writable) = @_;
  13         my $dir = $class->xdir($git_dir);
  14         require Search::Xapian::WritableDatabase;
  15         my $flag = Search::Xapian::DB_OPEN;
  16         if ($writable == 1) {
  17                 require File::Path;
  18                 File::Path::mkpath($dir);
  19                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  20         }
  21         my $db = Search::Xapian::WritableDatabase->new($dir, $flag);
  22         bless { xdb => $db, git_dir => $git_dir }, $class;
  23 }
  24
  25 sub add_message {
  26         my ($self, $mime) = @_; # mime = Email::MIME object
  27         my $db = $self->{xdb};
  28
  29         my $doc_id;
  30         my $mid_orig = mid_clean($mime->header_obj->header('Message-ID'));
  31         my $mid = mid_compressed($mid_orig);
  32         my $was_ghost = 0;
  33         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  34
  35         eval {
  36                 my $smsg = $self->lookup_message($mid);
  37                 my $doc;
  38
  39                 if ($smsg) {
  40                         $smsg->ensure_metadata;
  41                         # convert a ghost to a regular message
  42                         # it will also clobber any existing regular message
  43                         $smsg->mime($mime);
  44                         $doc = $smsg->{doc};
  45
  46                         my $type = xpfx('type');
  47                         eval {
  48                                 $doc->remove_term($type . 'ghost');
  49                                 $was_ghost = 1;
  50                         };
  51
  52                         # probably does not exist:
  53                         eval { $doc->remove_term($type . 'mail') };
  54                         $doc->add_term($type . 'mail');
  55                 }  else {
  56                         $smsg = PublicInbox::SearchMsg->new($mime);
  57                         $doc = $smsg->{doc};
  58                         $doc->add_term(xpfx('mid') . $mid);
  59                 }
  60
  61                 my $subj = $smsg->subject;
  62
  63                 if (length $subj) {
  64                         $doc->add_term(xpfx('subject') . $subj);
  65
  66                         my $path = $self->subject_path($subj);
  67                         $doc->add_term(xpfx('path') . mid_compressed($path));
  68                 }
  69
  70                 my $from = $smsg->from_name;
  71                 my $date = $smsg->date;
  72                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
  73                 $doc->add_value(PublicInbox::Search::TS, $ts);
  74
  75                 my $tg = $self->term_generator;
  76
  77                 $tg->set_document($doc);
  78                 $tg->index_text($subj, 1, 'S') if $subj;
  79                 $tg->increase_termpos;
  80                 $tg->index_text($subj) if $subj;
  81                 $tg->increase_termpos;
  82
  83                 $tg->index_text($smsg->from->format);
  84                 $tg->increase_termpos;
  85
  86                 $mime->walk_parts(sub {
  87                         my ($part) = @_;
  88                         return if $part->subparts; # walk_parts already recurses
  89                         my $ct = $part->content_type || $ct_msg;
  90
  91                         # account for filter bugs...
  92                         $ct =~ m!\btext/plain\b!i or return;
  93
  94                         my (@orig, @quot);
  95                         my $body = $part->body;
  96                         $part->body_set('');
  97                         my @lines = split(/\n/, $body);
  98                         while (defined(my $l = shift @lines)) {
  99                                 if ($l =~ /^\s*>/) {
 100                                         push @quot, $l;
 101                                 } else {
 102                                         push @orig, $l;
 103                                 }
 104                         }
 105                         if (@quot) {
 106                                 $tg->index_text(join("\n", @quot), 0);
 107                                 @quot = ();
 108                                 $tg->increase_termpos;
 109                         }
 110                         if (@orig) {
 111                                 $tg->index_text(join("\n", @orig));
 112                                 @orig = ();
 113                                 $tg->increase_termpos;
 114                         }
 115                 });
 116
 117                 if ($was_ghost) {
 118                         $doc_id = $smsg->doc_id;
 119                         $self->link_message($smsg, 0);
 120                         $doc->set_data($smsg->to_doc_data);
 121                         $db->replace_document($doc_id, $doc);
 122                 } else {
 123                         $self->link_message($smsg, 0);
 124                         $doc->set_data($smsg->to_doc_data);
 125                         $doc_id = $db->add_document($doc);
 126                 }
 127         };
 128
 129         if ($@) {
 130                 warn "failed to index message <$mid_orig>: $@\n";
 131                 return undef;
 132         }
 133         $doc_id;
 134 }
 135
 136 # returns deleted doc_id on success, undef on missing
 137 sub remove_message {
 138         my ($self, $mid_orig) = @_;
 139         my $db = $self->{xdb};
 140         my $doc_id;
 141         $mid_orig = mid_clean($mid_orig);
 142         my $mid = mid_compressed($mid_orig);
 143
 144         eval {
 145                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 146                 $db->delete_document($doc_id) if defined $doc_id;
 147         };
 148
 149         if ($@) {
 150                 warn "failed to remove message <$mid_orig>: $@\n";
 151                 return undef;
 152         }
 153         $doc_id;
 154 }
 155
 156 sub term_generator { # write-only
 157         my ($self) = @_;
 158
 159         my $tg = $self->{term_generator};
 160         return $tg if $tg;
 161
 162         $tg = Search::Xapian::TermGenerator->new;
 163         $tg->set_stemmer($self->stemmer);
 164
 165         $self->{term_generator} = $tg;
 166 }
 167
 168 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 169
 170 # increments last_thread_id counter
 171 # returns a 64-bit integer represented as a hex string
 172 sub next_thread_id {
 173         my ($self) = @_;
 174         my $db = $self->{xdb};
 175         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 176
 177         $db->set_metadata('last_thread_id', ++$last_thread_id);
 178
 179         $last_thread_id;
 180 }
 181
 182 sub link_message {
 183         my ($self, $smsg, $is_ghost) = @_;
 184
 185         if ($is_ghost) {
 186                 $smsg->ensure_metadata;
 187         } else {
 188                 $self->link_message_to_parents($smsg);
 189         }
 190 }
 191
 192 sub link_message_to_parents {
 193         my ($self, $smsg) = @_;
 194         my $doc = $smsg->{doc};
 195         my $mid = mid_compressed($smsg->mid);
 196         my $mime = $smsg->mime;
 197         my $refs = $mime->header_obj->header('References');
 198         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 199         my $irt = $mime->header_obj->header('In-Reply-To');
 200         if ($irt) {
 201                 $irt = mid_compressed(mid_clean($irt));
 202
 203                 # maybe some crazies will try to make a circular reference:
 204                 if ($irt eq $mid) {
 205                         $irt = undef;
 206                 } else {
 207                         # last References should be $irt
 208                         # we will de-dupe later
 209                         push @refs, $irt;
 210                 }
 211         }
 212
 213         my $tid;
 214         if (@refs) {
 215                 my @crefs = map { mid_compressed($_) } @refs;
 216                 my %uniq = ($mid => 1);
 217
 218                 # prevent circular references via References: here:
 219                 @refs = ();
 220                 foreach my $ref (@crefs) {
 221                         next if $uniq{$ref};
 222                         $uniq{$ref} = 1;
 223                         push @refs, $ref;
 224                 }
 225         }
 226         if (@refs) {
 227                 $doc->add_term(xpfx('inreplyto') . $irt) if defined $irt;
 228                 $smsg->{references_sorted} = '<'.join('><', @refs).'>';
 229
 230                 my $ref_pfx = xpfx('references');
 231
 232                 # first ref *should* be the thread root,
 233                 # but we can never trust clients to do the right thing
 234                 my $ref = shift @refs;
 235                 $doc->add_term($ref_pfx . $ref);
 236                 $tid = $self->_resolve_mid_to_tid($ref);
 237
 238                 # the rest of the refs should point to this tid:
 239                 foreach $ref (@refs) {
 240                         $doc->add_term($ref_pfx . $ref);
 241                         my $ptid = $self->_resolve_mid_to_tid($ref);
 242                         if ($tid ne $ptid) {
 243                                 $self->merge_threads($tid, $ptid);
 244                         }
 245                 }
 246         } else {
 247                 $tid = $self->next_thread_id;
 248         }
 249         $doc->add_term(xpfx('thread') . $tid);
 250 }
 251
 252 sub index_blob {
 253         my ($self, $git, $blob) = @_;
 254         my $mime = do_cat_mail($git, $blob) or return;
 255         eval { $self->add_message($mime) };
 256         warn "W: index_blob $blob: $@\n" if $@;
 257 }
 258
 259 sub unindex_blob {
 260         my ($self, $git, $blob) = @_;
 261         my $mime = do_cat_mail($git, $blob) or return;
 262         my $mid = $mime->header_obj->header('Message-ID');
 263         eval { $self->remove_message($mid) } if defined $mid;
 264         warn "W: unindex_blob $blob: $@\n" if $@;
 265 }
 266
 267 sub do_cat_mail {
 268         my ($git, $blob) = @_;
 269         my $mime = eval {
 270                 my $str = $git->cat_file($blob);
 271                 Email::MIME->new($str);
 272         };
 273         $@ ? undef : $mime;
 274 }
 275
 276 # indexes all unindexed messages
 277 sub index_sync {
 278         my ($self, $head) = @_;
 279         require PublicInbox::GitCatFile;
 280         my $db = $self->{xdb};
 281         my $hex = '[a-f0-9]';
 282         my $h40 = $hex .'{40}';
 283         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 284         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 285         $head ||= 'HEAD';
 286
 287         $db->begin_transaction;
 288         eval {
 289                 my $git = PublicInbox::GitCatFile->new($self->{git_dir});
 290
 291                 my $latest = $db->get_metadata('last_commit');
 292                 my $range = length $latest ? "$latest..$head" : $head;
 293                 $latest = undef;
 294
 295                 # get indexed messages
 296                 my @cmd = ('git', "--git-dir=$self->{git_dir}", "log",
 297                             qw/--reverse --no-notes --no-color --raw -r
 298                                --no-abbrev/, $range);
 299                 my $pid = open(my $log, '-|', @cmd) or
 300                         die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 301
 302                 while (my $line = <$log>) {
 303                         if ($line =~ /$addmsg/o) {
 304                                 $self->index_blob($git, $1);
 305                         } elsif ($line =~ /$delmsg/o) {
 306                                 $self->unindex_blob($git, $1);
 307                         } elsif ($line =~ /^commit ($h40)/o) {
 308                                 $latest = $1;
 309                         }
 310                 }
 311                 close $log;
 312                 $db->set_metadata('last_commit', $latest) if defined $latest;
 313         };
 314         if ($@) {
 315                 warn "indexing failed: $@\n";
 316                 $db->cancel_transaction;
 317         } else {
 318                 $db->commit_transaction;
 319         }
 320 }
 321
 322 # this will create a ghost as necessary
 323 sub _resolve_mid_to_tid {
 324         my ($self, $mid) = @_;
 325
 326         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 327         $smsg->thread_id;
 328 }
 329
 330 sub create_ghost {
 331         my ($self, $mid, $tid) = @_;
 332
 333         $mid = mid_compressed($mid);
 334         $tid = $self->next_thread_id unless defined $tid;
 335
 336         my $doc = Search::Xapian::Document->new;
 337         $doc->add_term(xpfx('mid') . $mid);
 338         $doc->add_term(xpfx('thread') . $tid);
 339         $doc->add_term(xpfx('type') . 'ghost');
 340
 341         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 342         $self->link_message($smsg, 1);
 343         $self->{xdb}->add_document($doc);
 344
 345         $smsg;
 346 }
 347
 348 sub merge_threads {
 349         my ($self, $winner_tid, $loser_tid) = @_;
 350         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 351         my $thread_pfx = xpfx('thread');
 352         my $db = $self->{xdb};
 353
 354         for (; $head != $tail; $head->inc) {
 355                 my $docid = $head->get_docid;
 356                 my $doc = $db->get_document($docid);
 357                 $doc->remove_term($thread_pfx . $loser_tid);
 358                 $doc->add_term($thread_pfx . $winner_tid);
 359                 $db->replace_document($docid, $doc);
 360         }
 361 }
 362
 363 1;