lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchIdx;
   5 use strict;
   6 use warnings;
   7 use base qw(PublicInbox::Search);
   8 use PublicInbox::MID qw/mid_clean mid_compress/;
   9 *xpfx = *PublicInbox::Search::xpfx;
  10
  11 use constant {
  12         PERM_UMASK => 0,
  13         OLD_PERM_GROUP => 1,
  14         OLD_PERM_EVERYBODY => 2,
  15         PERM_GROUP => 0660,
  16         PERM_EVERYBODY => 0664,
  17 };
  18
  19 sub new {
  20         my ($class, $git_dir, $writable) = @_;
  21         my $dir = $class->xdir($git_dir);
  22         require Search::Xapian::WritableDatabase;
  23         my $flag = Search::Xapian::DB_OPEN;
  24         my $self = bless { git_dir => $git_dir }, $class;
  25         my $perm = $self->_git_config_perm;
  26         my $umask = _umask_for($perm);
  27         $self->{umask} = $umask;
  28         $self->{xdb} = $self->with_umask(sub {
  29                 if ($writable == 1) {
  30                         require File::Path;
  31                         File::Path::mkpath($dir);
  32                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  33                 }
  34                 Search::Xapian::WritableDatabase->new($dir, $flag);
  35         });
  36         $self;
  37 }
  38
  39 sub add_message {
  40         my ($self, $mime) = @_; # mime = Email::MIME object
  41         my $db = $self->{xdb};
  42
  43         my $doc_id;
  44         my $mid_orig = mid_clean($mime->header('Message-ID'));
  45         my $mid = mid_compress($mid_orig);
  46         my $was_ghost = 0;
  47         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  48
  49         eval {
  50                 my $smsg = $self->lookup_message($mid);
  51                 my $doc;
  52
  53                 if ($smsg) {
  54                         $smsg->ensure_metadata;
  55                         # convert a ghost to a regular message
  56                         # it will also clobber any existing regular message
  57                         $smsg->mime($mime);
  58                         $doc = $smsg->{doc};
  59
  60                         my $type = xpfx('type');
  61                         eval {
  62                                 $doc->remove_term($type . 'ghost');
  63                                 $was_ghost = 1;
  64                         };
  65
  66                         # probably does not exist:
  67                         eval { $doc->remove_term($type . 'mail') };
  68                         $doc->add_term($type . 'mail');
  69                 }  else {
  70                         $smsg = PublicInbox::SearchMsg->new($mime);
  71                         $doc = $smsg->{doc};
  72                         $doc->add_term(xpfx('mid') . $mid);
  73                 }
  74
  75                 my $subj = $smsg->subject;
  76
  77                 if ($subj ne '') {
  78                         $doc->add_term(xpfx('subject') . $subj);
  79
  80                         my $path = $self->subject_path($subj);
  81                         $doc->add_term(xpfx('path') . mid_compress($path));
  82                 }
  83
  84                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
  85                 $doc->add_value(PublicInbox::Search::TS, $ts);
  86
  87                 my $tg = $self->term_generator;
  88
  89                 $tg->set_document($doc);
  90                 $tg->index_text($subj, 1, 'S') if $subj;
  91                 $tg->increase_termpos;
  92                 $tg->index_text($subj) if $subj;
  93                 $tg->increase_termpos;
  94
  95                 $tg->index_text($smsg->from->format);
  96                 $tg->increase_termpos;
  97
  98                 $mime->walk_parts(sub {
  99                         my ($part) = @_;
 100                         return if $part->subparts; # walk_parts already recurses
 101                         my $ct = $part->content_type || $ct_msg;
 102
 103                         # account for filter bugs...
 104                         $ct =~ m!\btext/plain\b!i or return;
 105
 106                         my (@orig, @quot);
 107                         my $body = $part->body;
 108                         $part->body_set('');
 109                         my @lines = split(/\n/, $body);
 110                         while (defined(my $l = shift @lines)) {
 111                                 if ($l =~ /^\s*>/) {
 112                                         push @quot, $l;
 113                                 } else {
 114                                         push @orig, $l;
 115                                 }
 116                         }
 117                         if (@quot) {
 118                                 $tg->index_text(join("\n", @quot), 0);
 119                                 @quot = ();
 120                                 $tg->increase_termpos;
 121                         }
 122                         if (@orig) {
 123                                 $tg->index_text(join("\n", @orig));
 124                                 @orig = ();
 125                                 $tg->increase_termpos;
 126                         }
 127                 });
 128
 129                 if ($was_ghost) {
 130                         $doc_id = $smsg->doc_id;
 131                         $self->link_message($smsg, 0);
 132                         $doc->set_data($smsg->to_doc_data);
 133                         $db->replace_document($doc_id, $doc);
 134                 } else {
 135                         $self->link_message($smsg, 0);
 136                         $doc->set_data($smsg->to_doc_data);
 137                         $doc_id = $db->add_document($doc);
 138                 }
 139         };
 140
 141         if ($@) {
 142                 warn "failed to index message <$mid_orig>: $@\n";
 143                 return undef;
 144         }
 145         $doc_id;
 146 }
 147
 148 # returns deleted doc_id on success, undef on missing
 149 sub remove_message {
 150         my ($self, $mid_orig) = @_;
 151         my $db = $self->{xdb};
 152         my $doc_id;
 153         $mid_orig = mid_clean($mid_orig);
 154         my $mid = mid_compress($mid_orig);
 155
 156         eval {
 157                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 158                 $db->delete_document($doc_id) if defined $doc_id;
 159         };
 160
 161         if ($@) {
 162                 warn "failed to remove message <$mid_orig>: $@\n";
 163                 return undef;
 164         }
 165         $doc_id;
 166 }
 167
 168 sub term_generator { # write-only
 169         my ($self) = @_;
 170
 171         my $tg = $self->{term_generator};
 172         return $tg if $tg;
 173
 174         $tg = Search::Xapian::TermGenerator->new;
 175         $tg->set_stemmer($self->stemmer);
 176
 177         $self->{term_generator} = $tg;
 178 }
 179
 180 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 181
 182 # increments last_thread_id counter
 183 # returns a 64-bit integer represented as a hex string
 184 sub next_thread_id {
 185         my ($self) = @_;
 186         my $db = $self->{xdb};
 187         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 188
 189         $db->set_metadata('last_thread_id', ++$last_thread_id);
 190
 191         $last_thread_id;
 192 }
 193
 194 sub link_message {
 195         my ($self, $smsg, $is_ghost) = @_;
 196
 197         if ($is_ghost) {
 198                 $smsg->ensure_metadata;
 199         } else {
 200                 $self->link_message_to_parents($smsg);
 201         }
 202 }
 203
 204 sub link_message_to_parents {
 205         my ($self, $smsg) = @_;
 206         my $doc = $smsg->{doc};
 207         my $mid = mid_compress($smsg->mid);
 208         my $mime = $smsg->mime;
 209         my $refs = $mime->header('References');
 210         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 211         my $irt = $mime->header('In-Reply-To');
 212         if ($irt) {
 213                 $irt = mid_compress(mid_clean($irt));
 214
 215                 # maybe some crazies will try to make a circular reference:
 216                 if ($irt eq $mid) {
 217                         $irt = undef;
 218                 } else {
 219                         # last References should be $irt
 220                         # we will de-dupe later
 221                         push @refs, $irt;
 222                 }
 223         }
 224
 225         my $tid;
 226         if (@refs) {
 227                 my @crefs = map { mid_compress($_) } @refs;
 228                 my %uniq = ($mid => 1);
 229
 230                 # prevent circular references via References: here:
 231                 @refs = ();
 232                 foreach my $ref (@crefs) {
 233                         next if $uniq{$ref};
 234                         $uniq{$ref} = 1;
 235                         push @refs, $ref;
 236                 }
 237         }
 238         if (@refs) {
 239                 $smsg->{references_sorted} = '<'.join('><', @refs).'>';
 240
 241                 # first ref *should* be the thread root,
 242                 # but we can never trust clients to do the right thing
 243                 my $ref = shift @refs;
 244                 $tid = $self->_resolve_mid_to_tid($ref);
 245
 246                 # the rest of the refs should point to this tid:
 247                 foreach $ref (@refs) {
 248                         my $ptid = $self->_resolve_mid_to_tid($ref);
 249                         if ($tid ne $ptid) {
 250                                 $self->merge_threads($tid, $ptid);
 251                         }
 252                 }
 253         } else {
 254                 $tid = $self->next_thread_id;
 255         }
 256         $doc->add_term(xpfx('thread') . $tid);
 257 }
 258
 259 sub index_blob {
 260         my ($self, $git, $blob) = @_;
 261         my $mime = do_cat_mail($git, $blob) or return;
 262         eval { $self->add_message($mime) };
 263         warn "W: index_blob $blob: $@\n" if $@;
 264 }
 265
 266 sub unindex_blob {
 267         my ($self, $git, $blob) = @_;
 268         my $mime = do_cat_mail($git, $blob) or return;
 269         my $mid = $mime->header('Message-ID');
 270         eval { $self->remove_message($mid) } if defined $mid;
 271         warn "W: unindex_blob $blob: $@\n" if $@;
 272 }
 273
 274 sub do_cat_mail {
 275         my ($git, $blob) = @_;
 276         my $mime = eval {
 277                 my $str = $git->cat_file($blob);
 278                 Email::MIME->new($str);
 279         };
 280         $@ ? undef : $mime;
 281 }
 282
 283 sub index_sync {
 284         my ($self, $head) = @_;
 285         $self->with_umask(sub { $self->_index_sync($head) });
 286 }
 287
 288 # indexes all unindexed messages
 289 sub _index_sync {
 290         my ($self, $head) = @_;
 291         require PublicInbox::GitCatFile;
 292         my $db = $self->{xdb};
 293         my $hex = '[a-f0-9]';
 294         my $h40 = $hex .'{40}';
 295         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 296         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 297         $head ||= 'HEAD';
 298
 299         $db->begin_transaction;
 300         eval {
 301                 my $git = PublicInbox::GitCatFile->new($self->{git_dir});
 302
 303                 my $latest = $db->get_metadata('last_commit');
 304                 my $range = $latest eq '' ? $head : "$latest..$head";
 305                 $latest = undef;
 306
 307                 # get indexed messages
 308                 my @cmd = ('git', "--git-dir=$self->{git_dir}", "log",
 309                             qw/--reverse --no-notes --no-color --raw -r
 310                                --no-abbrev/, $range);
 311                 my $pid = open(my $log, '-|', @cmd) or
 312                         die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 313
 314                 while (my $line = <$log>) {
 315                         if ($line =~ /$addmsg/o) {
 316                                 $self->index_blob($git, $1);
 317                         } elsif ($line =~ /$delmsg/o) {
 318                                 $self->unindex_blob($git, $1);
 319                         } elsif ($line =~ /^commit ($h40)/o) {
 320                                 $latest = $1;
 321                         }
 322                 }
 323                 close $log;
 324                 $db->set_metadata('last_commit', $latest) if defined $latest;
 325         };
 326         if ($@) {
 327                 warn "indexing failed: $@\n";
 328                 $db->cancel_transaction;
 329         } else {
 330                 $db->commit_transaction;
 331         }
 332 }
 333
 334 # this will create a ghost as necessary
 335 sub _resolve_mid_to_tid {
 336         my ($self, $mid) = @_;
 337
 338         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 339         $smsg->thread_id;
 340 }
 341
 342 sub create_ghost {
 343         my ($self, $mid, $tid) = @_;
 344
 345         $mid = mid_compress($mid);
 346         $tid = $self->next_thread_id unless defined $tid;
 347
 348         my $doc = Search::Xapian::Document->new;
 349         $doc->add_term(xpfx('mid') . $mid);
 350         $doc->add_term(xpfx('thread') . $tid);
 351         $doc->add_term(xpfx('type') . 'ghost');
 352
 353         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 354         $self->link_message($smsg, 1);
 355         $self->{xdb}->add_document($doc);
 356
 357         $smsg;
 358 }
 359
 360 sub merge_threads {
 361         my ($self, $winner_tid, $loser_tid) = @_;
 362         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 363         my $thread_pfx = xpfx('thread');
 364         my $db = $self->{xdb};
 365
 366         for (; $head != $tail; $head->inc) {
 367                 my $docid = $head->get_docid;
 368                 my $doc = $db->get_document($docid);
 369                 $doc->remove_term($thread_pfx . $loser_tid);
 370                 $doc->add_term($thread_pfx . $winner_tid);
 371                 $db->replace_document($docid, $doc);
 372         }
 373 }
 374
 375 sub _read_git_config_perm {
 376         my ($self) = @_;
 377         my @cmd = ('git', "--git-dir=$self->{git_dir}",
 378                    qw(config core.sharedRepository));
 379         my $pid = open(my $fh, '-|', @cmd) or
 380                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 381         my $perm = <$fh>;
 382         close $fh;
 383         chomp $perm if defined $perm;
 384         $perm;
 385 }
 386
 387 sub _git_config_perm {
 388         my $self = shift;
 389         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 390         return PERM_GROUP if (!defined($perm) || $perm eq '');
 391         return PERM_UMASK if ($perm eq 'umask');
 392         return PERM_GROUP if ($perm eq 'group');
 393         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 394                 return PERM_EVERYBODY;
 395         }
 396         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 397         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 398
 399         my $i = oct($perm);
 400         return PERM_UMASK if ($i == PERM_UMASK);
 401         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 402         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 403
 404         if (($i & 0600) != 0600) {
 405                 die "core.sharedRepository mode invalid: ".
 406                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 407         }
 408         ($i & 0666);
 409 }
 410
 411 sub _umask_for {
 412         my ($perm) = @_; # _git_config_perm return value
 413         my $rv = $perm;
 414         return umask if $rv == 0;
 415
 416         # set +x bit if +r or +w were set
 417         $rv |= 0100 if ($rv & 0600);
 418         $rv |= 0010 if ($rv & 0060);
 419         $rv |= 0001 if ($rv & 0006);
 420         (~$rv & 0777);
 421 }
 422
 423 sub with_umask {
 424         my ($self, $cb) = @_;
 425         my $old = umask $self->{umask};
 426         my $rv = eval { $cb->() };
 427         my $err = $@;
 428         umask $old;
 429         die $err if $@;
 430         $rv;
 431 }
 432
 433 1;