lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak carp);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::OverIdx;
  22 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  23 use PublicInbox::Git qw(git_unquote);
  24 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  25 our @EXPORT_OK = qw(log2stack is_ancestor check_size prepare_stack
  26         index_text term_generator add_val is_bad_blob);
  27 my $X = \%PublicInbox::Search::X;
  28 our ($DB_CREATE_OR_OPEN, $DB_OPEN);
  29 our $DB_NO_SYNC = 0;
  30 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  31 use constant DEBUG => !!$ENV{DEBUG};
  32
  33 my $xapianlevels = qr/\A(?:full|medium)\z/;
  34 my $hex = '[a-f0-9]';
  35 my $OID = $hex .'{40,}';
  36 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  37
  38 sub new {
  39         my ($class, $ibx, $creat, $shard) = @_;
  40         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  41         my $inboxdir = $ibx->{inboxdir};
  42         my $version = $ibx->version;
  43         my $indexlevel = 'full';
  44         my $altid = $ibx->{altid};
  45         if ($altid) {
  46                 require PublicInbox::AltId;
  47                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  48         }
  49         if ($ibx->{indexlevel}) {
  50                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  51                         $indexlevel = $ibx->{indexlevel};
  52                 } else {
  53                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  54                 }
  55         }
  56         $ibx = PublicInbox::InboxWritable->new($ibx);
  57         my $self = PublicInbox::Search->new($ibx);
  58         bless $self, $class;
  59         $self->{ibx} = $ibx;
  60         $self->{-altid} = $altid;
  61         $self->{indexlevel} = $indexlevel;
  62         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  63         if ($ibx->{-skip_docdata}) {
  64                 $self->{-set_skip_docdata_once} = 1;
  65                 $self->{-skip_docdata} = 1;
  66         }
  67         if ($version == 1) {
  68                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  69                 my $dir = $self->xdir;
  70                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  71                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  72         } elsif ($version == 2) {
  73                 defined $shard or die "shard is required for v2\n";
  74                 # shard is a number
  75                 $self->{shard} = $shard;
  76                 $self->{lock_path} = undef;
  77         } else {
  78                 die "unsupported inbox version=$version\n";
  79         }
  80         $self->{creat} = ($creat || 0) == 1;
  81         $self;
  82 }
  83
  84 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  85
  86 sub idx_release {
  87         my ($self, $wake) = @_;
  88         if (need_xapian($self)) {
  89                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  90                 $xdb->close;
  91         }
  92         $self->lock_release($wake) if $self->{creat};
  93         undef;
  94 }
  95
  96 sub load_xapian_writable () {
  97         return 1 if $X->{WritableDatabase};
  98         PublicInbox::Search::load_xapian() or return;
  99         my $xap = $PublicInbox::Search::Xap;
 100         for (qw(Document TermGenerator WritableDatabase)) {
 101                 $X->{$_} = $xap.'::'.$_;
 102         }
 103         eval 'require '.$X->{WritableDatabase} or die;
 104         *sortable_serialise = $xap.'::sortable_serialise';
 105         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 106         $DB_OPEN = eval($xap.'::DB_OPEN()');
 107         my $ver = (eval($xap.'::major_version()') << 16) |
 108                 (eval($xap.'::minor_version()') << 8) |
 109                 eval($xap.'::revision()');
 110         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 111         # Xapian v1.2.21..v1.2.24 were missing close-on-exec on OFD locks
 112         $X->{CLOEXEC_UNSET} = 1 if $ver >= 0x010215 && $ver <= 0x010218;
 113         1;
 114 }
 115
 116 sub idx_acquire {
 117         my ($self) = @_;
 118         my $flag;
 119         my $dir = $self->xdir;
 120         if (need_xapian($self)) {
 121                 croak 'already acquired' if $self->{xdb};
 122                 load_xapian_writable();
 123                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 124         }
 125         if ($self->{creat}) {
 126                 require File::Path;
 127                 $self->lock_acquire;
 128
 129                 # don't create empty Xapian directories if we don't need Xapian
 130                 my $is_shard = defined($self->{shard});
 131                 if (!-d $dir && (!$is_shard ||
 132                                 ($is_shard && need_xapian($self)))) {
 133                         File::Path::mkpath($dir);
 134                         nodatacow_dir($dir);
 135                         $self->{-set_has_threadid_once} = 1;
 136                 }
 137         }
 138         return unless defined $flag;
 139         $flag |= $DB_NO_SYNC if ($self->{ibx} // $self->{eidx})->{-no_fsync};
 140         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 141         croak "Failed opening $dir: $@" if $@;
 142         $self->{xdb} = $xdb;
 143 }
 144
 145 sub add_val ($$$) {
 146         my ($doc, $col, $num) = @_;
 147         $num = sortable_serialise($num);
 148         $doc->add_value($col, $num);
 149 }
 150
 151 sub term_generator ($) { # write-only
 152         my ($self) = @_;
 153
 154         $self->{term_generator} //= do {
 155                 my $tg = $X->{TermGenerator}->new;
 156                 $tg->set_stemmer(PublicInbox::Search::stemmer($self));
 157                 $tg;
 158         }
 159 }
 160
 161 sub index_text ($$$$) {
 162         my ($self, $text, $wdf_inc, $prefix) = @_;
 163         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 164
 165         if ($self->{indexlevel} eq 'full') {
 166                 $tg->index_text($text, $wdf_inc, $prefix);
 167                 $tg->increase_termpos;
 168         } else {
 169                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 170         }
 171 }
 172
 173 sub index_headers ($$) {
 174         my ($self, $smsg) = @_;
 175         my @x = (from => 'A', # Author
 176                 subject => 'S', to => 'XTO', cc => 'XCC');
 177         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 178                 my $val = $smsg->{$field};
 179                 index_text($self, $val, 1, $pfx) if $val ne '';
 180         }
 181 }
 182
 183 sub index_diff_inc ($$$$) {
 184         my ($self, $text, $pfx, $xnq) = @_;
 185         if (@$xnq) {
 186                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 187                 @$xnq = ();
 188         }
 189         index_text($self, $text, 1, $pfx);
 190 }
 191
 192 sub index_old_diff_fn {
 193         my ($self, $seen, $fa, $fb, $xnq) = @_;
 194
 195         # no renames or space support for traditional diffs,
 196         # find the number of leading common paths to strip:
 197         my @fa = split('/', $fa);
 198         my @fb = split('/', $fb);
 199         while (scalar(@fa) && scalar(@fb)) {
 200                 $fa = join('/', @fa);
 201                 $fb = join('/', @fb);
 202                 if ($fa eq $fb) {
 203                         unless ($seen->{$fa}++) {
 204                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 205                         }
 206                         return 1;
 207                 }
 208                 shift @fa;
 209                 shift @fb;
 210         }
 211         0;
 212 }
 213
 214 sub index_diff ($$$) {
 215         my ($self, $txt, $doc) = @_;
 216         my %seen;
 217         my $in_diff;
 218         my @xnq;
 219         my $xnq = \@xnq;
 220         foreach (split(/\n/, $txt)) {
 221                 if ($in_diff && s/^ //) { # diff context
 222                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 223                 } elsif (/^-- $/) { # email signature begins
 224                         $in_diff = undef;
 225                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 226                         # wait until "---" and "+++" to capture filenames
 227                         $in_diff = 1;
 228                 # traditional diff:
 229                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 230                         my ($opt, $fa, $fb) = ($1, $2, $3);
 231                         push @xnq, $_;
 232                         # only support unified:
 233                         next unless $opt =~ /[uU]/;
 234                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 235                                                         $xnq);
 236                 } elsif (m!^--- ("?[^/]+/.+)!) {
 237                         my $fn = $1;
 238                         $fn = (split('/', git_unquote($fn), 2))[1];
 239                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 240                         $in_diff = 1;
 241                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 242                         my $fn = $1;
 243                         $fn = (split('/', git_unquote($fn), 2))[1];
 244                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 245                         $in_diff = 1;
 246                 } elsif (/^--- (\S+)/) {
 247                         $in_diff = $1;
 248                         push @xnq, $_;
 249                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 250                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 251                                                         $1, $xnq);
 252                 } elsif ($in_diff && s/^\+//) { # diff added
 253                         index_diff_inc($self, $_, 'XDFB', $xnq);
 254                 } elsif ($in_diff && s/^-//) { # diff removed
 255                         index_diff_inc($self, $_, 'XDFA', $xnq);
 256                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 257                         my ($ba, $bb) = ($1, $2);
 258                         index_git_blob_id($doc, 'XDFPRE', $ba);
 259                         index_git_blob_id($doc, 'XDFPOST', $bb);
 260                         $in_diff = 1;
 261                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 262                         # traditional diff w/o -p
 263                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 264                         # hunk header context
 265                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 266                 # ignore the following lines:
 267                 } elsif (/^(?:dis)similarity index/ ||
 268                                 /^(?:old|new) mode/ ||
 269                                 /^(?:deleted|new) file mode/ ||
 270                                 /^(?:copy|rename) (?:from|to) / ||
 271                                 /^(?:dis)?similarity index / ||
 272                                 /^\\ No newline at end of file/ ||
 273                                 /^Binary files .* differ/) {
 274                         push @xnq, $_;
 275                 } elsif ($_ eq '') {
 276                         # possible to be in diff context, some mail may be
 277                         # stripped by MUA or even GNU diff(1).  "git apply"
 278                         # treats a bare "\n" as diff context, too
 279                 } else {
 280                         push @xnq, $_;
 281                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 282                         $in_diff = undef;
 283                 }
 284         }
 285
 286         index_text($self, join("\n", @xnq), 1, 'XNQ');
 287 }
 288
 289 sub index_xapian { # msg_iter callback
 290         my $part = $_[0]->[0]; # ignore $depth and $idx
 291         my ($self, $doc) = @{$_[1]};
 292         my $ct = $part->content_type || 'text/plain';
 293         my $fn = $part->filename;
 294         if (defined $fn && $fn ne '') {
 295                 index_text($self, $fn, 1, 'XFN');
 296         }
 297         if ($part->{is_submsg}) {
 298                 my $mids = mids_for_index($part);
 299                 index_ids($self, $doc, $part, $mids);
 300                 my $smsg = bless {}, 'PublicInbox::Smsg';
 301                 $smsg->populate($part);
 302                 index_headers($self, $smsg);
 303         }
 304
 305         my ($s, undef) = msg_part_text($part, $ct);
 306         defined $s or return;
 307         $_[0]->[0] = $part = undef; # free memory
 308
 309         # split off quoted and unquoted blocks:
 310         my @sections = PublicInbox::MsgIter::split_quotes($s);
 311         undef $s; # free memory
 312         for my $txt (@sections) {
 313                 if ($txt =~ /\A>/) {
 314                         index_text($self, $txt, 0, 'XQUOT');
 315                 } else {
 316                         # does it look like a diff?
 317                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 318                                 index_diff($self, $txt, $doc);
 319                         } else {
 320                                 index_text($self, $txt, 1, 'XNQ');
 321                         }
 322                 }
 323                 undef $txt; # free memory
 324         }
 325 }
 326
 327 sub index_list_id ($$$) {
 328         my ($self, $doc, $hdr) = @_;
 329         for my $l ($hdr->header_raw('List-Id')) {
 330                 $l =~ /<([^>]+)>/ or next;
 331                 my $lid = lc $1;
 332                 $doc->add_boolean_term('G' . $lid);
 333                 index_text($self, $lid, 1, 'XL'); # probabilistic
 334         }
 335 }
 336
 337 sub index_ids ($$$$) {
 338         my ($self, $doc, $hdr, $mids) = @_;
 339         for my $mid (@$mids) {
 340                 index_text($self, $mid, 1, 'XM');
 341
 342                 # because too many Message-IDs are prefixed with
 343                 # "Pine.LNX."...
 344                 if ($mid =~ /\w{12,}/) {
 345                         my @long = ($mid =~ /(\w{3,}+)/g);
 346                         index_text($self, join(' ', @long), 1, 'XM');
 347                 }
 348         }
 349         $doc->add_boolean_term('Q' . $_) for @$mids;
 350         index_list_id($self, $doc, $hdr);
 351 }
 352
 353 sub eml2doc ($$$;$) {
 354         my ($self, $eml, $smsg, $mids) = @_;
 355         $mids //= mids_for_index($eml);
 356         my $doc = $X->{Document}->new;
 357         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 358         my @ds = gmtime($smsg->{ds});
 359         my $yyyymmdd = strftime('%Y%m%d', @ds);
 360         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 361         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 362         add_val($doc, PublicInbox::Search::DT(), $dt);
 363         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 364         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 365         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 366
 367         my $tg = term_generator($self);
 368         $tg->set_document($doc);
 369         index_headers($self, $smsg);
 370
 371         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 372                 $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 373         }
 374         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 375         index_ids($self, $doc, $eml, $mids);
 376
 377         # by default, we maintain compatibility with v1.5.0 and earlier
 378         # by writing to docdata.glass, users who never exect to downgrade can
 379         # use --skip-docdata
 380         if (!$self->{-skip_docdata}) {
 381                 # WWW doesn't need {to} or {cc}, only NNTP
 382                 $smsg->{to} = $smsg->{cc} = '';
 383                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 384                 my $data = $smsg->to_doc_data;
 385                 $doc->set_data($data);
 386         }
 387
 388         if (my $altid = $self->{-altid}) {
 389                 foreach my $alt (@$altid) {
 390                         my $pfx = $alt->{xprefix};
 391                         foreach my $mid (@$mids) {
 392                                 my $id = $alt->mid2alt($mid);
 393                                 next unless defined $id;
 394                                 $doc->add_boolean_term($pfx . $id);
 395                         }
 396                 }
 397         }
 398         $doc;
 399 }
 400
 401 sub add_xapian ($$$$) {
 402         my ($self, $eml, $smsg, $mids) = @_;
 403         begin_txn_lazy($self);
 404         my $doc = eml2doc($self, $eml, $smsg, $mids);
 405         $self->{xdb}->replace_document($smsg->{num}, $doc);
 406 }
 407
 408 sub _msgmap_init ($) {
 409         my ($self) = @_;
 410         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx}->version != 1;
 411         $self->{mm} //= eval {
 412                 require PublicInbox::Msgmap;
 413                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 414                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 415         };
 416 }
 417
 418 sub add_message {
 419         # mime = PublicInbox::Eml or Email::MIME object
 420         my ($self, $mime, $smsg, $sync) = @_;
 421         begin_txn_lazy($self);
 422         my $mids = mids_for_index($mime);
 423         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 424         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 425         $smsg->{num} //= do { # v1
 426                 _msgmap_init($self);
 427                 index_mm($self, $mime, $smsg->{blob}, $sync);
 428         };
 429
 430         # v1 and tests only:
 431         $smsg->populate($mime, $sync);
 432         $smsg->{bytes} //= length($mime->as_string);
 433
 434         eval {
 435                 # order matters, overview stores every possible piece of
 436                 # data in doc_data (deflated).  Xapian only stores a subset
 437                 # of the fields which exist in over.sqlite3.  We may stop
 438                 # storing doc_data in Xapian sometime after we get multi-inbox
 439                 # search working.
 440                 if (my $oidx = $self->{oidx}) { # v1 only
 441                         $oidx->add_overview($mime, $smsg);
 442                 }
 443                 if (need_xapian($self)) {
 444                         add_xapian($self, $mime, $smsg, $mids);
 445                 }
 446         };
 447
 448         if ($@) {
 449                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 450                 return undef;
 451         }
 452         $smsg->{num};
 453 }
 454
 455 sub _get_doc ($$) {
 456         my ($self, $docid) = @_;
 457         my $doc = eval { $self->{xdb}->get_document($docid) };
 458         $doc // do {
 459                 warn "E: $@\n" if $@;
 460                 warn "E: #$docid missing in Xapian\n";
 461                 undef;
 462         }
 463 }
 464
 465 sub add_eidx_info {
 466         my ($self, $docid, $eidx_key, $eml) = @_;
 467         begin_txn_lazy($self);
 468         my $doc = _get_doc($self, $docid) or return;
 469         term_generator($self)->set_document($doc);
 470         $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 471         index_list_id($self, $doc, $eml);
 472         $self->{xdb}->replace_document($docid, $doc);
 473 }
 474
 475 sub remove_eidx_info {
 476         my ($self, $docid, $eidx_key, $eml) = @_;
 477         begin_txn_lazy($self);
 478         my $doc = _get_doc($self, $docid) or return;
 479         eval { $doc->remove_term('O'.$eidx_key) };
 480         warn "W: ->remove_term O$eidx_key: $@\n" if $@;
 481         for my $l ($eml ? $eml->header_raw('List-Id') : ()) {
 482                 $l =~ /<([^>]+)>/ or next;
 483                 my $lid = lc $1;
 484                 eval { $doc->remove_term('G' . $lid) };
 485                 warn "W: ->remove_term G$lid: $@\n" if $@;
 486
 487                 # nb: we don't remove the XL probabilistic terms
 488                 # since terms may overlap if cross-posted.
 489                 #
 490                 # IOW, a message which has both <foo.example.com>
 491                 # and <bar.example.com> would have overlapping
 492                 # "XLexample" and "XLcom" as terms and which we
 493                 # wouldn't know if they're safe to remove if we just
 494                 # unindex <foo.example.com> while preserving
 495                 # <bar.example.com>.
 496                 #
 497                 # In any case, this entire sub is will likely never
 498                 # be needed and users using the "l:" prefix are probably
 499                 # rarer.
 500         }
 501         $self->{xdb}->replace_document($docid, $doc);
 502 }
 503
 504 sub set_keywords {
 505         my ($self, $docid, @kw) = @_;
 506         begin_txn_lazy($self);
 507         my $doc = _get_doc($self, $docid) or return;
 508         my %keep = map { $_ => 1 } @kw;
 509         my %add = %keep;
 510         my @rm;
 511         my $end = $doc->termlist_end;
 512         for (my $cur = $doc->termlist_begin; $cur != $end; $cur++) {
 513                 $cur->skip_to('K');
 514                 last if $cur == $end;
 515                 my $kw = $cur->get_termname;
 516                 $kw =~ s/\AK//s or next;
 517                 $keep{$kw} ? delete($add{$kw}) : push(@rm, $kw);
 518         }
 519         return unless (scalar(@rm) + scalar(keys %add));
 520         $doc->remove_term('K'.$_) for @rm;
 521         $doc->add_boolean_term('K'.$_) for (keys %add);
 522         $self->{xdb}->replace_document($docid, $doc);
 523 }
 524
 525 sub add_keywords {
 526         my ($self, $docid, @kw) = @_;
 527         begin_txn_lazy($self);
 528         my $doc = _get_doc($self, $docid) or return;
 529         $doc->add_boolean_term('K'.$_) for @kw;
 530         $self->{xdb}->replace_document($docid, $doc);
 531 }
 532
 533 sub remove_keywords {
 534         my ($self, $docid, @kw) = @_;
 535         begin_txn_lazy($self);
 536         my $doc = _get_doc($self, $docid) or return;
 537         my $replace;
 538         eval {
 539                 $doc->remove_term('K'.$_);
 540                 $replace = 1
 541         } for @kw;
 542         $self->{xdb}->replace_document($docid, $doc) if $replace;
 543 }
 544
 545 sub smsg_from_doc ($) {
 546         my ($doc) = @_;
 547         my $data = $doc->get_data or return;
 548         my $smsg = bless {}, 'PublicInbox::Smsg';
 549         $smsg->{ts} = int_val($doc, PublicInbox::Search::TS());
 550         my $dt = int_val($doc, PublicInbox::Search::DT());
 551         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
 552         $smsg->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
 553         $smsg->load_from_data($data);
 554         $smsg;
 555 }
 556
 557 sub xdb_remove {
 558         my ($self, @docids) = @_;
 559         $self->begin_txn_lazy;
 560         my $xdb = $self->{xdb} or return;
 561         for my $docid (@docids) {
 562                 eval { $xdb->delete_document($docid) };
 563                 warn "E: #$docid not in in Xapian? $@\n" if $@;
 564         }
 565 }
 566
 567 sub index_git_blob_id {
 568         my ($doc, $pfx, $objid) = @_;
 569
 570         my $len = length($objid);
 571         for (my $len = length($objid); $len >= 7; ) {
 572                 $doc->add_term($pfx.$objid);
 573                 $objid = substr($objid, 0, --$len);
 574         }
 575 }
 576
 577 # v1 only
 578 sub unindex_eml {
 579         my ($self, $oid, $eml) = @_;
 580         my $mids = mids($eml);
 581         my $nr = 0;
 582         my %tmp;
 583         for my $mid (@$mids) {
 584                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 585                 $nr += scalar @removed;
 586                 $tmp{$_}++ for @removed;
 587         }
 588         if (!$nr) {
 589                 my $m = join('> <', @$mids);
 590                 warn "W: <$m> missing for removal from overview\n";
 591         }
 592         while (my ($num, $nr) = each %tmp) {
 593                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 594         }
 595         if ($nr) {
 596                 $self->{mm}->num_delete($_) for (keys %tmp);
 597         } else { # just in case msgmap and over.sqlite3 become desynched:
 598                 $self->{mm}->mid_delete($mids->[0]);
 599         }
 600         xdb_remove($self, keys %tmp) if need_xapian($self);
 601 }
 602
 603 sub index_mm {
 604         my ($self, $mime, $oid, $sync) = @_;
 605         my $mids = mids($mime);
 606         my $mm = $self->{mm};
 607         if ($sync->{reindex}) {
 608                 my $oidx = $self->{oidx};
 609                 for my $mid (@$mids) {
 610                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 611                         return $num if defined $num;
 612                 }
 613                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 614         } else {
 615                 # fallback to num_for since filters like RubyLang set the number
 616                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 617         }
 618 }
 619
 620 sub is_bad_blob ($$$$) {
 621         my ($oid, $type, $size, $expect_oid) = @_;
 622         if ($type ne 'blob') {
 623                 carp "W: $expect_oid is not a blob (type=$type)";
 624                 return 1;
 625         }
 626         croak "BUG: $oid != $expect_oid" if $oid ne $expect_oid;
 627         $size == 0 ? 1 : 0; # size == 0 means purged
 628 }
 629
 630 sub index_both { # git->cat_async callback
 631         my ($bref, $oid, $type, $size, $sync) = @_;
 632         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 633         my ($nr, $max) = @$sync{qw(nr max)};
 634         ++$$nr;
 635         $$max -= $size;
 636         my $smsg = bless { blob => $oid }, 'PublicInbox::Smsg';
 637         $smsg->set_bytes($$bref, $size);
 638         my $self = $sync->{sidx};
 639         local $self->{current_info} = "$self->{current_info}: $oid";
 640         my $eml = PublicInbox::Eml->new($bref);
 641         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 642                 die "E: could not generate NNTP article number for $oid";
 643         add_message($self, $eml, $smsg, $sync);
 644         ++$self->{nidx};
 645         my $cur_cmt = $sync->{cur_cmt} // die 'BUG: {cur_cmt} missing';
 646         ${$sync->{latest_cmt}} = $cur_cmt;
 647 }
 648
 649 sub unindex_both { # git->cat_async callback
 650         my ($bref, $oid, $type, $size, $sync) = @_;
 651         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 652         my $self = $sync->{sidx};
 653         local $self->{current_info} = "$self->{current_info}: $oid";
 654         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 655         # may be undef if leftover
 656         if (defined(my $cur_cmt = $sync->{cur_cmt})) {
 657                 ${$sync->{latest_cmt}} = $cur_cmt;
 658         }
 659         ++$self->{nidx};
 660 }
 661
 662 sub with_umask {
 663         my $self = shift;
 664         ($self->{ibx} // $self->{eidx})->with_umask(@_);
 665 }
 666
 667 # called by public-inbox-index
 668 sub index_sync {
 669         my ($self, $opt) = @_;
 670         delete $self->{lock_path} if $opt->{-skip_lock};
 671         $self->with_umask(\&_index_sync, $self, $opt);
 672         if ($opt->{reindex} && !$opt->{quit}) {
 673                 my %again = %$opt;
 674                 delete @again{qw(rethread reindex)};
 675                 index_sync($self, \%again);
 676                 $opt->{quit} = $again{quit}; # propagate to caller
 677         }
 678 }
 679
 680 sub check_size { # check_async cb for -index --max-size=...
 681         my ($oid, $type, $size, $arg, $git) = @_;
 682         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 683         if ($size <= $arg->{max_size}) {
 684                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 685         } else {
 686                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 687         }
 688 }
 689
 690 sub v1_checkpoint ($$;$) {
 691         my ($self, $sync, $stk) = @_;
 692         $self->{ibx}->git->async_wait_all;
 693
 694         # $newest may be undef
 695         my $newest = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 696         if (defined($newest)) {
 697                 my $cur = $self->{mm}->last_commit || '';
 698                 if (need_update($self, $cur, $newest)) {
 699                         $self->{mm}->last_commit($newest);
 700                 }
 701         }
 702         ${$sync->{max}} = $self->{batch_bytes};
 703
 704         $self->{mm}->{dbh}->commit;
 705         my $xdb = need_xapian($self) ? $self->{xdb} : undef;
 706         if ($newest && $xdb) {
 707                 my $cur = $xdb->get_metadata('last_commit');
 708                 if (need_update($self, $cur, $newest)) {
 709                         $xdb->set_metadata('last_commit', $newest);
 710                 }
 711         }
 712         if ($stk) { # all done if $stk is passed
 713                 # let SearchView know a full --reindex was done so it can
 714                 # generate ->has_threadid-dependent links
 715                 if ($xdb && $sync->{reindex} && !ref($sync->{reindex})) {
 716                         my $n = $xdb->get_metadata('has_threadid');
 717                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 718                 }
 719                 $self->{oidx}->rethread_done($sync->{-opt}); # all done
 720         }
 721         commit_txn_lazy($self);
 722         $sync->{ibx}->git->cleanup;
 723         my $nr = ${$sync->{nr}};
 724         idx_release($self, $nr);
 725         # let another process do some work...
 726         if (my $pr = $sync->{-opt}->{-progress}) {
 727                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 728         }
 729         if (!$stk && !$sync->{quit}) { # more to come
 730                 begin_txn_lazy($self);
 731                 $self->{mm}->{dbh}->begin_work;
 732         }
 733 }
 734
 735 # only for v1
 736 sub process_stack {
 737         my ($self, $sync, $stk) = @_;
 738         my $git = $sync->{ibx}->git;
 739         my $max = $self->{batch_bytes};
 740         my $nr = 0;
 741         $sync->{nr} = \$nr;
 742         $sync->{max} = \$max;
 743         $sync->{sidx} = $self;
 744         $sync->{latest_cmt} = \(my $latest_cmt);
 745
 746         $self->{mm}->{dbh}->begin_work;
 747         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 748                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 749                 for my $oid (@leftovers) {
 750                         last if $sync->{quit};
 751                         $oid = unpack('H*', $oid);
 752                         $git->cat_async($oid, \&unindex_both, $sync);
 753                 }
 754         }
 755         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 756                 $sync->{index_oid} = \&index_both;
 757         }
 758         while (my ($f, $at, $ct, $oid, $cur_cmt) = $stk->pop_rec) {
 759                 my $arg = { %$sync, cur_cmt => $cur_cmt, oid => $oid };
 760                 last if $sync->{quit};
 761                 if ($f eq 'm') {
 762                         $arg->{autime} = $at;
 763                         $arg->{cotime} = $ct;
 764                         if ($sync->{max_size}) {
 765                                 $git->check_async($oid, \&check_size, $arg);
 766                         } else {
 767                                 $git->cat_async($oid, \&index_both, $arg);
 768                         }
 769                         v1_checkpoint($self, $sync) if $max <= 0;
 770                 } elsif ($f eq 'd') {
 771                         $git->cat_async($oid, \&unindex_both, $arg);
 772                 }
 773         }
 774         v1_checkpoint($self, $sync, $sync->{quit} ? undef : $stk);
 775 }
 776
 777 sub log2stack ($$$) {
 778         my ($sync, $git, $range) = @_;
 779         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 780         my ($add, $del);
 781         if ($sync->{ibx}->version == 1) {
 782                 my $path = $hex.'{2}/'.$hex.'{38}';
 783                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 784                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 785         } else {
 786                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 787                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 788         }
 789
 790         # Count the new files so they can be added newest to oldest
 791         # and still have numbers increasing from oldest to newest
 792         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 793                                 --no-notes --no-color --no-renames --no-abbrev),
 794                                 $range);
 795         my ($at, $ct, $stk, $cmt);
 796         while (<$fh>) {
 797                 return if $sync->{quit};
 798                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 799                         ($at, $ct, $cmt) = ($1 + 0, $2 + 0, $3);
 800                         $stk //= PublicInbox::IdxStack->new($cmt);
 801                 } elsif (/$del/) {
 802                         my $oid = $1;
 803                         if ($D) { # reindex case
 804                                 $D->{pack('H*', $oid)}++;
 805                         } else { # non-reindex case:
 806                                 $stk->push_rec('d', $at, $ct, $oid, $cmt);
 807                         }
 808                 } elsif (/$add/) {
 809                         my $oid = $1;
 810                         if ($D) {
 811                                 my $oid_bin = pack('H*', $oid);
 812                                 my $nr = --$D->{$oid_bin};
 813                                 delete($D->{$oid_bin}) if $nr <= 0;
 814                                 # nr < 0 (-1) means it never existed
 815                                 next if $nr >= 0;
 816                         }
 817                         $stk->push_rec('m', $at, $ct, $oid, $cmt);
 818                 }
 819         }
 820         close $fh or die "git log failed: \$?=$?";
 821         $stk //= PublicInbox::IdxStack->new;
 822         $stk->read_prepare;
 823 }
 824
 825 sub prepare_stack ($$) {
 826         my ($sync, $range) = @_;
 827         my $git = $sync->{ibx}->git;
 828
 829         if (index($range, '..') < 0) {
 830                 # don't show annoying git errors to users who run -index
 831                 # on empty inboxes
 832                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 833                 return PublicInbox::IdxStack->new->read_prepare if $?;
 834         }
 835         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 836         log2stack($sync, $git, $range);
 837 }
 838
 839 # --is-ancestor requires git 1.8.0+
 840 sub is_ancestor ($$$) {
 841         my ($git, $cur, $tip) = @_;
 842         return 0 unless $git->check($cur);
 843         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 844                 qw(merge-base --is-ancestor), $cur, $tip ];
 845         my $pid = spawn($cmd);
 846         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 847         $? == 0;
 848 }
 849
 850 sub need_update ($$$) {
 851         my ($self, $cur, $new) = @_;
 852         my $git = $self->{ibx}->git;
 853         return 1 if $cur && !is_ancestor($git, $cur, $new);
 854         my $range = $cur eq '' ? $new : "$cur..$new";
 855         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 856         ($n eq '' || $n > 0);
 857 }
 858
 859 # The last git commit we indexed with Xapian or SQLite (msgmap)
 860 # This needs to account for cases where Xapian or SQLite is
 861 # out-of-date with respect to the other.
 862 sub _last_x_commit {
 863         my ($self, $mm) = @_;
 864         my $lm = $mm->last_commit || '';
 865         my $lx = '';
 866         if (need_xapian($self)) {
 867                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 868         } else {
 869                 $lx = $lm;
 870         }
 871         # Use last_commit from msgmap if it is older or unset
 872         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 873                 $lx = $lm;
 874         }
 875         $lx;
 876 }
 877
 878 sub reindex_from ($$) {
 879         my ($reindex, $last_commit) = @_;
 880         return $last_commit unless $reindex;
 881         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 882 }
 883
 884 sub quit_cb ($) {
 885         my ($sync) = @_;
 886         sub {
 887                 # we set {-opt}->{quit} too, so ->index_sync callers
 888                 # can abort multi-inbox loops this way
 889                 $sync->{quit} = $sync->{-opt}->{quit} = 1;
 890                 warn "gracefully quitting\n";
 891         }
 892 }
 893
 894 # indexes all unindexed messages (v1 only)
 895 sub _index_sync {
 896         my ($self, $opt) = @_;
 897         my $tip = $opt->{ref} || 'HEAD';
 898         my $ibx = $self->{ibx};
 899         local $self->{current_info} = "$ibx->{inboxdir}";
 900         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 901         $ibx->git->batch_prepare;
 902         my $pr = $opt->{-progress};
 903         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
 904         my $quit = quit_cb($sync);
 905         local $SIG{QUIT} = $quit;
 906         local $SIG{INT} = $quit;
 907         local $SIG{TERM} = $quit;
 908         my $xdb = $self->begin_txn_lazy;
 909         $self->{oidx}->rethread_prepare($opt);
 910         my $mm = _msgmap_init($self);
 911         if ($sync->{reindex}) {
 912                 my $last = $mm->last_commit;
 913                 if ($last) {
 914                         $tip = $last;
 915                 } else {
 916                         # somebody just blindly added --reindex when indexing
 917                         # for the first time, allow it:
 918                         undef $sync->{reindex};
 919                 }
 920         }
 921         my $last_commit = _last_x_commit($self, $mm);
 922         my $lx = reindex_from($sync->{reindex}, $last_commit);
 923         my $range = $lx eq '' ? $tip : "$lx..$tip";
 924         $pr->("counting changes\n\t$range ... ") if $pr;
 925         my $stk = prepare_stack($sync, $range);
 926         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 927         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 928         process_stack($self, $sync, $stk) if !$sync->{quit};
 929 }
 930
 931 sub DESTROY {
 932         # order matters for unlocking
 933         $_[0]->{xdb} = undef;
 934         $_[0]->{lockfh} = undef;
 935 }
 936
 937 sub _begin_txn {
 938         my ($self) = @_;
 939         my $xdb = $self->{xdb} || idx_acquire($self);
 940         $self->{oidx}->begin_lazy if $self->{oidx};
 941         $xdb->begin_transaction if $xdb;
 942         $self->{txn} = 1;
 943         $xdb;
 944 }
 945
 946 sub begin_txn_lazy {
 947         my ($self) = @_;
 948         $self->with_umask(\&_begin_txn, $self) if !$self->{txn};
 949 }
 950
 951 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 952 # This metadata is read by Admin::detect_indexlevel:
 953 sub set_metadata_once {
 954         my ($self) = @_;
 955
 956         return if $self->{shard}; # only continue if undef or 0, not >0
 957         my $xdb = $self->{xdb};
 958
 959         if (delete($self->{-set_has_threadid_once})) {
 960                 $xdb->set_metadata('has_threadid', '1');
 961         }
 962         if (delete($self->{-set_indexlevel_once})) {
 963                 my $level = $xdb->get_metadata('indexlevel');
 964                 if (!$level || $level ne 'medium') {
 965                         $xdb->set_metadata('indexlevel', 'medium');
 966                 }
 967         }
 968         if (delete($self->{-set_skip_docdata_once})) {
 969                 $xdb->get_metadata('skip_docdata') or
 970                         $xdb->set_metadata('skip_docdata', '1');
 971         }
 972 }
 973
 974 sub _commit_txn {
 975         my ($self) = @_;
 976         if (my $eidx = $self->{eidx}) {
 977                 $eidx->git->async_wait_all;
 978                 $eidx->{transact_bytes} = 0;
 979         }
 980         if (my $xdb = $self->{xdb}) {
 981                 set_metadata_once($self);
 982                 $xdb->commit_transaction;
 983         }
 984         $self->{oidx}->commit_lazy if $self->{oidx};
 985 }
 986
 987 sub commit_txn_lazy {
 988         my ($self) = @_;
 989         delete($self->{txn}) and
 990                 $self->with_umask(\&_commit_txn, $self);
 991 }
 992
 993 sub eidx_shard_new {
 994         my ($class, $eidx, $shard) = @_;
 995         my $self = bless {
 996                 eidx => $eidx,
 997                 xpfx => $eidx->{xpfx},
 998                 indexlevel => $eidx->{indexlevel},
 999                 -skip_docdata => 1,
1000                 shard => $shard,
1001                 creat => 1,
1002         }, $class;
1003         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
1004         $self;
1005 }
1006
1007 # ensure there's no stale Xapian docs by treating $over as canonical
1008 sub over_check {
1009         my ($self, $over) = @_;
1010         begin_txn_lazy($self);
1011         my $sth = $over->dbh->prepare(<<'');
1012 SELECT COUNT(*) FROM over WHERE num = ?
1013
1014         my $xdb = $self->{xdb};
1015         my $cur = $xdb->postlist_begin('');
1016         my $end = $xdb->postlist_end('');
1017         my $xdir = $self->xdir;
1018         for (; $cur != $end; $cur++) {
1019                 my $docid = $cur->get_docid;
1020                 $sth->execute($docid);
1021                 my $x = $sth->fetchrow_array;
1022                 next if $x > 0;
1023                 warn "I: removing $xdir #$docid, not in `over'\n";
1024                 $xdb->delete_document($docid);
1025         }
1026 }
1027
1028 1;