lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 require PublicInbox::Git;
  22 use Compress::Zlib qw(compress);
  23
  24 use constant {
  25         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000,
  27         DEBUG => !!$ENV{DEBUG},
  28 };
  29
  30 my %GIT_ESC = (
  31         a => "\a",
  32         b => "\b",
  33         f => "\f",
  34         n => "\n",
  35         r => "\r",
  36         t => "\t",
  37         v => "\013",
  38 );
  39
  40 sub git_unquote ($) {
  41         my ($s) = @_;
  42         return $s unless ($s =~ /\A"(.*)"\z/);
  43         $s = $1;
  44         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  45         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  46         $s;
  47 }
  48
  49 sub new {
  50         my ($class, $ibx, $creat, $part) = @_;
  51         my $levels = qr/\A(?:full|medium|basic)\z/;
  52         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  53         my $git_dir = $mainrepo;
  54         my ($altid, $git);
  55         my $version = 1;
  56         my $indexlevel = 'full';
  57         if (ref $ibx) {
  58                 $mainrepo = $ibx->{mainrepo};
  59                 $altid = $ibx->{altid};
  60                 $version = $ibx->{version} || 1;
  61                 if ($altid) {
  62                         require PublicInbox::AltId;
  63                         $altid = [ map {
  64                                 PublicInbox::AltId->new($ibx, $_);
  65                         } @$altid ];
  66                 }
  67                 if ($ibx->{indexlevel}) {
  68                         if ($ibx->{indexlevel} =~ $levels) {
  69                                 $indexlevel = $ibx->{indexlevel};
  70                         } else {
  71                                 die("Invalid indexlevel $ibx->{indexlevel}\n");
  72                         }
  73                 }
  74         } else { # v1
  75                 $ibx = { mainrepo => $git_dir, version => 1 };
  76         }
  77         $ibx = PublicInbox::InboxWritable->new($ibx);
  78         require Search::Xapian::WritableDatabase;
  79         my $self = bless {
  80                 mainrepo => $mainrepo,
  81                 -inbox => $ibx,
  82                 git => $ibx->git,
  83                 -altid => $altid,
  84                 version => $version,
  85                 indexlevel => $indexlevel,
  86         }, $class;
  87         $ibx->umask_prepare;
  88         if ($version == 1) {
  89                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  90                 my $dir = $self->xdir;
  91                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  92         } elsif ($version == 2) {
  93                 defined $part or die "partition is required for v2\n";
  94                 # partition is a number
  95                 $self->{partition} = $part;
  96                 $self->{lock_path} = undef;
  97         } else {
  98                 die "unsupported inbox version=$version\n";
  99         }
 100         $self->{creat} = ($creat || 0) == 1;
 101         $self;
 102 }
 103
 104 sub _xdb_release {
 105         my ($self) = @_;
 106         my $xdb = delete $self->{xdb} or croak 'not acquired';
 107         $xdb->close;
 108         $self->lock_release if $self->{creat};
 109         undef;
 110 }
 111
 112 sub _xdb_acquire {
 113         my ($self) = @_;
 114         croak 'already acquired' if $self->{xdb};
 115         my $dir = $self->xdir;
 116         my $flag = Search::Xapian::DB_OPEN;
 117         if ($self->{creat}) {
 118                 require File::Path;
 119                 $self->lock_acquire;
 120                 File::Path::mkpath($dir);
 121                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 122         }
 123         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 124 }
 125
 126 sub add_val ($$$) {
 127         my ($doc, $col, $num) = @_;
 128         $num = Search::Xapian::sortable_serialise($num);
 129         $doc->add_value($col, $num);
 130 }
 131
 132 sub index_text ($$$$)
 133 {
 134         my ($self, $field, $n, $text) = @_;
 135         my $tg = $self->term_generator;
 136
 137         if ($self->{indexlevel} eq 'full') {
 138                 $tg->index_text($field, $n, $text);
 139                 $tg->increase_termpos;
 140         } else {
 141                 $tg->index_text_without_positions($field, $n, $text);
 142         }
 143 }
 144
 145 sub index_users ($$) {
 146         my ($self, $smsg) = @_;
 147
 148         my $from = $smsg->from;
 149         my $to = $smsg->to;
 150         my $cc = $smsg->cc;
 151
 152         $self->index_text($from, 1, 'A'); # A - author
 153         $self->index_text($to, 1, 'XTO') if $to ne '';
 154         $self->index_text($cc, 1, 'XCC') if $cc ne '';
 155 }
 156
 157 sub index_diff_inc ($$$$) {
 158         my ($self, $text, $pfx, $xnq) = @_;
 159         if (@$xnq) {
 160                 $self->index_text(join("\n", @$xnq), 1, 'XNQ');
 161                 @$xnq = ();
 162         }
 163         $self->index_text($text, 1, $pfx);
 164 }
 165
 166 sub index_old_diff_fn {
 167         my ($self, $seen, $fa, $fb, $xnq) = @_;
 168
 169         # no renames or space support for traditional diffs,
 170         # find the number of leading common paths to strip:
 171         my @fa = split('/', $fa);
 172         my @fb = split('/', $fb);
 173         while (scalar(@fa) && scalar(@fb)) {
 174                 $fa = join('/', @fa);
 175                 $fb = join('/', @fb);
 176                 if ($fa eq $fb) {
 177                         unless ($seen->{$fa}++) {
 178                                 $self->index_diff_inc($fa, 'XDFN', $xnq);
 179                         }
 180                         return 1;
 181                 }
 182                 shift @fa;
 183                 shift @fb;
 184         }
 185         0;
 186 }
 187
 188 sub index_diff ($$$) {
 189         my ($self, $lines, $doc) = @_;
 190         my %seen;
 191         my $in_diff;
 192         my @xnq;
 193         my $xnq = \@xnq;
 194         foreach (@$lines) {
 195                 if ($in_diff && s/^ //) { # diff context
 196                         $self->index_diff_inc($_, 'XDFCTX', $xnq);
 197                 } elsif (/^-- $/) { # email signature begins
 198                         $in_diff = undef;
 199                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 200                         my ($fa, $fb) = ($1, $2);
 201                         my $fn = (split('/', git_unquote($fa), 2))[1];
 202                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 203                         $fn = (split('/', git_unquote($fb), 2))[1];
 204                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 205                         $in_diff = 1;
 206                 # traditional diff:
 207                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 208                         my ($opt, $fa, $fb) = ($1, $2, $3);
 209                         push @xnq, $_;
 210                         # only support unified:
 211                         next unless $opt =~ /[uU]/;
 212                         $in_diff = $self->index_old_diff_fn(\%seen, $fa, $fb,
 213                                                         $xnq);
 214                 } elsif (m!^--- ("?a/.+)!) {
 215                         my $fn = (split('/', git_unquote($1), 2))[1];
 216                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 217                         $in_diff = 1;
 218                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 219                         my $fn = (split('/', git_unquote($1), 2))[1];
 220                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 221                         $in_diff = 1;
 222                 } elsif (/^--- (\S+)/) {
 223                         $in_diff = $1;
 224                         push @xnq, $_;
 225                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 226                         $in_diff = $self->index_old_diff_fn(\%seen, $in_diff, $1,
 227                                                         $xnq);
 228                 } elsif ($in_diff && s/^\+//) { # diff added
 229                         $self->index_diff_inc($_, 'XDFB', $xnq);
 230                 } elsif ($in_diff && s/^-//) { # diff removed
 231                         $self->index_diff_inc($_, 'XDFA', $xnq);
 232                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 233                         my ($ba, $bb) = ($1, $2);
 234                         index_git_blob_id($doc, 'XDFPRE', $ba);
 235                         index_git_blob_id($doc, 'XDFPOST', $bb);
 236                         $in_diff = 1;
 237                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 238                         # traditional diff w/o -p
 239                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 240                         # hunk header context
 241                         $self->index_diff_inc($1, 'XDFHH', $xnq);
 242                 # ignore the following lines:
 243                 } elsif (/^(?:dis)similarity index/ ||
 244                                 /^(?:old|new) mode/ ||
 245                                 /^(?:deleted|new) file mode/ ||
 246                                 /^(?:copy|rename) (?:from|to) / ||
 247                                 /^(?:dis)?similarity index / ||
 248                                 /^\\ No newline at end of file/ ||
 249                                 /^Binary files .* differ/) {
 250                         push @xnq, $_;
 251                 } elsif ($_ eq '') {
 252                         $in_diff = undef;
 253                 } else {
 254                         push @xnq, $_;
 255                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 256                         $in_diff = undef;
 257                 }
 258         }
 259
 260         $self->index_text(join("\n", @xnq), 1, 'XNQ');
 261 }
 262
 263 sub index_body ($$$) {
 264         my ($self, $lines, $doc) = @_;
 265         my $txt = join("\n", @$lines);
 266         if ($doc) {
 267                 # does it look like a diff?
 268                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 269                         $txt = undef;
 270                         $self->index_diff($lines, $doc);
 271                 } else {
 272                         $self->index_text($txt, 1, 'XNQ');
 273                 }
 274         } else {
 275                 $self->index_text($txt, 0, 'XQUOT');
 276         }
 277         @$lines = ();
 278 }
 279
 280 sub add_xapian ($$$$$) {
 281         my ($self, $mime, $num, $oid, $mids, $mid0) = @_;
 282         my $smsg = PublicInbox::SearchMsg->new($mime);
 283         my $doc = $smsg->{doc};
 284         my $subj = $smsg->subject;
 285         add_val($doc, PublicInbox::Search::TS(), $smsg->ts);
 286         my @ds = gmtime($smsg->ds);
 287         my $yyyymmdd = strftime('%Y%m%d', @ds);
 288         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 289         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 290         add_val($doc, PublicInbox::Search::DT(), $dt);
 291
 292         my $tg = $self->term_generator;
 293
 294         $tg->set_document($doc);
 295         $self->index_text($subj, 1, 'S') if $subj;
 296         $self->index_users($smsg);
 297
 298         msg_iter($mime, sub {
 299                 my ($part, $depth, @idx) = @{$_[0]};
 300                 my $ct = $part->content_type || 'text/plain';
 301                 my $fn = $part->filename;
 302                 if (defined $fn && $fn ne '') {
 303                         $self->index_text($fn, 1, 'XFN');
 304                 }
 305
 306                 return if $ct =~ m!\btext/x?html\b!i;
 307
 308                 my $s = eval { $part->body_str };
 309                 if ($@) {
 310                         if ($ct =~ m!\btext/plain\b!i) {
 311                                 # Try to assume UTF-8 because Alpine
 312                                 # seems to do wacky things and set
 313                                 # charset=X-UNKNOWN
 314                                 $part->charset_set('UTF-8');
 315                                 $s = eval { $part->body_str };
 316                                 $s = $part->body if $@;
 317                         }
 318                 }
 319                 defined $s or return;
 320
 321                 my (@orig, @quot);
 322                 my $body = $part->body;
 323                 my @lines = split(/\n/, $body);
 324                 while (defined(my $l = shift @lines)) {
 325                         if ($l =~ /^>/) {
 326                                 $self->index_body(\@orig, $doc) if @orig;
 327                                 push @quot, $l;
 328                         } else {
 329                                 $self->index_body(\@quot, 0) if @quot;
 330                                 push @orig, $l;
 331                         }
 332                 }
 333                 $self->index_body(\@quot, 0) if @quot;
 334                 $self->index_body(\@orig, $doc) if @orig;
 335         });
 336
 337         foreach my $mid (@$mids) {
 338                 $self->index_text($mid, 1, 'XM');
 339
 340                 # because too many Message-IDs are prefixed with
 341                 # "Pine.LNX."...
 342                 if ($mid =~ /\w{12,}/) {
 343                         my @long = ($mid =~ /(\w{3,}+)/g);
 344                         $self->index_text(join(' ', @long), 1, 'XM');
 345                 }
 346         }
 347         $smsg->{to} = $smsg->{cc} = '';
 348         PublicInbox::OverIdx::parse_references($smsg, $mid0, $mids);
 349         my $data = $smsg->to_doc_data($oid, $mid0);
 350         $doc->set_data($data);
 351         if (my $altid = $self->{-altid}) {
 352                 foreach my $alt (@$altid) {
 353                         my $pfx = $alt->{xprefix};
 354                         foreach my $mid (@$mids) {
 355                                 my $id = $alt->mid2alt($mid);
 356                                 next unless defined $id;
 357                                 $doc->add_boolean_term($pfx . $id);
 358                         }
 359                 }
 360         }
 361         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 362         $self->{xdb}->replace_document($num, $doc);
 363 }
 364
 365 sub add_message {
 366         # mime = Email::MIME object
 367         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 368         my $xapianlevels = qr/\A(?:full|medium)\z/;
 369         my $mids = mids($mime->header_obj);
 370         $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 371         unless (defined $num) { # v1
 372                 $self->_msgmap_init;
 373                 $num = index_mm($self, $mime);
 374         }
 375         eval {
 376                 if ($self->{indexlevel} =~ $xapianlevels) {
 377                         $self->add_xapian($mime, $num, $oid, $mids, $mid0)
 378                 }
 379                 if (my $over = $self->{over}) {
 380                         $over->add_overview($mime, $bytes, $num, $oid, $mid0);
 381                 }
 382         };
 383
 384         if ($@) {
 385                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 386                 return undef;
 387         }
 388         $num;
 389 }
 390
 391 # returns begin and end PostingIterator
 392 sub find_doc_ids {
 393         my ($self, $termval) = @_;
 394         my $db = $self->{xdb};
 395
 396         ($db->postlist_begin($termval), $db->postlist_end($termval));
 397 }
 398
 399 sub batch_do {
 400         my ($self, $termval, $cb) = @_;
 401         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 402         while (1) {
 403                 my ($head, $tail) = $self->find_doc_ids($termval);
 404                 return if $head == $tail;
 405                 my @ids;
 406                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 407                         push @ids, $head->get_docid;
 408                 }
 409                 $cb->(\@ids);
 410         }
 411 }
 412
 413 sub remove_message {
 414         my ($self, $mid) = @_;
 415         my $db = $self->{xdb};
 416         my $called;
 417         $mid = mid_clean($mid);
 418         my $over = $self->{over};
 419
 420         eval {
 421                 batch_do($self, 'Q' . $mid, sub {
 422                         my ($ids) = @_;
 423                         $db->delete_document($_) for @$ids;
 424                         $over->delete_articles($ids) if $over;
 425                         $called = 1;
 426                 });
 427         };
 428         if ($@) {
 429                 warn "failed to remove message <$mid>: $@\n";
 430         } elsif (!$called) {
 431                 warn "cannot remove non-existent <$mid>\n";
 432         }
 433 }
 434
 435 # MID is a hint in V2
 436 sub remove_by_oid {
 437         my ($self, $oid, $mid) = @_;
 438         my $db = $self->{xdb};
 439
 440         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 441
 442         # XXX careful, we cannot use batch_do here since we conditionally
 443         # delete documents based on other factors, so we cannot call
 444         # find_doc_ids twice.
 445         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 446         return if $head == $tail;
 447
 448         # there is only ONE element in @delete unless we
 449         # have bugs in our v2writable deduplication check
 450         my @delete;
 451         for (; $head != $tail; $head->inc) {
 452                 my $docid = $head->get_docid;
 453                 my $doc = $db->get_document($docid);
 454                 my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 455                 $smsg->load_expand;
 456                 if ($smsg->{blob} eq $oid) {
 457                         push(@delete, $docid);
 458                 }
 459         }
 460         $db->delete_document($_) foreach @delete;
 461         scalar(@delete);
 462 }
 463
 464 sub term_generator { # write-only
 465         my ($self) = @_;
 466
 467         my $tg = $self->{term_generator};
 468         return $tg if $tg;
 469
 470         $tg = Search::Xapian::TermGenerator->new;
 471         $tg->set_stemmer($self->stemmer);
 472
 473         $self->{term_generator} = $tg;
 474 }
 475
 476 sub index_git_blob_id {
 477         my ($doc, $pfx, $objid) = @_;
 478
 479         my $len = length($objid);
 480         for (my $len = length($objid); $len >= 7; ) {
 481                 $doc->add_term($pfx.$objid);
 482                 $objid = substr($objid, 0, --$len);
 483         }
 484 }
 485
 486 sub unindex_blob {
 487         my ($self, $mime) = @_;
 488         my $mid = eval { mid_clean(mid_mime($mime)) };
 489         $self->remove_message($mid) if defined $mid;
 490 }
 491
 492 sub index_mm {
 493         my ($self, $mime) = @_;
 494         my $mid = mid_clean(mid_mime($mime));
 495         my $mm = $self->{mm};
 496         my $num;
 497
 498         if (defined $self->{regen_down}) {
 499                 $num = $mm->num_for($mid) and return $num;
 500
 501                 while (($num = $self->{regen_down}--) > 0) {
 502                         if ($mm->mid_set($num, $mid) != 0) {
 503                                 return $num;
 504                         }
 505                 }
 506         } elsif (defined $self->{regen_up}) {
 507                 $num = $mm->num_for($mid) and return $num;
 508
 509                 # this is to fixup old bugs due to add-remove-add
 510                 while (($num = ++$self->{regen_up})) {
 511                         if ($mm->mid_set($num, $mid) != 0) {
 512                                 return $num;
 513                         }
 514                 }
 515         }
 516
 517         $num = $mm->mid_insert($mid) and return $num;
 518
 519         # fallback to num_for since filters like RubyLang set the number
 520         $mm->num_for($mid);
 521 }
 522
 523 sub unindex_mm {
 524         my ($self, $mime) = @_;
 525         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 526 }
 527
 528 sub index_both {
 529         my ($self, $mime, $bytes, $blob) = @_;
 530         my $num = index_mm($self, $mime);
 531         add_message($self, $mime, $bytes, $num, $blob);
 532 }
 533
 534 sub unindex_both {
 535         my ($self, $mime) = @_;
 536         unindex_blob($self, $mime);
 537         unindex_mm($self, $mime);
 538 }
 539
 540 sub do_cat_mail {
 541         my ($git, $blob, $sizeref) = @_;
 542         my $mime = eval {
 543                 my $str = $git->cat_file($blob, $sizeref);
 544                 # fixup bugs from import:
 545                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 546                 PublicInbox::MIME->new($str);
 547         };
 548         $@ ? undef : $mime;
 549 }
 550
 551 sub index_sync {
 552         my ($self, $opts) = @_;
 553         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 554 }
 555
 556 sub batch_adjust ($$$$) {
 557         my ($max, $bytes, $batch_cb, $latest) = @_;
 558         $$max -= $bytes;
 559         if ($$max <= 0) {
 560                 $$max = BATCH_BYTES;
 561                 $batch_cb->($latest);
 562         }
 563 }
 564
 565 # only for v1
 566 sub read_log {
 567         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 568         my $hex = '[a-f0-9]';
 569         my $h40 = $hex .'{40}';
 570         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 571         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 572         my $git = $self->{git};
 573         my $latest;
 574         my $bytes;
 575         my $max = BATCH_BYTES;
 576         local $/ = "\n";
 577         my %D;
 578         my $line;
 579         my $newest;
 580         while (defined($line = <$log>)) {
 581                 if ($line =~ /$addmsg/o) {
 582                         my $blob = $1;
 583                         if (delete $D{$blob}) {
 584                                 if (defined $self->{regen_down}) {
 585                                         $self->{regen_down}--;
 586                                 }
 587                                 next;
 588                         }
 589                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 590                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 591                         $add_cb->($self, $mime, $bytes, $blob);
 592                 } elsif ($line =~ /$delmsg/o) {
 593                         my $blob = $1;
 594                         $D{$blob} = 1;
 595                 } elsif ($line =~ /^commit ($h40)/o) {
 596                         $latest = $1;
 597                         $newest ||= $latest;
 598                 }
 599         }
 600         # get the leftovers
 601         foreach my $blob (keys %D) {
 602                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 603                 $del_cb->($self, $mime);
 604         }
 605         $batch_cb->($latest, $newest);
 606 }
 607
 608 sub _msgmap_init {
 609         my ($self) = @_;
 610         die "BUG: _msgmap_init is only for v1\n" if $self->{version} != 1;
 611         $self->{mm} ||= eval {
 612                 require PublicInbox::Msgmap;
 613                 PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 614         };
 615 }
 616
 617 sub _git_log {
 618         my ($self, $range) = @_;
 619         my $git = $self->{git};
 620
 621         if (index($range, '..') < 0) {
 622                 my $regen_max = 0;
 623                 # can't use 'rev-list --count' if we use --diff-filter
 624                 my $fh = $git->popen(qw(log --pretty=tformat:%h
 625                                 --no-notes --no-color --no-renames
 626                                 --diff-filter=AM), $range);
 627                 ++$regen_max while <$fh>;
 628                 my (undef, $max) = $self->{mm}->minmax;
 629
 630                 if ($max && $max == $regen_max) {
 631                         # fix up old bugs in full indexes which caused messages to
 632                         # not appear in Msgmap
 633                         $self->{regen_up} = $max;
 634                 } else {
 635                         # normal regen is for for fresh data
 636                         $self->{regen_down} = $regen_max;
 637                 }
 638         }
 639
 640         $git->popen(qw/log --no-notes --no-color --no-renames
 641                                 --raw -r --no-abbrev/, $range);
 642 }
 643
 644 sub is_ancestor ($$$) {
 645         my ($git, $cur, $tip) = @_;
 646         return 0 unless $git->check($cur);
 647         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 648                 qw(merge-base --is-ancestor), $cur, $tip ];
 649         my $pid = spawn($cmd);
 650         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 651         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 652         $? == 0;
 653 }
 654
 655 sub need_update ($$$) {
 656         my ($self, $cur, $new) = @_;
 657         my $git = $self->{git};
 658         return 1 if $cur && !is_ancestor($git, $cur, $new);
 659         my $range = $cur eq '' ? $new : "$cur..$new";
 660         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 661         ($n eq '' || $n > 0);
 662 }
 663
 664 # indexes all unindexed messages (v1 only)
 665 sub _index_sync {
 666         my ($self, $opts) = @_;
 667         my $tip = $opts->{ref} || 'HEAD';
 668         my $reindex = $opts->{reindex};
 669         my ($mkey, $last_commit, $lx, $xlog);
 670         my $git = $self->{git};
 671         $git->batch_prepare;
 672
 673         my $xdb = $self->begin_txn_lazy;
 674         my $mm = _msgmap_init($self);
 675         do {
 676                 $xlog = undef;
 677                 $mkey = 'last_commit';
 678                 $last_commit = $xdb->get_metadata('last_commit');
 679                 $lx = $last_commit;
 680                 if ($reindex) {
 681                         $lx = '';
 682                         $mkey = undef if $last_commit ne '';
 683                 }
 684
 685                 # use last_commit from msgmap if it is older or unset
 686                 my $lm = $mm->last_commit || '';
 687                 if (!$lm || ($lm && $lx && is_ancestor($git, $lm, $lx))) {
 688                         $lx = $lm;
 689                 }
 690
 691                 $self->{over}->rollback_lazy;
 692                 $self->{over}->disconnect;
 693                 $git->cleanup;
 694                 delete $self->{txn};
 695                 $xdb->cancel_transaction;
 696                 $xdb = _xdb_release($self);
 697
 698                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 699                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 700                 $xlog = _git_log($self, $range);
 701
 702                 $xdb = $self->begin_txn_lazy;
 703         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 704
 705         my $dbh = $mm->{dbh} if $mm;
 706         my $cb = sub {
 707                 my ($commit, $newest) = @_;
 708                 if ($dbh) {
 709                         if ($newest) {
 710                                 my $cur = $mm->last_commit || '';
 711                                 if (need_update($self, $cur, $newest)) {
 712                                         $mm->last_commit($newest);
 713                                 }
 714                         }
 715                         $dbh->commit;
 716                 }
 717                 if ($mkey && $newest) {
 718                         my $cur = $xdb->get_metadata($mkey);
 719                         if (need_update($self, $cur, $newest)) {
 720                                 $xdb->set_metadata($mkey, $newest);
 721                         }
 722                 }
 723                 $self->commit_txn_lazy;
 724                 $git->cleanup;
 725                 $xdb = _xdb_release($self);
 726                 # let another process do some work... <
 727                 if (!$newest) {
 728                         $xdb = $self->begin_txn_lazy;
 729                         $dbh->begin_work if $dbh;
 730                 }
 731         };
 732
 733         $dbh->begin_work;
 734         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 735 }
 736
 737 sub DESTROY {
 738         # order matters for unlocking
 739         $_[0]->{xdb} = undef;
 740         $_[0]->{lockfh} = undef;
 741 }
 742
 743 # remote_* subs are only used by SearchIdxPart
 744 sub remote_commit {
 745         my ($self) = @_;
 746         if (my $w = $self->{w}) {
 747                 print $w "commit\n" or die "failed to write commit: $!";
 748         } else {
 749                 $self->commit_txn_lazy;
 750         }
 751 }
 752
 753 sub remote_close {
 754         my ($self) = @_;
 755         if (my $w = delete $self->{w}) {
 756                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 757                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 758                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 759                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 760                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 761         } else {
 762                 die "transaction in progress $self\n" if $self->{txn};
 763                 $self->_xdb_release if $self->{xdb};
 764         }
 765 }
 766
 767 sub remote_remove {
 768         my ($self, $oid, $mid) = @_;
 769         if (my $w = $self->{w}) {
 770                 # triggers remove_by_oid in a partition
 771                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 772         } else {
 773                 $self->begin_txn_lazy;
 774                 $self->remove_by_oid($oid, $mid);
 775         }
 776 }
 777
 778 sub begin_txn_lazy {
 779         my ($self) = @_;
 780         return if $self->{txn};
 781
 782         $self->{-inbox}->with_umask(sub {
 783                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 784                 $self->{over}->begin_lazy if $self->{over};
 785                 $xdb->begin_transaction;
 786                 $self->{txn} = 1;
 787                 $xdb;
 788         });
 789 }
 790
 791 sub commit_txn_lazy {
 792         my ($self) = @_;
 793         delete $self->{txn} or return;
 794         $self->{-inbox}->with_umask(sub {
 795                 $self->{xdb}->commit_transaction;
 796                 $self->{over}->commit_lazy if $self->{over};
 797         });
 798 }
 799
 800 sub worker_done {
 801         my ($self) = @_;
 802         die "$$ $0 xdb not released\n" if $self->{xdb};
 803         die "$$ $0 still in transaction\n" if $self->{txn};
 804 }
 805
 806 1;