lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by Mail::Thread.  This writes to the search
   8 # index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use Email::MIME;
  14 use Email::MIME::ContentType;
  15 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  16 use base qw(PublicInbox::Search);
  17 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  18 use PublicInbox::MsgIter;
  19 use Carp qw(croak);
  20 use POSIX qw(strftime);
  21 require PublicInbox::Git;
  22 *xpfx = *PublicInbox::Search::xpfx;
  23
  24 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  25 use constant {
  26         PERM_UMASK => 0,
  27         OLD_PERM_GROUP => 1,
  28         OLD_PERM_EVERYBODY => 2,
  29         PERM_GROUP => 0660,
  30         PERM_EVERYBODY => 0664,
  31 };
  32
  33 sub new {
  34         my ($class, $inbox, $creat) = @_;
  35         my $git_dir = $inbox;
  36         my $altid;
  37         if (ref $inbox) {
  38                 $git_dir = $inbox->{mainrepo};
  39                 $altid = $inbox->{altid};
  40                 if ($altid) {
  41                         require PublicInbox::AltId;
  42                         $altid = [ map {
  43                                 PublicInbox::AltId->new($inbox, $_);
  44                         } @$altid ];
  45                 }
  46         }
  47         require Search::Xapian::WritableDatabase;
  48         my $self = bless { git_dir => $git_dir, -altid => $altid }, $class;
  49         my $perm = $self->_git_config_perm;
  50         my $umask = _umask_for($perm);
  51         $self->{umask} = $umask;
  52         $self->{lock_path} = "$git_dir/ssoma.lock";
  53         $self->{git} = PublicInbox::Git->new($git_dir);
  54         $self->{creat} = ($creat || 0) == 1;
  55         $self;
  56 }
  57
  58 sub _xdb_release {
  59         my ($self) = @_;
  60         my $xdb = delete $self->{xdb} or croak 'not acquired';
  61         $xdb->close;
  62         _lock_release($self) if $self->{creat};
  63         undef;
  64 }
  65
  66 sub _xdb_acquire {
  67         my ($self) = @_;
  68         croak 'already acquired' if $self->{xdb};
  69         my $dir = PublicInbox::Search->xdir($self->{git_dir});
  70         my $flag = Search::Xapian::DB_OPEN;
  71         if ($self->{creat}) {
  72                 require File::Path;
  73                 _lock_acquire($self);
  74                 File::Path::mkpath($dir);
  75                 $self->{batch_size} = 100;
  76                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  77         }
  78         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
  79 }
  80
  81 # we only acquire the flock if creating or reindexing;
  82 # PublicInbox::Import already has the lock on its own.
  83 sub _lock_acquire {
  84         my ($self) = @_;
  85         croak 'already locked' if $self->{lockfh};
  86         sysopen(my $lockfh, $self->{lock_path}, O_WRONLY|O_CREAT) or
  87                 die "failed to open lock $self->{lock_path}: $!\n";
  88         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
  89         $self->{lockfh} = $lockfh;
  90 }
  91
  92 sub _lock_release {
  93         my ($self) = @_;
  94         my $lockfh = delete $self->{lockfh} or croak 'not locked';
  95         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
  96         close $lockfh or die "close failed: $!\n";
  97 }
  98
  99 sub add_val ($$$) {
 100         my ($doc, $col, $num) = @_;
 101         $num = Search::Xapian::sortable_serialise($num);
 102         $doc->add_value($col, $num);
 103 }
 104
 105 sub add_values ($$$) {
 106         my ($smsg, $bytes, $num) = @_;
 107
 108         my $ts = $smsg->ts;
 109         my $doc = $smsg->{doc};
 110         add_val($doc, &PublicInbox::Search::TS, $ts);
 111
 112         defined($num) and add_val($doc, &PublicInbox::Search::NUM, $num);
 113
 114         defined($bytes) and add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 115
 116         add_val($doc, &PublicInbox::Search::LINES,
 117                         $smsg->{mime}->body_raw =~ tr!\n!\n!);
 118
 119         my $yyyymmdd = strftime('%Y%m%d', gmtime($ts));
 120         $doc->add_value(&PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 121 }
 122
 123 sub index_users ($$) {
 124         my ($tg, $smsg) = @_;
 125
 126         my $from = $smsg->from;
 127         my $to = $smsg->to;
 128         my $cc = $smsg->cc;
 129
 130         $tg->index_text($from, 1, 'A'); # A - author
 131         $tg->increase_termpos;
 132         $tg->index_text($to, 1, 'XTO') if $to ne '';
 133         $tg->increase_termpos;
 134         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 135         $tg->increase_termpos;
 136 }
 137
 138 sub add_message {
 139         my ($self, $mime, $bytes, $num, $blob) = @_; # mime = Email::MIME object
 140         my $db = $self->{xdb};
 141
 142         my ($doc_id, $old_tid);
 143         my $mid = mid_clean(mid_mime($mime));
 144         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
 145
 146         eval {
 147                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
 148                 my $smsg = $self->lookup_message($mid);
 149                 if ($smsg) {
 150                         # convert a ghost to a regular message
 151                         # it will also clobber any existing regular message
 152                         $doc_id = $smsg->doc_id;
 153                         $old_tid = $smsg->thread_id;
 154                 }
 155                 $smsg = PublicInbox::SearchMsg->new($mime);
 156                 my $doc = $smsg->{doc};
 157                 $doc->add_term(xpfx('mid') . $mid);
 158
 159                 my $subj = $smsg->subject;
 160                 if ($subj ne '') {
 161                         my $path = $self->subject_path($subj);
 162                         $doc->add_term(xpfx('path') . id_compress($path));
 163                 }
 164
 165                 add_values($smsg, $bytes, $num);
 166
 167                 my $tg = $self->term_generator;
 168
 169                 $tg->set_document($doc);
 170                 $tg->index_text($subj, 1, 'S') if $subj;
 171                 $tg->increase_termpos;
 172
 173                 index_users($tg, $smsg);
 174
 175                 msg_iter($mime, sub {
 176                         my ($part, $depth, @idx) = @{$_[0]};
 177                         my $ct = $part->content_type || $ct_msg;
 178
 179                         # account for filter bugs...
 180                         $ct =~ m!\btext/plain\b!i or return;
 181
 182                         my (@orig, @quot);
 183                         my $body = $part->body;
 184                         $part->body_set('');
 185                         my @lines = split(/\n/, $body);
 186                         while (defined(my $l = shift @lines)) {
 187                                 if ($l =~ /^>/) {
 188                                         push @quot, $l;
 189                                 } else {
 190                                         push @orig, $l;
 191                                 }
 192                         }
 193                         if (@quot) {
 194                                 my $s = join("\n", @quot);
 195                                 @quot = ();
 196                                 $tg->index_text($s, 0, 'XQUOT');
 197                                 $tg->increase_termpos;
 198                         }
 199                         if (@orig) {
 200                                 my $s = join("\n", @orig);
 201                                 @orig = ();
 202                                 $tg->index_text($s, 1, 'XNQ');
 203                                 $tg->increase_termpos;
 204                         }
 205                 });
 206
 207                 link_message($self, $smsg, $old_tid);
 208                 $tg->index_text($mid, 1, 'XMID');
 209                 $doc->set_data($smsg->to_doc_data($blob));
 210
 211                 if (my $altid = $self->{-altid}) {
 212                         foreach my $alt (@$altid) {
 213                                 my $id = $alt->mid2alt($mid);
 214                                 next unless defined $id;
 215                                 $doc->add_term($alt->{xprefix} . $id);
 216                         }
 217                 }
 218                 if (defined $doc_id) {
 219                         $db->replace_document($doc_id, $doc);
 220                 } else {
 221                         $doc_id = $db->add_document($doc);
 222                 }
 223         };
 224
 225         if ($@) {
 226                 warn "failed to index message <$mid>: $@\n";
 227                 return undef;
 228         }
 229         $doc_id;
 230 }
 231
 232 # returns deleted doc_id on success, undef on missing
 233 sub remove_message {
 234         my ($self, $mid) = @_;
 235         my $db = $self->{xdb};
 236         my $doc_id;
 237         $mid = mid_clean($mid);
 238
 239         eval {
 240                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 241                 $db->delete_document($doc_id) if defined $doc_id;
 242         };
 243
 244         if ($@) {
 245                 warn "failed to remove message <$mid>: $@\n";
 246                 return undef;
 247         }
 248         $doc_id;
 249 }
 250
 251 sub term_generator { # write-only
 252         my ($self) = @_;
 253
 254         my $tg = $self->{term_generator};
 255         return $tg if $tg;
 256
 257         $tg = Search::Xapian::TermGenerator->new;
 258         $tg->set_stemmer($self->stemmer);
 259
 260         $self->{term_generator} = $tg;
 261 }
 262
 263 # increments last_thread_id counter
 264 # returns a 64-bit integer represented as a hex string
 265 sub next_thread_id {
 266         my ($self) = @_;
 267         my $db = $self->{xdb};
 268         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 269
 270         $db->set_metadata('last_thread_id', ++$last_thread_id);
 271
 272         $last_thread_id;
 273 }
 274
 275 sub link_message {
 276         my ($self, $smsg, $old_tid) = @_;
 277         my $doc = $smsg->{doc};
 278         my $mid = $smsg->mid;
 279         my $mime = $smsg->mime;
 280         my $hdr = $mime->header_obj;
 281         my $refs = $hdr->header_raw('References');
 282         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 283         if (my $irt = $hdr->header_raw('In-Reply-To')) {
 284                 # last References should be $irt
 285                 # we will de-dupe later
 286                 push @refs, mid_clean($irt);
 287         }
 288
 289         my $tid;
 290         if (@refs) {
 291                 my %uniq = ($mid => 1);
 292                 my @orig_refs = @refs;
 293                 @refs = ();
 294
 295                 # prevent circular references via References: here:
 296                 foreach my $ref (@orig_refs) {
 297                         if (length($ref) > MAX_MID_SIZE) {
 298                                 warn "References: <$ref> too long, ignoring\n";
 299                         }
 300                         next if $uniq{$ref};
 301                         $uniq{$ref} = 1;
 302                         push @refs, $ref;
 303                 }
 304         }
 305         if (@refs) {
 306                 $smsg->{references} = '<'.join('> <', @refs).'>';
 307
 308                 # first ref *should* be the thread root,
 309                 # but we can never trust clients to do the right thing
 310                 my $ref = shift @refs;
 311                 $tid = $self->_resolve_mid_to_tid($ref);
 312                 $self->merge_threads($tid, $old_tid) if defined $old_tid;
 313
 314                 # the rest of the refs should point to this tid:
 315                 foreach $ref (@refs) {
 316                         my $ptid = $self->_resolve_mid_to_tid($ref);
 317                         merge_threads($self, $tid, $ptid);
 318                 }
 319         } else {
 320                 $tid = $self->next_thread_id;
 321         }
 322         $doc->add_term(xpfx('thread') . $tid);
 323 }
 324
 325 sub index_blob {
 326         my ($self, $mime, $bytes, $num, $blob) = @_;
 327         $self->add_message($mime, $bytes, $num, $blob);
 328 }
 329
 330 sub unindex_blob {
 331         my ($self, $mime) = @_;
 332         my $mid = eval { mid_clean(mid_mime($mime)) };
 333         $self->remove_message($mid) if defined $mid;
 334 }
 335
 336 sub index_mm {
 337         my ($self, $mime) = @_;
 338         $self->{mm}->mid_insert(mid_clean(mid_mime($mime)));
 339 }
 340
 341 sub unindex_mm {
 342         my ($self, $mime) = @_;
 343         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 344 }
 345
 346 sub index_mm2 {
 347         my ($self, $mime, $bytes, $blob) = @_;
 348         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 349         index_blob($self, $mime, $bytes, $num, $blob);
 350 }
 351
 352 sub unindex_mm2 {
 353         my ($self, $mime) = @_;
 354         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 355         unindex_blob($self, $mime);
 356 }
 357
 358 sub index_both {
 359         my ($self, $mime, $bytes, $blob) = @_;
 360         my $num = index_mm($self, $mime);
 361         index_blob($self, $mime, $bytes, $num, $blob);
 362 }
 363
 364 sub unindex_both {
 365         my ($self, $mime) = @_;
 366         unindex_blob($self, $mime);
 367         unindex_mm($self, $mime);
 368 }
 369
 370 sub do_cat_mail {
 371         my ($git, $blob, $sizeref) = @_;
 372         my $mime = eval {
 373                 my $str = $git->cat_file($blob, $sizeref);
 374                 # fixup bugs from import:
 375                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 376                 Email::MIME->new($str);
 377         };
 378         $@ ? undef : $mime;
 379 }
 380
 381 sub index_sync {
 382         my ($self, $opts) = @_;
 383         with_umask($self, sub { $self->_index_sync($opts) });
 384 }
 385
 386 sub rlog {
 387         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 388         my $hex = '[a-f0-9]';
 389         my $h40 = $hex .'{40}';
 390         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 391         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 392         my $git = $self->{git};
 393         my $latest;
 394         my $bytes;
 395         my $max = $self->{batch_size}; # may be undef
 396         local $/ = "\n";
 397         my $line;
 398         while (defined($line = <$log>)) {
 399                 if ($line =~ /$addmsg/o) {
 400                         my $blob = $1;
 401                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 402                         $add_cb->($self, $mime, $bytes, $blob);
 403                 } elsif ($line =~ /$delmsg/o) {
 404                         my $blob = $1;
 405                         my $mime = do_cat_mail($git, $blob) or next;
 406                         $del_cb->($self, $mime);
 407                 } elsif ($line =~ /^commit ($h40)/o) {
 408                         if (defined $max && --$max <= 0) {
 409                                 $max = $self->{batch_size};
 410                                 $batch_cb->($latest, 1);
 411                         }
 412                         $latest = $1;
 413                 }
 414         }
 415         $batch_cb->($latest, 0);
 416 }
 417
 418 sub _msgmap_init {
 419         my ($self) = @_;
 420         $self->{mm} = eval {
 421                 require PublicInbox::Msgmap;
 422                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 423         };
 424 }
 425
 426 sub _git_log {
 427         my ($self, $range) = @_;
 428         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 429                                 --raw -r --no-abbrev/, $range);
 430 }
 431
 432 # indexes all unindexed messages
 433 sub _index_sync {
 434         my ($self, $opts) = @_;
 435         my $tip = $opts->{ref} || 'HEAD';
 436         my $reindex = $opts->{reindex};
 437         my ($mkey, $last_commit, $lx, $xlog);
 438         $self->{git}->batch_prepare;
 439         my $xdb = _xdb_acquire($self);
 440         $xdb->begin_transaction;
 441         do {
 442                 $xlog = undef;
 443                 $mkey = 'last_commit';
 444                 $last_commit = $xdb->get_metadata('last_commit');
 445                 $lx = $last_commit;
 446                 if ($reindex) {
 447                         $lx = '';
 448                         $mkey = undef if $last_commit ne '';
 449                 }
 450                 $xdb->cancel_transaction;
 451                 $xdb = _xdb_release($self);
 452
 453                 # ensure we leak no FDs to "git log"
 454                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 455                 $xlog = _git_log($self, $range);
 456
 457                 $xdb = _xdb_acquire($self);
 458                 $xdb->begin_transaction;
 459         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 460
 461         my $mm = _msgmap_init($self);
 462         my $dbh = $mm->{dbh} if $mm;
 463         my $mm_only;
 464         my $cb = sub {
 465                 my ($commit, $more) = @_;
 466                 if ($dbh) {
 467                         $mm->last_commit($commit) if $commit;
 468                         $dbh->commit;
 469                 }
 470                 if (!$mm_only) {
 471                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 472                         $xdb->commit_transaction;
 473                         $xdb = _xdb_release($self);
 474                 }
 475                 # let another process do some work... <
 476                 if ($more) {
 477                         if (!$mm_only) {
 478                                 $xdb = _xdb_acquire($self);
 479                                 $xdb->begin_transaction;
 480                         }
 481                         $dbh->begin_work if $dbh;
 482                 }
 483         };
 484
 485         if ($mm) {
 486                 $dbh->begin_work;
 487                 my $lm = $mm->last_commit || '';
 488                 if ($lm eq $lx) {
 489                         # Common case is the indexes are synced,
 490                         # we only need to run git-log once:
 491                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 492                 } else {
 493                         # Uncommon case, msgmap and xapian are out-of-sync
 494                         # do not care for performance (but git is fast :>)
 495                         # This happens if we have to reindex Xapian since
 496                         # msgmap is a frozen format and our Xapian format
 497                         # is evolving.
 498                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 499
 500                         # first, ensure msgmap is up-to-date:
 501                         my $mkey_prev = $mkey;
 502                         $mkey = undef; # ignore xapian, for now
 503                         my $mlog = _git_log($self, $r);
 504                         $mm_only = 1;
 505                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 506                         $mm_only = $mlog = undef;
 507
 508                         # now deal with Xapian
 509                         $mkey = $mkey_prev;
 510                         $dbh = undef;
 511                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 512                 }
 513         } else {
 514                 # user didn't install DBD::SQLite and DBI
 515                 rlog($self, $xlog, *index_blob, *unindex_blob, $cb);
 516         }
 517 }
 518
 519 # this will create a ghost as necessary
 520 sub _resolve_mid_to_tid {
 521         my ($self, $mid) = @_;
 522
 523         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 524         $smsg->thread_id;
 525 }
 526
 527 sub create_ghost {
 528         my ($self, $mid) = @_;
 529
 530         my $tid = $self->next_thread_id;
 531         my $doc = Search::Xapian::Document->new;
 532         $doc->add_term(xpfx('mid') . $mid);
 533         $doc->add_term(xpfx('thread') . $tid);
 534         $doc->add_term(xpfx('type') . 'ghost');
 535
 536         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 537         $self->{xdb}->add_document($doc);
 538
 539         $smsg;
 540 }
 541
 542 sub merge_threads {
 543         my ($self, $winner_tid, $loser_tid) = @_;
 544         return if $winner_tid == $loser_tid;
 545         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 546         my $thread_pfx = xpfx('thread');
 547         my $db = $self->{xdb};
 548
 549         for (; $head != $tail; $head->inc) {
 550                 my $docid = $head->get_docid;
 551                 my $doc = $db->get_document($docid);
 552                 $doc->remove_term($thread_pfx . $loser_tid);
 553                 $doc->add_term($thread_pfx . $winner_tid);
 554                 $db->replace_document($docid, $doc);
 555         }
 556 }
 557
 558 sub _read_git_config_perm {
 559         my ($self) = @_;
 560         my @cmd = qw(config core.sharedRepository);
 561         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 562         local $/ = "\n";
 563         my $perm = <$fh>;
 564         chomp $perm if defined $perm;
 565         $perm;
 566 }
 567
 568 sub _git_config_perm {
 569         my $self = shift;
 570         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 571         return PERM_GROUP if (!defined($perm) || $perm eq '');
 572         return PERM_UMASK if ($perm eq 'umask');
 573         return PERM_GROUP if ($perm eq 'group');
 574         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 575                 return PERM_EVERYBODY;
 576         }
 577         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 578         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 579
 580         my $i = oct($perm);
 581         return PERM_UMASK if ($i == PERM_UMASK);
 582         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 583         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 584
 585         if (($i & 0600) != 0600) {
 586                 die "core.sharedRepository mode invalid: ".
 587                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 588         }
 589         ($i & 0666);
 590 }
 591
 592 sub _umask_for {
 593         my ($perm) = @_; # _git_config_perm return value
 594         my $rv = $perm;
 595         return umask if $rv == 0;
 596
 597         # set +x bit if +r or +w were set
 598         $rv |= 0100 if ($rv & 0600);
 599         $rv |= 0010 if ($rv & 0060);
 600         $rv |= 0001 if ($rv & 0006);
 601         (~$rv & 0777);
 602 }
 603
 604 sub with_umask {
 605         my ($self, $cb) = @_;
 606         my $old = umask $self->{umask};
 607         my $rv = eval { $cb->() };
 608         my $err = $@;
 609         umask $old;
 610         die $err if $@;
 611         $rv;
 612 }
 613
 614 sub DESTROY {
 615         # order matters for unlocking
 616         $_[0]->{xdb} = undef;
 617         $_[0]->{lockfh} = undef;
 618 }
 619
 620 1;