lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use PublicInbox::MIME;
  14 use base qw(PublicInbox::Search);
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids references/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 require PublicInbox::Git;
  20
  21 use constant {
  22         PERM_UMASK => 0,
  23         OLD_PERM_GROUP => 1,
  24         OLD_PERM_EVERYBODY => 2,
  25         PERM_GROUP => 0660,
  26         PERM_EVERYBODY => 0664,
  27         BATCH_BYTES => 1_000_000,
  28         DEBUG => !!$ENV{DEBUG},
  29 };
  30
  31 my %GIT_ESC = (
  32         a => "\a",
  33         b => "\b",
  34         f => "\f",
  35         n => "\n",
  36         r => "\r",
  37         t => "\t",
  38         v => "\013",
  39 );
  40
  41 sub git_unquote ($) {
  42         my ($s) = @_;
  43         return $s unless ($s =~ /\A"(.*)"\z/);
  44         $s = $1;
  45         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  46         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  47         $s;
  48 }
  49
  50 sub new {
  51         my ($class, $ibx, $creat, $part) = @_;
  52         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  53         my $git_dir = $mainrepo;
  54         my ($altid, $git);
  55         my $version = 1;
  56         if (ref $ibx) {
  57                 $mainrepo = $ibx->{mainrepo};
  58                 $altid = $ibx->{altid};
  59                 $version = $ibx->{version} || 1;
  60                 if ($altid) {
  61                         require PublicInbox::AltId;
  62                         $altid = [ map {
  63                                 PublicInbox::AltId->new($ibx, $_);
  64                         } @$altid ];
  65                 }
  66                 $git = $ibx->git;
  67         } else {
  68                 $git = PublicInbox::Git->new($git_dir); # v1 only
  69         }
  70         require Search::Xapian::WritableDatabase;
  71         my $self = bless {
  72                 mainrepo => $mainrepo,
  73                 git => $git,
  74                 -altid => $altid,
  75                 version => $version,
  76         }, $class;
  77         my $perm = $self->_git_config_perm;
  78         my $umask = _umask_for($perm);
  79         $self->{umask} = $umask;
  80         if ($version == 1) {
  81                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  82         } elsif ($version == 2) {
  83                 defined $part or die "partition is required for v2\n";
  84                 # partition is a number or "all"
  85                 $self->{partition} = $part;
  86                 $self->{lock_path} = undef;
  87                 $self->{msgmap_path} = "$mainrepo/msgmap.sqlite3";
  88         } else {
  89                 die "unsupported inbox version=$version\n";
  90         }
  91         $self->{creat} = ($creat || 0) == 1;
  92         $self;
  93 }
  94
  95 sub _xdb_release {
  96         my ($self) = @_;
  97         my $xdb = delete $self->{xdb} or croak 'not acquired';
  98         $xdb->close;
  99         _lock_release($self) if $self->{creat};
 100         undef;
 101 }
 102
 103 sub _xdb_acquire {
 104         my ($self) = @_;
 105         croak 'already acquired' if $self->{xdb};
 106         my $dir = $self->xdir;
 107         my $flag = Search::Xapian::DB_OPEN;
 108         if ($self->{creat}) {
 109                 require File::Path;
 110                 _lock_acquire($self);
 111                 File::Path::mkpath($dir);
 112                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 113         }
 114         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 115 }
 116
 117 # we only acquire the flock if creating or reindexing;
 118 # PublicInbox::Import already has the lock on its own.
 119 sub _lock_acquire {
 120         my ($self) = @_;
 121         croak 'already locked' if $self->{lockfh};
 122         my $lock_path = $self->{lock_path} or return;
 123         sysopen(my $lockfh, $lock_path, O_WRONLY|O_CREAT) or
 124                 die "failed to open lock $lock_path: $!\n";
 125         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
 126         $self->{lockfh} = $lockfh;
 127 }
 128
 129 sub _lock_release {
 130         my ($self) = @_;
 131         return unless $self->{lock_path};
 132         my $lockfh = delete $self->{lockfh} or croak 'not locked';
 133         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
 134         close $lockfh or die "close failed: $!\n";
 135 }
 136
 137 sub add_val ($$$) {
 138         my ($doc, $col, $num) = @_;
 139         $num = Search::Xapian::sortable_serialise($num);
 140         $doc->add_value($col, $num);
 141 }
 142
 143 sub add_values ($$) {
 144         my ($doc, $values) = @_;
 145
 146         my $ts = $values->[PublicInbox::Search::TS];
 147         add_val($doc, PublicInbox::Search::TS, $ts);
 148
 149         my $num = $values->[PublicInbox::Search::NUM];
 150         defined($num) and add_val($doc, PublicInbox::Search::NUM, $num);
 151
 152         my $bytes = $values->[PublicInbox::Search::BYTES];
 153         defined($bytes) and add_val($doc, PublicInbox::Search::BYTES, $bytes);
 154
 155         my $lines = $values->[PublicInbox::Search::LINES];
 156         add_val($doc, PublicInbox::Search::LINES, $lines);
 157
 158         my $yyyymmdd = strftime('%Y%m%d', gmtime($ts));
 159         add_val($doc, PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 160 }
 161
 162 sub index_users ($$) {
 163         my ($tg, $smsg) = @_;
 164
 165         my $from = $smsg->from;
 166         my $to = $smsg->to;
 167         my $cc = $smsg->cc;
 168
 169         $tg->index_text($from, 1, 'A'); # A - author
 170         $tg->increase_termpos;
 171         $tg->index_text($to, 1, 'XTO') if $to ne '';
 172         $tg->increase_termpos;
 173         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 174         $tg->increase_termpos;
 175 }
 176
 177 sub index_diff_inc ($$$$) {
 178         my ($tg, $text, $pfx, $xnq) = @_;
 179         if (@$xnq) {
 180                 $tg->index_text(join("\n", @$xnq), 1, 'XNQ');
 181                 $tg->increase_termpos;
 182                 @$xnq = ();
 183         }
 184         $tg->index_text($text, 1, $pfx);
 185         $tg->increase_termpos;
 186 }
 187
 188 sub index_old_diff_fn {
 189         my ($tg, $seen, $fa, $fb, $xnq) = @_;
 190
 191         # no renames or space support for traditional diffs,
 192         # find the number of leading common paths to strip:
 193         my @fa = split('/', $fa);
 194         my @fb = split('/', $fb);
 195         while (scalar(@fa) && scalar(@fb)) {
 196                 $fa = join('/', @fa);
 197                 $fb = join('/', @fb);
 198                 if ($fa eq $fb) {
 199                         unless ($seen->{$fa}++) {
 200                                 index_diff_inc($tg, $fa, 'XDFN', $xnq);
 201                         }
 202                         return 1;
 203                 }
 204                 shift @fa;
 205                 shift @fb;
 206         }
 207         0;
 208 }
 209
 210 sub index_diff ($$$) {
 211         my ($tg, $lines, $doc) = @_;
 212         my %seen;
 213         my $in_diff;
 214         my @xnq;
 215         my $xnq = \@xnq;
 216         foreach (@$lines) {
 217                 if ($in_diff && s/^ //) { # diff context
 218                         index_diff_inc($tg, $_, 'XDFCTX', $xnq);
 219                 } elsif (/^-- $/) { # email signature begins
 220                         $in_diff = undef;
 221                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 222                         my ($fa, $fb) = ($1, $2);
 223                         my $fn = (split('/', git_unquote($fa), 2))[1];
 224                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 225                         $fn = (split('/', git_unquote($fb), 2))[1];
 226                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 227                         $in_diff = 1;
 228                 # traditional diff:
 229                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 230                         my ($opt, $fa, $fb) = ($1, $2, $3);
 231                         push @xnq, $_;
 232                         # only support unified:
 233                         next unless $opt =~ /[uU]/;
 234                         $in_diff = index_old_diff_fn($tg, \%seen, $fa, $fb,
 235                                                         $xnq);
 236                 } elsif (m!^--- ("?a/.+)!) {
 237                         my $fn = (split('/', git_unquote($1), 2))[1];
 238                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 239                         $in_diff = 1;
 240                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 241                         my $fn = (split('/', git_unquote($1), 2))[1];
 242                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 243                         $in_diff = 1;
 244                 } elsif (/^--- (\S+)/) {
 245                         $in_diff = $1;
 246                         push @xnq, $_;
 247                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 248                         $in_diff = index_old_diff_fn($tg, \%seen, $in_diff, $1,
 249                                                         $xnq);
 250                 } elsif ($in_diff && s/^\+//) { # diff added
 251                         index_diff_inc($tg, $_, 'XDFB', $xnq);
 252                 } elsif ($in_diff && s/^-//) { # diff removed
 253                         index_diff_inc($tg, $_, 'XDFA', $xnq);
 254                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 255                         my ($ba, $bb) = ($1, $2);
 256                         index_git_blob_id($doc, 'XDFPRE', $ba);
 257                         index_git_blob_id($doc, 'XDFPOST', $bb);
 258                         $in_diff = 1;
 259                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 260                         # traditional diff w/o -p
 261                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 262                         # hunk header context
 263                         index_diff_inc($tg, $1, 'XDFHH', $xnq);
 264                 # ignore the following lines:
 265                 } elsif (/^(?:dis)similarity index/ ||
 266                                 /^(?:old|new) mode/ ||
 267                                 /^(?:deleted|new) file mode/ ||
 268                                 /^(?:copy|rename) (?:from|to) / ||
 269                                 /^(?:dis)?similarity index / ||
 270                                 /^\\ No newline at end of file/ ||
 271                                 /^Binary files .* differ/) {
 272                         push @xnq, $_;
 273                 } elsif ($_ eq '') {
 274                         $in_diff = undef;
 275                 } else {
 276                         push @xnq, $_;
 277                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 278                         $in_diff = undef;
 279                 }
 280         }
 281
 282         $tg->index_text(join("\n", @xnq), 1, 'XNQ');
 283         $tg->increase_termpos;
 284 }
 285
 286 sub index_body ($$$) {
 287         my ($tg, $lines, $doc) = @_;
 288         my $txt = join("\n", @$lines);
 289         if ($doc) {
 290                 # does it look like a diff?
 291                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 292                         $txt = undef;
 293                         index_diff($tg, $lines, $doc);
 294                 } else {
 295                         $tg->index_text($txt, 1, 'XNQ');
 296                 }
 297         } else {
 298                 $tg->index_text($txt, 0, 'XQUOT');
 299         }
 300         $tg->increase_termpos;
 301         @$lines = ();
 302 }
 303
 304 sub add_message {
 305         my ($self, $mime, $bytes, $num, $blob) = @_; # mime = Email::MIME object
 306         my $doc_id;
 307         my $mids = mids($mime->header_obj);
 308         my $skel = $self->{skeleton};
 309
 310         eval {
 311                 my $smsg = PublicInbox::SearchMsg->new($mime);
 312                 my $doc = $smsg->{doc};
 313                 my $subj = $smsg->subject;
 314                 my $xpath;
 315                 if ($subj ne '') {
 316                         $xpath = $self->subject_path($subj);
 317                         $xpath = id_compress($xpath);
 318                 }
 319
 320                 my $lines = $mime->body_raw =~ tr!\n!\n!;
 321                 my @values = ($smsg->ts, $num, $bytes, $lines);
 322                 add_values($doc, \@values);
 323
 324                 my $tg = $self->term_generator;
 325
 326                 $tg->set_document($doc);
 327                 $tg->index_text($subj, 1, 'S') if $subj;
 328                 $tg->increase_termpos;
 329
 330                 index_users($tg, $smsg);
 331
 332                 msg_iter($mime, sub {
 333                         my ($part, $depth, @idx) = @{$_[0]};
 334                         my $ct = $part->content_type || 'text/plain';
 335                         my $fn = $part->filename;
 336                         if (defined $fn && $fn ne '') {
 337                                 $tg->index_text($fn, 1, 'XFN');
 338                         }
 339
 340                         return if $ct =~ m!\btext/x?html\b!i;
 341
 342                         my $s = eval { $part->body_str };
 343                         if ($@) {
 344                                 if ($ct =~ m!\btext/plain\b!i) {
 345                                         # Try to assume UTF-8 because Alpine
 346                                         # seems to do wacky things and set
 347                                         # charset=X-UNKNOWN
 348                                         $part->charset_set('UTF-8');
 349                                         $s = eval { $part->body_str };
 350                                         $s = $part->body if $@;
 351                                 }
 352                         }
 353                         defined $s or return;
 354
 355                         my (@orig, @quot);
 356                         my $body = $part->body;
 357                         my @lines = split(/\n/, $body);
 358                         while (defined(my $l = shift @lines)) {
 359                                 if ($l =~ /^>/) {
 360                                         index_body($tg, \@orig, $doc) if @orig;
 361                                         push @quot, $l;
 362                                 } else {
 363                                         index_body($tg, \@quot, 0) if @quot;
 364                                         push @orig, $l;
 365                                 }
 366                         }
 367                         index_body($tg, \@quot, 0) if @quot;
 368                         index_body($tg, \@orig, $doc) if @orig;
 369                 });
 370
 371                 # populates smsg->references for smsg->to_doc_data
 372                 my $refs = parse_references($smsg);
 373                 my $data = $smsg->to_doc_data($blob);
 374                 foreach my $mid (@$mids) {
 375                         $tg->index_text($mid, 1, 'XM');
 376                 }
 377                 $doc->set_data($data);
 378                 if (my $altid = $self->{-altid}) {
 379                         foreach my $alt (@$altid) {
 380                                 my $pfx = $alt->{xprefix};
 381                                 foreach my $mid (@$mids) {
 382                                         my $id = $alt->mid2alt($mid);
 383                                         next unless defined $id;
 384                                         $doc->add_boolean_term($pfx . $id);
 385                                 }
 386                         }
 387                 }
 388
 389                 if ($skel) {
 390                         push @values, $mids, $xpath, $data;
 391                         $skel->index_skeleton(\@values);
 392                         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 393                         $doc_id = $self->{xdb}->add_document($doc);
 394                 } else {
 395                         $doc_id = link_and_save($self, $doc, $mids, $refs,
 396                                                 $num, $xpath);
 397                 }
 398         };
 399
 400         if ($@) {
 401                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 402                 return undef;
 403         }
 404         $doc_id;
 405 }
 406
 407 # returns deleted doc_id on success, undef on missing
 408 sub remove_message {
 409         my ($self, $mid) = @_;
 410         my $db = $self->{xdb};
 411         my $doc_id;
 412         $mid = mid_clean($mid);
 413
 414         eval {
 415                 my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 416                 if ($head->equal($tail)) {
 417                         warn "cannot remove non-existent <$mid>\n";
 418                 }
 419                 for (; $head != $tail; $head->inc) {
 420                         my $docid = $head->get_docid;
 421                         $db->delete_document($docid);
 422                 }
 423         };
 424
 425         if ($@) {
 426                 warn "failed to remove message <$mid>: $@\n";
 427                 return undef;
 428         }
 429         $doc_id;
 430 }
 431
 432 sub term_generator { # write-only
 433         my ($self) = @_;
 434
 435         my $tg = $self->{term_generator};
 436         return $tg if $tg;
 437
 438         $tg = Search::Xapian::TermGenerator->new;
 439         $tg->set_stemmer($self->stemmer);
 440
 441         $self->{term_generator} = $tg;
 442 }
 443
 444 # increments last_thread_id counter
 445 # returns a 64-bit integer represented as a decimal string
 446 sub next_thread_id {
 447         my ($self) = @_;
 448         my $db = $self->{xdb};
 449         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 450
 451         $db->set_metadata('last_thread_id', ++$last_thread_id);
 452
 453         $last_thread_id;
 454 }
 455
 456 sub parse_references ($) {
 457         my ($smsg) = @_;
 458         my $mime = $smsg->{mime};
 459         my $hdr = $mime->header_obj;
 460         my $refs = references($hdr);
 461         return $refs if scalar(@$refs) == 0;
 462
 463         # prevent circular references via References here:
 464         my %mids = map { $_ => 1 } @{mids($hdr)};
 465         my @keep;
 466         foreach my $ref (@$refs) {
 467                 if (length($ref) > PublicInbox::MID::MAX_MID_SIZE) {
 468                         warn "References: <$ref> too long, ignoring\n";
 469                         next;
 470                 }
 471                 next if $mids{$ref};
 472                 push @keep, $ref;
 473         }
 474         $smsg->{references} = '<'.join('> <', @keep).'>' if @keep;
 475         \@keep;
 476 }
 477
 478 sub link_doc {
 479         my ($self, $doc, $refs, $old_tid) = @_;
 480         my $tid;
 481
 482         if (@$refs) {
 483                 # first ref *should* be the thread root,
 484                 # but we can never trust clients to do the right thing
 485                 my $ref = shift @$refs;
 486                 $tid = resolve_mid_to_tid($self, $ref);
 487                 merge_threads($self, $tid, $old_tid) if defined $old_tid;
 488
 489                 # the rest of the refs should point to this tid:
 490                 foreach $ref (@$refs) {
 491                         my $ptid = resolve_mid_to_tid($self, $ref);
 492                         merge_threads($self, $tid, $ptid);
 493                 }
 494         } else {
 495                 $tid = defined $old_tid ? $old_tid : $self->next_thread_id;
 496         }
 497         $doc->add_boolean_term('G' . $tid);
 498         $tid;
 499 }
 500
 501 sub link_and_save {
 502         my ($self, $doc, $mids, $refs, $num, $xpath) = @_;
 503         my $db = $self->{xdb};
 504         my $old_tid;
 505         my $doc_id;
 506         $doc->add_boolean_term('XNUM' . $num) if defined $num;
 507         $doc->add_boolean_term('XPATH' . $xpath) if defined $xpath;
 508         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 509
 510         my $vivified = 0;
 511         foreach my $mid (@$mids) {
 512                 $self->each_smsg_by_mid($mid, sub {
 513                         my ($cur) = @_;
 514                         my $type = $cur->type;
 515                         my $cur_tid = $cur->thread_id;
 516                         $old_tid = $cur_tid unless defined $old_tid;
 517                         if ($type eq 'mail') {
 518                                 # do not break existing mail messages,
 519                                 # just merge the threads
 520                                 merge_threads($self, $old_tid, $cur_tid);
 521                                 return 1;
 522                         }
 523                         if ($type ne 'ghost') {
 524                                 die "<$mid> has a bad type: $type\n";
 525                         }
 526                         my $tid = link_doc($self, $doc, $refs, $old_tid);
 527                         $old_tid = $tid unless defined $old_tid;
 528                         $doc_id = $cur->{doc_id};
 529                         $self->{xdb}->replace_document($doc_id, $doc);
 530                         ++$vivified;
 531                         1;
 532                 });
 533         }
 534         # not really important, but we return any vivified ghost docid, here:
 535         return $doc_id if defined $doc_id;
 536         link_doc($self, $doc, $refs, $old_tid);
 537         $self->{xdb}->add_document($doc);
 538 }
 539
 540 sub index_git_blob_id {
 541         my ($doc, $pfx, $objid) = @_;
 542
 543         my $len = length($objid);
 544         for (my $len = length($objid); $len >= 7; ) {
 545                 $doc->add_term($pfx.$objid);
 546                 $objid = substr($objid, 0, --$len);
 547         }
 548 }
 549
 550 sub unindex_blob {
 551         my ($self, $mime) = @_;
 552         my $mid = eval { mid_clean(mid_mime($mime)) };
 553         $self->remove_message($mid) if defined $mid;
 554 }
 555
 556 sub index_mm {
 557         my ($self, $mime) = @_;
 558         my $mid = mid_clean(mid_mime($mime));
 559         my $mm = $self->{mm};
 560         my $num = $mm->mid_insert($mid);
 561         return $num if defined $num;
 562
 563         # fallback to num_for since filters like RubyLang set the number
 564         $mm->num_for($mid);
 565 }
 566
 567 sub unindex_mm {
 568         my ($self, $mime) = @_;
 569         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 570 }
 571
 572 sub index_mm2 {
 573         my ($self, $mime, $bytes, $blob) = @_;
 574         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 575         add_message($self, $mime, $bytes, $num, $blob);
 576 }
 577
 578 sub unindex_mm2 {
 579         my ($self, $mime) = @_;
 580         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 581         unindex_blob($self, $mime);
 582 }
 583
 584 sub index_both {
 585         my ($self, $mime, $bytes, $blob) = @_;
 586         my $num = index_mm($self, $mime);
 587         add_message($self, $mime, $bytes, $num, $blob);
 588 }
 589
 590 sub unindex_both {
 591         my ($self, $mime) = @_;
 592         unindex_blob($self, $mime);
 593         unindex_mm($self, $mime);
 594 }
 595
 596 sub do_cat_mail {
 597         my ($git, $blob, $sizeref) = @_;
 598         my $mime = eval {
 599                 my $str = $git->cat_file($blob, $sizeref);
 600                 # fixup bugs from import:
 601                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 602                 PublicInbox::MIME->new($str);
 603         };
 604         $@ ? undef : $mime;
 605 }
 606
 607 sub index_sync {
 608         my ($self, $opts) = @_;
 609         with_umask($self, sub { $self->_index_sync($opts) });
 610 }
 611
 612 sub batch_adjust ($$$$) {
 613         my ($max, $bytes, $batch_cb, $latest) = @_;
 614         $$max -= $bytes;
 615         if ($$max <= 0) {
 616                 $$max = BATCH_BYTES;
 617                 $batch_cb->($latest, 1);
 618         }
 619 }
 620
 621 # only for v1
 622 sub rlog {
 623         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 624         my $hex = '[a-f0-9]';
 625         my $h40 = $hex .'{40}';
 626         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 627         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 628         my $git = $self->{git};
 629         my $latest;
 630         my $bytes;
 631         my $max = BATCH_BYTES;
 632         local $/ = "\n";
 633         my $line;
 634         while (defined($line = <$log>)) {
 635                 if ($line =~ /$addmsg/o) {
 636                         my $blob = $1;
 637                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 638                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 639                         $add_cb->($self, $mime, $bytes, $blob);
 640                 } elsif ($line =~ /$delmsg/o) {
 641                         my $blob = $1;
 642                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 643                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 644                         $del_cb->($self, $mime);
 645                 } elsif ($line =~ /^commit ($h40)/o) {
 646                         $latest = $1;
 647                 }
 648         }
 649         $batch_cb->($latest, 0);
 650 }
 651
 652 sub _msgmap_init {
 653         my ($self) = @_;
 654         $self->{mm} ||= eval {
 655                 require PublicInbox::Msgmap;
 656                 my $msgmap_path = $self->{msgmap_path};
 657                 if (defined $msgmap_path) { # v2
 658                         PublicInbox::Msgmap->new_file($msgmap_path, 1);
 659                 } else {
 660                         PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 661                 }
 662         };
 663 }
 664
 665 sub _git_log {
 666         my ($self, $range) = @_;
 667         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 668                                 --raw -r --no-abbrev/, $range);
 669 }
 670
 671 # indexes all unindexed messages
 672 sub _index_sync {
 673         my ($self, $opts) = @_;
 674         my $tip = $opts->{ref} || 'HEAD';
 675         my $reindex = $opts->{reindex};
 676         my ($mkey, $last_commit, $lx, $xlog);
 677         $self->{git}->batch_prepare;
 678         my $xdb = _xdb_acquire($self);
 679         $xdb->begin_transaction;
 680         do {
 681                 $xlog = undef;
 682                 $mkey = 'last_commit';
 683                 $last_commit = $xdb->get_metadata('last_commit');
 684                 $lx = $last_commit;
 685                 if ($reindex) {
 686                         $lx = '';
 687                         $mkey = undef if $last_commit ne '';
 688                 }
 689                 $xdb->cancel_transaction;
 690                 $xdb = _xdb_release($self);
 691
 692                 # ensure we leak no FDs to "git log"
 693                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 694                 $xlog = _git_log($self, $range);
 695
 696                 $xdb = _xdb_acquire($self);
 697                 $xdb->begin_transaction;
 698         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 699
 700         my $mm = _msgmap_init($self);
 701         my $dbh = $mm->{dbh} if $mm;
 702         my $mm_only;
 703         my $cb = sub {
 704                 my ($commit, $more) = @_;
 705                 if ($dbh) {
 706                         $mm->last_commit($commit) if $commit;
 707                         $dbh->commit;
 708                 }
 709                 if (!$mm_only) {
 710                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 711                         $xdb->commit_transaction;
 712                         $xdb = _xdb_release($self);
 713                 }
 714                 # let another process do some work... <
 715                 if ($more) {
 716                         if (!$mm_only) {
 717                                 $xdb = _xdb_acquire($self);
 718                                 $xdb->begin_transaction;
 719                         }
 720                         $dbh->begin_work if $dbh;
 721                 }
 722         };
 723
 724         if ($mm) {
 725                 $dbh->begin_work;
 726                 my $lm = $mm->last_commit || '';
 727                 if ($lm eq $lx) {
 728                         # Common case is the indexes are synced,
 729                         # we only need to run git-log once:
 730                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 731                 } else {
 732                         # Uncommon case, msgmap and xapian are out-of-sync
 733                         # do not care for performance (but git is fast :>)
 734                         # This happens if we have to reindex Xapian since
 735                         # msgmap is a frozen format and our Xapian format
 736                         # is evolving.
 737                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 738
 739                         # first, ensure msgmap is up-to-date:
 740                         my $mkey_prev = $mkey;
 741                         $mkey = undef; # ignore xapian, for now
 742                         my $mlog = _git_log($self, $r);
 743                         $mm_only = 1;
 744                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 745                         $mm_only = $mlog = undef;
 746
 747                         # now deal with Xapian
 748                         $mkey = $mkey_prev;
 749                         $dbh = undef;
 750                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 751                 }
 752         } else {
 753                 # user didn't install DBD::SQLite and DBI
 754                 rlog($self, $xlog, *add_message, *unindex_blob, $cb);
 755         }
 756 }
 757
 758 # this will create a ghost as necessary
 759 sub resolve_mid_to_tid {
 760         my ($self, $mid) = @_;
 761         my $tid;
 762         $self->each_smsg_by_mid($mid, sub {
 763                 my ($smsg) = @_;
 764                 my $cur_tid = $smsg->thread_id;
 765                 if (defined $tid) {
 766                         merge_threads($self, $tid, $cur_tid);
 767                 } else {
 768                         $tid = $smsg->thread_id;
 769                 }
 770                 1;
 771         });
 772         return $tid if defined $tid;
 773
 774         $self->create_ghost($mid)->thread_id;
 775 }
 776
 777 sub create_ghost {
 778         my ($self, $mid) = @_;
 779
 780         my $tid = $self->next_thread_id;
 781         my $doc = Search::Xapian::Document->new;
 782         $doc->add_boolean_term('Q' . $mid);
 783         $doc->add_boolean_term('G' . $tid);
 784         $doc->add_boolean_term('T' . 'ghost');
 785
 786         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 787         $self->{xdb}->add_document($doc);
 788
 789         $smsg;
 790 }
 791
 792 sub merge_threads {
 793         my ($self, $winner_tid, $loser_tid) = @_;
 794         return if $winner_tid == $loser_tid;
 795         my $db = $self->{xdb};
 796
 797         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 798         while (1) {
 799                 my ($head, $tail) = $self->find_doc_ids('G' . $loser_tid);
 800                 return if $head == $tail;
 801                 my @ids;
 802                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 803                         push @ids, $head->get_docid;
 804                 }
 805                 foreach my $docid (@ids) {
 806                         my $doc = $db->get_document($docid);
 807                         $doc->remove_term('G' . $loser_tid);
 808                         $doc->add_boolean_term('G' . $winner_tid);
 809                         $db->replace_document($docid, $doc);
 810                 }
 811         }
 812 }
 813
 814 sub _read_git_config_perm {
 815         my ($self) = @_;
 816         my @cmd = qw(config);
 817         if ($self->{version} == 2) {
 818                 push @cmd, "--file=$self->{mainrepo}/inbox-config";
 819         }
 820         my $fh = $self->{git}->popen(@cmd, 'core.sharedRepository');
 821         local $/ = "\n";
 822         my $perm = <$fh>;
 823         chomp $perm if defined $perm;
 824         $perm;
 825 }
 826
 827 sub _git_config_perm {
 828         my $self = shift;
 829         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 830         return PERM_GROUP if (!defined($perm) || $perm eq '');
 831         return PERM_UMASK if ($perm eq 'umask');
 832         return PERM_GROUP if ($perm eq 'group');
 833         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 834                 return PERM_EVERYBODY;
 835         }
 836         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 837         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 838
 839         my $i = oct($perm);
 840         return PERM_UMASK if ($i == PERM_UMASK);
 841         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 842         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 843
 844         if (($i & 0600) != 0600) {
 845                 die "core.sharedRepository mode invalid: ".
 846                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 847         }
 848         ($i & 0666);
 849 }
 850
 851 sub _umask_for {
 852         my ($perm) = @_; # _git_config_perm return value
 853         my $rv = $perm;
 854         return umask if $rv == 0;
 855
 856         # set +x bit if +r or +w were set
 857         $rv |= 0100 if ($rv & 0600);
 858         $rv |= 0010 if ($rv & 0060);
 859         $rv |= 0001 if ($rv & 0006);
 860         (~$rv & 0777);
 861 }
 862
 863 sub with_umask {
 864         my ($self, $cb) = @_;
 865         my $old = umask $self->{umask};
 866         my $rv = eval { $cb->() };
 867         my $err = $@;
 868         umask $old;
 869         die $err if $err;
 870         $rv;
 871 }
 872
 873 sub DESTROY {
 874         # order matters for unlocking
 875         $_[0]->{xdb} = undef;
 876         $_[0]->{lockfh} = undef;
 877 }
 878
 879 # remote_* subs are only used by SearchIdxPart and SearchIdxSkeleton
 880 sub remote_commit {
 881         my ($self) = @_;
 882         print { $self->{w} } "commit\n" or die "failed to write commit: $!";
 883 }
 884
 885 sub remote_close {
 886         my ($self) = @_;
 887         my $pid = delete $self->{pid} or die "no process to wait on\n";
 888         my $w = delete $self->{w} or die "no pipe to write to\n";
 889         print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 890         close $w or die "failed to close pipe for pid:$pid: $!\n";
 891         waitpid($pid, 0) == $pid or die "remote process did not finish";
 892         $? == 0 or die ref($self)." pid:$pid exited with: $?";
 893 }
 894
 895 1;