lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchIdx;
   5 use strict;
   6 use warnings;
   7 use base qw(PublicInbox::Search);
   8 use PublicInbox::MID qw/mid_clean mid_compress/;
   9 *xpfx = *PublicInbox::Search::xpfx;
  10
  11 use constant {
  12         PERM_UMASK => 0,
  13         OLD_PERM_GROUP => 1,
  14         OLD_PERM_EVERYBODY => 2,
  15         PERM_GROUP => 0660,
  16         PERM_EVERYBODY => 0664,
  17 };
  18
  19 sub new {
  20         my ($class, $git_dir, $writable) = @_;
  21         my $dir = $class->xdir($git_dir);
  22         require Search::Xapian::WritableDatabase;
  23         my $flag = Search::Xapian::DB_OPEN;
  24         my $self = bless { git_dir => $git_dir }, $class;
  25         my $perm = $self->_git_config_perm;
  26         my $umask = _umask_for($perm);
  27         $self->{umask} = $umask;
  28         $self->{xdb} = $self->with_umask(sub {
  29                 if ($writable == 1) {
  30                         require File::Path;
  31                         File::Path::mkpath($dir);
  32                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  33                 }
  34                 Search::Xapian::WritableDatabase->new($dir, $flag);
  35         });
  36         $self;
  37 }
  38
  39 sub add_message {
  40         my ($self, $mime) = @_; # mime = Email::MIME object
  41         my $db = $self->{xdb};
  42
  43         my $doc_id;
  44         my $mid_orig = mid_clean($mime->header('Message-ID'));
  45         my $mid = mid_compress($mid_orig);
  46         my $was_ghost = 0;
  47         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  48
  49         eval {
  50                 my $smsg = $self->lookup_message($mid);
  51                 my $doc;
  52
  53                 if ($smsg) {
  54                         $smsg->ensure_metadata;
  55                         # convert a ghost to a regular message
  56                         # it will also clobber any existing regular message
  57                         $smsg->mime($mime);
  58                         $doc = $smsg->{doc};
  59
  60                         my $type = xpfx('type');
  61                         eval {
  62                                 $doc->remove_term($type . 'ghost');
  63                                 $was_ghost = 1;
  64                         };
  65
  66                         # probably does not exist:
  67                         eval { $doc->remove_term($type . 'mail') };
  68                         $doc->add_term($type . 'mail');
  69                 }  else {
  70                         $smsg = PublicInbox::SearchMsg->new($mime);
  71                         $doc = $smsg->{doc};
  72                         $doc->add_term(xpfx('mid') . $mid);
  73                 }
  74
  75                 my $subj = $smsg->subject;
  76
  77                 if ($subj ne '') {
  78                         $doc->add_term(xpfx('subject') . $subj);
  79
  80                         my $path = $self->subject_path($subj);
  81                         $doc->add_term(xpfx('path') . mid_compress($path));
  82                 }
  83
  84                 my $from = $smsg->from_name;
  85                 my $date = $smsg->date;
  86                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
  87                 $doc->add_value(PublicInbox::Search::TS, $ts);
  88
  89                 my $tg = $self->term_generator;
  90
  91                 $tg->set_document($doc);
  92                 $tg->index_text($subj, 1, 'S') if $subj;
  93                 $tg->increase_termpos;
  94                 $tg->index_text($subj) if $subj;
  95                 $tg->increase_termpos;
  96
  97                 $tg->index_text($smsg->from->format);
  98                 $tg->increase_termpos;
  99
 100                 $mime->walk_parts(sub {
 101                         my ($part) = @_;
 102                         return if $part->subparts; # walk_parts already recurses
 103                         my $ct = $part->content_type || $ct_msg;
 104
 105                         # account for filter bugs...
 106                         $ct =~ m!\btext/plain\b!i or return;
 107
 108                         my (@orig, @quot);
 109                         my $body = $part->body;
 110                         $part->body_set('');
 111                         my @lines = split(/\n/, $body);
 112                         while (defined(my $l = shift @lines)) {
 113                                 if ($l =~ /^\s*>/) {
 114                                         push @quot, $l;
 115                                 } else {
 116                                         push @orig, $l;
 117                                 }
 118                         }
 119                         if (@quot) {
 120                                 $tg->index_text(join("\n", @quot), 0);
 121                                 @quot = ();
 122                                 $tg->increase_termpos;
 123                         }
 124                         if (@orig) {
 125                                 $tg->index_text(join("\n", @orig));
 126                                 @orig = ();
 127                                 $tg->increase_termpos;
 128                         }
 129                 });
 130
 131                 if ($was_ghost) {
 132                         $doc_id = $smsg->doc_id;
 133                         $self->link_message($smsg, 0);
 134                         $doc->set_data($smsg->to_doc_data);
 135                         $db->replace_document($doc_id, $doc);
 136                 } else {
 137                         $self->link_message($smsg, 0);
 138                         $doc->set_data($smsg->to_doc_data);
 139                         $doc_id = $db->add_document($doc);
 140                 }
 141         };
 142
 143         if ($@) {
 144                 warn "failed to index message <$mid_orig>: $@\n";
 145                 return undef;
 146         }
 147         $doc_id;
 148 }
 149
 150 # returns deleted doc_id on success, undef on missing
 151 sub remove_message {
 152         my ($self, $mid_orig) = @_;
 153         my $db = $self->{xdb};
 154         my $doc_id;
 155         $mid_orig = mid_clean($mid_orig);
 156         my $mid = mid_compress($mid_orig);
 157
 158         eval {
 159                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 160                 $db->delete_document($doc_id) if defined $doc_id;
 161         };
 162
 163         if ($@) {
 164                 warn "failed to remove message <$mid_orig>: $@\n";
 165                 return undef;
 166         }
 167         $doc_id;
 168 }
 169
 170 sub term_generator { # write-only
 171         my ($self) = @_;
 172
 173         my $tg = $self->{term_generator};
 174         return $tg if $tg;
 175
 176         $tg = Search::Xapian::TermGenerator->new;
 177         $tg->set_stemmer($self->stemmer);
 178
 179         $self->{term_generator} = $tg;
 180 }
 181
 182 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 183
 184 # increments last_thread_id counter
 185 # returns a 64-bit integer represented as a hex string
 186 sub next_thread_id {
 187         my ($self) = @_;
 188         my $db = $self->{xdb};
 189         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 190
 191         $db->set_metadata('last_thread_id', ++$last_thread_id);
 192
 193         $last_thread_id;
 194 }
 195
 196 sub link_message {
 197         my ($self, $smsg, $is_ghost) = @_;
 198
 199         if ($is_ghost) {
 200                 $smsg->ensure_metadata;
 201         } else {
 202                 $self->link_message_to_parents($smsg);
 203         }
 204 }
 205
 206 sub link_message_to_parents {
 207         my ($self, $smsg) = @_;
 208         my $doc = $smsg->{doc};
 209         my $mid = mid_compress($smsg->mid);
 210         my $mime = $smsg->mime;
 211         my $refs = $mime->header('References');
 212         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 213         my $irt = $mime->header('In-Reply-To');
 214         if ($irt) {
 215                 $irt = mid_compress(mid_clean($irt));
 216
 217                 # maybe some crazies will try to make a circular reference:
 218                 if ($irt eq $mid) {
 219                         $irt = undef;
 220                 } else {
 221                         # last References should be $irt
 222                         # we will de-dupe later
 223                         push @refs, $irt;
 224                 }
 225         }
 226
 227         my $tid;
 228         if (@refs) {
 229                 my @crefs = map { mid_compress($_) } @refs;
 230                 my %uniq = ($mid => 1);
 231
 232                 # prevent circular references via References: here:
 233                 @refs = ();
 234                 foreach my $ref (@crefs) {
 235                         next if $uniq{$ref};
 236                         $uniq{$ref} = 1;
 237                         push @refs, $ref;
 238                 }
 239         }
 240         if (@refs) {
 241                 $smsg->{references_sorted} = '<'.join('><', @refs).'>';
 242
 243                 # first ref *should* be the thread root,
 244                 # but we can never trust clients to do the right thing
 245                 my $ref = shift @refs;
 246                 $tid = $self->_resolve_mid_to_tid($ref);
 247
 248                 # the rest of the refs should point to this tid:
 249                 foreach $ref (@refs) {
 250                         my $ptid = $self->_resolve_mid_to_tid($ref);
 251                         if ($tid ne $ptid) {
 252                                 $self->merge_threads($tid, $ptid);
 253                         }
 254                 }
 255         } else {
 256                 $tid = $self->next_thread_id;
 257         }
 258         $doc->add_term(xpfx('thread') . $tid);
 259 }
 260
 261 sub index_blob {
 262         my ($self, $git, $blob) = @_;
 263         my $mime = do_cat_mail($git, $blob) or return;
 264         eval { $self->add_message($mime) };
 265         warn "W: index_blob $blob: $@\n" if $@;
 266 }
 267
 268 sub unindex_blob {
 269         my ($self, $git, $blob) = @_;
 270         my $mime = do_cat_mail($git, $blob) or return;
 271         my $mid = $mime->header('Message-ID');
 272         eval { $self->remove_message($mid) } if defined $mid;
 273         warn "W: unindex_blob $blob: $@\n" if $@;
 274 }
 275
 276 sub do_cat_mail {
 277         my ($git, $blob) = @_;
 278         my $mime = eval {
 279                 my $str = $git->cat_file($blob);
 280                 Email::MIME->new($str);
 281         };
 282         $@ ? undef : $mime;
 283 }
 284
 285 sub index_sync {
 286         my ($self, $head) = @_;
 287         $self->with_umask(sub { $self->_index_sync($head) });
 288 }
 289
 290 # indexes all unindexed messages
 291 sub _index_sync {
 292         my ($self, $head) = @_;
 293         require PublicInbox::GitCatFile;
 294         my $db = $self->{xdb};
 295         my $hex = '[a-f0-9]';
 296         my $h40 = $hex .'{40}';
 297         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 298         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 299         $head ||= 'HEAD';
 300
 301         $db->begin_transaction;
 302         eval {
 303                 my $git = PublicInbox::GitCatFile->new($self->{git_dir});
 304
 305                 my $latest = $db->get_metadata('last_commit');
 306                 my $range = $latest eq '' ? $head : "$latest..$head";
 307                 $latest = undef;
 308
 309                 # get indexed messages
 310                 my @cmd = ('git', "--git-dir=$self->{git_dir}", "log",
 311                             qw/--reverse --no-notes --no-color --raw -r
 312                                --no-abbrev/, $range);
 313                 my $pid = open(my $log, '-|', @cmd) or
 314                         die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 315
 316                 while (my $line = <$log>) {
 317                         if ($line =~ /$addmsg/o) {
 318                                 $self->index_blob($git, $1);
 319                         } elsif ($line =~ /$delmsg/o) {
 320                                 $self->unindex_blob($git, $1);
 321                         } elsif ($line =~ /^commit ($h40)/o) {
 322                                 $latest = $1;
 323                         }
 324                 }
 325                 close $log;
 326                 $db->set_metadata('last_commit', $latest) if defined $latest;
 327         };
 328         if ($@) {
 329                 warn "indexing failed: $@\n";
 330                 $db->cancel_transaction;
 331         } else {
 332                 $db->commit_transaction;
 333         }
 334 }
 335
 336 # this will create a ghost as necessary
 337 sub _resolve_mid_to_tid {
 338         my ($self, $mid) = @_;
 339
 340         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 341         $smsg->thread_id;
 342 }
 343
 344 sub create_ghost {
 345         my ($self, $mid, $tid) = @_;
 346
 347         $mid = mid_compress($mid);
 348         $tid = $self->next_thread_id unless defined $tid;
 349
 350         my $doc = Search::Xapian::Document->new;
 351         $doc->add_term(xpfx('mid') . $mid);
 352         $doc->add_term(xpfx('thread') . $tid);
 353         $doc->add_term(xpfx('type') . 'ghost');
 354
 355         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 356         $self->link_message($smsg, 1);
 357         $self->{xdb}->add_document($doc);
 358
 359         $smsg;
 360 }
 361
 362 sub merge_threads {
 363         my ($self, $winner_tid, $loser_tid) = @_;
 364         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 365         my $thread_pfx = xpfx('thread');
 366         my $db = $self->{xdb};
 367
 368         for (; $head != $tail; $head->inc) {
 369                 my $docid = $head->get_docid;
 370                 my $doc = $db->get_document($docid);
 371                 $doc->remove_term($thread_pfx . $loser_tid);
 372                 $doc->add_term($thread_pfx . $winner_tid);
 373                 $db->replace_document($docid, $doc);
 374         }
 375 }
 376
 377 sub _read_git_config_perm {
 378         my ($self) = @_;
 379         my @cmd = ('git', "--git-dir=$self->{git_dir}",
 380                    qw(config core.sharedRepository));
 381         my $pid = open(my $fh, '-|', @cmd) or
 382                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 383         my $perm = <$fh>;
 384         close $fh;
 385         chomp $perm if defined $perm;
 386         $perm;
 387 }
 388
 389 sub _git_config_perm {
 390         my $self = shift;
 391         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 392         return PERM_GROUP if (!defined($perm) || $perm eq '');
 393         return PERM_UMASK if ($perm eq 'umask');
 394         return PERM_GROUP if ($perm eq 'group');
 395         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 396                 return PERM_EVERYBODY;
 397         }
 398         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 399         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 400
 401         my $i = oct($perm);
 402         return PERM_UMASK if ($i == PERM_UMASK);
 403         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 404         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 405
 406         if (($i & 0600) != 0600) {
 407                 die "core.sharedRepository mode invalid: ".
 408                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 409         }
 410         ($i & 0666);
 411 }
 412
 413 sub _umask_for {
 414         my ($perm) = @_; # _git_config_perm return value
 415         my $rv = $perm;
 416         return umask if $rv == 0;
 417
 418         # set +x bit if +r or +w were set
 419         $rv |= 0100 if ($rv & 0600);
 420         $rv |= 0010 if ($rv & 0060);
 421         $rv |= 0001 if ($rv & 0006);
 422         (~$rv & 0777);
 423 }
 424
 425 sub with_umask {
 426         my ($self, $cb) = @_;
 427         my $old = umask $self->{umask};
 428         my $rv = eval { $cb->() };
 429         my $err = $@;
 430         umask $old;
 431         die $err if $@;
 432         $rv;
 433 }
 434
 435 1;