lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 require PublicInbox::Git;
  22 use Compress::Zlib qw(compress);
  23
  24 use constant {
  25         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000,
  27         DEBUG => !!$ENV{DEBUG},
  28 };
  29
  30 my $xapianlevels = qr/\A(?:full|medium)\z/;
  31
  32 my %GIT_ESC = (
  33         a => "\a",
  34         b => "\b",
  35         f => "\f",
  36         n => "\n",
  37         r => "\r",
  38         t => "\t",
  39         v => "\013",
  40 );
  41
  42 sub git_unquote ($) {
  43         my ($s) = @_;
  44         return $s unless ($s =~ /\A"(.*)"\z/);
  45         $s = $1;
  46         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  47         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  48         $s;
  49 }
  50
  51 sub new {
  52         my ($class, $ibx, $creat, $part) = @_;
  53         my $levels = qr/\A(?:full|medium|basic)\z/;
  54         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  55         my $git_dir = $mainrepo;
  56         my ($altid, $git);
  57         my $version = 1;
  58         my $indexlevel = 'full';
  59         if (ref $ibx) {
  60                 $mainrepo = $ibx->{mainrepo};
  61                 $altid = $ibx->{altid};
  62                 $version = $ibx->{version} || 1;
  63                 if ($altid) {
  64                         require PublicInbox::AltId;
  65                         $altid = [ map {
  66                                 PublicInbox::AltId->new($ibx, $_);
  67                         } @$altid ];
  68                 }
  69                 if ($ibx->{indexlevel}) {
  70                         if ($ibx->{indexlevel} =~ $levels) {
  71                                 $indexlevel = $ibx->{indexlevel};
  72                         } else {
  73                                 die("Invalid indexlevel $ibx->{indexlevel}\n");
  74                         }
  75                 }
  76         } else { # v1
  77                 $ibx = { mainrepo => $git_dir, version => 1 };
  78         }
  79         $ibx = PublicInbox::InboxWritable->new($ibx);
  80         require Search::Xapian::WritableDatabase;
  81         my $self = bless {
  82                 mainrepo => $mainrepo,
  83                 -inbox => $ibx,
  84                 git => $ibx->git,
  85                 -altid => $altid,
  86                 version => $version,
  87                 indexlevel => $indexlevel,
  88         }, $class;
  89         $ibx->umask_prepare;
  90         if ($version == 1) {
  91                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  92                 my $dir = $self->xdir;
  93                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  94         } elsif ($version == 2) {
  95                 defined $part or die "partition is required for v2\n";
  96                 # partition is a number
  97                 $self->{partition} = $part;
  98                 $self->{lock_path} = undef;
  99         } else {
 100                 die "unsupported inbox version=$version\n";
 101         }
 102         $self->{creat} = ($creat || 0) == 1;
 103         $self;
 104 }
 105
 106 sub _xdb_release {
 107         my ($self) = @_;
 108         my $xdb = delete $self->{xdb} or croak 'not acquired';
 109         $xdb->close;
 110         $self->lock_release if $self->{creat};
 111         undef;
 112 }
 113
 114 sub _xdb_acquire {
 115         my ($self) = @_;
 116         croak 'already acquired' if $self->{xdb};
 117         my $dir = $self->xdir;
 118         my $flag = Search::Xapian::DB_OPEN;
 119         if ($self->{creat}) {
 120                 require File::Path;
 121                 $self->lock_acquire;
 122                 File::Path::mkpath($dir);
 123                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 124         }
 125         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 126 }
 127
 128 sub add_val ($$$) {
 129         my ($doc, $col, $num) = @_;
 130         $num = Search::Xapian::sortable_serialise($num);
 131         $doc->add_value($col, $num);
 132 }
 133
 134 sub index_text ($$$$)
 135 {
 136         my ($self, $field, $n, $text) = @_;
 137         my $tg = $self->term_generator;
 138
 139         if ($self->{indexlevel} eq 'full') {
 140                 $tg->index_text($field, $n, $text);
 141                 $tg->increase_termpos;
 142         } else {
 143                 $tg->index_text_without_positions($field, $n, $text);
 144         }
 145 }
 146
 147 sub index_users ($$) {
 148         my ($self, $smsg) = @_;
 149
 150         my $from = $smsg->from;
 151         my $to = $smsg->to;
 152         my $cc = $smsg->cc;
 153
 154         $self->index_text($from, 1, 'A'); # A - author
 155         $self->index_text($to, 1, 'XTO') if $to ne '';
 156         $self->index_text($cc, 1, 'XCC') if $cc ne '';
 157 }
 158
 159 sub index_diff_inc ($$$$) {
 160         my ($self, $text, $pfx, $xnq) = @_;
 161         if (@$xnq) {
 162                 $self->index_text(join("\n", @$xnq), 1, 'XNQ');
 163                 @$xnq = ();
 164         }
 165         $self->index_text($text, 1, $pfx);
 166 }
 167
 168 sub index_old_diff_fn {
 169         my ($self, $seen, $fa, $fb, $xnq) = @_;
 170
 171         # no renames or space support for traditional diffs,
 172         # find the number of leading common paths to strip:
 173         my @fa = split('/', $fa);
 174         my @fb = split('/', $fb);
 175         while (scalar(@fa) && scalar(@fb)) {
 176                 $fa = join('/', @fa);
 177                 $fb = join('/', @fb);
 178                 if ($fa eq $fb) {
 179                         unless ($seen->{$fa}++) {
 180                                 $self->index_diff_inc($fa, 'XDFN', $xnq);
 181                         }
 182                         return 1;
 183                 }
 184                 shift @fa;
 185                 shift @fb;
 186         }
 187         0;
 188 }
 189
 190 sub index_diff ($$$) {
 191         my ($self, $lines, $doc) = @_;
 192         my %seen;
 193         my $in_diff;
 194         my @xnq;
 195         my $xnq = \@xnq;
 196         foreach (@$lines) {
 197                 if ($in_diff && s/^ //) { # diff context
 198                         $self->index_diff_inc($_, 'XDFCTX', $xnq);
 199                 } elsif (/^-- $/) { # email signature begins
 200                         $in_diff = undef;
 201                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 202                         my ($fa, $fb) = ($1, $2);
 203                         my $fn = (split('/', git_unquote($fa), 2))[1];
 204                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 205                         $fn = (split('/', git_unquote($fb), 2))[1];
 206                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 207                         $in_diff = 1;
 208                 # traditional diff:
 209                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 210                         my ($opt, $fa, $fb) = ($1, $2, $3);
 211                         push @xnq, $_;
 212                         # only support unified:
 213                         next unless $opt =~ /[uU]/;
 214                         $in_diff = $self->index_old_diff_fn(\%seen, $fa, $fb,
 215                                                         $xnq);
 216                 } elsif (m!^--- ("?a/.+)!) {
 217                         my $fn = (split('/', git_unquote($1), 2))[1];
 218                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 219                         $in_diff = 1;
 220                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 221                         my $fn = (split('/', git_unquote($1), 2))[1];
 222                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 223                         $in_diff = 1;
 224                 } elsif (/^--- (\S+)/) {
 225                         $in_diff = $1;
 226                         push @xnq, $_;
 227                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 228                         $in_diff = $self->index_old_diff_fn(\%seen, $in_diff, $1,
 229                                                         $xnq);
 230                 } elsif ($in_diff && s/^\+//) { # diff added
 231                         $self->index_diff_inc($_, 'XDFB', $xnq);
 232                 } elsif ($in_diff && s/^-//) { # diff removed
 233                         $self->index_diff_inc($_, 'XDFA', $xnq);
 234                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 235                         my ($ba, $bb) = ($1, $2);
 236                         index_git_blob_id($doc, 'XDFPRE', $ba);
 237                         index_git_blob_id($doc, 'XDFPOST', $bb);
 238                         $in_diff = 1;
 239                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 240                         # traditional diff w/o -p
 241                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 242                         # hunk header context
 243                         $self->index_diff_inc($1, 'XDFHH', $xnq);
 244                 # ignore the following lines:
 245                 } elsif (/^(?:dis)similarity index/ ||
 246                                 /^(?:old|new) mode/ ||
 247                                 /^(?:deleted|new) file mode/ ||
 248                                 /^(?:copy|rename) (?:from|to) / ||
 249                                 /^(?:dis)?similarity index / ||
 250                                 /^\\ No newline at end of file/ ||
 251                                 /^Binary files .* differ/) {
 252                         push @xnq, $_;
 253                 } elsif ($_ eq '') {
 254                         $in_diff = undef;
 255                 } else {
 256                         push @xnq, $_;
 257                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 258                         $in_diff = undef;
 259                 }
 260         }
 261
 262         $self->index_text(join("\n", @xnq), 1, 'XNQ');
 263 }
 264
 265 sub index_body ($$$) {
 266         my ($self, $lines, $doc) = @_;
 267         my $txt = join("\n", @$lines);
 268         if ($doc) {
 269                 # does it look like a diff?
 270                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 271                         $txt = undef;
 272                         $self->index_diff($lines, $doc);
 273                 } else {
 274                         $self->index_text($txt, 1, 'XNQ');
 275                 }
 276         } else {
 277                 $self->index_text($txt, 0, 'XQUOT');
 278         }
 279         @$lines = ();
 280 }
 281
 282 sub add_xapian ($$$$$) {
 283         my ($self, $mime, $num, $oid, $mids, $mid0) = @_;
 284         my $smsg = PublicInbox::SearchMsg->new($mime);
 285         my $doc = $smsg->{doc};
 286         my $subj = $smsg->subject;
 287         add_val($doc, PublicInbox::Search::TS(), $smsg->ts);
 288         my @ds = gmtime($smsg->ds);
 289         my $yyyymmdd = strftime('%Y%m%d', @ds);
 290         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 291         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 292         add_val($doc, PublicInbox::Search::DT(), $dt);
 293
 294         my $tg = $self->term_generator;
 295
 296         $tg->set_document($doc);
 297         $self->index_text($subj, 1, 'S') if $subj;
 298         $self->index_users($smsg);
 299
 300         msg_iter($mime, sub {
 301                 my ($part, $depth, @idx) = @{$_[0]};
 302                 my $ct = $part->content_type || 'text/plain';
 303                 my $fn = $part->filename;
 304                 if (defined $fn && $fn ne '') {
 305                         $self->index_text($fn, 1, 'XFN');
 306                 }
 307
 308                 return if $ct =~ m!\btext/x?html\b!i;
 309
 310                 my $s = eval { $part->body_str };
 311                 if ($@) {
 312                         if ($ct =~ m!\btext/plain\b!i) {
 313                                 # Try to assume UTF-8 because Alpine
 314                                 # seems to do wacky things and set
 315                                 # charset=X-UNKNOWN
 316                                 $part->charset_set('UTF-8');
 317                                 $s = eval { $part->body_str };
 318                                 $s = $part->body if $@;
 319                         }
 320                 }
 321                 defined $s or return;
 322
 323                 my (@orig, @quot);
 324                 my $body = $part->body;
 325                 my @lines = split(/\n/, $body);
 326                 while (defined(my $l = shift @lines)) {
 327                         if ($l =~ /^>/) {
 328                                 $self->index_body(\@orig, $doc) if @orig;
 329                                 push @quot, $l;
 330                         } else {
 331                                 $self->index_body(\@quot, 0) if @quot;
 332                                 push @orig, $l;
 333                         }
 334                 }
 335                 $self->index_body(\@quot, 0) if @quot;
 336                 $self->index_body(\@orig, $doc) if @orig;
 337         });
 338
 339         foreach my $mid (@$mids) {
 340                 $self->index_text($mid, 1, 'XM');
 341
 342                 # because too many Message-IDs are prefixed with
 343                 # "Pine.LNX."...
 344                 if ($mid =~ /\w{12,}/) {
 345                         my @long = ($mid =~ /(\w{3,}+)/g);
 346                         $self->index_text(join(' ', @long), 1, 'XM');
 347                 }
 348         }
 349         $smsg->{to} = $smsg->{cc} = '';
 350         PublicInbox::OverIdx::parse_references($smsg, $mid0, $mids);
 351         my $data = $smsg->to_doc_data($oid, $mid0);
 352         $doc->set_data($data);
 353         if (my $altid = $self->{-altid}) {
 354                 foreach my $alt (@$altid) {
 355                         my $pfx = $alt->{xprefix};
 356                         foreach my $mid (@$mids) {
 357                                 my $id = $alt->mid2alt($mid);
 358                                 next unless defined $id;
 359                                 $doc->add_boolean_term($pfx . $id);
 360                         }
 361                 }
 362         }
 363         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 364         $self->{xdb}->replace_document($num, $doc);
 365 }
 366
 367 sub add_message {
 368         # mime = Email::MIME object
 369         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 370         my $mids = mids($mime->header_obj);
 371         $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 372         unless (defined $num) { # v1
 373                 $self->_msgmap_init;
 374                 $num = index_mm($self, $mime);
 375         }
 376         eval {
 377                 if ($self->{indexlevel} =~ $xapianlevels) {
 378                         $self->add_xapian($mime, $num, $oid, $mids, $mid0)
 379                 }
 380                 if (my $over = $self->{over}) {
 381                         $over->add_overview($mime, $bytes, $num, $oid, $mid0);
 382                 }
 383         };
 384
 385         if ($@) {
 386                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 387                 return undef;
 388         }
 389         $num;
 390 }
 391
 392 # returns begin and end PostingIterator
 393 sub find_doc_ids {
 394         my ($self, $termval) = @_;
 395         my $db = $self->{xdb};
 396
 397         ($db->postlist_begin($termval), $db->postlist_end($termval));
 398 }
 399
 400 sub batch_do {
 401         my ($self, $termval, $cb) = @_;
 402         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 403         while (1) {
 404                 my ($head, $tail) = $self->find_doc_ids($termval);
 405                 return if $head == $tail;
 406                 my @ids;
 407                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 408                         push @ids, $head->get_docid;
 409                 }
 410                 $cb->(\@ids);
 411         }
 412 }
 413
 414 sub remove_message {
 415         my ($self, $mid) = @_;
 416         my $db = $self->{xdb};
 417         my $called;
 418         $mid = mid_clean($mid);
 419         my $over = $self->{over};
 420
 421         eval {
 422                 batch_do($self, 'Q' . $mid, sub {
 423                         my ($ids) = @_;
 424                         $db->delete_document($_) for @$ids;
 425                         $over->delete_articles($ids) if $over;
 426                         $called = 1;
 427                 });
 428         };
 429         if ($@) {
 430                 warn "failed to remove message <$mid>: $@\n";
 431         } elsif (!$called) {
 432                 warn "cannot remove non-existent <$mid>\n";
 433         }
 434 }
 435
 436 # MID is a hint in V2
 437 sub remove_by_oid {
 438         my ($self, $oid, $mid) = @_;
 439         my $db = $self->{xdb};
 440
 441         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 442
 443         # XXX careful, we cannot use batch_do here since we conditionally
 444         # delete documents based on other factors, so we cannot call
 445         # find_doc_ids twice.
 446         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 447         return if $head == $tail;
 448
 449         # there is only ONE element in @delete unless we
 450         # have bugs in our v2writable deduplication check
 451         my @delete;
 452         for (; $head != $tail; $head->inc) {
 453                 my $docid = $head->get_docid;
 454                 my $doc = $db->get_document($docid);
 455                 my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 456                 $smsg->load_expand;
 457                 if ($smsg->{blob} eq $oid) {
 458                         push(@delete, $docid);
 459                 }
 460         }
 461         $db->delete_document($_) foreach @delete;
 462         scalar(@delete);
 463 }
 464
 465 sub term_generator { # write-only
 466         my ($self) = @_;
 467
 468         my $tg = $self->{term_generator};
 469         return $tg if $tg;
 470
 471         $tg = Search::Xapian::TermGenerator->new;
 472         $tg->set_stemmer($self->stemmer);
 473
 474         $self->{term_generator} = $tg;
 475 }
 476
 477 sub index_git_blob_id {
 478         my ($doc, $pfx, $objid) = @_;
 479
 480         my $len = length($objid);
 481         for (my $len = length($objid); $len >= 7; ) {
 482                 $doc->add_term($pfx.$objid);
 483                 $objid = substr($objid, 0, --$len);
 484         }
 485 }
 486
 487 sub unindex_blob {
 488         my ($self, $mime) = @_;
 489         my $mid = eval { mid_clean(mid_mime($mime)) };
 490         $self->remove_message($mid) if defined $mid;
 491 }
 492
 493 sub index_mm {
 494         my ($self, $mime) = @_;
 495         my $mid = mid_clean(mid_mime($mime));
 496         my $mm = $self->{mm};
 497         my $num;
 498
 499         if (defined $self->{regen_down}) {
 500                 $num = $mm->num_for($mid) and return $num;
 501
 502                 while (($num = $self->{regen_down}--) > 0) {
 503                         if ($mm->mid_set($num, $mid) != 0) {
 504                                 return $num;
 505                         }
 506                 }
 507         } elsif (defined $self->{regen_up}) {
 508                 $num = $mm->num_for($mid) and return $num;
 509
 510                 # this is to fixup old bugs due to add-remove-add
 511                 while (($num = ++$self->{regen_up})) {
 512                         if ($mm->mid_set($num, $mid) != 0) {
 513                                 return $num;
 514                         }
 515                 }
 516         }
 517
 518         $num = $mm->mid_insert($mid) and return $num;
 519
 520         # fallback to num_for since filters like RubyLang set the number
 521         $mm->num_for($mid);
 522 }
 523
 524 sub unindex_mm {
 525         my ($self, $mime) = @_;
 526         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 527 }
 528
 529 sub index_both {
 530         my ($self, $mime, $bytes, $blob) = @_;
 531         my $num = index_mm($self, $mime);
 532         add_message($self, $mime, $bytes, $num, $blob);
 533 }
 534
 535 sub unindex_both {
 536         my ($self, $mime) = @_;
 537         unindex_blob($self, $mime);
 538         unindex_mm($self, $mime);
 539 }
 540
 541 sub do_cat_mail {
 542         my ($git, $blob, $sizeref) = @_;
 543         my $mime = eval {
 544                 my $str = $git->cat_file($blob, $sizeref);
 545                 # fixup bugs from import:
 546                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 547                 PublicInbox::MIME->new($str);
 548         };
 549         $@ ? undef : $mime;
 550 }
 551
 552 sub index_sync {
 553         my ($self, $opts) = @_;
 554         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 555 }
 556
 557 sub batch_adjust ($$$$) {
 558         my ($max, $bytes, $batch_cb, $latest) = @_;
 559         $$max -= $bytes;
 560         if ($$max <= 0) {
 561                 $$max = BATCH_BYTES;
 562                 $batch_cb->($latest);
 563         }
 564 }
 565
 566 # only for v1
 567 sub read_log {
 568         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 569         my $hex = '[a-f0-9]';
 570         my $h40 = $hex .'{40}';
 571         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 572         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 573         my $git = $self->{git};
 574         my $latest;
 575         my $bytes;
 576         my $max = BATCH_BYTES;
 577         local $/ = "\n";
 578         my %D;
 579         my $line;
 580         my $newest;
 581         while (defined($line = <$log>)) {
 582                 if ($line =~ /$addmsg/o) {
 583                         my $blob = $1;
 584                         if (delete $D{$blob}) {
 585                                 if (defined $self->{regen_down}) {
 586                                         $self->{regen_down}--;
 587                                 }
 588                                 next;
 589                         }
 590                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 591                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 592                         $add_cb->($self, $mime, $bytes, $blob);
 593                 } elsif ($line =~ /$delmsg/o) {
 594                         my $blob = $1;
 595                         $D{$blob} = 1;
 596                 } elsif ($line =~ /^commit ($h40)/o) {
 597                         $latest = $1;
 598                         $newest ||= $latest;
 599                 }
 600         }
 601         # get the leftovers
 602         foreach my $blob (keys %D) {
 603                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 604                 $del_cb->($self, $mime);
 605         }
 606         $batch_cb->($latest, $newest);
 607 }
 608
 609 sub _msgmap_init {
 610         my ($self) = @_;
 611         die "BUG: _msgmap_init is only for v1\n" if $self->{version} != 1;
 612         $self->{mm} ||= eval {
 613                 require PublicInbox::Msgmap;
 614                 PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 615         };
 616 }
 617
 618 sub _git_log {
 619         my ($self, $range) = @_;
 620         my $git = $self->{git};
 621
 622         # Count the new files so they can be added newest to oldest
 623         # and still have numbers increasing from oldest to newest
 624         my $fcount = 0;
 625         # can't use 'rev-list --count' if we use --diff-filter
 626         my $fh = $git->popen(qw(log --pretty=tformat:%h
 627                              --no-notes --no-color --no-renames
 628                              --diff-filter=AM), $range);
 629         ++$fcount while <$fh>;
 630         my (undef, $max) = $self->{mm}->minmax;
 631
 632         if (index($range, '..') < 0) {
 633                 if ($max && $max == $fcount) {
 634                         # fix up old bugs in full indexes which caused messages to
 635                         # not appear in Msgmap
 636                         $self->{regen_up} = $max;
 637                 } else {
 638                         # normal regen is for for fresh data
 639                         $self->{regen_down} = $fcount;
 640                 }
 641         } else {
 642                 # Give oldest messages the smallest numbers
 643                 $self->{regen_down} = $max + $fcount;
 644         }
 645
 646         $git->popen(qw/log --no-notes --no-color --no-renames
 647                                 --raw -r --no-abbrev/, $range);
 648 }
 649
 650 sub is_ancestor ($$$) {
 651         my ($git, $cur, $tip) = @_;
 652         return 0 unless $git->check($cur);
 653         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 654                 qw(merge-base --is-ancestor), $cur, $tip ];
 655         my $pid = spawn($cmd);
 656         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 657         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 658         $? == 0;
 659 }
 660
 661 sub need_update ($$$) {
 662         my ($self, $cur, $new) = @_;
 663         my $git = $self->{git};
 664         return 1 if $cur && !is_ancestor($git, $cur, $new);
 665         my $range = $cur eq '' ? $new : "$cur..$new";
 666         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 667         ($n eq '' || $n > 0);
 668 }
 669
 670 # indexes all unindexed messages (v1 only)
 671 sub _index_sync {
 672         my ($self, $opts) = @_;
 673         my $tip = $opts->{ref} || 'HEAD';
 674         my $reindex = $opts->{reindex};
 675         my ($mkey, $last_commit, $lx, $xlog);
 676         my $git = $self->{git};
 677         $git->batch_prepare;
 678
 679         my $xdb = $self->begin_txn_lazy;
 680         my $mm = _msgmap_init($self);
 681         do {
 682                 $xlog = undef;
 683                 $mkey = 'last_commit';
 684                 $last_commit = $xdb->get_metadata('last_commit');
 685                 $lx = $last_commit;
 686                 if ($reindex) {
 687                         $lx = '';
 688                         $mkey = undef if $last_commit ne '';
 689                 }
 690
 691                 # use last_commit from msgmap if it is older or unset
 692                 my $lm = $mm->last_commit || '';
 693                 if (!$lm || ($lm && $lx && is_ancestor($git, $lm, $lx))) {
 694                         $lx = $lm;
 695                 }
 696
 697                 $self->{over}->rollback_lazy;
 698                 $self->{over}->disconnect;
 699                 $git->cleanup;
 700                 delete $self->{txn};
 701                 $xdb->cancel_transaction;
 702                 $xdb = _xdb_release($self);
 703
 704                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 705                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 706                 $xlog = _git_log($self, $range);
 707
 708                 $xdb = $self->begin_txn_lazy;
 709         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 710
 711         my $dbh = $mm->{dbh} if $mm;
 712         my $cb = sub {
 713                 my ($commit, $newest) = @_;
 714                 if ($dbh) {
 715                         if ($newest) {
 716                                 my $cur = $mm->last_commit || '';
 717                                 if (need_update($self, $cur, $newest)) {
 718                                         $mm->last_commit($newest);
 719                                 }
 720                         }
 721                         $dbh->commit;
 722                 }
 723                 if ($mkey && $newest && $self->{indexlevel} =~ $xapianlevels) {
 724                         my $cur = $xdb->get_metadata($mkey);
 725                         if (need_update($self, $cur, $newest)) {
 726                                 $xdb->set_metadata($mkey, $newest);
 727                         }
 728                 }
 729                 $self->commit_txn_lazy;
 730                 $git->cleanup;
 731                 $xdb = _xdb_release($self);
 732                 # let another process do some work... <
 733                 if (!$newest) {
 734                         $xdb = $self->begin_txn_lazy;
 735                         $dbh->begin_work if $dbh;
 736                 }
 737         };
 738
 739         $dbh->begin_work;
 740         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 741 }
 742
 743 sub DESTROY {
 744         # order matters for unlocking
 745         $_[0]->{xdb} = undef;
 746         $_[0]->{lockfh} = undef;
 747 }
 748
 749 # remote_* subs are only used by SearchIdxPart
 750 sub remote_commit {
 751         my ($self) = @_;
 752         if (my $w = $self->{w}) {
 753                 print $w "commit\n" or die "failed to write commit: $!";
 754         } else {
 755                 $self->commit_txn_lazy;
 756         }
 757 }
 758
 759 sub remote_close {
 760         my ($self) = @_;
 761         if (my $w = delete $self->{w}) {
 762                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 763                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 764                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 765                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 766                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 767         } else {
 768                 die "transaction in progress $self\n" if $self->{txn};
 769                 $self->_xdb_release if $self->{xdb};
 770         }
 771 }
 772
 773 sub remote_remove {
 774         my ($self, $oid, $mid) = @_;
 775         if (my $w = $self->{w}) {
 776                 # triggers remove_by_oid in a partition
 777                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 778         } else {
 779                 $self->begin_txn_lazy;
 780                 $self->remove_by_oid($oid, $mid);
 781         }
 782 }
 783
 784 sub begin_txn_lazy {
 785         my ($self) = @_;
 786         return if $self->{txn};
 787
 788         $self->{-inbox}->with_umask(sub {
 789                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 790                 $self->{over}->begin_lazy if $self->{over};
 791                 $xdb->begin_transaction;
 792                 $self->{txn} = 1;
 793                 $xdb;
 794         });
 795 }
 796
 797 sub commit_txn_lazy {
 798         my ($self) = @_;
 799         delete $self->{txn} or return;
 800         $self->{-inbox}->with_umask(sub {
 801                 $self->{xdb}->commit_transaction;
 802                 $self->{over}->commit_lazy if $self->{over};
 803         });
 804 }
 805
 806 sub worker_done {
 807         my ($self) = @_;
 808         die "$$ $0 xdb not released\n" if $self->{xdb};
 809         die "$$ $0 still in transaction\n" if $self->{txn};
 810 }
 811
 812 1;