lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mid_mime mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 our $BATCH_BYTES = defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000;
  27 use constant DEBUG => !!$ENV{DEBUG};
  28
  29 my $xapianlevels = qr/\A(?:full|medium)\z/;
  30
  31 sub new {
  32         my ($class, $ibx, $creat, $shard) = @_;
  33         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  34         my $levels = qr/\A(?:full|medium|basic)\z/;
  35         my $inboxdir = $ibx->{inboxdir};
  36         my $version = $ibx->version;
  37         my $indexlevel = 'full';
  38         my $altid = $ibx->{altid};
  39         if ($altid) {
  40                 require PublicInbox::AltId;
  41                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  42         }
  43         if ($ibx->{indexlevel}) {
  44                 if ($ibx->{indexlevel} =~ $levels) {
  45                         $indexlevel = $ibx->{indexlevel};
  46                 } else {
  47                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  48                 }
  49         }
  50         $ibx = PublicInbox::InboxWritable->new($ibx);
  51         my $self = bless {
  52                 inboxdir => $inboxdir,
  53                 -inbox => $ibx,
  54                 git => $ibx->git,
  55                 -altid => $altid,
  56                 ibx_ver => $version,
  57                 indexlevel => $indexlevel,
  58         }, $class;
  59         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  60         $ibx->umask_prepare;
  61         if ($version == 1) {
  62                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  63                 my $dir = $self->xdir;
  64                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  65                 $self->{index_max_size} = $ibx->{index_max_size};
  66         } elsif ($version == 2) {
  67                 defined $shard or die "shard is required for v2\n";
  68                 # shard is a number
  69                 $self->{shard} = $shard;
  70                 $self->{lock_path} = undef;
  71         } else {
  72                 die "unsupported inbox version=$version\n";
  73         }
  74         $self->{creat} = ($creat || 0) == 1;
  75         $self;
  76 }
  77
  78 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  79
  80 sub _xdb_release {
  81         my ($self, $wake) = @_;
  82         if (need_xapian($self)) {
  83                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  84                 $xdb->close;
  85         }
  86         $self->lock_release($wake) if $self->{creat};
  87         undef;
  88 }
  89
  90 sub load_xapian_writable () {
  91         return 1 if $X->{WritableDatabase};
  92         PublicInbox::Search::load_xapian() or return;
  93         my $xap = $PublicInbox::Search::Xap;
  94         for (qw(Document TermGenerator WritableDatabase)) {
  95                 $X->{$_} = $xap.'::'.$_;
  96         }
  97         eval 'require '.$X->{WritableDatabase} or die;
  98         *sortable_serialise = $xap.'::sortable_serialise';
  99         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 100         $DB_OPEN = eval($xap.'::DB_OPEN()');
 101         1;
 102 }
 103
 104 sub _xdb_acquire {
 105         my ($self) = @_;
 106         my $flag;
 107         my $dir = $self->xdir;
 108         if (need_xapian($self)) {
 109                 croak 'already acquired' if $self->{xdb};
 110                 load_xapian_writable();
 111                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 112         }
 113         if ($self->{creat}) {
 114                 require File::Path;
 115                 $self->lock_acquire;
 116
 117                 # don't create empty Xapian directories if we don't need Xapian
 118                 my $is_shard = defined($self->{shard});
 119                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 120                         File::Path::mkpath($dir);
 121                 }
 122         }
 123         return unless defined $flag;
 124         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 125         if ($@) {
 126                 die "Failed opening $dir: ", $@;
 127         }
 128         $self->{xdb} = $xdb;
 129 }
 130
 131 sub add_val ($$$) {
 132         my ($doc, $col, $num) = @_;
 133         $num = sortable_serialise($num);
 134         $doc->add_value($col, $num);
 135 }
 136
 137 sub term_generator ($) { # write-only
 138         my ($self) = @_;
 139
 140         $self->{term_generator} //= do {
 141                 my $tg = $X->{TermGenerator}->new;
 142                 $tg->set_stemmer($self->stemmer);
 143                 $tg;
 144         }
 145 }
 146
 147 sub index_text ($$$$) {
 148         my ($self, $text, $wdf_inc, $prefix) = @_;
 149         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 150
 151         if ($self->{indexlevel} eq 'full') {
 152                 $tg->index_text($text, $wdf_inc, $prefix);
 153                 $tg->increase_termpos;
 154         } else {
 155                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 156         }
 157 }
 158
 159 sub index_headers ($$) {
 160         my ($self, $smsg) = @_;
 161         my @x = (from => 'A', # Author
 162                 subject => 'S', to => 'XTO', cc => 'XCC');
 163         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 164                 my $val = $smsg->{$field};
 165                 index_text($self, $val, 1, $pfx) if $val ne '';
 166         }
 167 }
 168
 169 sub index_diff_inc ($$$$) {
 170         my ($self, $text, $pfx, $xnq) = @_;
 171         if (@$xnq) {
 172                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 173                 @$xnq = ();
 174         }
 175         index_text($self, $text, 1, $pfx);
 176 }
 177
 178 sub index_old_diff_fn {
 179         my ($self, $seen, $fa, $fb, $xnq) = @_;
 180
 181         # no renames or space support for traditional diffs,
 182         # find the number of leading common paths to strip:
 183         my @fa = split('/', $fa);
 184         my @fb = split('/', $fb);
 185         while (scalar(@fa) && scalar(@fb)) {
 186                 $fa = join('/', @fa);
 187                 $fb = join('/', @fb);
 188                 if ($fa eq $fb) {
 189                         unless ($seen->{$fa}++) {
 190                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 191                         }
 192                         return 1;
 193                 }
 194                 shift @fa;
 195                 shift @fb;
 196         }
 197         0;
 198 }
 199
 200 sub index_diff ($$$) {
 201         my ($self, $txt, $doc) = @_;
 202         my %seen;
 203         my $in_diff;
 204         my @xnq;
 205         my $xnq = \@xnq;
 206         foreach (split(/\n/, $txt)) {
 207                 if ($in_diff && s/^ //) { # diff context
 208                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 209                 } elsif (/^-- $/) { # email signature begins
 210                         $in_diff = undef;
 211                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 212                         # wait until "---" and "+++" to capture filenames
 213                         $in_diff = 1;
 214                 # traditional diff:
 215                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 216                         my ($opt, $fa, $fb) = ($1, $2, $3);
 217                         push @xnq, $_;
 218                         # only support unified:
 219                         next unless $opt =~ /[uU]/;
 220                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 221                                                         $xnq);
 222                 } elsif (m!^--- ("?[^/]+/.+)!) {
 223                         my $fn = $1;
 224                         $fn = (split('/', git_unquote($fn), 2))[1];
 225                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 226                         $in_diff = 1;
 227                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 228                         my $fn = $1;
 229                         $fn = (split('/', git_unquote($fn), 2))[1];
 230                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 231                         $in_diff = 1;
 232                 } elsif (/^--- (\S+)/) {
 233                         $in_diff = $1;
 234                         push @xnq, $_;
 235                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 236                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 237                                                         $1, $xnq);
 238                 } elsif ($in_diff && s/^\+//) { # diff added
 239                         index_diff_inc($self, $_, 'XDFB', $xnq);
 240                 } elsif ($in_diff && s/^-//) { # diff removed
 241                         index_diff_inc($self, $_, 'XDFA', $xnq);
 242                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 243                         my ($ba, $bb) = ($1, $2);
 244                         index_git_blob_id($doc, 'XDFPRE', $ba);
 245                         index_git_blob_id($doc, 'XDFPOST', $bb);
 246                         $in_diff = 1;
 247                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 248                         # traditional diff w/o -p
 249                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 250                         # hunk header context
 251                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 252                 # ignore the following lines:
 253                 } elsif (/^(?:dis)similarity index/ ||
 254                                 /^(?:old|new) mode/ ||
 255                                 /^(?:deleted|new) file mode/ ||
 256                                 /^(?:copy|rename) (?:from|to) / ||
 257                                 /^(?:dis)?similarity index / ||
 258                                 /^\\ No newline at end of file/ ||
 259                                 /^Binary files .* differ/) {
 260                         push @xnq, $_;
 261                 } elsif ($_ eq '') {
 262                         # possible to be in diff context, some mail may be
 263                         # stripped by MUA or even GNU diff(1).  "git apply"
 264                         # treats a bare "\n" as diff context, too
 265                 } else {
 266                         push @xnq, $_;
 267                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 268                         $in_diff = undef;
 269                 }
 270         }
 271
 272         index_text($self, join("\n", @xnq), 1, 'XNQ');
 273 }
 274
 275 sub index_xapian { # msg_iter callback
 276         my $part = $_[0]->[0]; # ignore $depth and $idx
 277         my ($self, $doc) = @{$_[1]};
 278         my $ct = $part->content_type || 'text/plain';
 279         my $fn = $part->filename;
 280         if (defined $fn && $fn ne '') {
 281                 index_text($self, $fn, 1, 'XFN');
 282         }
 283         if ($part->{is_submsg}) {
 284                 my $mids = mids_for_index($part);
 285                 index_ids($self, $doc, $part, $mids);
 286                 my $smsg = bless {}, 'PublicInbox::Smsg';
 287                 $smsg->populate($part);
 288                 index_headers($self, $smsg);
 289         }
 290
 291         my ($s, undef) = msg_part_text($part, $ct);
 292         defined $s or return;
 293         $_[0]->[0] = $part = undef; # free memory
 294
 295         # split off quoted and unquoted blocks:
 296         my @sections = PublicInbox::MsgIter::split_quotes($s);
 297         undef $s; # free memory
 298         for my $txt (@sections) {
 299                 if ($txt =~ /\A>/) {
 300                         index_text($self, $txt, 0, 'XQUOT');
 301                 } else {
 302                         # does it look like a diff?
 303                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 304                                 index_diff($self, $txt, $doc);
 305                         } else {
 306                                 index_text($self, $txt, 1, 'XNQ');
 307                         }
 308                 }
 309                 undef $txt; # free memory
 310         }
 311 }
 312
 313 sub index_ids ($$$$) {
 314         my ($self, $doc, $hdr, $mids) = @_;
 315         for my $mid (@$mids) {
 316                 index_text($self, $mid, 1, 'XM');
 317
 318                 # because too many Message-IDs are prefixed with
 319                 # "Pine.LNX."...
 320                 if ($mid =~ /\w{12,}/) {
 321                         my @long = ($mid =~ /(\w{3,}+)/g);
 322                         index_text($self, join(' ', @long), 1, 'XM');
 323                 }
 324         }
 325         $doc->add_boolean_term('Q' . $_) for @$mids;
 326         for my $l ($hdr->header_raw('List-Id')) {
 327                 $l =~ /<([^>]+)>/ or next;
 328                 my $lid = $1;
 329                 $doc->add_boolean_term('G' . $lid);
 330                 index_text($self, $lid, 1, 'XL'); # probabilistic
 331         }
 332 }
 333
 334 sub add_xapian ($$$$) {
 335         my ($self, $mime, $smsg, $mids) = @_;
 336         my $hdr = $mime->header_obj;
 337         my $doc = $X->{Document}->new;
 338         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 339         my @ds = gmtime($smsg->{ds});
 340         my $yyyymmdd = strftime('%Y%m%d', @ds);
 341         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 342         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 343         add_val($doc, PublicInbox::Search::DT(), $dt);
 344         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 345         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 346
 347         my $tg = term_generator($self);
 348         $tg->set_document($doc);
 349         index_headers($self, $smsg);
 350
 351         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 352         index_ids($self, $doc, $hdr, $mids);
 353         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 354         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 355         my $data = $smsg->to_doc_data;
 356         $doc->set_data($data);
 357         if (my $altid = $self->{-altid}) {
 358                 foreach my $alt (@$altid) {
 359                         my $pfx = $alt->{xprefix};
 360                         foreach my $mid (@$mids) {
 361                                 my $id = $alt->mid2alt($mid);
 362                                 next unless defined $id;
 363                                 $doc->add_boolean_term($pfx . $id);
 364                         }
 365                 }
 366         }
 367         $self->{xdb}->replace_document($smsg->{num}, $doc);
 368 }
 369
 370 sub _msgmap_init ($) {
 371         my ($self) = @_;
 372         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 373         $self->{mm} //= eval {
 374                 require PublicInbox::Msgmap;
 375                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 376         };
 377 }
 378
 379 sub add_message {
 380         # mime = PublicInbox::Eml or Email::MIME object
 381         my ($self, $mime, $smsg, $sync) = @_;
 382         my $hdr = $mime->header_obj;
 383         my $mids = mids_for_index($hdr);
 384         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 385         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 386         $smsg->{num} //= do { # v1
 387                 _msgmap_init($self);
 388                 index_mm($self, $mime);
 389         };
 390
 391         # v1 and tests only:
 392         $smsg->populate($hdr, $sync);
 393         $smsg->{bytes} //= length($mime->as_string);
 394
 395         eval {
 396                 # order matters, overview stores every possible piece of
 397                 # data in doc_data (deflated).  Xapian only stores a subset
 398                 # of the fields which exist in over.sqlite3.  We may stop
 399                 # storing doc_data in Xapian sometime after we get multi-inbox
 400                 # search working.
 401                 if (my $over = $self->{over}) { # v1 only
 402                         $over->add_overview($mime, $smsg);
 403                 }
 404                 if (need_xapian($self)) {
 405                         add_xapian($self, $mime, $smsg, $mids);
 406                 }
 407         };
 408
 409         if ($@) {
 410                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 411                 return undef;
 412         }
 413         $smsg->{num};
 414 }
 415
 416 sub xdb_remove {
 417         my ($self, $oid, @removed) = @_;
 418         my $xdb = $self->{xdb} or return;
 419         for my $num (@removed) {
 420                 my $doc = eval { $xdb->get_document($num) };
 421                 unless ($doc) {
 422                         warn "E: $@\n" if $@;
 423                         warn "E: #$num $oid missing in Xapian\n";
 424                         next;
 425                 }
 426                 my $smsg = bless {}, 'PublicInbox::Smsg';
 427                 $smsg->load_expand($doc);
 428                 my $blob = $smsg->{blob} // '(unset)';
 429                 if ($blob eq $oid) {
 430                         $xdb->delete_document($num);
 431                 } else {
 432                         warn "E: #$num $oid != $blob in Xapian\n";
 433                 }
 434         }
 435 }
 436
 437 sub remove_by_oid {
 438         my ($self, $oid, $num) = @_;
 439         die "BUG: remove_by_oid is v2-only\n" if $self->{over};
 440         $self->begin_txn_lazy;
 441         xdb_remove($self, $oid, $num) if need_xapian($self);
 442 }
 443
 444 sub index_git_blob_id {
 445         my ($doc, $pfx, $objid) = @_;
 446
 447         my $len = length($objid);
 448         for (my $len = length($objid); $len >= 7; ) {
 449                 $doc->add_term($pfx.$objid);
 450                 $objid = substr($objid, 0, --$len);
 451         }
 452 }
 453
 454 # v1 only
 455 sub unindex_eml {
 456         my ($self, $oid, $eml) = @_;
 457         my $mids = mids($eml);
 458         my $nr = 0;
 459         my %tmp;
 460         for my $mid (@$mids) {
 461                 my @removed = eval { $self->{over}->remove_oid($oid, $mid) };
 462                 if ($@) {
 463                         warn "E: failed to remove <$mid> from overview: $@\n";
 464                 } else {
 465                         $nr += scalar @removed;
 466                         $tmp{$_}++ for @removed;
 467                 }
 468         }
 469         if (!$nr) {
 470                 $mids = join('> <', @$mids);
 471                 warn "W: <$mids> missing for removal from overview\n";
 472         }
 473         while (my ($num, $nr) = each %tmp) {
 474                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 475         }
 476         xdb_remove($self, $oid, keys %tmp) if need_xapian($self);
 477 }
 478
 479 sub index_mm {
 480         my ($self, $mime) = @_;
 481         my $mid = mid_mime($mime);
 482         my $mm = $self->{mm};
 483         my $num;
 484
 485         if (defined $self->{regen_down}) {
 486                 $num = $mm->num_for($mid) and return $num;
 487
 488                 while (($num = $self->{regen_down}--) > 0) {
 489                         if ($mm->mid_set($num, $mid) != 0) {
 490                                 return $num;
 491                         }
 492                 }
 493         } elsif (defined $self->{regen_up}) {
 494                 $num = $mm->num_for($mid) and return $num;
 495
 496                 # this is to fixup old bugs due to add-remove-add
 497                 while (($num = ++$self->{regen_up})) {
 498                         if ($mm->mid_set($num, $mid) != 0) {
 499                                 return $num;
 500                         }
 501                 }
 502         }
 503
 504         $num = $mm->mid_insert($mid) and return $num;
 505
 506         # fallback to num_for since filters like RubyLang set the number
 507         $mm->num_for($mid);
 508 }
 509
 510 sub unindex_mm {
 511         my ($self, $mime) = @_;
 512         $self->{mm}->mid_delete(mid_mime($mime));
 513 }
 514
 515 # returns the number of bytes to add if given a non-CRLF arg
 516 sub crlf_adjust ($) {
 517         if (index($_[0], "\r\n") < 0) {
 518                 # common case is LF-only, every \n needs an \r;
 519                 # so favor a cheap tr// over an expensive m//g
 520                 $_[0] =~ tr/\n/\n/;
 521         } else { # count number of '\n' w/o '\r', expensive:
 522                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 523         }
 524 }
 525
 526 sub index_both { # git->cat_async callback
 527         my ($bref, $oid, $type, $size, $sync) = @_;
 528         my ($nr, $max) = @$sync{qw(nr max)};
 529         ++$$nr;
 530         $$max -= $size;
 531         $size += crlf_adjust($$bref);
 532         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 533         my $self = $sync->{sidx};
 534         my $eml = PublicInbox::Eml->new($bref);
 535         my $num = index_mm($self, $eml);
 536         $smsg->{num} = $num;
 537         add_message($self, $eml, $smsg, $sync);
 538 }
 539
 540 sub unindex_both { # git->cat_async callback
 541         my ($bref, $oid, $type, $size, $self) = @_;
 542         my $eml = PublicInbox::Eml->new($bref);
 543         unindex_eml($self, $oid, $eml);
 544         unindex_mm($self, $eml);
 545 }
 546
 547 # called by public-inbox-index
 548 sub index_sync {
 549         my ($self, $opts) = @_;
 550         delete $self->{lock_path} if $opts->{-skip_lock};
 551         $self->{-inbox}->with_umask(\&_index_sync, $self, $opts);
 552 }
 553
 554 sub too_big ($$$) {
 555         my ($self, $git, $oid) = @_;
 556         my $max_size = $self->{index_max_size} or return;
 557         my (undef, undef, $size) = $git->check($oid);
 558         die "E: bad $oid in $git->{git_dir}\n" if !defined($size);
 559         return if $size <= $max_size;
 560         warn "W: skipping $oid ($size > $max_size)\n";
 561         1;
 562 }
 563
 564 # only for v1
 565 sub read_log {
 566         my ($self, $log, $batch_cb) = @_;
 567         my $hex = '[a-f0-9]';
 568         my $h40 = $hex .'{40}';
 569         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 570         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 571         my $git = $self->{git};
 572         my $latest;
 573         my $max = $BATCH_BYTES;
 574         local $/ = "\n";
 575         my %D;
 576         my $line;
 577         my $newest;
 578         my $nr = 0;
 579         my $sync = { sidx => $self, nr => \$nr, max => \$max };
 580         while (defined($line = <$log>)) {
 581                 if ($line =~ /$addmsg/o) {
 582                         my $blob = $1;
 583                         if (delete $D{$blob}) {
 584                                 # make sure pending index writes are done
 585                                 # before writing to ->mm
 586                                 $git->cat_async_wait;
 587
 588                                 if (defined $self->{regen_down}) {
 589                                         my $num = $self->{regen_down}--;
 590                                         $self->{mm}->num_highwater($num);
 591                                 }
 592                                 next;
 593                         }
 594                         next if too_big($self, $git, $blob);
 595                         $git->cat_async($blob, \&index_both, { %$sync });
 596                         if ($max <= 0) {
 597                                 $git->cat_async_wait;
 598                                 $max = $BATCH_BYTES;
 599                                 $batch_cb->($nr, $latest);
 600                         }
 601                 } elsif ($line =~ /$delmsg/o) {
 602                         my $blob = $1;
 603                         $D{$blob} = 1 unless too_big($self, $git, $blob);
 604                 } elsif ($line =~ /^commit ($h40)/o) {
 605                         $latest = $1;
 606                         $newest ||= $latest;
 607                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 608                         $sync->{autime} = $1;
 609                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 610                         $sync->{cotime} = $1;
 611                 }
 612         }
 613         close($log) or die "git log failed: \$?=$?";
 614         # get the leftovers
 615         foreach my $blob (keys %D) {
 616                 $git->cat_async($blob, \&unindex_both, $self);
 617         }
 618         $git->cat_async_wait;
 619         $batch_cb->($nr, $latest, $newest);
 620 }
 621
 622 sub _git_log {
 623         my ($self, $opts, $range) = @_;
 624         my $git = $self->{git};
 625
 626         if (index($range, '..') < 0) {
 627                 # don't show annoying git errors to users who run -index
 628                 # on empty inboxes
 629                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 630                 if ($?) {
 631                         open my $fh, '<', '/dev/null' or
 632                                 die "failed to open /dev/null: $!\n";
 633                         return $fh;
 634                 }
 635         }
 636
 637         # Count the new files so they can be added newest to oldest
 638         # and still have numbers increasing from oldest to newest
 639         my $fcount = 0;
 640         my $pr = $opts->{-progress};
 641         $pr->("counting changes\n\t$range ... ") if $pr;
 642         # can't use 'rev-list --count' if we use --diff-filter
 643         my $fh = $git->popen(qw(log --pretty=tformat:%h
 644                              --no-notes --no-color --no-renames
 645                              --diff-filter=AM), $range);
 646         ++$fcount while <$fh>;
 647         close $fh or die "git log failed: \$?=$?";
 648         my $high = $self->{mm}->num_highwater;
 649         $pr->("$fcount\n") if $pr; # continue previous line
 650         $self->{ntodo} = $fcount;
 651
 652         if (index($range, '..') < 0) {
 653                 if ($high && $high == $fcount) {
 654                         # fix up old bugs in full indexes which caused messages to
 655                         # not appear in Msgmap
 656                         $self->{regen_up} = $high;
 657                 } else {
 658                         # normal regen is for for fresh data
 659                         $self->{regen_down} = $fcount;
 660                         $self->{regen_down} += $high unless $opts->{reindex};
 661                 }
 662         } else {
 663                 # Give oldest messages the smallest numbers
 664                 $self->{regen_down} = $high + $fcount;
 665         }
 666
 667         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 668                                 --raw -r --no-abbrev/, $range);
 669 }
 670
 671 # --is-ancestor requires git 1.8.0+
 672 sub is_ancestor ($$$) {
 673         my ($git, $cur, $tip) = @_;
 674         return 0 unless $git->check($cur);
 675         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 676                 qw(merge-base --is-ancestor), $cur, $tip ];
 677         my $pid = spawn($cmd);
 678         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 679         $? == 0;
 680 }
 681
 682 sub need_update ($$$) {
 683         my ($self, $cur, $new) = @_;
 684         my $git = $self->{git};
 685         return 1 if $cur && !is_ancestor($git, $cur, $new);
 686         my $range = $cur eq '' ? $new : "$cur..$new";
 687         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 688         ($n eq '' || $n > 0);
 689 }
 690
 691 # The last git commit we indexed with Xapian or SQLite (msgmap)
 692 # This needs to account for cases where Xapian or SQLite is
 693 # out-of-date with respect to the other.
 694 sub _last_x_commit {
 695         my ($self, $mm) = @_;
 696         my $lm = $mm->last_commit || '';
 697         my $lx = '';
 698         if (need_xapian($self)) {
 699                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 700         } else {
 701                 $lx = $lm;
 702         }
 703         # Use last_commit from msgmap if it is older or unset
 704         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 705                 $lx = $lm;
 706         }
 707         $lx;
 708 }
 709
 710 sub reindex_from ($$) {
 711         my ($reindex, $last_commit) = @_;
 712         return $last_commit unless $reindex;
 713         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 714 }
 715
 716 # indexes all unindexed messages (v1 only)
 717 sub _index_sync {
 718         my ($self, $opts) = @_;
 719         my $tip = $opts->{ref} || 'HEAD';
 720         my ($last_commit, $lx, $xlog);
 721         my $git = $self->{git};
 722         $git->batch_prepare;
 723         my $pr = $opts->{-progress};
 724
 725         my $xdb = $self->begin_txn_lazy;
 726         $self->{over}->rethread_prepare($opts);
 727         my $mm = _msgmap_init($self);
 728         do {
 729                 $xlog = undef; # stop previous git-log via SIGPIPE
 730                 $last_commit = _last_x_commit($self, $mm);
 731                 $lx = reindex_from($opts->{reindex}, $last_commit);
 732
 733                 $self->{over}->rollback_lazy;
 734                 $self->{over}->disconnect;
 735                 $git->cleanup;
 736                 delete $self->{txn};
 737                 $xdb->cancel_transaction if $xdb;
 738                 $xdb = _xdb_release($self);
 739
 740                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 741                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 742                 $xlog = _git_log($self, $opts, $range);
 743
 744                 $xdb = $self->begin_txn_lazy;
 745         } while (_last_x_commit($self, $mm) ne $last_commit);
 746
 747         my $dbh = $mm->{dbh} if $mm;
 748         my $batch_cb = sub {
 749                 my ($nr, $commit, $newest) = @_;
 750                 if ($dbh) {
 751                         if ($newest) {
 752                                 my $cur = $mm->last_commit || '';
 753                                 if (need_update($self, $cur, $newest)) {
 754                                         $mm->last_commit($newest);
 755                                 }
 756                         }
 757                         $dbh->commit;
 758                 }
 759                 if ($newest && need_xapian($self)) {
 760                         my $cur = $xdb->get_metadata('last_commit');
 761                         if (need_update($self, $cur, $newest)) {
 762                                 $xdb->set_metadata('last_commit', $newest);
 763                         }
 764                 }
 765
 766                 $self->{over}->rethread_done($opts) if $newest; # all done
 767                 $self->commit_txn_lazy;
 768                 $git->cleanup;
 769                 $xdb = _xdb_release($self, $nr);
 770                 # let another process do some work...
 771                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 772                 if (!$newest) { # more to come
 773                         $xdb = $self->begin_txn_lazy;
 774                         $dbh->begin_work if $dbh;
 775                 }
 776         };
 777
 778         $dbh->begin_work;
 779         read_log($self, $xlog, $batch_cb);
 780 }
 781
 782 sub DESTROY {
 783         # order matters for unlocking
 784         $_[0]->{xdb} = undef;
 785         $_[0]->{lockfh} = undef;
 786 }
 787
 788 # remote_* subs are only used by SearchIdxPart
 789 sub remote_commit {
 790         my ($self) = @_;
 791         if (my $w = $self->{w}) {
 792                 print $w "commit\n" or die "failed to write commit: $!";
 793         } else {
 794                 $self->commit_txn_lazy;
 795         }
 796 }
 797
 798 sub remote_close {
 799         my ($self) = @_;
 800         if (my $w = delete $self->{w}) {
 801                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 802                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 803                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 804                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 805                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 806         } else {
 807                 die "transaction in progress $self\n" if $self->{txn};
 808                 $self->_xdb_release if $self->{xdb};
 809         }
 810 }
 811
 812 sub remote_remove {
 813         my ($self, $oid, $num) = @_;
 814         if (my $w = $self->{w}) {
 815                 # triggers remove_by_oid in a shard
 816                 print $w "D $oid $num\n" or die "failed to write remove $!";
 817         } else {
 818                 $self->remove_by_oid($oid, $num);
 819         }
 820 }
 821
 822 sub _begin_txn {
 823         my ($self) = @_;
 824         my $xdb = $self->{xdb} || $self->_xdb_acquire;
 825         $self->{over}->begin_lazy if $self->{over};
 826         $xdb->begin_transaction if $xdb;
 827         $self->{txn} = 1;
 828         $xdb;
 829 }
 830
 831 sub begin_txn_lazy {
 832         my ($self) = @_;
 833         $self->{-inbox}->with_umask(\&_begin_txn, $self) if !$self->{txn};
 834 }
 835
 836 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 837 # This metadata is read by Admin::detect_indexlevel:
 838 sub set_indexlevel {
 839         my ($self) = @_;
 840
 841         if (!$self->{shard} && # undef or 0, not >0
 842                         delete($self->{-set_indexlevel_once})) {
 843                 my $xdb = $self->{xdb};
 844                 my $level = $xdb->get_metadata('indexlevel');
 845                 if (!$level || $level ne 'medium') {
 846                         $xdb->set_metadata('indexlevel', 'medium');
 847                 }
 848         }
 849 }
 850
 851 sub _commit_txn {
 852         my ($self) = @_;
 853         if (my $xdb = $self->{xdb}) {
 854                 set_indexlevel($self);
 855                 $xdb->commit_transaction;
 856         }
 857         $self->{over}->commit_lazy if $self->{over};
 858 }
 859
 860 sub commit_txn_lazy {
 861         my ($self) = @_;
 862         delete($self->{txn}) and
 863                 $self->{-inbox}->with_umask(\&_commit_txn, $self);
 864 }
 865
 866 sub worker_done {
 867         my ($self) = @_;
 868         if (need_xapian($self)) {
 869                 die "$$ $0 xdb not released\n" if $self->{xdb};
 870         }
 871         die "$$ $0 still in transaction\n" if $self->{txn};
 872 }
 873
 874 1;