lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 my $X = \%PublicInbox::Search::X;
  23 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  24 use constant {
  25         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000,
  27         DEBUG => !!$ENV{DEBUG},
  28 };
  29
  30 my $xapianlevels = qr/\A(?:full|medium)\z/;
  31
  32 sub new {
  33         my ($class, $ibx, $creat, $shard) = @_;
  34         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  35         my $levels = qr/\A(?:full|medium|basic)\z/;
  36         my $inboxdir = $ibx->{inboxdir};
  37         my $version = $ibx->{version} || 1;
  38         my $indexlevel = 'full';
  39         my $altid = $ibx->{altid};
  40         if ($altid) {
  41                 require PublicInbox::AltId;
  42                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  43         }
  44         if ($ibx->{indexlevel}) {
  45                 if ($ibx->{indexlevel} =~ $levels) {
  46                         $indexlevel = $ibx->{indexlevel};
  47                 } else {
  48                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  49                 }
  50         }
  51         $ibx = PublicInbox::InboxWritable->new($ibx);
  52         my $self = bless {
  53                 inboxdir => $inboxdir,
  54                 -inbox => $ibx,
  55                 git => $ibx->git,
  56                 -altid => $altid,
  57                 version => $version,
  58                 indexlevel => $indexlevel,
  59         }, $class;
  60         $ibx->umask_prepare;
  61         if ($version == 1) {
  62                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  63                 my $dir = $self->xdir;
  64                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  65         } elsif ($version == 2) {
  66                 defined $shard or die "shard is required for v2\n";
  67                 # shard is a number
  68                 $self->{shard} = $shard;
  69                 $self->{lock_path} = undef;
  70         } else {
  71                 die "unsupported inbox version=$version\n";
  72         }
  73         $self->{creat} = ($creat || 0) == 1;
  74         $self;
  75 }
  76
  77 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  78
  79 sub _xdb_release {
  80         my ($self) = @_;
  81         if (need_xapian($self)) {
  82                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  83                 $xdb->close;
  84         }
  85         $self->lock_release if $self->{creat};
  86         undef;
  87 }
  88
  89 sub load_xapian_writable () {
  90         return 1 if $X->{WritableDatabase};
  91         PublicInbox::Search::load_xapian() or return;
  92         my $xap = $PublicInbox::Search::Xap;
  93         for (qw(Document TermGenerator WritableDatabase)) {
  94                 $X->{$_} = $xap.'::'.$_;
  95         }
  96         eval 'require '.$X->{WritableDatabase} or die;
  97         *sortable_serialise = $xap.'::sortable_serialise';
  98         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
  99         $DB_OPEN = eval($xap.'::DB_OPEN()');
 100         1;
 101 }
 102
 103 sub _xdb_acquire {
 104         my ($self) = @_;
 105         my $flag;
 106         my $dir = $self->xdir;
 107         if (need_xapian($self)) {
 108                 croak 'already acquired' if $self->{xdb};
 109                 load_xapian_writable();
 110                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 111         }
 112         if ($self->{creat}) {
 113                 require File::Path;
 114                 $self->lock_acquire;
 115
 116                 # don't create empty Xapian directories if we don't need Xapian
 117                 my $is_shard = defined($self->{shard});
 118                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 119                         File::Path::mkpath($dir);
 120                 }
 121         }
 122         return unless defined $flag;
 123         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 124         if ($@) {
 125                 die "Failed opening $dir: ", $@;
 126         }
 127         $self->{xdb} = $xdb;
 128 }
 129
 130 sub add_val ($$$) {
 131         my ($doc, $col, $num) = @_;
 132         $num = sortable_serialise($num);
 133         $doc->add_value($col, $num);
 134 }
 135
 136 sub index_text ($$$$)
 137 {
 138         my ($self, $field, $n, $text) = @_;
 139         my $tg = $self->term_generator;
 140
 141         if ($self->{indexlevel} eq 'full') {
 142                 $tg->index_text($field, $n, $text);
 143                 $tg->increase_termpos;
 144         } else {
 145                 $tg->index_text_without_positions($field, $n, $text);
 146         }
 147 }
 148
 149 sub index_users ($$) {
 150         my ($self, $smsg) = @_;
 151
 152         my $from = $smsg->from;
 153         my $to = $smsg->to;
 154         my $cc = $smsg->cc;
 155
 156         $self->index_text($from, 1, 'A'); # A - author
 157         $self->index_text($to, 1, 'XTO') if $to ne '';
 158         $self->index_text($cc, 1, 'XCC') if $cc ne '';
 159 }
 160
 161 sub index_diff_inc ($$$$) {
 162         my ($self, $text, $pfx, $xnq) = @_;
 163         if (@$xnq) {
 164                 $self->index_text(join("\n", @$xnq), 1, 'XNQ');
 165                 @$xnq = ();
 166         }
 167         $self->index_text($text, 1, $pfx);
 168 }
 169
 170 sub index_old_diff_fn {
 171         my ($self, $seen, $fa, $fb, $xnq) = @_;
 172
 173         # no renames or space support for traditional diffs,
 174         # find the number of leading common paths to strip:
 175         my @fa = split('/', $fa);
 176         my @fb = split('/', $fb);
 177         while (scalar(@fa) && scalar(@fb)) {
 178                 $fa = join('/', @fa);
 179                 $fb = join('/', @fb);
 180                 if ($fa eq $fb) {
 181                         unless ($seen->{$fa}++) {
 182                                 $self->index_diff_inc($fa, 'XDFN', $xnq);
 183                         }
 184                         return 1;
 185                 }
 186                 shift @fa;
 187                 shift @fb;
 188         }
 189         0;
 190 }
 191
 192 sub index_diff ($$$) {
 193         my ($self, $lines, $doc) = @_;
 194         my %seen;
 195         my $in_diff;
 196         my @xnq;
 197         my $xnq = \@xnq;
 198         foreach (@$lines) {
 199                 if ($in_diff && s/^ //) { # diff context
 200                         $self->index_diff_inc($_, 'XDFCTX', $xnq);
 201                 } elsif (/^-- $/) { # email signature begins
 202                         $in_diff = undef;
 203                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 204                         my ($fa, $fb) = ($1, $2);
 205                         my $fn = (split('/', git_unquote($fa), 2))[1];
 206                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 207                         $fn = (split('/', git_unquote($fb), 2))[1];
 208                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 209                         $in_diff = 1;
 210                 # traditional diff:
 211                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 212                         my ($opt, $fa, $fb) = ($1, $2, $3);
 213                         push @xnq, $_;
 214                         # only support unified:
 215                         next unless $opt =~ /[uU]/;
 216                         $in_diff = $self->index_old_diff_fn(\%seen, $fa, $fb,
 217                                                         $xnq);
 218                 } elsif (m!^--- ("?a/.+)!) {
 219                         my $fn = $1;
 220                         $fn = (split('/', git_unquote($fn), 2))[1];
 221                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 222                         $in_diff = 1;
 223                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 224                         my $fn = $1;
 225                         $fn = (split('/', git_unquote($fn), 2))[1];
 226                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 227                         $in_diff = 1;
 228                 } elsif (/^--- (\S+)/) {
 229                         $in_diff = $1;
 230                         push @xnq, $_;
 231                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 232                         $in_diff = $self->index_old_diff_fn(\%seen, $in_diff, $1,
 233                                                         $xnq);
 234                 } elsif ($in_diff && s/^\+//) { # diff added
 235                         $self->index_diff_inc($_, 'XDFB', $xnq);
 236                 } elsif ($in_diff && s/^-//) { # diff removed
 237                         $self->index_diff_inc($_, 'XDFA', $xnq);
 238                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 239                         my ($ba, $bb) = ($1, $2);
 240                         index_git_blob_id($doc, 'XDFPRE', $ba);
 241                         index_git_blob_id($doc, 'XDFPOST', $bb);
 242                         $in_diff = 1;
 243                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 244                         # traditional diff w/o -p
 245                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 246                         # hunk header context
 247                         $self->index_diff_inc($1, 'XDFHH', $xnq);
 248                 # ignore the following lines:
 249                 } elsif (/^(?:dis)similarity index/ ||
 250                                 /^(?:old|new) mode/ ||
 251                                 /^(?:deleted|new) file mode/ ||
 252                                 /^(?:copy|rename) (?:from|to) / ||
 253                                 /^(?:dis)?similarity index / ||
 254                                 /^\\ No newline at end of file/ ||
 255                                 /^Binary files .* differ/) {
 256                         push @xnq, $_;
 257                 } elsif ($_ eq '') {
 258                         # possible to be in diff context, some mail may be
 259                         # stripped by MUA or even GNU diff(1).  "git apply"
 260                         # treats a bare "\n" as diff context, too
 261                 } else {
 262                         push @xnq, $_;
 263                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 264                         $in_diff = undef;
 265                 }
 266         }
 267
 268         $self->index_text(join("\n", @xnq), 1, 'XNQ');
 269 }
 270
 271 sub index_body ($$$) {
 272         my ($self, $lines, $doc) = @_;
 273         my $txt = join("\n", @$lines);
 274         if ($doc) {
 275                 # does it look like a diff?
 276                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 277                         $txt = undef;
 278                         $self->index_diff($lines, $doc);
 279                 } else {
 280                         $self->index_text($txt, 1, 'XNQ');
 281                 }
 282         } else {
 283                 $self->index_text($txt, 0, 'XQUOT');
 284         }
 285         @$lines = ();
 286 }
 287
 288 sub index_xapian { # msg_iter callback
 289         my ($part, $depth, @idx) = @{$_[0]};
 290         my ($self, $doc) = @{$_[1]};
 291         my $ct = $part->content_type || 'text/plain';
 292         my $fn = $part->filename;
 293         if (defined $fn && $fn ne '') {
 294                 $self->index_text($fn, 1, 'XFN');
 295         }
 296
 297         my ($s, undef) = msg_part_text($part, $ct);
 298         defined $s or return;
 299
 300         my (@orig, @quot);
 301         my @lines = split(/\n/, $s);
 302         while (defined(my $l = shift @lines)) {
 303                 if ($l =~ /^>/) {
 304                         $self->index_body(\@orig, $doc) if @orig;
 305                         push @quot, $l;
 306                 } else {
 307                         $self->index_body(\@quot, 0) if @quot;
 308                         push @orig, $l;
 309                 }
 310         }
 311         $self->index_body(\@quot, 0) if @quot;
 312         $self->index_body(\@orig, $doc) if @orig;
 313 }
 314
 315 sub add_xapian ($$$$$) {
 316         my ($self, $mime, $num, $oid, $mids, $mid0) = @_;
 317         my $smsg = PublicInbox::SearchMsg->new($mime);
 318         my $doc = $X->{Document}->new;
 319         my $subj = $smsg->subject;
 320         add_val($doc, PublicInbox::Search::TS(), $smsg->ts);
 321         my @ds = gmtime($smsg->ds);
 322         my $yyyymmdd = strftime('%Y%m%d', @ds);
 323         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 324         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 325         add_val($doc, PublicInbox::Search::DT(), $dt);
 326
 327         my $tg = $self->term_generator;
 328
 329         $tg->set_document($doc);
 330         $self->index_text($subj, 1, 'S') if $subj;
 331         $self->index_users($smsg);
 332
 333         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 334         foreach my $mid (@$mids) {
 335                 $self->index_text($mid, 1, 'XM');
 336
 337                 # because too many Message-IDs are prefixed with
 338                 # "Pine.LNX."...
 339                 if ($mid =~ /\w{12,}/) {
 340                         my @long = ($mid =~ /(\w{3,}+)/g);
 341                         $self->index_text(join(' ', @long), 1, 'XM');
 342                 }
 343         }
 344         $smsg->{to} = $smsg->{cc} = '';
 345         PublicInbox::OverIdx::parse_references($smsg, $mid0, $mids);
 346         my $data = $smsg->to_doc_data($oid, $mid0);
 347         $doc->set_data($data);
 348         if (my $altid = $self->{-altid}) {
 349                 foreach my $alt (@$altid) {
 350                         my $pfx = $alt->{xprefix};
 351                         foreach my $mid (@$mids) {
 352                                 my $id = $alt->mid2alt($mid);
 353                                 next unless defined $id;
 354                                 $doc->add_boolean_term($pfx . $id);
 355                         }
 356                 }
 357         }
 358         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 359         $self->{xdb}->replace_document($num, $doc);
 360 }
 361
 362 sub add_message {
 363         # mime = Email::MIME object
 364         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 365         my $mids = mids_for_index($mime->header_obj);
 366         $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 367         unless (defined $num) { # v1
 368                 $self->_msgmap_init;
 369                 $num = index_mm($self, $mime);
 370         }
 371         eval {
 372                 if (need_xapian($self)) {
 373                         $self->add_xapian($mime, $num, $oid, $mids, $mid0)
 374                 }
 375                 if (my $over = $self->{over}) {
 376                         $over->add_overview($mime, $bytes, $num, $oid, $mid0);
 377                 }
 378         };
 379
 380         if ($@) {
 381                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 382                 return undef;
 383         }
 384         $num;
 385 }
 386
 387 # returns begin and end PostingIterator
 388 sub find_doc_ids {
 389         my ($self, $termval) = @_;
 390         my $db = $self->{xdb};
 391
 392         ($db->postlist_begin($termval), $db->postlist_end($termval));
 393 }
 394
 395 # v1 only
 396 sub batch_do {
 397         my ($self, $termval, $cb) = @_;
 398         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 399         while (1) {
 400                 my ($head, $tail) = $self->find_doc_ids($termval);
 401                 return if $head == $tail;
 402                 my @ids;
 403                 for (; $head != $tail && @ids < $batch_size; $head++) {
 404                         push @ids, $head->get_docid;
 405                 }
 406                 $cb->(\@ids);
 407         }
 408 }
 409
 410 # v1 only, where $mid is unique
 411 sub remove_message {
 412         my ($self, $mid) = @_;
 413         $mid = mid_clean($mid);
 414
 415         if (my $over = $self->{over}) {
 416                 my $nr = eval { $over->remove_oid(undef, $mid) };
 417                 if ($@) {
 418                         warn "failed to remove <$mid> from overview: $@\n";
 419                 } elsif ($nr == 0) {
 420                         warn "<$mid> missing for removal from overview\n";
 421                 }
 422         }
 423         return unless need_xapian($self);
 424         my $db = $self->{xdb};
 425         my $nr = 0;
 426         eval {
 427                 batch_do($self, 'Q' . $mid, sub {
 428                         my ($ids) = @_;
 429                         $db->delete_document($_) for @$ids;
 430                         $nr = scalar @$ids;
 431                 });
 432         };
 433         if ($@) {
 434                 warn "failed to remove <$mid> from Xapian: $@\n";
 435         } elsif ($nr == 0) {
 436                 warn "<$mid> missing for removal from Xapian\n";
 437         }
 438 }
 439
 440 # MID is a hint in V2
 441 sub remove_by_oid {
 442         my ($self, $oid, $mid) = @_;
 443
 444         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 445
 446         return unless need_xapian($self);
 447         my $db = $self->{xdb};
 448
 449         # XXX careful, we cannot use batch_do here since we conditionally
 450         # delete documents based on other factors, so we cannot call
 451         # find_doc_ids twice.
 452         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 453         return if $head == $tail;
 454
 455         # there is only ONE element in @delete unless we
 456         # have bugs in our v2writable deduplication check
 457         my @delete;
 458         for (; $head != $tail; $head++) {
 459                 my $docid = $head->get_docid;
 460                 my $doc = $db->get_document($docid);
 461                 my $smsg = PublicInbox::SearchMsg->wrap($mid);
 462                 $smsg->load_expand($doc);
 463                 if ($smsg->{blob} eq $oid) {
 464                         push(@delete, $docid);
 465                 }
 466         }
 467         $db->delete_document($_) foreach @delete;
 468         scalar(@delete);
 469 }
 470
 471 sub term_generator { # write-only
 472         my ($self) = @_;
 473
 474         my $tg = $self->{term_generator};
 475         return $tg if $tg;
 476
 477         $tg = $X->{TermGenerator}->new;
 478         $tg->set_stemmer($self->stemmer);
 479
 480         $self->{term_generator} = $tg;
 481 }
 482
 483 sub index_git_blob_id {
 484         my ($doc, $pfx, $objid) = @_;
 485
 486         my $len = length($objid);
 487         for (my $len = length($objid); $len >= 7; ) {
 488                 $doc->add_term($pfx.$objid);
 489                 $objid = substr($objid, 0, --$len);
 490         }
 491 }
 492
 493 sub unindex_blob {
 494         my ($self, $mime) = @_;
 495         my $mid = eval { mid_clean(mid_mime($mime)) };
 496         $self->remove_message($mid) if defined $mid;
 497 }
 498
 499 sub index_mm {
 500         my ($self, $mime) = @_;
 501         my $mid = mid_clean(mid_mime($mime));
 502         my $mm = $self->{mm};
 503         my $num;
 504
 505         if (defined $self->{regen_down}) {
 506                 $num = $mm->num_for($mid) and return $num;
 507
 508                 while (($num = $self->{regen_down}--) > 0) {
 509                         if ($mm->mid_set($num, $mid) != 0) {
 510                                 return $num;
 511                         }
 512                 }
 513         } elsif (defined $self->{regen_up}) {
 514                 $num = $mm->num_for($mid) and return $num;
 515
 516                 # this is to fixup old bugs due to add-remove-add
 517                 while (($num = ++$self->{regen_up})) {
 518                         if ($mm->mid_set($num, $mid) != 0) {
 519                                 return $num;
 520                         }
 521                 }
 522         }
 523
 524         $num = $mm->mid_insert($mid) and return $num;
 525
 526         # fallback to num_for since filters like RubyLang set the number
 527         $mm->num_for($mid);
 528 }
 529
 530 sub unindex_mm {
 531         my ($self, $mime) = @_;
 532         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 533 }
 534
 535 sub index_both {
 536         my ($self, $mime, $bytes, $blob) = @_;
 537         my $num = index_mm($self, $mime);
 538         add_message($self, $mime, $bytes, $num, $blob);
 539 }
 540
 541 sub unindex_both {
 542         my ($self, $mime) = @_;
 543         unindex_blob($self, $mime);
 544         unindex_mm($self, $mime);
 545 }
 546
 547 sub do_cat_mail {
 548         my ($git, $blob, $sizeref) = @_;
 549         my $mime = eval {
 550                 my $str = $git->cat_file($blob, $sizeref);
 551                 # fixup bugs from import:
 552                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 553                 PublicInbox::MIME->new($str);
 554         };
 555         $@ ? undef : $mime;
 556 }
 557
 558 # called by public-inbox-index
 559 sub index_sync {
 560         my ($self, $opts) = @_;
 561         delete $self->{lock_path} if $opts->{-skip_lock};
 562         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 563 }
 564
 565 sub batch_adjust ($$$$$) {
 566         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 567         $$max -= $bytes;
 568         if ($$max <= 0) {
 569                 $$max = BATCH_BYTES;
 570                 $batch_cb->($nr, $latest);
 571         }
 572 }
 573
 574 # only for v1
 575 sub read_log {
 576         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 577         my $hex = '[a-f0-9]';
 578         my $h40 = $hex .'{40}';
 579         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 580         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 581         my $git = $self->{git};
 582         my $latest;
 583         my $bytes;
 584         my $max = BATCH_BYTES;
 585         local $/ = "\n";
 586         my %D;
 587         my $line;
 588         my $newest;
 589         my $nr = 0;
 590         while (defined($line = <$log>)) {
 591                 if ($line =~ /$addmsg/o) {
 592                         my $blob = $1;
 593                         if (delete $D{$blob}) {
 594                                 if (defined $self->{regen_down}) {
 595                                         my $num = $self->{regen_down}--;
 596                                         $self->{mm}->num_highwater($num);
 597                                 }
 598                                 next;
 599                         }
 600                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 601                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 602                         $add_cb->($self, $mime, $bytes, $blob);
 603                 } elsif ($line =~ /$delmsg/o) {
 604                         my $blob = $1;
 605                         $D{$blob} = 1;
 606                 } elsif ($line =~ /^commit ($h40)/o) {
 607                         $latest = $1;
 608                         $newest ||= $latest;
 609                 }
 610         }
 611         close($log) or die "git log failed: \$?=$?";
 612         # get the leftovers
 613         foreach my $blob (keys %D) {
 614                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 615                 $del_cb->($self, $mime);
 616         }
 617         $batch_cb->($nr, $latest, $newest);
 618 }
 619
 620 sub _msgmap_init {
 621         my ($self) = @_;
 622         die "BUG: _msgmap_init is only for v1\n" if $self->{version} != 1;
 623         $self->{mm} ||= eval {
 624                 require PublicInbox::Msgmap;
 625                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 626         };
 627 }
 628
 629 sub _git_log {
 630         my ($self, $opts, $range) = @_;
 631         my $git = $self->{git};
 632
 633         if (index($range, '..') < 0) {
 634                 # don't show annoying git errrors to users who run -index
 635                 # on empty inboxes
 636                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 637                 if ($?) {
 638                         open my $fh, '<', '/dev/null' or
 639                                 die "failed to open /dev/null: $!\n";
 640                         return $fh;
 641                 }
 642         }
 643
 644         # Count the new files so they can be added newest to oldest
 645         # and still have numbers increasing from oldest to newest
 646         my $fcount = 0;
 647         my $pr = $opts->{-progress};
 648         $pr->("counting changes\n\t$range ... ") if $pr;
 649         # can't use 'rev-list --count' if we use --diff-filter
 650         my $fh = $git->popen(qw(log --pretty=tformat:%h
 651                              --no-notes --no-color --no-renames
 652                              --diff-filter=AM), $range);
 653         ++$fcount while <$fh>;
 654         close $fh or die "git log failed: \$?=$?";
 655         my $high = $self->{mm}->num_highwater;
 656         $pr->("$fcount\n") if $pr; # continue previous line
 657         $self->{ntodo} = $fcount;
 658
 659         if (index($range, '..') < 0) {
 660                 if ($high && $high == $fcount) {
 661                         # fix up old bugs in full indexes which caused messages to
 662                         # not appear in Msgmap
 663                         $self->{regen_up} = $high;
 664                 } else {
 665                         # normal regen is for for fresh data
 666                         $self->{regen_down} = $fcount;
 667                 }
 668         } else {
 669                 # Give oldest messages the smallest numbers
 670                 $self->{regen_down} = $high + $fcount;
 671         }
 672
 673         $git->popen(qw/log --no-notes --no-color --no-renames
 674                                 --raw -r --no-abbrev/, $range);
 675 }
 676
 677 # --is-ancestor requires git 1.8.0+
 678 sub is_ancestor ($$$) {
 679         my ($git, $cur, $tip) = @_;
 680         return 0 unless $git->check($cur);
 681         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 682                 qw(merge-base --is-ancestor), $cur, $tip ];
 683         my $pid = spawn($cmd);
 684         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 685         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 686         $? == 0;
 687 }
 688
 689 sub need_update ($$$) {
 690         my ($self, $cur, $new) = @_;
 691         my $git = $self->{git};
 692         return 1 if $cur && !is_ancestor($git, $cur, $new);
 693         my $range = $cur eq '' ? $new : "$cur..$new";
 694         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 695         ($n eq '' || $n > 0);
 696 }
 697
 698 # The last git commit we indexed with Xapian or SQLite (msgmap)
 699 # This needs to account for cases where Xapian or SQLite is
 700 # out-of-date with respect to the other.
 701 sub _last_x_commit {
 702         my ($self, $mm) = @_;
 703         my $lm = $mm->last_commit || '';
 704         my $lx = '';
 705         if (need_xapian($self)) {
 706                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 707         } else {
 708                 $lx = $lm;
 709         }
 710         # Use last_commit from msgmap if it is older or unset
 711         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 712                 $lx = $lm;
 713         }
 714         $lx;
 715 }
 716
 717 sub reindex_from ($$) {
 718         my ($reindex, $last_commit) = @_;
 719         return $last_commit unless $reindex;
 720         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 721 }
 722
 723 # indexes all unindexed messages (v1 only)
 724 sub _index_sync {
 725         my ($self, $opts) = @_;
 726         my $tip = $opts->{ref} || 'HEAD';
 727         my ($last_commit, $lx, $xlog);
 728         my $git = $self->{git};
 729         $git->batch_prepare;
 730         my $pr = $opts->{-progress};
 731
 732         my $xdb = $self->begin_txn_lazy;
 733         my $mm = _msgmap_init($self);
 734         do {
 735                 if ($xlog) {
 736                         close($xlog) or die "git log failed: \$?=$?";
 737                         $xlog = undef;
 738                 }
 739                 $last_commit = _last_x_commit($self, $mm);
 740                 $lx = reindex_from($opts->{reindex}, $last_commit);
 741
 742                 $self->{over}->rollback_lazy;
 743                 $self->{over}->disconnect;
 744                 $git->cleanup;
 745                 delete $self->{txn};
 746                 $xdb->cancel_transaction if $xdb;
 747                 $xdb = _xdb_release($self);
 748
 749                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 750                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 751                 $xlog = _git_log($self, $opts, $range);
 752
 753                 $xdb = $self->begin_txn_lazy;
 754         } while (_last_x_commit($self, $mm) ne $last_commit);
 755
 756         my $dbh = $mm->{dbh} if $mm;
 757         my $cb = sub {
 758                 my ($nr, $commit, $newest) = @_;
 759                 if ($dbh) {
 760                         if ($newest) {
 761                                 my $cur = $mm->last_commit || '';
 762                                 if (need_update($self, $cur, $newest)) {
 763                                         $mm->last_commit($newest);
 764                                 }
 765                         }
 766                         $dbh->commit;
 767                 }
 768                 if ($newest && need_xapian($self)) {
 769                         my $cur = $xdb->get_metadata('last_commit');
 770                         if (need_update($self, $cur, $newest)) {
 771                                 $xdb->set_metadata('last_commit', $newest);
 772                         }
 773                 }
 774                 $self->commit_txn_lazy;
 775                 $git->cleanup;
 776                 $xdb = _xdb_release($self);
 777                 # let another process do some work... <
 778                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 779                 if (!$newest) {
 780                         $xdb = $self->begin_txn_lazy;
 781                         $dbh->begin_work if $dbh;
 782                 }
 783         };
 784
 785         $dbh->begin_work;
 786         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 787 }
 788
 789 sub DESTROY {
 790         # order matters for unlocking
 791         $_[0]->{xdb} = undef;
 792         $_[0]->{lockfh} = undef;
 793 }
 794
 795 # remote_* subs are only used by SearchIdxPart
 796 sub remote_commit {
 797         my ($self) = @_;
 798         if (my $w = $self->{w}) {
 799                 print $w "commit\n" or die "failed to write commit: $!";
 800         } else {
 801                 $self->commit_txn_lazy;
 802         }
 803 }
 804
 805 sub remote_close {
 806         my ($self) = @_;
 807         if (my $w = delete $self->{w}) {
 808                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 809                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 810                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 811                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 812                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 813         } else {
 814                 die "transaction in progress $self\n" if $self->{txn};
 815                 $self->_xdb_release if $self->{xdb};
 816         }
 817 }
 818
 819 sub remote_remove {
 820         my ($self, $oid, $mid) = @_;
 821         if (my $w = $self->{w}) {
 822                 # triggers remove_by_oid in a shard
 823                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 824         } else {
 825                 $self->begin_txn_lazy;
 826                 $self->remove_by_oid($oid, $mid);
 827         }
 828 }
 829
 830 sub begin_txn_lazy {
 831         my ($self) = @_;
 832         return if $self->{txn};
 833
 834         $self->{-inbox}->with_umask(sub {
 835                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 836                 $self->{over}->begin_lazy if $self->{over};
 837                 $xdb->begin_transaction if $xdb;
 838                 $self->{txn} = 1;
 839                 $xdb;
 840         });
 841 }
 842
 843 sub commit_txn_lazy {
 844         my ($self) = @_;
 845         delete $self->{txn} or return;
 846         $self->{-inbox}->with_umask(sub {
 847                 if (my $xdb = $self->{xdb}) {
 848
 849                         # store 'indexlevel=medium' in v2 shard=0 and
 850                         # v1 (only one shard)
 851                         # This metadata is read by Admin::detect_indexlevel:
 852                         if (!$self->{shard} # undef or 0, not >0
 853                             && $self->{indexlevel} eq 'medium') {
 854                                 $xdb->set_metadata('indexlevel', 'medium');
 855                         }
 856
 857                         $xdb->commit_transaction;
 858                 }
 859                 $self->{over}->commit_lazy if $self->{over};
 860         });
 861 }
 862
 863 sub worker_done {
 864         my ($self) = @_;
 865         if (need_xapian($self)) {
 866                 die "$$ $0 xdb not released\n" if $self->{xdb};
 867         }
 868         die "$$ $0 still in transaction\n" if $self->{txn};
 869 }
 870
 871 1;