lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak carp);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::OverIdx;
  22 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  23 use PublicInbox::Git qw(git_unquote);
  24 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  25 our @EXPORT_OK = qw(crlf_adjust log2stack is_ancestor check_size prepare_stack
  26         index_text term_generator add_val is_bad_blob);
  27 my $X = \%PublicInbox::Search::X;
  28 our ($DB_CREATE_OR_OPEN, $DB_OPEN);
  29 our $DB_NO_SYNC = 0;
  30 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  31 use constant DEBUG => !!$ENV{DEBUG};
  32
  33 my $xapianlevels = qr/\A(?:full|medium)\z/;
  34 my $hex = '[a-f0-9]';
  35 my $OID = $hex .'{40,}';
  36 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  37
  38 sub new {
  39         my ($class, $ibx, $creat, $shard) = @_;
  40         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  41         my $inboxdir = $ibx->{inboxdir};
  42         my $version = $ibx->version;
  43         my $indexlevel = 'full';
  44         my $altid = $ibx->{altid};
  45         if ($altid) {
  46                 require PublicInbox::AltId;
  47                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  48         }
  49         if ($ibx->{indexlevel}) {
  50                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  51                         $indexlevel = $ibx->{indexlevel};
  52                 } else {
  53                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  54                 }
  55         }
  56         $ibx = PublicInbox::InboxWritable->new($ibx);
  57         my $self = bless {
  58                 ibx => $ibx,
  59                 xpfx => $inboxdir, # for xpfx_init
  60                 -altid => $altid,
  61                 ibx_ver => $version,
  62                 indexlevel => $indexlevel,
  63         }, $class;
  64         $self->xpfx_init;
  65         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  66         if ($ibx->{-skip_docdata}) {
  67                 $self->{-set_skip_docdata_once} = 1;
  68                 $self->{-skip_docdata} = 1;
  69         }
  70         $ibx->umask_prepare;
  71         if ($version == 1) {
  72                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  73                 my $dir = $self->xdir;
  74                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  75                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  76         } elsif ($version == 2) {
  77                 defined $shard or die "shard is required for v2\n";
  78                 # shard is a number
  79                 $self->{shard} = $shard;
  80                 $self->{lock_path} = undef;
  81         } else {
  82                 die "unsupported inbox version=$version\n";
  83         }
  84         $self->{creat} = ($creat || 0) == 1;
  85         $self;
  86 }
  87
  88 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  89
  90 sub idx_release {
  91         my ($self, $wake) = @_;
  92         if (need_xapian($self)) {
  93                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  94                 $xdb->close;
  95         }
  96         $self->lock_release($wake) if $self->{creat};
  97         undef;
  98 }
  99
 100 sub load_xapian_writable () {
 101         return 1 if $X->{WritableDatabase};
 102         PublicInbox::Search::load_xapian() or return;
 103         my $xap = $PublicInbox::Search::Xap;
 104         for (qw(Document TermGenerator WritableDatabase)) {
 105                 $X->{$_} = $xap.'::'.$_;
 106         }
 107         eval 'require '.$X->{WritableDatabase} or die;
 108         *sortable_serialise = $xap.'::sortable_serialise';
 109         *sortable_unserialise = $xap.'::sortable_unserialise';
 110         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 111         $DB_OPEN = eval($xap.'::DB_OPEN()');
 112         my $ver = (eval($xap.'::major_version()') << 16) |
 113                 (eval($xap.'::minor_version()') << 8);
 114         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 115         1;
 116 }
 117
 118 sub idx_acquire {
 119         my ($self) = @_;
 120         my $flag;
 121         my $dir = $self->xdir;
 122         if (need_xapian($self)) {
 123                 croak 'already acquired' if $self->{xdb};
 124                 load_xapian_writable();
 125                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 126         }
 127         if ($self->{creat}) {
 128                 require File::Path;
 129                 $self->lock_acquire;
 130
 131                 # don't create empty Xapian directories if we don't need Xapian
 132                 my $is_shard = defined($self->{shard});
 133                 if (!-d $dir && (!$is_shard ||
 134                                 ($is_shard && need_xapian($self)))) {
 135                         File::Path::mkpath($dir);
 136                         nodatacow_dir($dir);
 137                         $self->{-set_has_threadid_once} = 1;
 138                 }
 139         }
 140         return unless defined $flag;
 141         $flag |= $DB_NO_SYNC if ($self->{ibx} // $self->{eidx})->{-no_fsync};
 142         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 143         croak "Failed opening $dir: $@" if $@;
 144         $self->{xdb} = $xdb;
 145 }
 146
 147 sub add_val ($$$) {
 148         my ($doc, $col, $num) = @_;
 149         $num = sortable_serialise($num);
 150         $doc->add_value($col, $num);
 151 }
 152
 153 sub term_generator ($) { # write-only
 154         my ($self) = @_;
 155
 156         $self->{term_generator} //= do {
 157                 my $tg = $X->{TermGenerator}->new;
 158                 $tg->set_stemmer(PublicInbox::Search::stemmer($self));
 159                 $tg;
 160         }
 161 }
 162
 163 sub index_text ($$$$) {
 164         my ($self, $text, $wdf_inc, $prefix) = @_;
 165         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 166
 167         if ($self->{indexlevel} eq 'full') {
 168                 $tg->index_text($text, $wdf_inc, $prefix);
 169                 $tg->increase_termpos;
 170         } else {
 171                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 172         }
 173 }
 174
 175 sub index_headers ($$) {
 176         my ($self, $smsg) = @_;
 177         my @x = (from => 'A', # Author
 178                 subject => 'S', to => 'XTO', cc => 'XCC');
 179         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 180                 my $val = $smsg->{$field};
 181                 index_text($self, $val, 1, $pfx) if $val ne '';
 182         }
 183 }
 184
 185 sub index_diff_inc ($$$$) {
 186         my ($self, $text, $pfx, $xnq) = @_;
 187         if (@$xnq) {
 188                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 189                 @$xnq = ();
 190         }
 191         index_text($self, $text, 1, $pfx);
 192 }
 193
 194 sub index_old_diff_fn {
 195         my ($self, $seen, $fa, $fb, $xnq) = @_;
 196
 197         # no renames or space support for traditional diffs,
 198         # find the number of leading common paths to strip:
 199         my @fa = split('/', $fa);
 200         my @fb = split('/', $fb);
 201         while (scalar(@fa) && scalar(@fb)) {
 202                 $fa = join('/', @fa);
 203                 $fb = join('/', @fb);
 204                 if ($fa eq $fb) {
 205                         unless ($seen->{$fa}++) {
 206                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 207                         }
 208                         return 1;
 209                 }
 210                 shift @fa;
 211                 shift @fb;
 212         }
 213         0;
 214 }
 215
 216 sub index_diff ($$$) {
 217         my ($self, $txt, $doc) = @_;
 218         my %seen;
 219         my $in_diff;
 220         my @xnq;
 221         my $xnq = \@xnq;
 222         foreach (split(/\n/, $txt)) {
 223                 if ($in_diff && s/^ //) { # diff context
 224                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 225                 } elsif (/^-- $/) { # email signature begins
 226                         $in_diff = undef;
 227                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 228                         # wait until "---" and "+++" to capture filenames
 229                         $in_diff = 1;
 230                 # traditional diff:
 231                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 232                         my ($opt, $fa, $fb) = ($1, $2, $3);
 233                         push @xnq, $_;
 234                         # only support unified:
 235                         next unless $opt =~ /[uU]/;
 236                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 237                                                         $xnq);
 238                 } elsif (m!^--- ("?[^/]+/.+)!) {
 239                         my $fn = $1;
 240                         $fn = (split('/', git_unquote($fn), 2))[1];
 241                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 242                         $in_diff = 1;
 243                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 244                         my $fn = $1;
 245                         $fn = (split('/', git_unquote($fn), 2))[1];
 246                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 247                         $in_diff = 1;
 248                 } elsif (/^--- (\S+)/) {
 249                         $in_diff = $1;
 250                         push @xnq, $_;
 251                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 252                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 253                                                         $1, $xnq);
 254                 } elsif ($in_diff && s/^\+//) { # diff added
 255                         index_diff_inc($self, $_, 'XDFB', $xnq);
 256                 } elsif ($in_diff && s/^-//) { # diff removed
 257                         index_diff_inc($self, $_, 'XDFA', $xnq);
 258                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 259                         my ($ba, $bb) = ($1, $2);
 260                         index_git_blob_id($doc, 'XDFPRE', $ba);
 261                         index_git_blob_id($doc, 'XDFPOST', $bb);
 262                         $in_diff = 1;
 263                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 264                         # traditional diff w/o -p
 265                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 266                         # hunk header context
 267                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 268                 # ignore the following lines:
 269                 } elsif (/^(?:dis)similarity index/ ||
 270                                 /^(?:old|new) mode/ ||
 271                                 /^(?:deleted|new) file mode/ ||
 272                                 /^(?:copy|rename) (?:from|to) / ||
 273                                 /^(?:dis)?similarity index / ||
 274                                 /^\\ No newline at end of file/ ||
 275                                 /^Binary files .* differ/) {
 276                         push @xnq, $_;
 277                 } elsif ($_ eq '') {
 278                         # possible to be in diff context, some mail may be
 279                         # stripped by MUA or even GNU diff(1).  "git apply"
 280                         # treats a bare "\n" as diff context, too
 281                 } else {
 282                         push @xnq, $_;
 283                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 284                         $in_diff = undef;
 285                 }
 286         }
 287
 288         index_text($self, join("\n", @xnq), 1, 'XNQ');
 289 }
 290
 291 sub index_xapian { # msg_iter callback
 292         my $part = $_[0]->[0]; # ignore $depth and $idx
 293         my ($self, $doc) = @{$_[1]};
 294         my $ct = $part->content_type || 'text/plain';
 295         my $fn = $part->filename;
 296         if (defined $fn && $fn ne '') {
 297                 index_text($self, $fn, 1, 'XFN');
 298         }
 299         if ($part->{is_submsg}) {
 300                 my $mids = mids_for_index($part);
 301                 index_ids($self, $doc, $part, $mids);
 302                 my $smsg = bless {}, 'PublicInbox::Smsg';
 303                 $smsg->populate($part);
 304                 index_headers($self, $smsg);
 305         }
 306
 307         my ($s, undef) = msg_part_text($part, $ct);
 308         defined $s or return;
 309         $_[0]->[0] = $part = undef; # free memory
 310
 311         # split off quoted and unquoted blocks:
 312         my @sections = PublicInbox::MsgIter::split_quotes($s);
 313         undef $s; # free memory
 314         for my $txt (@sections) {
 315                 if ($txt =~ /\A>/) {
 316                         index_text($self, $txt, 0, 'XQUOT');
 317                 } else {
 318                         # does it look like a diff?
 319                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 320                                 index_diff($self, $txt, $doc);
 321                         } else {
 322                                 index_text($self, $txt, 1, 'XNQ');
 323                         }
 324                 }
 325                 undef $txt; # free memory
 326         }
 327 }
 328
 329 sub index_list_id ($$$) {
 330         my ($self, $doc, $hdr) = @_;
 331         for my $l ($hdr->header_raw('List-Id')) {
 332                 $l =~ /<([^>]+)>/ or next;
 333                 my $lid = lc $1;
 334                 $doc->add_boolean_term('G' . $lid);
 335                 index_text($self, $lid, 1, 'XL'); # probabilistic
 336         }
 337 }
 338
 339 sub index_ids ($$$$) {
 340         my ($self, $doc, $hdr, $mids) = @_;
 341         for my $mid (@$mids) {
 342                 index_text($self, $mid, 1, 'XM');
 343
 344                 # because too many Message-IDs are prefixed with
 345                 # "Pine.LNX."...
 346                 if ($mid =~ /\w{12,}/) {
 347                         my @long = ($mid =~ /(\w{3,}+)/g);
 348                         index_text($self, join(' ', @long), 1, 'XM');
 349                 }
 350         }
 351         $doc->add_boolean_term('Q' . $_) for @$mids;
 352         index_list_id($self, $doc, $hdr);
 353 }
 354
 355 sub eml2doc ($$$;$) {
 356         my ($self, $eml, $smsg, $mids) = @_;
 357         $mids //= mids_for_index($eml);
 358         my $doc = $X->{Document}->new;
 359         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 360         my @ds = gmtime($smsg->{ds});
 361         my $yyyymmdd = strftime('%Y%m%d', @ds);
 362         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 363         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 364         add_val($doc, PublicInbox::Search::DT(), $dt);
 365         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 366         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 367         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 368
 369         my $tg = term_generator($self);
 370         $tg->set_document($doc);
 371         index_headers($self, $smsg);
 372
 373         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 374                 $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 375         }
 376         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 377         index_ids($self, $doc, $eml, $mids);
 378
 379         # by default, we maintain compatibility with v1.5.0 and earlier
 380         # by writing to docdata.glass, users who never exect to downgrade can
 381         # use --skip-docdata
 382         if (!$self->{-skip_docdata}) {
 383                 # WWW doesn't need {to} or {cc}, only NNTP
 384                 $smsg->{to} = $smsg->{cc} = '';
 385                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 386                 my $data = $smsg->to_doc_data;
 387                 $doc->set_data($data);
 388         }
 389
 390         if (my $altid = $self->{-altid}) {
 391                 foreach my $alt (@$altid) {
 392                         my $pfx = $alt->{xprefix};
 393                         foreach my $mid (@$mids) {
 394                                 my $id = $alt->mid2alt($mid);
 395                                 next unless defined $id;
 396                                 $doc->add_boolean_term($pfx . $id);
 397                         }
 398                 }
 399         }
 400         $doc;
 401 }
 402
 403 sub add_xapian ($$$$) {
 404         my ($self, $eml, $smsg, $mids) = @_;
 405         my $doc = eml2doc($self, $eml, $smsg, $mids);
 406         $self->{xdb}->replace_document($smsg->{num}, $doc);
 407 }
 408
 409 sub _msgmap_init ($) {
 410         my ($self) = @_;
 411         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 412         $self->{mm} //= eval {
 413                 require PublicInbox::Msgmap;
 414                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 415                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 416         };
 417 }
 418
 419 sub add_message {
 420         # mime = PublicInbox::Eml or Email::MIME object
 421         my ($self, $mime, $smsg, $sync) = @_;
 422         my $mids = mids_for_index($mime);
 423         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 424         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 425         $smsg->{num} //= do { # v1
 426                 _msgmap_init($self);
 427                 index_mm($self, $mime, $smsg->{blob}, $sync);
 428         };
 429
 430         # v1 and tests only:
 431         $smsg->populate($mime, $sync);
 432         $smsg->{bytes} //= length($mime->as_string);
 433
 434         eval {
 435                 # order matters, overview stores every possible piece of
 436                 # data in doc_data (deflated).  Xapian only stores a subset
 437                 # of the fields which exist in over.sqlite3.  We may stop
 438                 # storing doc_data in Xapian sometime after we get multi-inbox
 439                 # search working.
 440                 if (my $oidx = $self->{oidx}) { # v1 only
 441                         $oidx->add_overview($mime, $smsg);
 442                 }
 443                 if (need_xapian($self)) {
 444                         add_xapian($self, $mime, $smsg, $mids);
 445                 }
 446         };
 447
 448         if ($@) {
 449                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 450                 return undef;
 451         }
 452         $smsg->{num};
 453 }
 454
 455 sub _get_doc ($$) {
 456         my ($self, $docid) = @_;
 457         my $doc = eval { $self->{xdb}->get_document($docid) };
 458         $doc // do {
 459                 warn "E: $@\n" if $@;
 460                 warn "E: #$docid missing in Xapian\n";
 461                 undef;
 462         }
 463 }
 464
 465 sub add_eidx_info {
 466         my ($self, $docid, $eidx_key, $eml) = @_;
 467         begin_txn_lazy($self);
 468         my $doc = _get_doc($self, $docid) or return;
 469         term_generator($self)->set_document($doc);
 470         $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 471         index_list_id($self, $doc, $eml);
 472         $self->{xdb}->replace_document($docid, $doc);
 473 }
 474
 475 sub remove_eidx_info {
 476         my ($self, $docid, $eidx_key, $eml) = @_;
 477         begin_txn_lazy($self);
 478         my $doc = _get_doc($self, $docid) or return;
 479         eval { $doc->remove_term('O'.$eidx_key) };
 480         warn "W: ->remove_term O$eidx_key: $@\n" if $@;
 481         for my $l ($eml ? $eml->header_raw('List-Id') : ()) {
 482                 $l =~ /<([^>]+)>/ or next;
 483                 my $lid = lc $1;
 484                 eval { $doc->remove_term('G' . $lid) };
 485                 warn "W: ->remove_term G$lid: $@\n" if $@;
 486
 487                 # nb: we don't remove the XL probabilistic terms
 488                 # since terms may overlap if cross-posted.
 489                 #
 490                 # IOW, a message which has both <foo.example.com>
 491                 # and <bar.example.com> would have overlapping
 492                 # "XLexample" and "XLcom" as terms and which we
 493                 # wouldn't know if they're safe to remove if we just
 494                 # unindex <foo.example.com> while preserving
 495                 # <bar.example.com>.
 496                 #
 497                 # In any case, this entire sub is will likely never
 498                 # be needed and users using the "l:" prefix are probably
 499                 # rarer.
 500         }
 501         $self->{xdb}->replace_document($docid, $doc);
 502 }
 503
 504 sub set_keywords {
 505         my ($self, $docid, @kw) = @_;
 506         begin_txn_lazy($self);
 507         my $doc = _get_doc($self, $docid) or return;
 508         my %keep = map { $_ => 1 } @kw;
 509         my %add = %keep;
 510         my @rm;
 511         my $end = $doc->termlist_end;
 512         for (my $cur = $doc->termlist_begin; $cur != $end; $cur++) {
 513                 $cur->skip_to('K');
 514                 last if $cur == $end;
 515                 my $kw = $cur->get_termname;
 516                 $kw =~ s/\AK//s or next;
 517                 $keep{$kw} ? delete($add{$kw}) : push(@rm, $kw);
 518         }
 519         return unless (scalar(@rm) + scalar(keys %add));
 520         $doc->remove_term('K'.$_) for @rm;
 521         $doc->add_boolean_term('K'.$_) for (keys %add);
 522         $self->{xdb}->replace_document($docid, $doc);
 523 }
 524
 525 sub add_keywords {
 526         my ($self, $docid, @kw) = @_;
 527         begin_txn_lazy($self);
 528         my $doc = _get_doc($self, $docid) or return;
 529         $doc->add_boolean_term('K'.$_) for @kw;
 530         $self->{xdb}->replace_document($docid, $doc);
 531 }
 532
 533 sub remove_keywords {
 534         my ($self, $docid, @kw) = @_;
 535         begin_txn_lazy($self);
 536         my $doc = _get_doc($self, $docid) or return;
 537         my $replace;
 538         eval {
 539                 $doc->remove_term('K'.$_);
 540                 $replace = 1
 541         } for @kw;
 542         $self->{xdb}->replace_document($docid, $doc) if $replace;
 543 }
 544
 545 sub get_val ($$) {
 546         my ($doc, $col) = @_;
 547         sortable_unserialise($doc->get_value($col));
 548 }
 549
 550 sub smsg_from_doc ($) {
 551         my ($doc) = @_;
 552         my $data = $doc->get_data or return;
 553         my $smsg = bless {}, 'PublicInbox::Smsg';
 554         $smsg->{ts} = get_val($doc, PublicInbox::Search::TS());
 555         my $dt = get_val($doc, PublicInbox::Search::DT());
 556         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
 557         $smsg->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
 558         $smsg->load_from_data($data);
 559         $smsg;
 560 }
 561
 562 sub xdb_remove {
 563         my ($self, @docids) = @_;
 564         my $xdb = $self->{xdb} or return;
 565         for my $docid (@docids) {
 566                 eval { $xdb->delete_document($docid) };
 567                 warn "E: #$docid not in in Xapian? $@\n" if $@;
 568         }
 569 }
 570
 571 sub remove_by_docid {
 572         my ($self, $num) = @_;
 573         die "BUG: remove_by_docid is v2-only\n" if $self->{oidx};
 574         $self->begin_txn_lazy;
 575         xdb_remove($self, $num) if need_xapian($self);
 576 }
 577
 578 sub index_git_blob_id {
 579         my ($doc, $pfx, $objid) = @_;
 580
 581         my $len = length($objid);
 582         for (my $len = length($objid); $len >= 7; ) {
 583                 $doc->add_term($pfx.$objid);
 584                 $objid = substr($objid, 0, --$len);
 585         }
 586 }
 587
 588 # v1 only
 589 sub unindex_eml {
 590         my ($self, $oid, $eml) = @_;
 591         my $mids = mids($eml);
 592         my $nr = 0;
 593         my %tmp;
 594         for my $mid (@$mids) {
 595                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 596                 $nr += scalar @removed;
 597                 $tmp{$_}++ for @removed;
 598         }
 599         if (!$nr) {
 600                 my $m = join('> <', @$mids);
 601                 warn "W: <$m> missing for removal from overview\n";
 602         }
 603         while (my ($num, $nr) = each %tmp) {
 604                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 605         }
 606         if ($nr) {
 607                 $self->{mm}->num_delete($_) for (keys %tmp);
 608         } else { # just in case msgmap and over.sqlite3 become desynched:
 609                 $self->{mm}->mid_delete($mids->[0]);
 610         }
 611         xdb_remove($self, keys %tmp) if need_xapian($self);
 612 }
 613
 614 sub index_mm {
 615         my ($self, $mime, $oid, $sync) = @_;
 616         my $mids = mids($mime);
 617         my $mm = $self->{mm};
 618         if ($sync->{reindex}) {
 619                 my $oidx = $self->{oidx};
 620                 for my $mid (@$mids) {
 621                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 622                         return $num if defined $num;
 623                 }
 624                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 625         } else {
 626                 # fallback to num_for since filters like RubyLang set the number
 627                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 628         }
 629 }
 630
 631 # returns the number of bytes to add if given a non-CRLF arg
 632 sub crlf_adjust ($) {
 633         if (index($_[0], "\r\n") < 0) {
 634                 # common case is LF-only, every \n needs an \r;
 635                 # so favor a cheap tr// over an expensive m//g
 636                 $_[0] =~ tr/\n/\n/;
 637         } else { # count number of '\n' w/o '\r', expensive:
 638                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 639         }
 640 }
 641
 642 sub is_bad_blob ($$$$) {
 643         my ($oid, $type, $size, $expect_oid) = @_;
 644         if ($type ne 'blob') {
 645                 carp "W: $expect_oid is not a blob (type=$type)";
 646                 return 1;
 647         }
 648         croak "BUG: $oid != $expect_oid" if $oid ne $expect_oid;
 649         $size == 0 ? 1 : 0; # size == 0 means purged
 650 }
 651
 652 sub index_both { # git->cat_async callback
 653         my ($bref, $oid, $type, $size, $sync) = @_;
 654         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 655         my ($nr, $max) = @$sync{qw(nr max)};
 656         ++$$nr;
 657         $$max -= $size;
 658         $size += crlf_adjust($$bref);
 659         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 660         my $self = $sync->{sidx};
 661         local $self->{current_info} = "$self->{current_info}: $oid";
 662         my $eml = PublicInbox::Eml->new($bref);
 663         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 664                 die "E: could not generate NNTP article number for $oid";
 665         add_message($self, $eml, $smsg, $sync);
 666         my $cur_cmt = $sync->{cur_cmt} // die 'BUG: {cur_cmt} missing';
 667         ${$sync->{latest_cmt}} = $cur_cmt;
 668 }
 669
 670 sub unindex_both { # git->cat_async callback
 671         my ($bref, $oid, $type, $size, $sync) = @_;
 672         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 673         my $self = $sync->{sidx};
 674         local $self->{current_info} = "$self->{current_info}: $oid";
 675         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 676         # may be undef if leftover
 677         if (defined(my $cur_cmt = $sync->{cur_cmt})) {
 678                 ${$sync->{latest_cmt}} = $cur_cmt;
 679         }
 680 }
 681
 682 sub with_umask {
 683         my $self = shift;
 684         ($self->{ibx} // $self->{eidx})->with_umask(@_);
 685 }
 686
 687 # called by public-inbox-index
 688 sub index_sync {
 689         my ($self, $opt) = @_;
 690         delete $self->{lock_path} if $opt->{-skip_lock};
 691         $self->with_umask(\&_index_sync, $self, $opt);
 692         if ($opt->{reindex} && !$opt->{quit}) {
 693                 my %again = %$opt;
 694                 delete @again{qw(rethread reindex)};
 695                 index_sync($self, \%again);
 696                 $opt->{quit} = $again{quit}; # propagate to caller
 697         }
 698 }
 699
 700 sub check_size { # check_async cb for -index --max-size=...
 701         my ($oid, $type, $size, $arg, $git) = @_;
 702         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 703         if ($size <= $arg->{max_size}) {
 704                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 705         } else {
 706                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 707         }
 708 }
 709
 710 sub v1_checkpoint ($$;$) {
 711         my ($self, $sync, $stk) = @_;
 712         $self->{ibx}->git->async_wait_all;
 713
 714         # $newest may be undef
 715         my $newest = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 716         if (defined($newest)) {
 717                 my $cur = $self->{mm}->last_commit || '';
 718                 if (need_update($self, $cur, $newest)) {
 719                         $self->{mm}->last_commit($newest);
 720                 }
 721         }
 722         ${$sync->{max}} = $self->{batch_bytes};
 723
 724         $self->{mm}->{dbh}->commit;
 725         my $xdb = need_xapian($self) ? $self->{xdb} : undef;
 726         if ($newest && $xdb) {
 727                 my $cur = $xdb->get_metadata('last_commit');
 728                 if (need_update($self, $cur, $newest)) {
 729                         $xdb->set_metadata('last_commit', $newest);
 730                 }
 731         }
 732         if ($stk) { # all done if $stk is passed
 733                 # let SearchView know a full --reindex was done so it can
 734                 # generate ->has_threadid-dependent links
 735                 if ($xdb && $sync->{reindex} && !ref($sync->{reindex})) {
 736                         my $n = $xdb->get_metadata('has_threadid');
 737                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 738                 }
 739                 $self->{oidx}->rethread_done($sync->{-opt}); # all done
 740         }
 741         commit_txn_lazy($self);
 742         $sync->{ibx}->git->cleanup;
 743         my $nr = ${$sync->{nr}};
 744         idx_release($self, $nr);
 745         # let another process do some work...
 746         if (my $pr = $sync->{-opt}->{-progress}) {
 747                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 748         }
 749         if (!$stk && !$sync->{quit}) { # more to come
 750                 begin_txn_lazy($self);
 751                 $self->{mm}->{dbh}->begin_work;
 752         }
 753 }
 754
 755 # only for v1
 756 sub process_stack {
 757         my ($self, $sync, $stk) = @_;
 758         my $git = $sync->{ibx}->git;
 759         my $max = $self->{batch_bytes};
 760         my $nr = 0;
 761         $sync->{nr} = \$nr;
 762         $sync->{max} = \$max;
 763         $sync->{sidx} = $self;
 764         $sync->{latest_cmt} = \(my $latest_cmt);
 765
 766         $self->{mm}->{dbh}->begin_work;
 767         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 768                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 769                 for my $oid (@leftovers) {
 770                         last if $sync->{quit};
 771                         $oid = unpack('H*', $oid);
 772                         $git->cat_async($oid, \&unindex_both, $sync);
 773                 }
 774         }
 775         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 776                 $sync->{index_oid} = \&index_both;
 777         }
 778         while (my ($f, $at, $ct, $oid, $cur_cmt) = $stk->pop_rec) {
 779                 my $arg = { %$sync, cur_cmt => $cur_cmt, oid => $oid };
 780                 last if $sync->{quit};
 781                 if ($f eq 'm') {
 782                         $arg->{autime} = $at;
 783                         $arg->{cotime} = $ct;
 784                         if ($sync->{max_size}) {
 785                                 $git->check_async($oid, \&check_size, $arg);
 786                         } else {
 787                                 $git->cat_async($oid, \&index_both, $arg);
 788                         }
 789                         v1_checkpoint($self, $sync) if $max <= 0;
 790                 } elsif ($f eq 'd') {
 791                         $git->cat_async($oid, \&unindex_both, $arg);
 792                 }
 793         }
 794         v1_checkpoint($self, $sync, $sync->{quit} ? undef : $stk);
 795 }
 796
 797 sub log2stack ($$$) {
 798         my ($sync, $git, $range) = @_;
 799         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 800         my ($add, $del);
 801         if ($sync->{ibx}->version == 1) {
 802                 my $path = $hex.'{2}/'.$hex.'{38}';
 803                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 804                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 805         } else {
 806                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 807                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 808         }
 809
 810         # Count the new files so they can be added newest to oldest
 811         # and still have numbers increasing from oldest to newest
 812         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 813                                 --no-notes --no-color --no-renames --no-abbrev),
 814                                 $range);
 815         my ($at, $ct, $stk, $cmt);
 816         while (<$fh>) {
 817                 return if $sync->{quit};
 818                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 819                         ($at, $ct, $cmt) = ($1 + 0, $2 + 0, $3);
 820                         $stk //= PublicInbox::IdxStack->new($cmt);
 821                 } elsif (/$del/) {
 822                         my $oid = $1;
 823                         if ($D) { # reindex case
 824                                 $D->{pack('H*', $oid)}++;
 825                         } else { # non-reindex case:
 826                                 $stk->push_rec('d', $at, $ct, $oid, $cmt);
 827                         }
 828                 } elsif (/$add/) {
 829                         my $oid = $1;
 830                         if ($D) {
 831                                 my $oid_bin = pack('H*', $oid);
 832                                 my $nr = --$D->{$oid_bin};
 833                                 delete($D->{$oid_bin}) if $nr <= 0;
 834                                 # nr < 0 (-1) means it never existed
 835                                 next if $nr >= 0;
 836                         }
 837                         $stk->push_rec('m', $at, $ct, $oid, $cmt);
 838                 }
 839         }
 840         close $fh or die "git log failed: \$?=$?";
 841         $stk //= PublicInbox::IdxStack->new;
 842         $stk->read_prepare;
 843 }
 844
 845 sub prepare_stack ($$) {
 846         my ($sync, $range) = @_;
 847         my $git = $sync->{ibx}->git;
 848
 849         if (index($range, '..') < 0) {
 850                 # don't show annoying git errors to users who run -index
 851                 # on empty inboxes
 852                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 853                 return PublicInbox::IdxStack->new->read_prepare if $?;
 854         }
 855         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 856         log2stack($sync, $git, $range);
 857 }
 858
 859 # --is-ancestor requires git 1.8.0+
 860 sub is_ancestor ($$$) {
 861         my ($git, $cur, $tip) = @_;
 862         return 0 unless $git->check($cur);
 863         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 864                 qw(merge-base --is-ancestor), $cur, $tip ];
 865         my $pid = spawn($cmd);
 866         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 867         $? == 0;
 868 }
 869
 870 sub need_update ($$$) {
 871         my ($self, $cur, $new) = @_;
 872         my $git = $self->{ibx}->git;
 873         return 1 if $cur && !is_ancestor($git, $cur, $new);
 874         my $range = $cur eq '' ? $new : "$cur..$new";
 875         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 876         ($n eq '' || $n > 0);
 877 }
 878
 879 # The last git commit we indexed with Xapian or SQLite (msgmap)
 880 # This needs to account for cases where Xapian or SQLite is
 881 # out-of-date with respect to the other.
 882 sub _last_x_commit {
 883         my ($self, $mm) = @_;
 884         my $lm = $mm->last_commit || '';
 885         my $lx = '';
 886         if (need_xapian($self)) {
 887                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 888         } else {
 889                 $lx = $lm;
 890         }
 891         # Use last_commit from msgmap if it is older or unset
 892         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 893                 $lx = $lm;
 894         }
 895         $lx;
 896 }
 897
 898 sub reindex_from ($$) {
 899         my ($reindex, $last_commit) = @_;
 900         return $last_commit unless $reindex;
 901         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 902 }
 903
 904 sub quit_cb ($) {
 905         my ($sync) = @_;
 906         sub {
 907                 # we set {-opt}->{quit} too, so ->index_sync callers
 908                 # can abort multi-inbox loops this way
 909                 $sync->{quit} = $sync->{-opt}->{quit} = 1;
 910                 warn "gracefully quitting\n";
 911         }
 912 }
 913
 914 # indexes all unindexed messages (v1 only)
 915 sub _index_sync {
 916         my ($self, $opt) = @_;
 917         my $tip = $opt->{ref} || 'HEAD';
 918         my $ibx = $self->{ibx};
 919         local $self->{current_info} = "$ibx->{inboxdir}";
 920         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 921         $ibx->git->batch_prepare;
 922         my $pr = $opt->{-progress};
 923         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
 924         my $quit = quit_cb($sync);
 925         local $SIG{QUIT} = $quit;
 926         local $SIG{INT} = $quit;
 927         local $SIG{TERM} = $quit;
 928         my $xdb = $self->begin_txn_lazy;
 929         $self->{oidx}->rethread_prepare($opt);
 930         my $mm = _msgmap_init($self);
 931         if ($sync->{reindex}) {
 932                 my $last = $mm->last_commit;
 933                 if ($last) {
 934                         $tip = $last;
 935                 } else {
 936                         # somebody just blindly added --reindex when indexing
 937                         # for the first time, allow it:
 938                         undef $sync->{reindex};
 939                 }
 940         }
 941         my $last_commit = _last_x_commit($self, $mm);
 942         my $lx = reindex_from($sync->{reindex}, $last_commit);
 943         my $range = $lx eq '' ? $tip : "$lx..$tip";
 944         $pr->("counting changes\n\t$range ... ") if $pr;
 945         my $stk = prepare_stack($sync, $range);
 946         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 947         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 948         process_stack($self, $sync, $stk) if !$sync->{quit};
 949 }
 950
 951 sub DESTROY {
 952         # order matters for unlocking
 953         $_[0]->{xdb} = undef;
 954         $_[0]->{lockfh} = undef;
 955 }
 956
 957 sub _begin_txn {
 958         my ($self) = @_;
 959         my $xdb = $self->{xdb} || idx_acquire($self);
 960         $self->{oidx}->begin_lazy if $self->{oidx};
 961         $xdb->begin_transaction if $xdb;
 962         $self->{txn} = 1;
 963         $xdb;
 964 }
 965
 966 sub begin_txn_lazy {
 967         my ($self) = @_;
 968         $self->with_umask(\&_begin_txn, $self) if !$self->{txn};
 969 }
 970
 971 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 972 # This metadata is read by Admin::detect_indexlevel:
 973 sub set_metadata_once {
 974         my ($self) = @_;
 975
 976         return if $self->{shard}; # only continue if undef or 0, not >0
 977         my $xdb = $self->{xdb};
 978
 979         if (delete($self->{-set_has_threadid_once})) {
 980                 $xdb->set_metadata('has_threadid', '1');
 981         }
 982         if (delete($self->{-set_indexlevel_once})) {
 983                 my $level = $xdb->get_metadata('indexlevel');
 984                 if (!$level || $level ne 'medium') {
 985                         $xdb->set_metadata('indexlevel', 'medium');
 986                 }
 987         }
 988         if (delete($self->{-set_skip_docdata_once})) {
 989                 $xdb->get_metadata('skip_docdata') or
 990                         $xdb->set_metadata('skip_docdata', '1');
 991         }
 992 }
 993
 994 sub _commit_txn {
 995         my ($self) = @_;
 996         if (my $eidx = $self->{eidx}) {
 997                 $eidx->git->async_wait_all;
 998                 $eidx->{transact_bytes} = 0;
 999         }
1000         if (my $xdb = $self->{xdb}) {
1001                 set_metadata_once($self);
1002                 $xdb->commit_transaction;
1003         }
1004         $self->{oidx}->commit_lazy if $self->{oidx};
1005 }
1006
1007 sub commit_txn_lazy {
1008         my ($self) = @_;
1009         delete($self->{txn}) and
1010                 $self->with_umask(\&_commit_txn, $self);
1011 }
1012
1013 sub worker_done {
1014         my ($self) = @_;
1015         if (need_xapian($self)) {
1016                 die "$$ $0 xdb not released\n" if $self->{xdb};
1017         }
1018         die "$$ $0 still in transaction\n" if $self->{txn};
1019 }
1020
1021 sub eidx_shard_new {
1022         my ($class, $eidx, $shard) = @_;
1023         my $self = bless {
1024                 eidx => $eidx,
1025                 xpfx => $eidx->{xpfx},
1026                 indexlevel => $eidx->{indexlevel},
1027                 -skip_docdata => 1,
1028                 shard => $shard,
1029                 creat => 1,
1030         }, $class;
1031         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
1032         $self;
1033 }
1034
1035 # ensure there's no stale Xapian docs by treating $over as canonical
1036 sub over_check {
1037         my ($self, $over) = @_;
1038         begin_txn_lazy($self);
1039         my $sth = $over->dbh->prepare(<<'');
1040 SELECT COUNT(*) FROM over WHERE num = ?
1041
1042         my $xdb = $self->{xdb};
1043         my $cur = $xdb->postlist_begin('');
1044         my $end = $xdb->postlist_end('');
1045         my $xdir = $self->xdir;
1046         for (; $cur != $end; $cur++) {
1047                 my $docid = $cur->get_docid;
1048                 $sth->execute($docid);
1049                 my $x = $sth->fetchrow_array;
1050                 next if $x > 0;
1051                 warn "I: removing $xdir #$docid, not in `over'\n";
1052                 $xdb->delete_document($docid);
1053         }
1054 }
1055
1056 1;