lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 our $BATCH_BYTES = defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000;
  27 use constant DEBUG => !!$ENV{DEBUG};
  28
  29 my $xapianlevels = qr/\A(?:full|medium)\z/;
  30
  31 sub new {
  32         my ($class, $ibx, $creat, $shard) = @_;
  33         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  34         my $levels = qr/\A(?:full|medium|basic)\z/;
  35         my $inboxdir = $ibx->{inboxdir};
  36         my $version = $ibx->version;
  37         my $indexlevel = 'full';
  38         my $altid = $ibx->{altid};
  39         if ($altid) {
  40                 require PublicInbox::AltId;
  41                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  42         }
  43         if ($ibx->{indexlevel}) {
  44                 if ($ibx->{indexlevel} =~ $levels) {
  45                         $indexlevel = $ibx->{indexlevel};
  46                 } else {
  47                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  48                 }
  49         }
  50         $ibx = PublicInbox::InboxWritable->new($ibx);
  51         my $self = bless {
  52                 inboxdir => $inboxdir,
  53                 -inbox => $ibx,
  54                 git => $ibx->git,
  55                 -altid => $altid,
  56                 ibx_ver => $version,
  57                 indexlevel => $indexlevel,
  58         }, $class;
  59         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  60         $ibx->umask_prepare;
  61         if ($version == 1) {
  62                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  63                 my $dir = $self->xdir;
  64                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  65                 $self->{index_max_size} = $ibx->{index_max_size};
  66         } elsif ($version == 2) {
  67                 defined $shard or die "shard is required for v2\n";
  68                 # shard is a number
  69                 $self->{shard} = $shard;
  70                 $self->{lock_path} = undef;
  71         } else {
  72                 die "unsupported inbox version=$version\n";
  73         }
  74         $self->{creat} = ($creat || 0) == 1;
  75         $self;
  76 }
  77
  78 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  79
  80 sub _xdb_release {
  81         my ($self) = @_;
  82         if (need_xapian($self)) {
  83                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  84                 $xdb->close;
  85         }
  86         $self->lock_release if $self->{creat};
  87         undef;
  88 }
  89
  90 sub load_xapian_writable () {
  91         return 1 if $X->{WritableDatabase};
  92         PublicInbox::Search::load_xapian() or return;
  93         my $xap = $PublicInbox::Search::Xap;
  94         for (qw(Document TermGenerator WritableDatabase)) {
  95                 $X->{$_} = $xap.'::'.$_;
  96         }
  97         eval 'require '.$X->{WritableDatabase} or die;
  98         *sortable_serialise = $xap.'::sortable_serialise';
  99         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 100         $DB_OPEN = eval($xap.'::DB_OPEN()');
 101         1;
 102 }
 103
 104 sub _xdb_acquire {
 105         my ($self) = @_;
 106         my $flag;
 107         my $dir = $self->xdir;
 108         if (need_xapian($self)) {
 109                 croak 'already acquired' if $self->{xdb};
 110                 load_xapian_writable();
 111                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 112         }
 113         if ($self->{creat}) {
 114                 require File::Path;
 115                 $self->lock_acquire;
 116
 117                 # don't create empty Xapian directories if we don't need Xapian
 118                 my $is_shard = defined($self->{shard});
 119                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 120                         File::Path::mkpath($dir);
 121                 }
 122         }
 123         return unless defined $flag;
 124         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 125         if ($@) {
 126                 die "Failed opening $dir: ", $@;
 127         }
 128         $self->{xdb} = $xdb;
 129 }
 130
 131 sub add_val ($$$) {
 132         my ($doc, $col, $num) = @_;
 133         $num = sortable_serialise($num);
 134         $doc->add_value($col, $num);
 135 }
 136
 137 sub term_generator ($) { # write-only
 138         my ($self) = @_;
 139
 140         $self->{term_generator} //= do {
 141                 my $tg = $X->{TermGenerator}->new;
 142                 $tg->set_stemmer($self->stemmer);
 143                 $tg;
 144         }
 145 }
 146
 147 sub index_text ($$$$) {
 148         my ($self, $text, $wdf_inc, $prefix) = @_;
 149         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 150
 151         if ($self->{indexlevel} eq 'full') {
 152                 $tg->index_text($text, $wdf_inc, $prefix);
 153                 $tg->increase_termpos;
 154         } else {
 155                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 156         }
 157 }
 158
 159 sub index_headers ($$) {
 160         my ($self, $smsg) = @_;
 161         my @x = (from => 'A', # Author
 162                 subject => 'S', to => 'XTO', cc => 'XCC');
 163         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 164                 my $val = $smsg->{$field};
 165                 index_text($self, $val, 1, $pfx) if $val ne '';
 166         }
 167 }
 168
 169 sub index_diff_inc ($$$$) {
 170         my ($self, $text, $pfx, $xnq) = @_;
 171         if (@$xnq) {
 172                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 173                 @$xnq = ();
 174         }
 175         index_text($self, $text, 1, $pfx);
 176 }
 177
 178 sub index_old_diff_fn {
 179         my ($self, $seen, $fa, $fb, $xnq) = @_;
 180
 181         # no renames or space support for traditional diffs,
 182         # find the number of leading common paths to strip:
 183         my @fa = split('/', $fa);
 184         my @fb = split('/', $fb);
 185         while (scalar(@fa) && scalar(@fb)) {
 186                 $fa = join('/', @fa);
 187                 $fb = join('/', @fb);
 188                 if ($fa eq $fb) {
 189                         unless ($seen->{$fa}++) {
 190                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 191                         }
 192                         return 1;
 193                 }
 194                 shift @fa;
 195                 shift @fb;
 196         }
 197         0;
 198 }
 199
 200 sub index_diff ($$$) {
 201         my ($self, $txt, $doc) = @_;
 202         my %seen;
 203         my $in_diff;
 204         my @xnq;
 205         my $xnq = \@xnq;
 206         foreach (split(/\n/, $txt)) {
 207                 if ($in_diff && s/^ //) { # diff context
 208                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 209                 } elsif (/^-- $/) { # email signature begins
 210                         $in_diff = undef;
 211                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 212                         # wait until "---" and "+++" to capture filenames
 213                         $in_diff = 1;
 214                 # traditional diff:
 215                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 216                         my ($opt, $fa, $fb) = ($1, $2, $3);
 217                         push @xnq, $_;
 218                         # only support unified:
 219                         next unless $opt =~ /[uU]/;
 220                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 221                                                         $xnq);
 222                 } elsif (m!^--- ("?[^/]+/.+)!) {
 223                         my $fn = $1;
 224                         $fn = (split('/', git_unquote($fn), 2))[1];
 225                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 226                         $in_diff = 1;
 227                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 228                         my $fn = $1;
 229                         $fn = (split('/', git_unquote($fn), 2))[1];
 230                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 231                         $in_diff = 1;
 232                 } elsif (/^--- (\S+)/) {
 233                         $in_diff = $1;
 234                         push @xnq, $_;
 235                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 236                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 237                                                         $1, $xnq);
 238                 } elsif ($in_diff && s/^\+//) { # diff added
 239                         index_diff_inc($self, $_, 'XDFB', $xnq);
 240                 } elsif ($in_diff && s/^-//) { # diff removed
 241                         index_diff_inc($self, $_, 'XDFA', $xnq);
 242                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 243                         my ($ba, $bb) = ($1, $2);
 244                         index_git_blob_id($doc, 'XDFPRE', $ba);
 245                         index_git_blob_id($doc, 'XDFPOST', $bb);
 246                         $in_diff = 1;
 247                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 248                         # traditional diff w/o -p
 249                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 250                         # hunk header context
 251                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 252                 # ignore the following lines:
 253                 } elsif (/^(?:dis)similarity index/ ||
 254                                 /^(?:old|new) mode/ ||
 255                                 /^(?:deleted|new) file mode/ ||
 256                                 /^(?:copy|rename) (?:from|to) / ||
 257                                 /^(?:dis)?similarity index / ||
 258                                 /^\\ No newline at end of file/ ||
 259                                 /^Binary files .* differ/) {
 260                         push @xnq, $_;
 261                 } elsif ($_ eq '') {
 262                         # possible to be in diff context, some mail may be
 263                         # stripped by MUA or even GNU diff(1).  "git apply"
 264                         # treats a bare "\n" as diff context, too
 265                 } else {
 266                         push @xnq, $_;
 267                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 268                         $in_diff = undef;
 269                 }
 270         }
 271
 272         index_text($self, join("\n", @xnq), 1, 'XNQ');
 273 }
 274
 275 sub index_xapian { # msg_iter callback
 276         my $part = $_[0]->[0]; # ignore $depth and $idx
 277         my ($self, $doc) = @{$_[1]};
 278         my $ct = $part->content_type || 'text/plain';
 279         my $fn = $part->filename;
 280         if (defined $fn && $fn ne '') {
 281                 index_text($self, $fn, 1, 'XFN');
 282         }
 283         if ($part->{is_submsg}) {
 284                 my $mids = mids_for_index($part);
 285                 index_ids($self, $doc, $part, $mids);
 286                 my $smsg = bless {}, 'PublicInbox::Smsg';
 287                 $smsg->populate($part);
 288                 index_headers($self, $smsg);
 289         }
 290
 291         my ($s, undef) = msg_part_text($part, $ct);
 292         defined $s or return;
 293         $_[0]->[0] = $part = undef; # free memory
 294
 295         # split off quoted and unquoted blocks:
 296         my @sections = PublicInbox::MsgIter::split_quotes($s);
 297         undef $s; # free memory
 298         for my $txt (@sections) {
 299                 if ($txt =~ /\A>/) {
 300                         index_text($self, $txt, 0, 'XQUOT');
 301                 } else {
 302                         # does it look like a diff?
 303                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 304                                 index_diff($self, $txt, $doc);
 305                         } else {
 306                                 index_text($self, $txt, 1, 'XNQ');
 307                         }
 308                 }
 309                 undef $txt; # free memory
 310         }
 311 }
 312
 313 sub index_ids ($$$$) {
 314         my ($self, $doc, $hdr, $mids) = @_;
 315         for my $mid (@$mids) {
 316                 index_text($self, $mid, 1, 'XM');
 317
 318                 # because too many Message-IDs are prefixed with
 319                 # "Pine.LNX."...
 320                 if ($mid =~ /\w{12,}/) {
 321                         my @long = ($mid =~ /(\w{3,}+)/g);
 322                         index_text($self, join(' ', @long), 1, 'XM');
 323                 }
 324         }
 325         $doc->add_boolean_term('Q' . $_) for @$mids;
 326         for my $l ($hdr->header_raw('List-Id')) {
 327                 $l =~ /<([^>]+)>/ or next;
 328                 my $lid = $1;
 329                 $doc->add_boolean_term('G' . $lid);
 330                 index_text($self, $lid, 1, 'XL'); # probabilistic
 331         }
 332 }
 333
 334 sub add_xapian ($$$$) {
 335         my ($self, $mime, $smsg, $mids) = @_;
 336         my $hdr = $mime->header_obj;
 337         my $doc = $X->{Document}->new;
 338         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 339         my @ds = gmtime($smsg->{ds});
 340         my $yyyymmdd = strftime('%Y%m%d', @ds);
 341         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 342         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 343         add_val($doc, PublicInbox::Search::DT(), $dt);
 344
 345         my $tg = term_generator($self);
 346         $tg->set_document($doc);
 347         index_headers($self, $smsg);
 348
 349         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 350         index_ids($self, $doc, $hdr, $mids);
 351         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 352         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 353         my $data = $smsg->to_doc_data;
 354         $doc->set_data($data);
 355         if (my $altid = $self->{-altid}) {
 356                 foreach my $alt (@$altid) {
 357                         my $pfx = $alt->{xprefix};
 358                         foreach my $mid (@$mids) {
 359                                 my $id = $alt->mid2alt($mid);
 360                                 next unless defined $id;
 361                                 $doc->add_boolean_term($pfx . $id);
 362                         }
 363                 }
 364         }
 365         $self->{xdb}->replace_document($smsg->{num}, $doc);
 366 }
 367
 368 sub _msgmap_init ($) {
 369         my ($self) = @_;
 370         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 371         $self->{mm} //= eval {
 372                 require PublicInbox::Msgmap;
 373                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 374         };
 375 }
 376
 377 sub add_message {
 378         # mime = PublicInbox::Eml or Email::MIME object
 379         my ($self, $mime, $smsg) = @_;
 380         my $hdr = $mime->header_obj;
 381         my $mids = mids_for_index($hdr);
 382         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 383         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 384         $smsg->{num} //= do { # v1
 385                 _msgmap_init($self);
 386                 index_mm($self, $mime);
 387         };
 388
 389         # v1 and tests only:
 390         $smsg->populate($hdr, $self);
 391
 392         eval {
 393                 # order matters, overview stores every possible piece of
 394                 # data in doc_data (deflated).  Xapian only stores a subset
 395                 # of the fields which exist in over.sqlite3.  We may stop
 396                 # storing doc_data in Xapian sometime after we get multi-inbox
 397                 # search working.
 398                 if (my $over = $self->{over}) { # v1 only
 399                         $over->add_overview($mime, $smsg);
 400                 }
 401                 if (need_xapian($self)) {
 402                         add_xapian($self, $mime, $smsg, $mids);
 403                 }
 404         };
 405
 406         if ($@) {
 407                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 408                 return undef;
 409         }
 410         $smsg->{num};
 411 }
 412
 413 # returns begin and end PostingIterator
 414 sub find_doc_ids {
 415         my ($self, $termval) = @_;
 416         my $db = $self->{xdb};
 417
 418         ($db->postlist_begin($termval), $db->postlist_end($termval));
 419 }
 420
 421 # v1 only
 422 sub batch_do {
 423         my ($self, $termval, $cb) = @_;
 424         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 425         while (1) {
 426                 my ($head, $tail) = $self->find_doc_ids($termval);
 427                 return if $head == $tail;
 428                 my @ids;
 429                 for (; $head != $tail && @ids < $batch_size; $head++) {
 430                         push @ids, $head->get_docid;
 431                 }
 432                 $cb->(\@ids);
 433         }
 434 }
 435
 436 # v1 only, where $mid is unique
 437 sub remove_message {
 438         my ($self, $mid) = @_;
 439         $mid = mid_clean($mid);
 440
 441         if (my $over = $self->{over}) {
 442                 my $nr = eval { $over->remove_oid(undef, $mid) };
 443                 if ($@) {
 444                         warn "failed to remove <$mid> from overview: $@\n";
 445                 } elsif ($nr == 0) {
 446                         warn "<$mid> missing for removal from overview\n";
 447                 }
 448         }
 449         return unless need_xapian($self);
 450         my $db = $self->{xdb};
 451         my $nr = 0;
 452         eval {
 453                 batch_do($self, 'Q' . $mid, sub {
 454                         my ($ids) = @_;
 455                         $db->delete_document($_) for @$ids;
 456                         $nr += scalar @$ids;
 457                 });
 458         };
 459         if ($@) {
 460                 warn "failed to remove <$mid> from Xapian: $@\n";
 461         } elsif ($nr == 0) {
 462                 warn "<$mid> missing for removal from Xapian\n";
 463         }
 464 }
 465
 466 # MID is a hint in V2
 467 sub remove_by_oid {
 468         my ($self, $oid, $mid) = @_;
 469
 470         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 471
 472         return unless need_xapian($self);
 473         my $db = $self->{xdb};
 474
 475         # XXX careful, we cannot use batch_do here since we conditionally
 476         # delete documents based on other factors, so we cannot call
 477         # find_doc_ids twice.
 478         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 479         return if $head == $tail;
 480
 481         # there is only ONE element in @delete unless we
 482         # have bugs in our v2writable deduplication check
 483         my @delete;
 484         for (; $head != $tail; $head++) {
 485                 my $docid = $head->get_docid;
 486                 my $doc = $db->get_document($docid);
 487                 my $smsg = bless { mid => $mid }, 'PublicInbox::Smsg';
 488                 $smsg->load_expand($doc);
 489                 if ($smsg->{blob} eq $oid) {
 490                         push(@delete, $docid);
 491                 }
 492         }
 493         $db->delete_document($_) foreach @delete;
 494         scalar(@delete);
 495 }
 496
 497 sub index_git_blob_id {
 498         my ($doc, $pfx, $objid) = @_;
 499
 500         my $len = length($objid);
 501         for (my $len = length($objid); $len >= 7; ) {
 502                 $doc->add_term($pfx.$objid);
 503                 $objid = substr($objid, 0, --$len);
 504         }
 505 }
 506
 507 sub unindex_blob {
 508         my ($self, $mime) = @_;
 509         my $mid = eval { mid_mime($mime) };
 510         $self->remove_message($mid) if defined $mid;
 511 }
 512
 513 sub index_mm {
 514         my ($self, $mime) = @_;
 515         my $mid = mid_mime($mime);
 516         my $mm = $self->{mm};
 517         my $num;
 518
 519         if (defined $self->{regen_down}) {
 520                 $num = $mm->num_for($mid) and return $num;
 521
 522                 while (($num = $self->{regen_down}--) > 0) {
 523                         if ($mm->mid_set($num, $mid) != 0) {
 524                                 return $num;
 525                         }
 526                 }
 527         } elsif (defined $self->{regen_up}) {
 528                 $num = $mm->num_for($mid) and return $num;
 529
 530                 # this is to fixup old bugs due to add-remove-add
 531                 while (($num = ++$self->{regen_up})) {
 532                         if ($mm->mid_set($num, $mid) != 0) {
 533                                 return $num;
 534                         }
 535                 }
 536         }
 537
 538         $num = $mm->mid_insert($mid) and return $num;
 539
 540         # fallback to num_for since filters like RubyLang set the number
 541         $mm->num_for($mid);
 542 }
 543
 544 sub unindex_mm {
 545         my ($self, $mime) = @_;
 546         $self->{mm}->mid_delete(mid_mime($mime));
 547 }
 548
 549 sub index_both {
 550         my ($self, $mime, $smsg) = @_;
 551         my $num = index_mm($self, $mime);
 552         $smsg->{num} = $num;
 553         add_message($self, $mime, $smsg);
 554 }
 555
 556 sub unindex_both {
 557         my ($self, $mime) = @_;
 558         unindex_blob($self, $mime);
 559         unindex_mm($self, $mime);
 560 }
 561
 562 sub do_cat_mail {
 563         my ($git, $blob, $sizeref) = @_;
 564         my $str = $git->cat_file($blob, $sizeref) or
 565                 die "BUG: $blob not found in $git->{git_dir}";
 566         PublicInbox::Eml->new($str);
 567 }
 568
 569 # called by public-inbox-index
 570 sub index_sync {
 571         my ($self, $opts) = @_;
 572         delete $self->{lock_path} if $opts->{-skip_lock};
 573         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 574 }
 575
 576 sub batch_adjust ($$$$$) {
 577         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 578         $$max -= $bytes;
 579         if ($$max <= 0) {
 580                 $$max = $BATCH_BYTES;
 581                 $batch_cb->($nr, $latest);
 582         }
 583 }
 584
 585 sub too_big ($$$) {
 586         my ($self, $git, $oid) = @_;
 587         my $max_size = $self->{index_max_size} or return;
 588         my (undef, undef, $size) = $git->check($oid);
 589         die "E: bad $oid in $git->{git_dir}\n" if !defined($size);
 590         return if $size <= $max_size;
 591         warn "W: skipping $oid ($size > $max_size)\n";
 592         1;
 593 }
 594
 595 # only for v1
 596 sub read_log {
 597         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 598         my $hex = '[a-f0-9]';
 599         my $h40 = $hex .'{40}';
 600         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 601         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 602         my $git = $self->{git};
 603         my $latest;
 604         my $bytes;
 605         my $max = $BATCH_BYTES;
 606         local $/ = "\n";
 607         my %D;
 608         my $line;
 609         my $newest;
 610         my $nr = 0;
 611         while (defined($line = <$log>)) {
 612                 if ($line =~ /$addmsg/o) {
 613                         my $blob = $1;
 614                         if (delete $D{$blob}) {
 615                                 if (defined $self->{regen_down}) {
 616                                         my $num = $self->{regen_down}--;
 617                                         $self->{mm}->num_highwater($num);
 618                                 }
 619                                 next;
 620                         }
 621                         next if too_big($self, $git, $blob);
 622                         my $mime = do_cat_mail($git, $blob, \$bytes);
 623                         my $smsg = bless {}, 'PublicInbox::Smsg';
 624                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 625                         $smsg->{blob} = $blob;
 626                         $smsg->{bytes} = $bytes;
 627                         $add_cb->($self, $mime, $smsg);
 628                 } elsif ($line =~ /$delmsg/o) {
 629                         my $blob = $1;
 630                         $D{$blob} = 1 unless too_big($self, $git, $blob);
 631                 } elsif ($line =~ /^commit ($h40)/o) {
 632                         $latest = $1;
 633                         $newest ||= $latest;
 634                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 635                         $self->{autime} = $1;
 636                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 637                         $self->{cotime} = $1;
 638                 }
 639         }
 640         close($log) or die "git log failed: \$?=$?";
 641         # get the leftovers
 642         foreach my $blob (keys %D) {
 643                 my $mime = do_cat_mail($git, $blob, \$bytes);
 644                 $del_cb->($self, $mime);
 645         }
 646         delete @$self{qw(autime cotime)};
 647         $batch_cb->($nr, $latest, $newest);
 648 }
 649
 650 sub _git_log {
 651         my ($self, $opts, $range) = @_;
 652         my $git = $self->{git};
 653
 654         if (index($range, '..') < 0) {
 655                 # don't show annoying git errors to users who run -index
 656                 # on empty inboxes
 657                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 658                 if ($?) {
 659                         open my $fh, '<', '/dev/null' or
 660                                 die "failed to open /dev/null: $!\n";
 661                         return $fh;
 662                 }
 663         }
 664
 665         # Count the new files so they can be added newest to oldest
 666         # and still have numbers increasing from oldest to newest
 667         my $fcount = 0;
 668         my $pr = $opts->{-progress};
 669         $pr->("counting changes\n\t$range ... ") if $pr;
 670         # can't use 'rev-list --count' if we use --diff-filter
 671         my $fh = $git->popen(qw(log --pretty=tformat:%h
 672                              --no-notes --no-color --no-renames
 673                              --diff-filter=AM), $range);
 674         ++$fcount while <$fh>;
 675         close $fh or die "git log failed: \$?=$?";
 676         my $high = $self->{mm}->num_highwater;
 677         $pr->("$fcount\n") if $pr; # continue previous line
 678         $self->{ntodo} = $fcount;
 679
 680         if (index($range, '..') < 0) {
 681                 if ($high && $high == $fcount) {
 682                         # fix up old bugs in full indexes which caused messages to
 683                         # not appear in Msgmap
 684                         $self->{regen_up} = $high;
 685                 } else {
 686                         # normal regen is for for fresh data
 687                         $self->{regen_down} = $fcount;
 688                 }
 689         } else {
 690                 # Give oldest messages the smallest numbers
 691                 $self->{regen_down} = $high + $fcount;
 692         }
 693
 694         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 695                                 --raw -r --no-abbrev/, $range);
 696 }
 697
 698 # --is-ancestor requires git 1.8.0+
 699 sub is_ancestor ($$$) {
 700         my ($git, $cur, $tip) = @_;
 701         return 0 unless $git->check($cur);
 702         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 703                 qw(merge-base --is-ancestor), $cur, $tip ];
 704         my $pid = spawn($cmd);
 705         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 706         $? == 0;
 707 }
 708
 709 sub need_update ($$$) {
 710         my ($self, $cur, $new) = @_;
 711         my $git = $self->{git};
 712         return 1 if $cur && !is_ancestor($git, $cur, $new);
 713         my $range = $cur eq '' ? $new : "$cur..$new";
 714         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 715         ($n eq '' || $n > 0);
 716 }
 717
 718 # The last git commit we indexed with Xapian or SQLite (msgmap)
 719 # This needs to account for cases where Xapian or SQLite is
 720 # out-of-date with respect to the other.
 721 sub _last_x_commit {
 722         my ($self, $mm) = @_;
 723         my $lm = $mm->last_commit || '';
 724         my $lx = '';
 725         if (need_xapian($self)) {
 726                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 727         } else {
 728                 $lx = $lm;
 729         }
 730         # Use last_commit from msgmap if it is older or unset
 731         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 732                 $lx = $lm;
 733         }
 734         $lx;
 735 }
 736
 737 sub reindex_from ($$) {
 738         my ($reindex, $last_commit) = @_;
 739         return $last_commit unless $reindex;
 740         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 741 }
 742
 743 # indexes all unindexed messages (v1 only)
 744 sub _index_sync {
 745         my ($self, $opts) = @_;
 746         my $tip = $opts->{ref} || 'HEAD';
 747         my ($last_commit, $lx, $xlog);
 748         my $git = $self->{git};
 749         $git->batch_prepare;
 750         my $pr = $opts->{-progress};
 751
 752         my $xdb = $self->begin_txn_lazy;
 753         my $mm = _msgmap_init($self);
 754         do {
 755                 $xlog = undef; # stop previous git-log via SIGPIPE
 756                 $last_commit = _last_x_commit($self, $mm);
 757                 $lx = reindex_from($opts->{reindex}, $last_commit);
 758
 759                 $self->{over}->rollback_lazy;
 760                 $self->{over}->disconnect;
 761                 $git->cleanup;
 762                 delete $self->{txn};
 763                 $xdb->cancel_transaction if $xdb;
 764                 $xdb = _xdb_release($self);
 765
 766                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 767                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 768                 $xlog = _git_log($self, $opts, $range);
 769
 770                 $xdb = $self->begin_txn_lazy;
 771         } while (_last_x_commit($self, $mm) ne $last_commit);
 772
 773         my $dbh = $mm->{dbh} if $mm;
 774         my $cb = sub {
 775                 my ($nr, $commit, $newest) = @_;
 776                 if ($dbh) {
 777                         if ($newest) {
 778                                 my $cur = $mm->last_commit || '';
 779                                 if (need_update($self, $cur, $newest)) {
 780                                         $mm->last_commit($newest);
 781                                 }
 782                         }
 783                         $dbh->commit;
 784                 }
 785                 if ($newest && need_xapian($self)) {
 786                         my $cur = $xdb->get_metadata('last_commit');
 787                         if (need_update($self, $cur, $newest)) {
 788                                 $xdb->set_metadata('last_commit', $newest);
 789                         }
 790                 }
 791                 $self->commit_txn_lazy;
 792                 $git->cleanup;
 793                 $xdb = _xdb_release($self);
 794                 # let another process do some work... <
 795                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 796                 if (!$newest) {
 797                         $xdb = $self->begin_txn_lazy;
 798                         $dbh->begin_work if $dbh;
 799                 }
 800         };
 801
 802         $dbh->begin_work;
 803         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 804 }
 805
 806 sub DESTROY {
 807         # order matters for unlocking
 808         $_[0]->{xdb} = undef;
 809         $_[0]->{lockfh} = undef;
 810 }
 811
 812 # remote_* subs are only used by SearchIdxPart
 813 sub remote_commit {
 814         my ($self) = @_;
 815         if (my $w = $self->{w}) {
 816                 print $w "commit\n" or die "failed to write commit: $!";
 817         } else {
 818                 $self->commit_txn_lazy;
 819         }
 820 }
 821
 822 sub remote_close {
 823         my ($self) = @_;
 824         if (my $w = delete $self->{w}) {
 825                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 826                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 827                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 828                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 829                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 830         } else {
 831                 die "transaction in progress $self\n" if $self->{txn};
 832                 $self->_xdb_release if $self->{xdb};
 833         }
 834 }
 835
 836 sub remote_remove {
 837         my ($self, $oid, $mid) = @_;
 838         if (my $w = $self->{w}) {
 839                 # triggers remove_by_oid in a shard
 840                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 841         } else {
 842                 $self->begin_txn_lazy;
 843                 $self->remove_by_oid($oid, $mid);
 844         }
 845 }
 846
 847 sub begin_txn_lazy {
 848         my ($self) = @_;
 849         return if $self->{txn};
 850
 851         $self->{-inbox}->with_umask(sub {
 852                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 853                 $self->{over}->begin_lazy if $self->{over};
 854                 $xdb->begin_transaction if $xdb;
 855                 $self->{txn} = 1;
 856                 $xdb;
 857         });
 858 }
 859
 860 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 861 # This metadata is read by Admin::detect_indexlevel:
 862 sub set_indexlevel {
 863         my ($self) = @_;
 864
 865         if (!$self->{shard} && # undef or 0, not >0
 866                         delete($self->{-set_indexlevel_once})) {
 867                 my $xdb = $self->{xdb};
 868                 my $level = $xdb->get_metadata('indexlevel');
 869                 if (!$level || $level ne 'medium') {
 870                         $xdb->set_metadata('indexlevel', 'medium');
 871                 }
 872         }
 873 }
 874
 875 sub commit_txn_lazy {
 876         my ($self) = @_;
 877         delete $self->{txn} or return;
 878         $self->{-inbox}->with_umask(sub {
 879                 if (my $xdb = $self->{xdb}) {
 880                         set_indexlevel($self);
 881                         $xdb->commit_transaction;
 882                 }
 883                 $self->{over}->commit_lazy if $self->{over};
 884         });
 885 }
 886
 887 sub worker_done {
 888         my ($self) = @_;
 889         if (need_xapian($self)) {
 890                 die "$$ $0 xdb not released\n" if $self->{xdb};
 891         }
 892         die "$$ $0 still in transaction\n" if $self->{txn};
 893 }
 894
 895 1;