lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchIdx;
   5 use strict;
   6 use warnings;
   7 use base qw(PublicInbox::Search);
   8 use PublicInbox::MID qw/mid_clean mid_compress/;
   9 *xpfx = *PublicInbox::Search::xpfx;
  10
  11 use constant {
  12         PERM_UMASK => 0,
  13         OLD_PERM_GROUP => 1,
  14         OLD_PERM_EVERYBODY => 2,
  15         PERM_GROUP => 0660,
  16         PERM_EVERYBODY => 0664,
  17 };
  18
  19 sub new {
  20         my ($class, $git_dir, $writable) = @_;
  21         my $dir = $class->xdir($git_dir);
  22         require Search::Xapian::WritableDatabase;
  23         my $flag = Search::Xapian::DB_OPEN;
  24         my $self = bless { git_dir => $git_dir }, $class;
  25         my $perm = $self->_git_config_perm;
  26         my $umask = _umask_for($perm);
  27         $self->{umask} = $umask;
  28         $self->{xdb} = $self->with_umask(sub {
  29                 if ($writable == 1) {
  30                         require File::Path;
  31                         File::Path::mkpath($dir);
  32                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  33                 }
  34                 Search::Xapian::WritableDatabase->new($dir, $flag);
  35         });
  36         $self;
  37 }
  38
  39 sub add_val {
  40         my ($doc, $col, $num) = @_;
  41         $num = Search::Xapian::sortable_serialise($num);
  42         $doc->add_value($col, $num);
  43 }
  44
  45 sub add_message {
  46         my ($self, $mime, $bytes, $num) = @_; # mime = Email::MIME object
  47         my $db = $self->{xdb};
  48
  49         my $doc_id;
  50         my $mid = mid_clean($mime->header('Message-ID'));
  51         my $was_ghost = 0;
  52         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  53
  54         eval {
  55                 my $smsg = $self->lookup_message($mid);
  56                 my $doc;
  57
  58                 if ($smsg) {
  59                         $smsg->ensure_metadata;
  60                         # convert a ghost to a regular message
  61                         # it will also clobber any existing regular message
  62                         $smsg->mime($mime);
  63                         $doc = $smsg->{doc};
  64
  65                         my $type = xpfx('type');
  66                         eval {
  67                                 $doc->remove_term($type . 'ghost');
  68                                 $was_ghost = 1;
  69                         };
  70
  71                         # probably does not exist:
  72                         eval { $doc->remove_term($type . 'mail') };
  73                         $doc->add_term($type . 'mail');
  74                 }  else {
  75                         $smsg = PublicInbox::SearchMsg->new($mime);
  76                         $doc = $smsg->{doc};
  77                         $doc->add_term(xpfx('mid') . $mid);
  78                 }
  79
  80                 my $subj = $smsg->subject;
  81
  82                 if ($subj ne '') {
  83                         my $path = $self->subject_path($subj);
  84                         $doc->add_term(xpfx('path') . mid_compress($path));
  85                 }
  86
  87                 add_val($doc, &PublicInbox::Search::TS, $smsg->ts);
  88
  89                 defined($num) and
  90                         add_val($doc, &PublicInbox::Search::NUM, $num);
  91
  92                 defined($bytes) and
  93                         add_val($doc, &PublicInbox::Search::BYTES, $bytes);
  94
  95                 add_val($doc, &PublicInbox::Search::LINES,
  96                                 $mime->body_raw =~ tr!\n!\n!);
  97
  98                 my $tg = $self->term_generator;
  99
 100                 $tg->set_document($doc);
 101                 $tg->index_text($subj, 1, 'S') if $subj;
 102                 $tg->increase_termpos;
 103                 $tg->index_text($subj) if $subj;
 104                 $tg->increase_termpos;
 105
 106                 $tg->index_text($smsg->from);
 107                 $tg->increase_termpos;
 108
 109                 $mime->walk_parts(sub {
 110                         my ($part) = @_;
 111                         return if $part->subparts; # walk_parts already recurses
 112                         my $ct = $part->content_type || $ct_msg;
 113
 114                         # account for filter bugs...
 115                         $ct =~ m!\btext/plain\b!i or return;
 116
 117                         my (@orig, @quot);
 118                         my $body = $part->body;
 119                         $part->body_set('');
 120                         my @lines = split(/\n/, $body);
 121                         while (defined(my $l = shift @lines)) {
 122                                 if ($l =~ /^\s*>/) {
 123                                         push @quot, $l;
 124                                 } else {
 125                                         push @orig, $l;
 126                                 }
 127                         }
 128                         if (@quot) {
 129                                 $tg->index_text(join("\n", @quot), 0);
 130                                 @quot = ();
 131                                 $tg->increase_termpos;
 132                         }
 133                         if (@orig) {
 134                                 $tg->index_text(join("\n", @orig));
 135                                 @orig = ();
 136                                 $tg->increase_termpos;
 137                         }
 138                 });
 139
 140                 if ($was_ghost) {
 141                         $doc_id = $smsg->doc_id;
 142                         $self->link_message($smsg, 0);
 143                         $doc->set_data($smsg->to_doc_data);
 144                         $db->replace_document($doc_id, $doc);
 145                 } else {
 146                         $self->link_message($smsg, 0);
 147                         $doc->set_data($smsg->to_doc_data);
 148                         $doc_id = $db->add_document($doc);
 149                 }
 150         };
 151
 152         if ($@) {
 153                 warn "failed to index message <$mid>: $@\n";
 154                 return undef;
 155         }
 156         $doc_id;
 157 }
 158
 159 # returns deleted doc_id on success, undef on missing
 160 sub remove_message {
 161         my ($self, $mid) = @_;
 162         my $db = $self->{xdb};
 163         my $doc_id;
 164         $mid = mid_clean($mid);
 165
 166         eval {
 167                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 168                 $db->delete_document($doc_id) if defined $doc_id;
 169         };
 170
 171         if ($@) {
 172                 warn "failed to remove message <$mid>: $@\n";
 173                 return undef;
 174         }
 175         $doc_id;
 176 }
 177
 178 sub term_generator { # write-only
 179         my ($self) = @_;
 180
 181         my $tg = $self->{term_generator};
 182         return $tg if $tg;
 183
 184         $tg = Search::Xapian::TermGenerator->new;
 185         $tg->set_stemmer($self->stemmer);
 186
 187         $self->{term_generator} = $tg;
 188 }
 189
 190 # increments last_thread_id counter
 191 # returns a 64-bit integer represented as a hex string
 192 sub next_thread_id {
 193         my ($self) = @_;
 194         my $db = $self->{xdb};
 195         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 196
 197         $db->set_metadata('last_thread_id', ++$last_thread_id);
 198
 199         $last_thread_id;
 200 }
 201
 202 sub link_message {
 203         my ($self, $smsg, $is_ghost) = @_;
 204
 205         if ($is_ghost) {
 206                 $smsg->ensure_metadata;
 207         } else {
 208                 $self->link_message_to_parents($smsg);
 209         }
 210 }
 211
 212 sub link_message_to_parents {
 213         my ($self, $smsg) = @_;
 214         my $doc = $smsg->{doc};
 215         my $mid = $smsg->mid;
 216         my $mime = $smsg->mime;
 217         my $refs = $mime->header('References');
 218         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 219         if (my $irt = $mime->header('In-Reply-To')) {
 220                 # last References should be $irt
 221                 # we will de-dupe later
 222                 push @refs, mid_clean($irt);
 223         }
 224
 225         my $tid;
 226         if (@refs) {
 227                 my %uniq = ($mid => 1);
 228                 my @orig_refs = @refs;
 229                 @refs = ();
 230
 231                 # prevent circular references via References: here:
 232                 foreach my $ref (@orig_refs) {
 233                         next if $uniq{$ref};
 234                         $uniq{$ref} = 1;
 235                         push @refs, $ref;
 236                 }
 237         }
 238         if (@refs) {
 239                 $smsg->{references} = '<'.join('> <', @refs).'>';
 240
 241                 # first ref *should* be the thread root,
 242                 # but we can never trust clients to do the right thing
 243                 my $ref = shift @refs;
 244                 $tid = $self->_resolve_mid_to_tid($ref);
 245
 246                 # the rest of the refs should point to this tid:
 247                 foreach $ref (@refs) {
 248                         my $ptid = $self->_resolve_mid_to_tid($ref);
 249                         if ($tid ne $ptid) {
 250                                 $self->merge_threads($tid, $ptid);
 251                         }
 252                 }
 253         } else {
 254                 $tid = $self->next_thread_id;
 255         }
 256         $doc->add_term(xpfx('thread') . $tid);
 257 }
 258
 259 sub index_blob {
 260         my ($self, $git, $mime, $bytes, $num) = @_;
 261         $self->add_message($mime, $bytes, $num);
 262 }
 263
 264 sub unindex_blob {
 265         my ($self, $git, $mime) = @_;
 266         my $mid = mid_clean($mime->header('Message-ID'));
 267         $self->remove_message($mid) if defined $mid;
 268 }
 269
 270 sub index_mm {
 271         my ($self, $git, $mime) = @_;
 272         $self->{mm}->mid_insert(mid_clean($mime->header('Message-ID')));
 273 }
 274
 275 sub unindex_mm {
 276         my ($self, $git, $mime) = @_;
 277         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 278 }
 279
 280 sub index_mm2 {
 281         my ($self, $git, $mime, $bytes) = @_;
 282         my $num = $self->{mm}->num_for(mid_clean($mime->header('Message-ID')));
 283         index_blob($self, $git, $mime, $bytes, $num);
 284 }
 285
 286 sub unindex_mm2 {
 287         my ($self, $git, $mime) = @_;
 288         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 289         unindex_blob($self, $git, $mime);
 290 }
 291
 292 sub index_both {
 293         my ($self, $git, $mime, $bytes) = @_;
 294         my $num = index_mm($self, $git, $mime);
 295         index_blob($self, $git, $mime, $bytes, $num);
 296 }
 297
 298 sub unindex_both {
 299         my ($self, $git, $mime) = @_;
 300         unindex_blob($self, $git, $mime);
 301         unindex_mm($self, $git, $mime);
 302 }
 303
 304 sub do_cat_mail {
 305         my ($git, $blob, $sizeref) = @_;
 306         my $mime = eval {
 307                 my $str = $git->cat_file($blob, $sizeref);
 308                 Email::MIME->new($str);
 309         };
 310         $@ ? undef : $mime;
 311 }
 312
 313 sub index_sync {
 314         my ($self, $head) = @_;
 315         $self->with_umask(sub { $self->_index_sync($head) });
 316 }
 317
 318 sub rlog {
 319         my ($self, $range, $add_cb, $del_cb) = @_;
 320         my $hex = '[a-f0-9]';
 321         my $h40 = $hex .'{40}';
 322         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 323         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 324         my $git_dir = $self->{git_dir};
 325         require PublicInbox::GitCatFile;
 326         my $git = PublicInbox::GitCatFile->new($git_dir);
 327         my @cmd = ('git', "--git-dir=$git_dir", "log",
 328                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 329                     $range);
 330         my $latest;
 331         my $bytes;
 332         my $pid = open(my $log, '-|', @cmd) or
 333                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 334         while (my $line = <$log>) {
 335                 if ($line =~ /$addmsg/o) {
 336                         my $mime = do_cat_mail($git, $1, \$bytes) or next;
 337                         $add_cb->($self, $git, $mime, $bytes);
 338                 } elsif ($line =~ /$delmsg/o) {
 339                         my $mime = do_cat_mail($git, $1) or next;
 340                         $del_cb->($self, $git, $mime);
 341                 } elsif ($line =~ /^commit ($h40)/o) {
 342                         $latest = $1;
 343                 }
 344         }
 345         close $log;
 346         $latest;
 347 }
 348
 349 # indexes all unindexed messages
 350 sub _index_sync {
 351         my ($self, $head) = @_;
 352         my $db = $self->{xdb};
 353         $head ||= 'HEAD';
 354         my $mm = $self->{mm} = eval {
 355                 require PublicInbox::Msgmap;
 356                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 357         };
 358
 359         $db->begin_transaction;
 360         my $lx = $db->get_metadata('last_commit');
 361         my $range = $lx eq '' ? $head : "$lx..$head";
 362         if ($mm) {
 363                 $mm->{dbh}->begin_work;
 364                 my $lm = $mm->last_commit || '';
 365                 if ($lm eq $lx) {
 366                         # Common case is the indexes are synced,
 367                         # we only need to run git-log once:
 368                         $lx = $self->rlog($range, *index_both, *unindex_both);
 369                         $mm->{dbh}->commit;
 370                         if (defined $lx) {
 371                                 $db->set_metadata('last_commit', $lx);
 372                                 $mm->last_commit($lx);
 373                         }
 374                 } else {
 375                         # dumb case, msgmap and xapian are out-of-sync
 376                         # do not care for performance:
 377                         my $r = $lm eq '' ? $head : "$lm..$head";
 378                         $lm = $self->rlog($r, *index_mm, *unindex_mm);
 379                         $mm->{dbh}->commit;
 380                         $mm->last_commit($lm) if defined $lm;
 381
 382                         $lx = $self->rlog($range, *index_mm2, *unindex_mm2);
 383                         $db->set_metadata('last_commit', $lx) if defined $lx;
 384                 }
 385         } else {
 386                 # user didn't install DBD::SQLite and DBI
 387                 $lx = $self->rlog($range, *index_blob, *unindex_blob);
 388                 $db->set_metadata('last_commit', $lx) if defined $lx;
 389         }
 390         if ($@) {
 391                 $db->cancel_transaction;
 392                 $mm->{dbh}->rollback if $mm;
 393         } else {
 394                 $db->commit_transaction;
 395         }
 396 }
 397
 398 # this will create a ghost as necessary
 399 sub _resolve_mid_to_tid {
 400         my ($self, $mid) = @_;
 401
 402         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 403         $smsg->thread_id;
 404 }
 405
 406 sub create_ghost {
 407         my ($self, $mid, $tid) = @_;
 408
 409         $tid = $self->next_thread_id unless defined $tid;
 410
 411         my $doc = Search::Xapian::Document->new;
 412         $doc->add_term(xpfx('mid') . $mid);
 413         $doc->add_term(xpfx('thread') . $tid);
 414         $doc->add_term(xpfx('type') . 'ghost');
 415
 416         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 417         $self->link_message($smsg, 1);
 418         $self->{xdb}->add_document($doc);
 419
 420         $smsg;
 421 }
 422
 423 sub merge_threads {
 424         my ($self, $winner_tid, $loser_tid) = @_;
 425         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 426         my $thread_pfx = xpfx('thread');
 427         my $db = $self->{xdb};
 428
 429         for (; $head != $tail; $head->inc) {
 430                 my $docid = $head->get_docid;
 431                 my $doc = $db->get_document($docid);
 432                 $doc->remove_term($thread_pfx . $loser_tid);
 433                 $doc->add_term($thread_pfx . $winner_tid);
 434                 $db->replace_document($docid, $doc);
 435         }
 436 }
 437
 438 sub _read_git_config_perm {
 439         my ($self) = @_;
 440         my @cmd = ('git', "--git-dir=$self->{git_dir}",
 441                    qw(config core.sharedRepository));
 442         my $pid = open(my $fh, '-|', @cmd) or
 443                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 444         my $perm = <$fh>;
 445         close $fh;
 446         chomp $perm if defined $perm;
 447         $perm;
 448 }
 449
 450 sub _git_config_perm {
 451         my $self = shift;
 452         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 453         return PERM_GROUP if (!defined($perm) || $perm eq '');
 454         return PERM_UMASK if ($perm eq 'umask');
 455         return PERM_GROUP if ($perm eq 'group');
 456         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 457                 return PERM_EVERYBODY;
 458         }
 459         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 460         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 461
 462         my $i = oct($perm);
 463         return PERM_UMASK if ($i == PERM_UMASK);
 464         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 465         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 466
 467         if (($i & 0600) != 0600) {
 468                 die "core.sharedRepository mode invalid: ".
 469                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 470         }
 471         ($i & 0666);
 472 }
 473
 474 sub _umask_for {
 475         my ($perm) = @_; # _git_config_perm return value
 476         my $rv = $perm;
 477         return umask if $rv == 0;
 478
 479         # set +x bit if +r or +w were set
 480         $rv |= 0100 if ($rv & 0600);
 481         $rv |= 0010 if ($rv & 0060);
 482         $rv |= 0001 if ($rv & 0006);
 483         (~$rv & 0777);
 484 }
 485
 486 sub with_umask {
 487         my ($self, $cb) = @_;
 488         my $old = umask $self->{umask};
 489         my $rv = eval { $cb->() };
 490         my $err = $@;
 491         umask $old;
 492         die $err if $@;
 493         $rv;
 494 }
 495
 496 1;