lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by Mail::Thread.  This writes to the search
   8 # index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use Email::MIME;
  14 use Email::MIME::ContentType;
  15 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  16 use base qw(PublicInbox::Search);
  17 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  18 use PublicInbox::MsgIter;
  19 use Carp qw(croak);
  20 use POSIX qw(strftime);
  21 require PublicInbox::Git;
  22 *xpfx = *PublicInbox::Search::xpfx;
  23
  24 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  25 use constant {
  26         PERM_UMASK => 0,
  27         OLD_PERM_GROUP => 1,
  28         OLD_PERM_EVERYBODY => 2,
  29         PERM_GROUP => 0660,
  30         PERM_EVERYBODY => 0664,
  31 };
  32
  33 sub new {
  34         my ($class, $inbox, $creat) = @_;
  35         my $git_dir = $inbox;
  36         my $altid;
  37         if (ref $inbox) {
  38                 $git_dir = $inbox->{mainrepo};
  39                 $altid = $inbox->{altid};
  40                 if ($altid) {
  41                         require PublicInbox::AltId;
  42                         $altid = [ map {
  43                                 PublicInbox::AltId->new($inbox, $_);
  44                         } @$altid ];
  45                 }
  46         }
  47         require Search::Xapian::WritableDatabase;
  48         my $self = bless { git_dir => $git_dir, -altid => $altid }, $class;
  49         my $perm = $self->_git_config_perm;
  50         my $umask = _umask_for($perm);
  51         $self->{umask} = $umask;
  52         $self->{lock_path} = "$git_dir/ssoma.lock";
  53         $self->{git} = PublicInbox::Git->new($git_dir);
  54         $self->{creat} = ($creat || 0) == 1;
  55         $self;
  56 }
  57
  58 sub _xdb_release {
  59         my ($self) = @_;
  60         my $xdb = delete $self->{xdb} or croak 'not acquired';
  61         $xdb->close;
  62         _lock_release($self) if $self->{creat};
  63         undef;
  64 }
  65
  66 sub _xdb_acquire {
  67         my ($self) = @_;
  68         croak 'already acquired' if $self->{xdb};
  69         my $dir = PublicInbox::Search->xdir($self->{git_dir});
  70         my $flag = Search::Xapian::DB_OPEN;
  71         if ($self->{creat}) {
  72                 require File::Path;
  73                 _lock_acquire($self);
  74                 File::Path::mkpath($dir);
  75                 $self->{batch_size} = 100;
  76                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  77         }
  78         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
  79 }
  80
  81 # we only acquire the flock if creating or reindexing;
  82 # PublicInbox::Import already has the lock on its own.
  83 sub _lock_acquire {
  84         my ($self) = @_;
  85         croak 'already locked' if $self->{lockfh};
  86         sysopen(my $lockfh, $self->{lock_path}, O_WRONLY|O_CREAT) or
  87                 die "failed to open lock $self->{lock_path}: $!\n";
  88         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
  89         $self->{lockfh} = $lockfh;
  90 }
  91
  92 sub _lock_release {
  93         my ($self) = @_;
  94         my $lockfh = delete $self->{lockfh} or croak 'not locked';
  95         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
  96         close $lockfh or die "close failed: $!\n";
  97 }
  98
  99 sub add_val ($$$) {
 100         my ($doc, $col, $num) = @_;
 101         $num = Search::Xapian::sortable_serialise($num);
 102         $doc->add_value($col, $num);
 103 }
 104
 105 sub add_values ($$$) {
 106         my ($smsg, $bytes, $num) = @_;
 107
 108         my $ts = $smsg->ts;
 109         my $doc = $smsg->{doc};
 110         add_val($doc, &PublicInbox::Search::TS, $ts);
 111
 112         defined($num) and add_val($doc, &PublicInbox::Search::NUM, $num);
 113
 114         defined($bytes) and add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 115
 116         add_val($doc, &PublicInbox::Search::LINES,
 117                         $smsg->{mime}->body_raw =~ tr!\n!\n!);
 118
 119         my $yyyymmdd = strftime('%Y%m%d', gmtime($ts));
 120         $doc->add_value(&PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 121 }
 122
 123 sub index_users ($$) {
 124         my ($tg, $smsg) = @_;
 125
 126         my $from = $smsg->from;
 127         my $to = $smsg->to;
 128         my $cc = $smsg->cc;
 129
 130         $tg->index_text($from, 1, 'A'); # A - author
 131         $tg->increase_termpos;
 132
 133         $tg->index_text($to, 1, 'XTO') if $to ne '';
 134         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 135         my $tc = join("\t", $to, $cc);
 136         $tg->index_text($tc, 1, 'XTC') if $tc ne '';
 137         my $tcf = join("\t", $tc, $from);
 138         $tg->index_text($tcf, 1, 'XTCF') if $tcf ne '';
 139
 140         $tg->index_text($from);
 141         $tg->increase_termpos;
 142 }
 143
 144 sub add_message {
 145         my ($self, $mime, $bytes, $num, $blob) = @_; # mime = Email::MIME object
 146         my $db = $self->{xdb};
 147
 148         my ($doc_id, $old_tid);
 149         my $mid = mid_clean(mid_mime($mime));
 150         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
 151
 152         eval {
 153                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
 154                 my $smsg = $self->lookup_message($mid);
 155                 if ($smsg) {
 156                         # convert a ghost to a regular message
 157                         # it will also clobber any existing regular message
 158                         $doc_id = $smsg->doc_id;
 159                         $old_tid = $smsg->thread_id;
 160                 }
 161                 $smsg = PublicInbox::SearchMsg->new($mime);
 162                 my $doc = $smsg->{doc};
 163                 $doc->add_term(xpfx('mid') . $mid);
 164
 165                 my $subj = $smsg->subject;
 166                 if ($subj ne '') {
 167                         my $path = $self->subject_path($subj);
 168                         $doc->add_term(xpfx('path') . id_compress($path));
 169                 }
 170
 171                 add_values($smsg, $bytes, $num);
 172
 173                 my $tg = $self->term_generator;
 174
 175                 $tg->set_document($doc);
 176                 if ($subj) {
 177                         $tg->index_text($subj, 1, 'S');
 178                         $tg->index_text($subj, 1, 'XBS');
 179                 }
 180                 $tg->increase_termpos;
 181                 $tg->index_text($subj) if $subj;
 182                 $tg->increase_termpos;
 183
 184                 index_users($tg, $smsg);
 185
 186                 msg_iter($mime, sub {
 187                         my ($part, $depth, @idx) = @{$_[0]};
 188                         my $ct = $part->content_type || $ct_msg;
 189
 190                         # account for filter bugs...
 191                         $ct =~ m!\btext/plain\b!i or return;
 192
 193                         my (@orig, @quot);
 194                         my $body = $part->body;
 195                         $part->body_set('');
 196                         my @lines = split(/\n/, $body);
 197                         while (defined(my $l = shift @lines)) {
 198                                 if ($l =~ /^\s*>/) {
 199                                         push @quot, $l;
 200                                 } else {
 201                                         push @orig, $l;
 202                                 }
 203                         }
 204                         if (@quot) {
 205                                 my $s = join("\n", @quot);
 206                                 @quot = ();
 207                                 $tg->index_text($s, 1, 'XQUOT');
 208                                 $tg->index_text($s, 0, 'XBS');
 209                                 $tg->index_text($s, 0, 'XBODY');
 210                                 $tg->index_text($s, 0);
 211                                 $tg->increase_termpos;
 212                         }
 213                         if (@orig) {
 214                                 my $s = join("\n", @orig);
 215                                 @orig = ();
 216                                 $tg->index_text($s, 1, 'XNQ');
 217                                 $tg->index_text($s, 1, 'XBS');
 218                                 $tg->index_text($s, 1, 'XBODY');
 219                                 $tg->index_text($s);
 220                                 $tg->increase_termpos;
 221                         }
 222                 });
 223
 224                 link_message($self, $smsg, $old_tid);
 225                 $tg->index_text($mid, 1);
 226                 $doc->set_data($smsg->to_doc_data($blob));
 227
 228                 if (my $altid = $self->{-altid}) {
 229                         foreach my $alt (@$altid) {
 230                                 my $id = $alt->mid2alt($mid);
 231                                 next unless defined $id;
 232                                 $doc->add_term($alt->{xprefix} . $id);
 233                         }
 234                 }
 235                 if (defined $doc_id) {
 236                         $db->replace_document($doc_id, $doc);
 237                 } else {
 238                         $doc_id = $db->add_document($doc);
 239                 }
 240         };
 241
 242         if ($@) {
 243                 warn "failed to index message <$mid>: $@\n";
 244                 return undef;
 245         }
 246         $doc_id;
 247 }
 248
 249 # returns deleted doc_id on success, undef on missing
 250 sub remove_message {
 251         my ($self, $mid) = @_;
 252         my $db = $self->{xdb};
 253         my $doc_id;
 254         $mid = mid_clean($mid);
 255
 256         eval {
 257                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 258                 $db->delete_document($doc_id) if defined $doc_id;
 259         };
 260
 261         if ($@) {
 262                 warn "failed to remove message <$mid>: $@\n";
 263                 return undef;
 264         }
 265         $doc_id;
 266 }
 267
 268 sub term_generator { # write-only
 269         my ($self) = @_;
 270
 271         my $tg = $self->{term_generator};
 272         return $tg if $tg;
 273
 274         $tg = Search::Xapian::TermGenerator->new;
 275         $tg->set_stemmer($self->stemmer);
 276
 277         $self->{term_generator} = $tg;
 278 }
 279
 280 # increments last_thread_id counter
 281 # returns a 64-bit integer represented as a hex string
 282 sub next_thread_id {
 283         my ($self) = @_;
 284         my $db = $self->{xdb};
 285         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 286
 287         $db->set_metadata('last_thread_id', ++$last_thread_id);
 288
 289         $last_thread_id;
 290 }
 291
 292 sub link_message {
 293         my ($self, $smsg, $old_tid) = @_;
 294         my $doc = $smsg->{doc};
 295         my $mid = $smsg->mid;
 296         my $mime = $smsg->mime;
 297         my $hdr = $mime->header_obj;
 298         my $refs = $hdr->header_raw('References');
 299         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 300         if (my $irt = $hdr->header_raw('In-Reply-To')) {
 301                 # last References should be $irt
 302                 # we will de-dupe later
 303                 push @refs, mid_clean($irt);
 304         }
 305
 306         my $tid;
 307         if (@refs) {
 308                 my %uniq = ($mid => 1);
 309                 my @orig_refs = @refs;
 310                 @refs = ();
 311
 312                 # prevent circular references via References: here:
 313                 foreach my $ref (@orig_refs) {
 314                         if (length($ref) > MAX_MID_SIZE) {
 315                                 warn "References: <$ref> too long, ignoring\n";
 316                         }
 317                         next if $uniq{$ref};
 318                         $uniq{$ref} = 1;
 319                         push @refs, $ref;
 320                 }
 321         }
 322         if (@refs) {
 323                 $smsg->{references} = '<'.join('> <', @refs).'>';
 324
 325                 # first ref *should* be the thread root,
 326                 # but we can never trust clients to do the right thing
 327                 my $ref = shift @refs;
 328                 $tid = $self->_resolve_mid_to_tid($ref);
 329                 $self->merge_threads($tid, $old_tid) if defined $old_tid;
 330
 331                 # the rest of the refs should point to this tid:
 332                 foreach $ref (@refs) {
 333                         my $ptid = $self->_resolve_mid_to_tid($ref);
 334                         merge_threads($self, $tid, $ptid);
 335                 }
 336         } else {
 337                 $tid = $self->next_thread_id;
 338         }
 339         $doc->add_term(xpfx('thread') . $tid);
 340 }
 341
 342 sub index_blob {
 343         my ($self, $mime, $bytes, $num, $blob) = @_;
 344         $self->add_message($mime, $bytes, $num, $blob);
 345 }
 346
 347 sub unindex_blob {
 348         my ($self, $mime) = @_;
 349         my $mid = eval { mid_clean(mid_mime($mime)) };
 350         $self->remove_message($mid) if defined $mid;
 351 }
 352
 353 sub index_mm {
 354         my ($self, $mime) = @_;
 355         $self->{mm}->mid_insert(mid_clean(mid_mime($mime)));
 356 }
 357
 358 sub unindex_mm {
 359         my ($self, $mime) = @_;
 360         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 361 }
 362
 363 sub index_mm2 {
 364         my ($self, $mime, $bytes, $blob) = @_;
 365         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 366         index_blob($self, $mime, $bytes, $num, $blob);
 367 }
 368
 369 sub unindex_mm2 {
 370         my ($self, $mime) = @_;
 371         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 372         unindex_blob($self, $mime);
 373 }
 374
 375 sub index_both {
 376         my ($self, $mime, $bytes, $blob) = @_;
 377         my $num = index_mm($self, $mime);
 378         index_blob($self, $mime, $bytes, $num, $blob);
 379 }
 380
 381 sub unindex_both {
 382         my ($self, $mime) = @_;
 383         unindex_blob($self, $mime);
 384         unindex_mm($self, $mime);
 385 }
 386
 387 sub do_cat_mail {
 388         my ($git, $blob, $sizeref) = @_;
 389         my $mime = eval {
 390                 my $str = $git->cat_file($blob, $sizeref);
 391                 # fixup bugs from import:
 392                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 393                 Email::MIME->new($str);
 394         };
 395         $@ ? undef : $mime;
 396 }
 397
 398 sub index_sync {
 399         my ($self, $opts) = @_;
 400         with_umask($self, sub { $self->_index_sync($opts) });
 401 }
 402
 403 sub rlog {
 404         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 405         my $hex = '[a-f0-9]';
 406         my $h40 = $hex .'{40}';
 407         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 408         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 409         my $git = $self->{git};
 410         my $latest;
 411         my $bytes;
 412         my $max = $self->{batch_size}; # may be undef
 413         local $/ = "\n";
 414         my $line;
 415         while (defined($line = <$log>)) {
 416                 if ($line =~ /$addmsg/o) {
 417                         my $blob = $1;
 418                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 419                         $add_cb->($self, $mime, $bytes, $blob);
 420                 } elsif ($line =~ /$delmsg/o) {
 421                         my $blob = $1;
 422                         my $mime = do_cat_mail($git, $blob) or next;
 423                         $del_cb->($self, $mime);
 424                 } elsif ($line =~ /^commit ($h40)/o) {
 425                         if (defined $max && --$max <= 0) {
 426                                 $max = $self->{batch_size};
 427                                 $batch_cb->($latest, 1);
 428                         }
 429                         $latest = $1;
 430                 }
 431         }
 432         $batch_cb->($latest, 0);
 433 }
 434
 435 sub _msgmap_init {
 436         my ($self) = @_;
 437         $self->{mm} = eval {
 438                 require PublicInbox::Msgmap;
 439                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 440         };
 441 }
 442
 443 sub _git_log {
 444         my ($self, $range) = @_;
 445         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 446                                 --raw -r --no-abbrev/, $range);
 447 }
 448
 449 # indexes all unindexed messages
 450 sub _index_sync {
 451         my ($self, $opts) = @_;
 452         my $tip = $opts->{ref} || 'HEAD';
 453         my $reindex = $opts->{reindex};
 454         my ($mkey, $last_commit, $lx, $xlog);
 455         $self->{git}->batch_prepare;
 456         my $xdb = _xdb_acquire($self);
 457         $xdb->begin_transaction;
 458         do {
 459                 $xlog = undef;
 460                 $mkey = 'last_commit';
 461                 $last_commit = $xdb->get_metadata('last_commit');
 462                 $lx = $last_commit;
 463                 if ($reindex) {
 464                         $lx = '';
 465                         $mkey = undef if $last_commit ne '';
 466                 }
 467                 $xdb->cancel_transaction;
 468                 $xdb = _xdb_release($self);
 469
 470                 # ensure we leak no FDs to "git log"
 471                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 472                 $xlog = _git_log($self, $range);
 473
 474                 $xdb = _xdb_acquire($self);
 475                 $xdb->begin_transaction;
 476         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 477
 478         my $mm = _msgmap_init($self);
 479         my $dbh = $mm->{dbh} if $mm;
 480         my $mm_only;
 481         my $cb = sub {
 482                 my ($commit, $more) = @_;
 483                 if ($dbh) {
 484                         $mm->last_commit($commit) if $commit;
 485                         $dbh->commit;
 486                 }
 487                 if (!$mm_only) {
 488                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 489                         $xdb->commit_transaction;
 490                         $xdb = _xdb_release($self);
 491                 }
 492                 # let another process do some work... <
 493                 if ($more) {
 494                         if (!$mm_only) {
 495                                 $xdb = _xdb_acquire($self);
 496                                 $xdb->begin_transaction;
 497                         }
 498                         $dbh->begin_work if $dbh;
 499                 }
 500         };
 501
 502         if ($mm) {
 503                 $dbh->begin_work;
 504                 my $lm = $mm->last_commit || '';
 505                 if ($lm eq $lx) {
 506                         # Common case is the indexes are synced,
 507                         # we only need to run git-log once:
 508                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 509                 } else {
 510                         # Uncommon case, msgmap and xapian are out-of-sync
 511                         # do not care for performance (but git is fast :>)
 512                         # This happens if we have to reindex Xapian since
 513                         # msgmap is a frozen format and our Xapian format
 514                         # is evolving.
 515                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 516
 517                         # first, ensure msgmap is up-to-date:
 518                         my $mkey_prev = $mkey;
 519                         $mkey = undef; # ignore xapian, for now
 520                         my $mlog = _git_log($self, $r);
 521                         $mm_only = 1;
 522                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 523                         $mm_only = $mlog = undef;
 524
 525                         # now deal with Xapian
 526                         $mkey = $mkey_prev;
 527                         $dbh = undef;
 528                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 529                 }
 530         } else {
 531                 # user didn't install DBD::SQLite and DBI
 532                 rlog($self, $xlog, *index_blob, *unindex_blob, $cb);
 533         }
 534 }
 535
 536 # this will create a ghost as necessary
 537 sub _resolve_mid_to_tid {
 538         my ($self, $mid) = @_;
 539
 540         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 541         $smsg->thread_id;
 542 }
 543
 544 sub create_ghost {
 545         my ($self, $mid) = @_;
 546
 547         my $tid = $self->next_thread_id;
 548         my $doc = Search::Xapian::Document->new;
 549         $doc->add_term(xpfx('mid') . $mid);
 550         $doc->add_term(xpfx('thread') . $tid);
 551         $doc->add_term(xpfx('type') . 'ghost');
 552
 553         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 554         $self->{xdb}->add_document($doc);
 555
 556         $smsg;
 557 }
 558
 559 sub merge_threads {
 560         my ($self, $winner_tid, $loser_tid) = @_;
 561         return if $winner_tid == $loser_tid;
 562         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 563         my $thread_pfx = xpfx('thread');
 564         my $db = $self->{xdb};
 565
 566         for (; $head != $tail; $head->inc) {
 567                 my $docid = $head->get_docid;
 568                 my $doc = $db->get_document($docid);
 569                 $doc->remove_term($thread_pfx . $loser_tid);
 570                 $doc->add_term($thread_pfx . $winner_tid);
 571                 $db->replace_document($docid, $doc);
 572         }
 573 }
 574
 575 sub _read_git_config_perm {
 576         my ($self) = @_;
 577         my @cmd = qw(config core.sharedRepository);
 578         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 579         local $/ = "\n";
 580         my $perm = <$fh>;
 581         chomp $perm if defined $perm;
 582         $perm;
 583 }
 584
 585 sub _git_config_perm {
 586         my $self = shift;
 587         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 588         return PERM_GROUP if (!defined($perm) || $perm eq '');
 589         return PERM_UMASK if ($perm eq 'umask');
 590         return PERM_GROUP if ($perm eq 'group');
 591         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 592                 return PERM_EVERYBODY;
 593         }
 594         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 595         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 596
 597         my $i = oct($perm);
 598         return PERM_UMASK if ($i == PERM_UMASK);
 599         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 600         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 601
 602         if (($i & 0600) != 0600) {
 603                 die "core.sharedRepository mode invalid: ".
 604                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 605         }
 606         ($i & 0666);
 607 }
 608
 609 sub _umask_for {
 610         my ($perm) = @_; # _git_config_perm return value
 611         my $rv = $perm;
 612         return umask if $rv == 0;
 613
 614         # set +x bit if +r or +w were set
 615         $rv |= 0100 if ($rv & 0600);
 616         $rv |= 0010 if ($rv & 0060);
 617         $rv |= 0001 if ($rv & 0006);
 618         (~$rv & 0777);
 619 }
 620
 621 sub with_umask {
 622         my ($self, $cb) = @_;
 623         my $old = umask $self->{umask};
 624         my $rv = eval { $cb->() };
 625         my $err = $@;
 626         umask $old;
 627         die $err if $@;
 628         $rv;
 629 }
 630
 631 sub DESTROY {
 632         # order matters for unlocking
 633         $_[0]->{xdb} = undef;
 634         $_[0]->{lockfh} = undef;
 635 }
 636
 637 1;