lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak carp);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::OverIdx;
  22 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  23 use PublicInbox::Git qw(git_unquote);
  24 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  25 our @EXPORT_OK = qw(crlf_adjust log2stack is_ancestor check_size prepare_stack
  26         index_text term_generator add_val is_bad_blob);
  27 my $X = \%PublicInbox::Search::X;
  28 our ($DB_CREATE_OR_OPEN, $DB_OPEN);
  29 our $DB_NO_SYNC = 0;
  30 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  31 use constant DEBUG => !!$ENV{DEBUG};
  32
  33 my $xapianlevels = qr/\A(?:full|medium)\z/;
  34 my $hex = '[a-f0-9]';
  35 my $OID = $hex .'{40,}';
  36 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  37
  38 sub new {
  39         my ($class, $ibx, $creat, $shard) = @_;
  40         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  41         my $inboxdir = $ibx->{inboxdir};
  42         my $version = $ibx->version;
  43         my $indexlevel = 'full';
  44         my $altid = $ibx->{altid};
  45         if ($altid) {
  46                 require PublicInbox::AltId;
  47                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  48         }
  49         if ($ibx->{indexlevel}) {
  50                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  51                         $indexlevel = $ibx->{indexlevel};
  52                 } else {
  53                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  54                 }
  55         }
  56         $ibx = PublicInbox::InboxWritable->new($ibx);
  57         my $self = bless {
  58                 ibx => $ibx,
  59                 xpfx => $inboxdir, # for xpfx_init
  60                 -altid => $altid,
  61                 ibx_ver => $version,
  62                 indexlevel => $indexlevel,
  63         }, $class;
  64         $self->xpfx_init;
  65         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  66         if ($ibx->{-skip_docdata}) {
  67                 $self->{-set_skip_docdata_once} = 1;
  68                 $self->{-skip_docdata} = 1;
  69         }
  70         $ibx->umask_prepare;
  71         if ($version == 1) {
  72                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  73                 my $dir = $self->xdir;
  74                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  75                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  76         } elsif ($version == 2) {
  77                 defined $shard or die "shard is required for v2\n";
  78                 # shard is a number
  79                 $self->{shard} = $shard;
  80                 $self->{lock_path} = undef;
  81         } else {
  82                 die "unsupported inbox version=$version\n";
  83         }
  84         $self->{creat} = ($creat || 0) == 1;
  85         $self;
  86 }
  87
  88 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  89
  90 sub idx_release {
  91         my ($self, $wake) = @_;
  92         if (need_xapian($self)) {
  93                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  94                 $xdb->close;
  95         }
  96         $self->lock_release($wake) if $self->{creat};
  97         undef;
  98 }
  99
 100 sub load_xapian_writable () {
 101         return 1 if $X->{WritableDatabase};
 102         PublicInbox::Search::load_xapian() or return;
 103         my $xap = $PublicInbox::Search::Xap;
 104         for (qw(Document TermGenerator WritableDatabase)) {
 105                 $X->{$_} = $xap.'::'.$_;
 106         }
 107         eval 'require '.$X->{WritableDatabase} or die;
 108         *sortable_serialise = $xap.'::sortable_serialise';
 109         *sortable_unserialise = $xap.'::sortable_unserialise';
 110         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 111         $DB_OPEN = eval($xap.'::DB_OPEN()');
 112         my $ver = (eval($xap.'::major_version()') << 16) |
 113                 (eval($xap.'::minor_version()') << 8);
 114         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 115         1;
 116 }
 117
 118 sub idx_acquire {
 119         my ($self) = @_;
 120         my $flag;
 121         my $dir = $self->xdir;
 122         if (need_xapian($self)) {
 123                 croak 'already acquired' if $self->{xdb};
 124                 load_xapian_writable();
 125                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 126         }
 127         if ($self->{creat}) {
 128                 require File::Path;
 129                 $self->lock_acquire;
 130
 131                 # don't create empty Xapian directories if we don't need Xapian
 132                 my $is_shard = defined($self->{shard});
 133                 if (!-d $dir && (!$is_shard ||
 134                                 ($is_shard && need_xapian($self)))) {
 135                         File::Path::mkpath($dir);
 136                         nodatacow_dir($dir);
 137                         $self->{-set_has_threadid_once} = 1;
 138                 }
 139         }
 140         return unless defined $flag;
 141         $flag |= $DB_NO_SYNC if ($self->{ibx} // $self->{eidx})->{-no_fsync};
 142         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 143         croak "Failed opening $dir: $@" if $@;
 144         $self->{xdb} = $xdb;
 145 }
 146
 147 sub add_val ($$$) {
 148         my ($doc, $col, $num) = @_;
 149         $num = sortable_serialise($num);
 150         $doc->add_value($col, $num);
 151 }
 152
 153 sub term_generator ($) { # write-only
 154         my ($self) = @_;
 155
 156         $self->{term_generator} //= do {
 157                 my $tg = $X->{TermGenerator}->new;
 158                 $tg->set_stemmer(PublicInbox::Search::stemmer($self));
 159                 $tg;
 160         }
 161 }
 162
 163 sub index_text ($$$$) {
 164         my ($self, $text, $wdf_inc, $prefix) = @_;
 165         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 166
 167         if ($self->{indexlevel} eq 'full') {
 168                 $tg->index_text($text, $wdf_inc, $prefix);
 169                 $tg->increase_termpos;
 170         } else {
 171                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 172         }
 173 }
 174
 175 sub index_headers ($$) {
 176         my ($self, $smsg) = @_;
 177         my @x = (from => 'A', # Author
 178                 subject => 'S', to => 'XTO', cc => 'XCC');
 179         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 180                 my $val = $smsg->{$field};
 181                 index_text($self, $val, 1, $pfx) if $val ne '';
 182         }
 183 }
 184
 185 sub index_diff_inc ($$$$) {
 186         my ($self, $text, $pfx, $xnq) = @_;
 187         if (@$xnq) {
 188                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 189                 @$xnq = ();
 190         }
 191         index_text($self, $text, 1, $pfx);
 192 }
 193
 194 sub index_old_diff_fn {
 195         my ($self, $seen, $fa, $fb, $xnq) = @_;
 196
 197         # no renames or space support for traditional diffs,
 198         # find the number of leading common paths to strip:
 199         my @fa = split('/', $fa);
 200         my @fb = split('/', $fb);
 201         while (scalar(@fa) && scalar(@fb)) {
 202                 $fa = join('/', @fa);
 203                 $fb = join('/', @fb);
 204                 if ($fa eq $fb) {
 205                         unless ($seen->{$fa}++) {
 206                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 207                         }
 208                         return 1;
 209                 }
 210                 shift @fa;
 211                 shift @fb;
 212         }
 213         0;
 214 }
 215
 216 sub index_diff ($$$) {
 217         my ($self, $txt, $doc) = @_;
 218         my %seen;
 219         my $in_diff;
 220         my @xnq;
 221         my $xnq = \@xnq;
 222         foreach (split(/\n/, $txt)) {
 223                 if ($in_diff && s/^ //) { # diff context
 224                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 225                 } elsif (/^-- $/) { # email signature begins
 226                         $in_diff = undef;
 227                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 228                         # wait until "---" and "+++" to capture filenames
 229                         $in_diff = 1;
 230                 # traditional diff:
 231                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 232                         my ($opt, $fa, $fb) = ($1, $2, $3);
 233                         push @xnq, $_;
 234                         # only support unified:
 235                         next unless $opt =~ /[uU]/;
 236                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 237                                                         $xnq);
 238                 } elsif (m!^--- ("?[^/]+/.+)!) {
 239                         my $fn = $1;
 240                         $fn = (split('/', git_unquote($fn), 2))[1];
 241                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 242                         $in_diff = 1;
 243                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 244                         my $fn = $1;
 245                         $fn = (split('/', git_unquote($fn), 2))[1];
 246                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 247                         $in_diff = 1;
 248                 } elsif (/^--- (\S+)/) {
 249                         $in_diff = $1;
 250                         push @xnq, $_;
 251                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 252                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 253                                                         $1, $xnq);
 254                 } elsif ($in_diff && s/^\+//) { # diff added
 255                         index_diff_inc($self, $_, 'XDFB', $xnq);
 256                 } elsif ($in_diff && s/^-//) { # diff removed
 257                         index_diff_inc($self, $_, 'XDFA', $xnq);
 258                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 259                         my ($ba, $bb) = ($1, $2);
 260                         index_git_blob_id($doc, 'XDFPRE', $ba);
 261                         index_git_blob_id($doc, 'XDFPOST', $bb);
 262                         $in_diff = 1;
 263                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 264                         # traditional diff w/o -p
 265                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 266                         # hunk header context
 267                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 268                 # ignore the following lines:
 269                 } elsif (/^(?:dis)similarity index/ ||
 270                                 /^(?:old|new) mode/ ||
 271                                 /^(?:deleted|new) file mode/ ||
 272                                 /^(?:copy|rename) (?:from|to) / ||
 273                                 /^(?:dis)?similarity index / ||
 274                                 /^\\ No newline at end of file/ ||
 275                                 /^Binary files .* differ/) {
 276                         push @xnq, $_;
 277                 } elsif ($_ eq '') {
 278                         # possible to be in diff context, some mail may be
 279                         # stripped by MUA or even GNU diff(1).  "git apply"
 280                         # treats a bare "\n" as diff context, too
 281                 } else {
 282                         push @xnq, $_;
 283                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 284                         $in_diff = undef;
 285                 }
 286         }
 287
 288         index_text($self, join("\n", @xnq), 1, 'XNQ');
 289 }
 290
 291 sub index_xapian { # msg_iter callback
 292         my $part = $_[0]->[0]; # ignore $depth and $idx
 293         my ($self, $doc) = @{$_[1]};
 294         my $ct = $part->content_type || 'text/plain';
 295         my $fn = $part->filename;
 296         if (defined $fn && $fn ne '') {
 297                 index_text($self, $fn, 1, 'XFN');
 298         }
 299         if ($part->{is_submsg}) {
 300                 my $mids = mids_for_index($part);
 301                 index_ids($self, $doc, $part, $mids);
 302                 my $smsg = bless {}, 'PublicInbox::Smsg';
 303                 $smsg->populate($part);
 304                 index_headers($self, $smsg);
 305         }
 306
 307         my ($s, undef) = msg_part_text($part, $ct);
 308         defined $s or return;
 309         $_[0]->[0] = $part = undef; # free memory
 310
 311         # split off quoted and unquoted blocks:
 312         my @sections = PublicInbox::MsgIter::split_quotes($s);
 313         undef $s; # free memory
 314         for my $txt (@sections) {
 315                 if ($txt =~ /\A>/) {
 316                         index_text($self, $txt, 0, 'XQUOT');
 317                 } else {
 318                         # does it look like a diff?
 319                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 320                                 index_diff($self, $txt, $doc);
 321                         } else {
 322                                 index_text($self, $txt, 1, 'XNQ');
 323                         }
 324                 }
 325                 undef $txt; # free memory
 326         }
 327 }
 328
 329 sub index_list_id ($$$) {
 330         my ($self, $doc, $hdr) = @_;
 331         for my $l ($hdr->header_raw('List-Id')) {
 332                 $l =~ /<([^>]+)>/ or next;
 333                 my $lid = lc $1;
 334                 $doc->add_boolean_term('G' . $lid);
 335                 index_text($self, $lid, 1, 'XL'); # probabilistic
 336         }
 337 }
 338
 339 sub index_ids ($$$$) {
 340         my ($self, $doc, $hdr, $mids) = @_;
 341         for my $mid (@$mids) {
 342                 index_text($self, $mid, 1, 'XM');
 343
 344                 # because too many Message-IDs are prefixed with
 345                 # "Pine.LNX."...
 346                 if ($mid =~ /\w{12,}/) {
 347                         my @long = ($mid =~ /(\w{3,}+)/g);
 348                         index_text($self, join(' ', @long), 1, 'XM');
 349                 }
 350         }
 351         $doc->add_boolean_term('Q' . $_) for @$mids;
 352         index_list_id($self, $doc, $hdr);
 353 }
 354
 355 sub eml2doc ($$$;$) {
 356         my ($self, $eml, $smsg, $mids) = @_;
 357         $mids //= mids_for_index($eml);
 358         my $doc = $X->{Document}->new;
 359         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 360         my @ds = gmtime($smsg->{ds});
 361         my $yyyymmdd = strftime('%Y%m%d', @ds);
 362         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 363         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 364         add_val($doc, PublicInbox::Search::DT(), $dt);
 365         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 366         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 367         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 368
 369         my $tg = term_generator($self);
 370         $tg->set_document($doc);
 371         index_headers($self, $smsg);
 372
 373         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 374                 $doc->add_boolean_term('O'.$eidx_key);
 375         }
 376         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 377         index_ids($self, $doc, $eml, $mids);
 378
 379         # by default, we maintain compatibility with v1.5.0 and earlier
 380         # by writing to docdata.glass, users who never exect to downgrade can
 381         # use --skip-docdata
 382         if (!$self->{-skip_docdata}) {
 383                 # WWW doesn't need {to} or {cc}, only NNTP
 384                 $smsg->{to} = $smsg->{cc} = '';
 385                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 386                 my $data = $smsg->to_doc_data;
 387                 $doc->set_data($data);
 388         }
 389
 390         if (my $altid = $self->{-altid}) {
 391                 foreach my $alt (@$altid) {
 392                         my $pfx = $alt->{xprefix};
 393                         foreach my $mid (@$mids) {
 394                                 my $id = $alt->mid2alt($mid);
 395                                 next unless defined $id;
 396                                 $doc->add_boolean_term($pfx . $id);
 397                         }
 398                 }
 399         }
 400         $doc;
 401 }
 402
 403 sub add_xapian ($$$$) {
 404         my ($self, $eml, $smsg, $mids) = @_;
 405         my $doc = eml2doc($self, $eml, $smsg, $mids);
 406         $self->{xdb}->replace_document($smsg->{num}, $doc);
 407 }
 408
 409 sub _msgmap_init ($) {
 410         my ($self) = @_;
 411         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 412         $self->{mm} //= eval {
 413                 require PublicInbox::Msgmap;
 414                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 415                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 416         };
 417 }
 418
 419 sub add_message {
 420         # mime = PublicInbox::Eml or Email::MIME object
 421         my ($self, $mime, $smsg, $sync) = @_;
 422         my $mids = mids_for_index($mime);
 423         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 424         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 425         $smsg->{num} //= do { # v1
 426                 _msgmap_init($self);
 427                 index_mm($self, $mime, $smsg->{blob}, $sync);
 428         };
 429
 430         # v1 and tests only:
 431         $smsg->populate($mime, $sync);
 432         $smsg->{bytes} //= length($mime->as_string);
 433
 434         eval {
 435                 # order matters, overview stores every possible piece of
 436                 # data in doc_data (deflated).  Xapian only stores a subset
 437                 # of the fields which exist in over.sqlite3.  We may stop
 438                 # storing doc_data in Xapian sometime after we get multi-inbox
 439                 # search working.
 440                 if (my $oidx = $self->{oidx}) { # v1 only
 441                         $oidx->add_overview($mime, $smsg);
 442                 }
 443                 if (need_xapian($self)) {
 444                         add_xapian($self, $mime, $smsg, $mids);
 445                 }
 446         };
 447
 448         if ($@) {
 449                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 450                 return undef;
 451         }
 452         $smsg->{num};
 453 }
 454
 455 sub _get_doc ($$) {
 456         my ($self, $docid) = @_;
 457         my $doc = eval { $self->{xdb}->get_document($docid) };
 458         $doc // do {
 459                 warn "E: $@\n" if $@;
 460                 warn "E: #$docid missing in Xapian\n";
 461                 undef;
 462         }
 463 }
 464
 465 sub add_eidx_info {
 466         my ($self, $docid, $eidx_key, $eml) = @_;
 467         begin_txn_lazy($self);
 468         my $doc = _get_doc($self, $docid) or return;
 469         term_generator($self)->set_document($doc);
 470         $doc->add_boolean_term('O'.$eidx_key);
 471         index_list_id($self, $doc, $eml);
 472         $self->{xdb}->replace_document($docid, $doc);
 473 }
 474
 475 sub remove_eidx_info {
 476         my ($self, $docid, $eidx_key, $eml) = @_;
 477         begin_txn_lazy($self);
 478         my $doc = _get_doc($self, $docid) or return;
 479         eval { $doc->remove_term('O'.$eidx_key) };
 480         warn "W: ->remove_term O$eidx_key: $@\n" if $@;
 481         for my $l ($eml ? $eml->header_raw('List-Id') : ()) {
 482                 $l =~ /<([^>]+)>/ or next;
 483                 my $lid = lc $1;
 484                 eval { $doc->remove_term('G' . $lid) };
 485                 warn "W: ->remove_term G$lid: $@\n" if $@;
 486
 487                 # nb: we don't remove the XL probabilistic terms
 488                 # since terms may overlap if cross-posted.
 489                 #
 490                 # IOW, a message which has both <foo.example.com>
 491                 # and <bar.example.com> would have overlapping
 492                 # "XLexample" and "XLcom" as terms and which we
 493                 # wouldn't know if they're safe to remove if we just
 494                 # unindex <foo.example.com> while preserving
 495                 # <bar.example.com>.
 496                 #
 497                 # In any case, this entire sub is will likely never
 498                 # be needed and users using the "l:" prefix are probably
 499                 # rarer.
 500         }
 501         $self->{xdb}->replace_document($docid, $doc);
 502 }
 503
 504 sub get_val ($$) {
 505         my ($doc, $col) = @_;
 506         sortable_unserialise($doc->get_value($col));
 507 }
 508
 509 sub smsg_from_doc ($) {
 510         my ($doc) = @_;
 511         my $data = $doc->get_data or return;
 512         my $smsg = bless {}, 'PublicInbox::Smsg';
 513         $smsg->{ts} = get_val($doc, PublicInbox::Search::TS());
 514         my $dt = get_val($doc, PublicInbox::Search::DT());
 515         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
 516         $smsg->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
 517         $smsg->load_from_data($data);
 518         $smsg;
 519 }
 520
 521 sub xdb_remove {
 522         my ($self, @docids) = @_;
 523         my $xdb = $self->{xdb} or return;
 524         for my $docid (@docids) {
 525                 eval { $xdb->delete_document($docid) };
 526                 warn "E: #$docid not in in Xapian? $@\n" if $@;
 527         }
 528 }
 529
 530 sub remove_by_docid {
 531         my ($self, $num) = @_;
 532         die "BUG: remove_by_docid is v2-only\n" if $self->{oidx};
 533         $self->begin_txn_lazy;
 534         xdb_remove($self, $num) if need_xapian($self);
 535 }
 536
 537 sub index_git_blob_id {
 538         my ($doc, $pfx, $objid) = @_;
 539
 540         my $len = length($objid);
 541         for (my $len = length($objid); $len >= 7; ) {
 542                 $doc->add_term($pfx.$objid);
 543                 $objid = substr($objid, 0, --$len);
 544         }
 545 }
 546
 547 # v1 only
 548 sub unindex_eml {
 549         my ($self, $oid, $eml) = @_;
 550         my $mids = mids($eml);
 551         my $nr = 0;
 552         my %tmp;
 553         for my $mid (@$mids) {
 554                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 555                 $nr += scalar @removed;
 556                 $tmp{$_}++ for @removed;
 557         }
 558         if (!$nr) {
 559                 my $m = join('> <', @$mids);
 560                 warn "W: <$m> missing for removal from overview\n";
 561         }
 562         while (my ($num, $nr) = each %tmp) {
 563                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 564         }
 565         if ($nr) {
 566                 $self->{mm}->num_delete($_) for (keys %tmp);
 567         } else { # just in case msgmap and over.sqlite3 become desynched:
 568                 $self->{mm}->mid_delete($mids->[0]);
 569         }
 570         xdb_remove($self, keys %tmp) if need_xapian($self);
 571 }
 572
 573 sub index_mm {
 574         my ($self, $mime, $oid, $sync) = @_;
 575         my $mids = mids($mime);
 576         my $mm = $self->{mm};
 577         if ($sync->{reindex}) {
 578                 my $oidx = $self->{oidx};
 579                 for my $mid (@$mids) {
 580                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 581                         return $num if defined $num;
 582                 }
 583                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 584         } else {
 585                 # fallback to num_for since filters like RubyLang set the number
 586                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 587         }
 588 }
 589
 590 # returns the number of bytes to add if given a non-CRLF arg
 591 sub crlf_adjust ($) {
 592         if (index($_[0], "\r\n") < 0) {
 593                 # common case is LF-only, every \n needs an \r;
 594                 # so favor a cheap tr// over an expensive m//g
 595                 $_[0] =~ tr/\n/\n/;
 596         } else { # count number of '\n' w/o '\r', expensive:
 597                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 598         }
 599 }
 600
 601 sub is_bad_blob ($$$$) {
 602         my ($oid, $type, $size, $expect_oid) = @_;
 603         if ($type ne 'blob') {
 604                 carp "W: $expect_oid is not a blob (type=$type)";
 605                 return 1;
 606         }
 607         croak "BUG: $oid != $expect_oid" if $oid ne $expect_oid;
 608         $size == 0 ? 1 : 0; # size == 0 means purged
 609 }
 610
 611 sub index_both { # git->cat_async callback
 612         my ($bref, $oid, $type, $size, $sync) = @_;
 613         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 614         my ($nr, $max) = @$sync{qw(nr max)};
 615         ++$$nr;
 616         $$max -= $size;
 617         $size += crlf_adjust($$bref);
 618         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 619         my $self = $sync->{sidx};
 620         local $self->{current_info} = "$self->{current_info}: $oid";
 621         my $eml = PublicInbox::Eml->new($bref);
 622         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 623                 die "E: could not generate NNTP article number for $oid";
 624         add_message($self, $eml, $smsg, $sync);
 625         my $cur_cmt = $sync->{cur_cmt} // die 'BUG: {cur_cmt} missing';
 626         ${$sync->{latest_cmt}} = $cur_cmt;
 627 }
 628
 629 sub unindex_both { # git->cat_async callback
 630         my ($bref, $oid, $type, $size, $sync) = @_;
 631         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 632         my $self = $sync->{sidx};
 633         local $self->{current_info} = "$self->{current_info}: $oid";
 634         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 635         # may be undef if leftover
 636         if (defined(my $cur_cmt = $sync->{cur_cmt})) {
 637                 ${$sync->{latest_cmt}} = $cur_cmt;
 638         }
 639 }
 640
 641 sub with_umask {
 642         my $self = shift;
 643         ($self->{ibx} // $self->{eidx})->with_umask(@_);
 644 }
 645
 646 # called by public-inbox-index
 647 sub index_sync {
 648         my ($self, $opt) = @_;
 649         delete $self->{lock_path} if $opt->{-skip_lock};
 650         $self->with_umask(\&_index_sync, $self, $opt);
 651         if ($opt->{reindex} && !$opt->{quit}) {
 652                 my %again = %$opt;
 653                 delete @again{qw(rethread reindex)};
 654                 index_sync($self, \%again);
 655                 $opt->{quit} = $again{quit}; # propagate to caller
 656         }
 657 }
 658
 659 sub check_size { # check_async cb for -index --max-size=...
 660         my ($oid, $type, $size, $arg, $git) = @_;
 661         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 662         if ($size <= $arg->{max_size}) {
 663                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 664         } else {
 665                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 666         }
 667 }
 668
 669 sub v1_checkpoint ($$;$) {
 670         my ($self, $sync, $stk) = @_;
 671         $self->{ibx}->git->async_wait_all;
 672
 673         # $newest may be undef
 674         my $newest = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 675         if (defined($newest)) {
 676                 my $cur = $self->{mm}->last_commit || '';
 677                 if (need_update($self, $cur, $newest)) {
 678                         $self->{mm}->last_commit($newest);
 679                 }
 680         }
 681         ${$sync->{max}} = $self->{batch_bytes};
 682
 683         $self->{mm}->{dbh}->commit;
 684         my $xdb = need_xapian($self) ? $self->{xdb} : undef;
 685         if ($newest && $xdb) {
 686                 my $cur = $xdb->get_metadata('last_commit');
 687                 if (need_update($self, $cur, $newest)) {
 688                         $xdb->set_metadata('last_commit', $newest);
 689                 }
 690         }
 691         if ($stk) { # all done if $stk is passed
 692                 # let SearchView know a full --reindex was done so it can
 693                 # generate ->has_threadid-dependent links
 694                 if ($xdb && $sync->{reindex} && !ref($sync->{reindex})) {
 695                         my $n = $xdb->get_metadata('has_threadid');
 696                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 697                 }
 698                 $self->{oidx}->rethread_done($sync->{-opt}); # all done
 699         }
 700         commit_txn_lazy($self);
 701         $sync->{ibx}->git->cleanup;
 702         my $nr = ${$sync->{nr}};
 703         idx_release($self, $nr);
 704         # let another process do some work...
 705         if (my $pr = $sync->{-opt}->{-progress}) {
 706                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 707         }
 708         if (!$stk && !$sync->{quit}) { # more to come
 709                 begin_txn_lazy($self);
 710                 $self->{mm}->{dbh}->begin_work;
 711         }
 712 }
 713
 714 # only for v1
 715 sub process_stack {
 716         my ($self, $sync, $stk) = @_;
 717         my $git = $sync->{ibx}->git;
 718         my $max = $self->{batch_bytes};
 719         my $nr = 0;
 720         $sync->{nr} = \$nr;
 721         $sync->{max} = \$max;
 722         $sync->{sidx} = $self;
 723         $sync->{latest_cmt} = \(my $latest_cmt);
 724
 725         $self->{mm}->{dbh}->begin_work;
 726         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 727                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 728                 for my $oid (@leftovers) {
 729                         last if $sync->{quit};
 730                         $oid = unpack('H*', $oid);
 731                         $git->cat_async($oid, \&unindex_both, $sync);
 732                 }
 733         }
 734         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 735                 $sync->{index_oid} = \&index_both;
 736         }
 737         while (my ($f, $at, $ct, $oid, $cur_cmt) = $stk->pop_rec) {
 738                 my $arg = { %$sync, cur_cmt => $cur_cmt, oid => $oid };
 739                 last if $sync->{quit};
 740                 if ($f eq 'm') {
 741                         $arg->{autime} = $at;
 742                         $arg->{cotime} = $ct;
 743                         if ($sync->{max_size}) {
 744                                 $git->check_async($oid, \&check_size, $arg);
 745                         } else {
 746                                 $git->cat_async($oid, \&index_both, $arg);
 747                         }
 748                         v1_checkpoint($self, $sync) if $max <= 0;
 749                 } elsif ($f eq 'd') {
 750                         $git->cat_async($oid, \&unindex_both, $arg);
 751                 }
 752         }
 753         v1_checkpoint($self, $sync, $sync->{quit} ? undef : $stk);
 754 }
 755
 756 sub log2stack ($$$) {
 757         my ($sync, $git, $range) = @_;
 758         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 759         my ($add, $del);
 760         if ($sync->{ibx}->version == 1) {
 761                 my $path = $hex.'{2}/'.$hex.'{38}';
 762                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 763                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 764         } else {
 765                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 766                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 767         }
 768
 769         # Count the new files so they can be added newest to oldest
 770         # and still have numbers increasing from oldest to newest
 771         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 772                                 --no-notes --no-color --no-renames --no-abbrev),
 773                                 $range);
 774         my ($at, $ct, $stk, $cmt);
 775         while (<$fh>) {
 776                 return if $sync->{quit};
 777                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 778                         ($at, $ct, $cmt) = ($1 + 0, $2 + 0, $3);
 779                         $stk //= PublicInbox::IdxStack->new($cmt);
 780                 } elsif (/$del/) {
 781                         my $oid = $1;
 782                         if ($D) { # reindex case
 783                                 $D->{pack('H*', $oid)}++;
 784                         } else { # non-reindex case:
 785                                 $stk->push_rec('d', $at, $ct, $oid, $cmt);
 786                         }
 787                 } elsif (/$add/) {
 788                         my $oid = $1;
 789                         if ($D) {
 790                                 my $oid_bin = pack('H*', $oid);
 791                                 my $nr = --$D->{$oid_bin};
 792                                 delete($D->{$oid_bin}) if $nr <= 0;
 793                                 # nr < 0 (-1) means it never existed
 794                                 next if $nr >= 0;
 795                         }
 796                         $stk->push_rec('m', $at, $ct, $oid, $cmt);
 797                 }
 798         }
 799         close $fh or die "git log failed: \$?=$?";
 800         $stk //= PublicInbox::IdxStack->new;
 801         $stk->read_prepare;
 802 }
 803
 804 sub prepare_stack ($$) {
 805         my ($sync, $range) = @_;
 806         my $git = $sync->{ibx}->git;
 807
 808         if (index($range, '..') < 0) {
 809                 # don't show annoying git errors to users who run -index
 810                 # on empty inboxes
 811                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 812                 return PublicInbox::IdxStack->new->read_prepare if $?;
 813         }
 814         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 815         log2stack($sync, $git, $range);
 816 }
 817
 818 # --is-ancestor requires git 1.8.0+
 819 sub is_ancestor ($$$) {
 820         my ($git, $cur, $tip) = @_;
 821         return 0 unless $git->check($cur);
 822         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 823                 qw(merge-base --is-ancestor), $cur, $tip ];
 824         my $pid = spawn($cmd);
 825         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 826         $? == 0;
 827 }
 828
 829 sub need_update ($$$) {
 830         my ($self, $cur, $new) = @_;
 831         my $git = $self->{ibx}->git;
 832         return 1 if $cur && !is_ancestor($git, $cur, $new);
 833         my $range = $cur eq '' ? $new : "$cur..$new";
 834         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 835         ($n eq '' || $n > 0);
 836 }
 837
 838 # The last git commit we indexed with Xapian or SQLite (msgmap)
 839 # This needs to account for cases where Xapian or SQLite is
 840 # out-of-date with respect to the other.
 841 sub _last_x_commit {
 842         my ($self, $mm) = @_;
 843         my $lm = $mm->last_commit || '';
 844         my $lx = '';
 845         if (need_xapian($self)) {
 846                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 847         } else {
 848                 $lx = $lm;
 849         }
 850         # Use last_commit from msgmap if it is older or unset
 851         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 852                 $lx = $lm;
 853         }
 854         $lx;
 855 }
 856
 857 sub reindex_from ($$) {
 858         my ($reindex, $last_commit) = @_;
 859         return $last_commit unless $reindex;
 860         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 861 }
 862
 863 sub quit_cb ($) {
 864         my ($sync) = @_;
 865         sub {
 866                 # we set {-opt}->{quit} too, so ->index_sync callers
 867                 # can abort multi-inbox loops this way
 868                 $sync->{quit} = $sync->{-opt}->{quit} = 1;
 869                 warn "gracefully quitting\n";
 870         }
 871 }
 872
 873 # indexes all unindexed messages (v1 only)
 874 sub _index_sync {
 875         my ($self, $opt) = @_;
 876         my $tip = $opt->{ref} || 'HEAD';
 877         my $ibx = $self->{ibx};
 878         local $self->{current_info} = "$ibx->{inboxdir}";
 879         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 880         $ibx->git->batch_prepare;
 881         my $pr = $opt->{-progress};
 882         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
 883         my $quit = quit_cb($sync);
 884         local $SIG{QUIT} = $quit;
 885         local $SIG{INT} = $quit;
 886         local $SIG{TERM} = $quit;
 887         my $xdb = $self->begin_txn_lazy;
 888         $self->{oidx}->rethread_prepare($opt);
 889         my $mm = _msgmap_init($self);
 890         if ($sync->{reindex}) {
 891                 my $last = $mm->last_commit;
 892                 if ($last) {
 893                         $tip = $last;
 894                 } else {
 895                         # somebody just blindly added --reindex when indexing
 896                         # for the first time, allow it:
 897                         undef $sync->{reindex};
 898                 }
 899         }
 900         my $last_commit = _last_x_commit($self, $mm);
 901         my $lx = reindex_from($sync->{reindex}, $last_commit);
 902         my $range = $lx eq '' ? $tip : "$lx..$tip";
 903         $pr->("counting changes\n\t$range ... ") if $pr;
 904         my $stk = prepare_stack($sync, $range);
 905         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 906         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 907         process_stack($self, $sync, $stk) if !$sync->{quit};
 908 }
 909
 910 sub DESTROY {
 911         # order matters for unlocking
 912         $_[0]->{xdb} = undef;
 913         $_[0]->{lockfh} = undef;
 914 }
 915
 916 sub _begin_txn {
 917         my ($self) = @_;
 918         my $xdb = $self->{xdb} || idx_acquire($self);
 919         $self->{oidx}->begin_lazy if $self->{oidx};
 920         $xdb->begin_transaction if $xdb;
 921         $self->{txn} = 1;
 922         $xdb;
 923 }
 924
 925 sub begin_txn_lazy {
 926         my ($self) = @_;
 927         $self->with_umask(\&_begin_txn, $self) if !$self->{txn};
 928 }
 929
 930 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 931 # This metadata is read by Admin::detect_indexlevel:
 932 sub set_metadata_once {
 933         my ($self) = @_;
 934
 935         return if $self->{shard}; # only continue if undef or 0, not >0
 936         my $xdb = $self->{xdb};
 937
 938         if (delete($self->{-set_has_threadid_once})) {
 939                 $xdb->set_metadata('has_threadid', '1');
 940         }
 941         if (delete($self->{-set_indexlevel_once})) {
 942                 my $level = $xdb->get_metadata('indexlevel');
 943                 if (!$level || $level ne 'medium') {
 944                         $xdb->set_metadata('indexlevel', 'medium');
 945                 }
 946         }
 947         if (delete($self->{-set_skip_docdata_once})) {
 948                 $xdb->get_metadata('skip_docdata') or
 949                         $xdb->set_metadata('skip_docdata', '1');
 950         }
 951 }
 952
 953 sub _commit_txn {
 954         my ($self) = @_;
 955         if (my $eidx = $self->{eidx}) {
 956                 $eidx->git->async_wait_all;
 957                 $eidx->{transact_bytes} = 0;
 958         }
 959         if (my $xdb = $self->{xdb}) {
 960                 set_metadata_once($self);
 961                 $xdb->commit_transaction;
 962         }
 963         $self->{oidx}->commit_lazy if $self->{oidx};
 964 }
 965
 966 sub commit_txn_lazy {
 967         my ($self) = @_;
 968         delete($self->{txn}) and
 969                 $self->with_umask(\&_commit_txn, $self);
 970 }
 971
 972 sub worker_done {
 973         my ($self) = @_;
 974         if (need_xapian($self)) {
 975                 die "$$ $0 xdb not released\n" if $self->{xdb};
 976         }
 977         die "$$ $0 still in transaction\n" if $self->{txn};
 978 }
 979
 980 sub eidx_shard_new {
 981         my ($class, $eidx, $shard) = @_;
 982         my $self = bless {
 983                 eidx => $eidx,
 984                 xpfx => $eidx->{xpfx},
 985                 indexlevel => $eidx->{indexlevel},
 986                 -skip_docdata => 1,
 987                 shard => $shard,
 988                 creat => 1,
 989         }, $class;
 990         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
 991         $self;
 992 }
 993
 994 # ensure there's no stale Xapian docs by treating $over as canonical
 995 sub over_check {
 996         my ($self, $over) = @_;
 997         begin_txn_lazy($self);
 998         my $sth = $over->dbh->prepare(<<'');
 999 SELECT COUNT(*) FROM over WHERE num = ?
1000
1001         my $xdb = $self->{xdb};
1002         my $cur = $xdb->postlist_begin('');
1003         my $end = $xdb->postlist_end('');
1004         my $xdir = $self->xdir;
1005         for (; $cur != $end; $cur++) {
1006                 my $docid = $cur->get_docid;
1007                 $sth->execute($docid);
1008                 my $x = $sth->fetchrow_array;
1009                 next if $x > 0;
1010                 warn "I: removing $xdir #$docid, not in `over'\n";
1011                 $xdb->delete_document($docid);
1012         }
1013 }
1014
1015 1;