lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by Mail::Thread.  This writes to the search
   8 # index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Email::MIME;
  13 use Email::MIME::ContentType;
  14 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  15 use base qw(PublicInbox::Search);
  16 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  17 use PublicInbox::MsgIter;
  18 require PublicInbox::Git;
  19 *xpfx = *PublicInbox::Search::xpfx;
  20
  21 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  22 use constant {
  23         PERM_UMASK => 0,
  24         OLD_PERM_GROUP => 1,
  25         OLD_PERM_EVERYBODY => 2,
  26         PERM_GROUP => 0660,
  27         PERM_EVERYBODY => 0664,
  28 };
  29
  30 sub new {
  31         my ($class, $git_dir, $writable) = @_;
  32         my $dir = $class->xdir($git_dir);
  33         require Search::Xapian::WritableDatabase;
  34         my $flag = Search::Xapian::DB_OPEN;
  35         my $self = bless { git_dir => $git_dir }, $class;
  36         my $perm = $self->_git_config_perm;
  37         my $umask = _umask_for($perm);
  38         $self->{umask} = $umask;
  39         $self->{xdb} = $self->with_umask(sub {
  40                 if ($writable == 1) {
  41                         require File::Path;
  42                         File::Path::mkpath($dir);
  43                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  44                 }
  45                 Search::Xapian::WritableDatabase->new($dir, $flag);
  46         });
  47         $self;
  48 }
  49
  50 sub add_val {
  51         my ($doc, $col, $num) = @_;
  52         $num = Search::Xapian::sortable_serialise($num);
  53         $doc->add_value($col, $num);
  54 }
  55
  56 sub add_message {
  57         my ($self, $mime, $bytes, $num) = @_; # mime = Email::MIME object
  58         my $db = $self->{xdb};
  59
  60         my $doc_id;
  61         my $mid = mid_clean(mid_mime($mime));
  62         my $was_ghost = 0;
  63         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  64
  65         eval {
  66                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
  67                 my $smsg = $self->lookup_message($mid);
  68                 my $doc;
  69
  70                 if ($smsg) {
  71                         $smsg->ensure_metadata;
  72                         # convert a ghost to a regular message
  73                         # it will also clobber any existing regular message
  74                         $smsg->mime($mime);
  75                         $doc = $smsg->{doc};
  76
  77                         my $type = xpfx('type');
  78                         eval {
  79                                 $doc->remove_term($type . 'ghost');
  80                                 $was_ghost = 1;
  81                         };
  82
  83                         # probably does not exist:
  84                         eval { $doc->remove_term($type . 'mail') };
  85                         $doc->add_term($type . 'mail');
  86                 }  else {
  87                         $smsg = PublicInbox::SearchMsg->new($mime);
  88                         $doc = $smsg->{doc};
  89                         $doc->add_term(xpfx('mid') . $mid);
  90                 }
  91
  92                 my $subj = $smsg->subject;
  93
  94                 if ($subj ne '') {
  95                         my $path = $self->subject_path($subj);
  96                         $doc->add_term(xpfx('path') . id_compress($path));
  97                 }
  98
  99                 add_val($doc, &PublicInbox::Search::TS, $smsg->ts);
 100
 101                 defined($num) and
 102                         add_val($doc, &PublicInbox::Search::NUM, $num);
 103
 104                 defined($bytes) and
 105                         add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 106
 107                 add_val($doc, &PublicInbox::Search::LINES,
 108                                 $mime->body_raw =~ tr!\n!\n!);
 109
 110                 my $tg = $self->term_generator;
 111
 112                 $tg->set_document($doc);
 113                 $tg->index_text($subj, 1, 'S') if $subj;
 114                 $tg->increase_termpos;
 115                 $tg->index_text($subj) if $subj;
 116                 $tg->increase_termpos;
 117
 118                 $tg->index_text($smsg->from);
 119                 $tg->increase_termpos;
 120
 121                 msg_iter($mime, sub {
 122                         my ($part, $depth, @idx) = @{$_[0]};
 123                         my $ct = $part->content_type || $ct_msg;
 124
 125                         # account for filter bugs...
 126                         $ct =~ m!\btext/plain\b!i or return;
 127
 128                         my (@orig, @quot);
 129                         my $body = $part->body;
 130                         $part->body_set('');
 131                         my @lines = split(/\n/, $body);
 132                         while (defined(my $l = shift @lines)) {
 133                                 if ($l =~ /^\s*>/) {
 134                                         push @quot, $l;
 135                                 } else {
 136                                         push @orig, $l;
 137                                 }
 138                         }
 139                         if (@quot) {
 140                                 $tg->index_text(join("\n", @quot), 0);
 141                                 @quot = ();
 142                                 $tg->increase_termpos;
 143                         }
 144                         if (@orig) {
 145                                 $tg->index_text(join("\n", @orig));
 146                                 @orig = ();
 147                                 $tg->increase_termpos;
 148                         }
 149                 });
 150
 151                 if ($was_ghost) {
 152                         $doc_id = $smsg->doc_id;
 153                         $self->link_message($smsg, $smsg->thread_id);
 154                         $doc->set_data($smsg->to_doc_data);
 155                         $db->replace_document($doc_id, $doc);
 156                 } else {
 157                         $self->link_message($smsg);
 158                         $doc->set_data($smsg->to_doc_data);
 159                         $doc_id = $db->add_document($doc);
 160                 }
 161         };
 162
 163         if ($@) {
 164                 warn "failed to index message <$mid>: $@\n";
 165                 return undef;
 166         }
 167         $doc_id;
 168 }
 169
 170 # returns deleted doc_id on success, undef on missing
 171 sub remove_message {
 172         my ($self, $mid) = @_;
 173         my $db = $self->{xdb};
 174         my $doc_id;
 175         $mid = mid_clean($mid);
 176
 177         eval {
 178                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 179                 $db->delete_document($doc_id) if defined $doc_id;
 180         };
 181
 182         if ($@) {
 183                 warn "failed to remove message <$mid>: $@\n";
 184                 return undef;
 185         }
 186         $doc_id;
 187 }
 188
 189 sub term_generator { # write-only
 190         my ($self) = @_;
 191
 192         my $tg = $self->{term_generator};
 193         return $tg if $tg;
 194
 195         $tg = Search::Xapian::TermGenerator->new;
 196         $tg->set_stemmer($self->stemmer);
 197
 198         $self->{term_generator} = $tg;
 199 }
 200
 201 # increments last_thread_id counter
 202 # returns a 64-bit integer represented as a hex string
 203 sub next_thread_id {
 204         my ($self) = @_;
 205         my $db = $self->{xdb};
 206         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 207
 208         $db->set_metadata('last_thread_id', ++$last_thread_id);
 209
 210         $last_thread_id;
 211 }
 212
 213 sub link_message {
 214         my ($self, $smsg, $old_tid) = @_;
 215         my $doc = $smsg->{doc};
 216         my $mid = $smsg->mid;
 217         my $mime = $smsg->mime;
 218         my $hdr = $mime->header_obj;
 219         my $refs = $hdr->header_raw('References');
 220         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 221         if (my $irt = $hdr->header_raw('In-Reply-To')) {
 222                 # last References should be $irt
 223                 # we will de-dupe later
 224                 push @refs, mid_clean($irt);
 225         }
 226
 227         my $tid;
 228         if (@refs) {
 229                 my %uniq = ($mid => 1);
 230                 my @orig_refs = @refs;
 231                 @refs = ();
 232
 233                 # prevent circular references via References: here:
 234                 foreach my $ref (@orig_refs) {
 235                         if (length($ref) > MAX_MID_SIZE) {
 236                                 warn "References: <$ref> too long, ignoring\n";
 237                         }
 238                         next if $uniq{$ref};
 239                         $uniq{$ref} = 1;
 240                         push @refs, $ref;
 241                 }
 242         }
 243         if (@refs) {
 244                 $smsg->{references} = '<'.join('> <', @refs).'>';
 245
 246                 # first ref *should* be the thread root,
 247                 # but we can never trust clients to do the right thing
 248                 my $ref = shift @refs;
 249                 $tid = $self->_resolve_mid_to_tid($ref);
 250                 $self->merge_threads($tid, $old_tid) if defined $old_tid;
 251
 252                 # the rest of the refs should point to this tid:
 253                 foreach $ref (@refs) {
 254                         my $ptid = $self->_resolve_mid_to_tid($ref);
 255                         if ($tid ne $ptid) {
 256                                 $self->merge_threads($tid, $ptid);
 257                         }
 258                 }
 259         } else {
 260                 $tid = $self->next_thread_id;
 261         }
 262         $doc->add_term(xpfx('thread') . $tid);
 263 }
 264
 265 sub index_blob {
 266         my ($self, $git, $mime, $bytes, $num) = @_;
 267         $self->add_message($mime, $bytes, $num);
 268 }
 269
 270 sub unindex_blob {
 271         my ($self, $git, $mime) = @_;
 272         my $mid = eval { mid_clean(mid_mime($mime)) };
 273         $self->remove_message($mid) if defined $mid;
 274 }
 275
 276 sub index_mm {
 277         my ($self, $git, $mime) = @_;
 278         $self->{mm}->mid_insert(mid_clean(mid_mime($mime)));
 279 }
 280
 281 sub unindex_mm {
 282         my ($self, $git, $mime) = @_;
 283         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 284 }
 285
 286 sub index_mm2 {
 287         my ($self, $git, $mime, $bytes) = @_;
 288         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 289         index_blob($self, $git, $mime, $bytes, $num);
 290 }
 291
 292 sub unindex_mm2 {
 293         my ($self, $git, $mime) = @_;
 294         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 295         unindex_blob($self, $git, $mime);
 296 }
 297
 298 sub index_both {
 299         my ($self, $git, $mime, $bytes) = @_;
 300         my $num = index_mm($self, $git, $mime);
 301         index_blob($self, $git, $mime, $bytes, $num);
 302 }
 303
 304 sub unindex_both {
 305         my ($self, $git, $mime) = @_;
 306         unindex_blob($self, $git, $mime);
 307         unindex_mm($self, $git, $mime);
 308 }
 309
 310 sub do_cat_mail {
 311         my ($git, $blob, $sizeref) = @_;
 312         my $mime = eval {
 313                 my $str = $git->cat_file($blob, $sizeref);
 314                 Email::MIME->new($str);
 315         };
 316         $@ ? undef : $mime;
 317 }
 318
 319 sub index_sync {
 320         my ($self, $head) = @_;
 321         $self->with_umask(sub { $self->_index_sync($head) });
 322 }
 323
 324 sub rlog {
 325         my ($self, $range, $add_cb, $del_cb) = @_;
 326         my $hex = '[a-f0-9]';
 327         my $h40 = $hex .'{40}';
 328         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 329         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 330         my $git = PublicInbox::Git->new($self->{git_dir});
 331         my $log = $git->popen(qw/log --reverse --no-notes --no-color
 332                                 --raw -r --no-abbrev/, $range);
 333         my $latest;
 334         my $bytes;
 335         local $/ = "\n";
 336         while (defined(my $line = <$log>)) {
 337                 if ($line =~ /$addmsg/o) {
 338                         my $mime = do_cat_mail($git, $1, \$bytes) or next;
 339                         $add_cb->($self, $git, $mime, $bytes);
 340                 } elsif ($line =~ /$delmsg/o) {
 341                         my $mime = do_cat_mail($git, $1) or next;
 342                         $del_cb->($self, $git, $mime);
 343                 } elsif ($line =~ /^commit ($h40)/o) {
 344                         $latest = $1;
 345                 }
 346         }
 347         $latest;
 348 }
 349
 350 # indexes all unindexed messages
 351 sub _index_sync {
 352         my ($self, $head) = @_;
 353         my $db = $self->{xdb};
 354         $head ||= 'HEAD';
 355         my $mm = $self->{mm} = eval {
 356                 require PublicInbox::Msgmap;
 357                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 358         };
 359
 360         $db->begin_transaction;
 361         my $lx = $db->get_metadata('last_commit');
 362         my $range = $lx eq '' ? $head : "$lx..$head";
 363         if ($mm) {
 364                 $mm->{dbh}->begin_work;
 365                 my $lm = $mm->last_commit || '';
 366                 if ($lm eq $lx) {
 367                         # Common case is the indexes are synced,
 368                         # we only need to run git-log once:
 369                         $lx = $self->rlog($range, *index_both, *unindex_both);
 370                         $mm->{dbh}->commit;
 371                         if (defined $lx) {
 372                                 $db->set_metadata('last_commit', $lx);
 373                                 $mm->last_commit($lx);
 374                         }
 375                 } else {
 376                         # dumb case, msgmap and xapian are out-of-sync
 377                         # do not care for performance:
 378                         my $r = $lm eq '' ? $head : "$lm..$head";
 379                         $lm = $self->rlog($r, *index_mm, *unindex_mm);
 380                         $mm->{dbh}->commit;
 381                         $mm->last_commit($lm) if defined $lm;
 382
 383                         $lx = $self->rlog($range, *index_mm2, *unindex_mm2);
 384                         $db->set_metadata('last_commit', $lx) if defined $lx;
 385                 }
 386         } else {
 387                 # user didn't install DBD::SQLite and DBI
 388                 $lx = $self->rlog($range, *index_blob, *unindex_blob);
 389                 $db->set_metadata('last_commit', $lx) if defined $lx;
 390         }
 391         if ($@) {
 392                 $db->cancel_transaction;
 393                 $mm->{dbh}->rollback if $mm;
 394         } else {
 395                 $db->commit_transaction;
 396         }
 397 }
 398
 399 # this will create a ghost as necessary
 400 sub _resolve_mid_to_tid {
 401         my ($self, $mid) = @_;
 402
 403         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 404         $smsg->thread_id;
 405 }
 406
 407 sub create_ghost {
 408         my ($self, $mid) = @_;
 409
 410         my $tid = $self->next_thread_id;
 411         my $doc = Search::Xapian::Document->new;
 412         $doc->add_term(xpfx('mid') . $mid);
 413         $doc->add_term(xpfx('thread') . $tid);
 414         $doc->add_term(xpfx('type') . 'ghost');
 415
 416         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 417         $self->{xdb}->add_document($doc);
 418
 419         $smsg;
 420 }
 421
 422 sub merge_threads {
 423         my ($self, $winner_tid, $loser_tid) = @_;
 424         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 425         my $thread_pfx = xpfx('thread');
 426         my $db = $self->{xdb};
 427
 428         for (; $head != $tail; $head->inc) {
 429                 my $docid = $head->get_docid;
 430                 my $doc = $db->get_document($docid);
 431                 $doc->remove_term($thread_pfx . $loser_tid);
 432                 $doc->add_term($thread_pfx . $winner_tid);
 433                 $db->replace_document($docid, $doc);
 434         }
 435 }
 436
 437 sub _read_git_config_perm {
 438         my ($self) = @_;
 439         my @cmd = qw(config core.sharedRepository);
 440         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 441         local $/ = "\n";
 442         my $perm = <$fh>;
 443         chomp $perm if defined $perm;
 444         $perm;
 445 }
 446
 447 sub _git_config_perm {
 448         my $self = shift;
 449         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 450         return PERM_GROUP if (!defined($perm) || $perm eq '');
 451         return PERM_UMASK if ($perm eq 'umask');
 452         return PERM_GROUP if ($perm eq 'group');
 453         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 454                 return PERM_EVERYBODY;
 455         }
 456         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 457         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 458
 459         my $i = oct($perm);
 460         return PERM_UMASK if ($i == PERM_UMASK);
 461         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 462         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 463
 464         if (($i & 0600) != 0600) {
 465                 die "core.sharedRepository mode invalid: ".
 466                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 467         }
 468         ($i & 0666);
 469 }
 470
 471 sub _umask_for {
 472         my ($perm) = @_; # _git_config_perm return value
 473         my $rv = $perm;
 474         return umask if $rv == 0;
 475
 476         # set +x bit if +r or +w were set
 477         $rv |= 0100 if ($rv & 0600);
 478         $rv |= 0010 if ($rv & 0060);
 479         $rv |= 0001 if ($rv & 0006);
 480         (~$rv & 0777);
 481 }
 482
 483 sub with_umask {
 484         my ($self, $cb) = @_;
 485         my $old = umask $self->{umask};
 486         my $rv = eval { $cb->() };
 487         my $err = $@;
 488         umask $old;
 489         die $err if $@;
 490         $rv;
 491 }
 492
 493 1;