lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 our $BATCH_BYTES = defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000;
  27 use constant DEBUG => !!$ENV{DEBUG};
  28
  29 my $xapianlevels = qr/\A(?:full|medium)\z/;
  30
  31 sub new {
  32         my ($class, $ibx, $creat, $shard) = @_;
  33         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  34         my $levels = qr/\A(?:full|medium|basic)\z/;
  35         my $inboxdir = $ibx->{inboxdir};
  36         my $version = $ibx->version;
  37         my $indexlevel = 'full';
  38         my $altid = $ibx->{altid};
  39         if ($altid) {
  40                 require PublicInbox::AltId;
  41                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  42         }
  43         if ($ibx->{indexlevel}) {
  44                 if ($ibx->{indexlevel} =~ $levels) {
  45                         $indexlevel = $ibx->{indexlevel};
  46                 } else {
  47                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  48                 }
  49         }
  50         $ibx = PublicInbox::InboxWritable->new($ibx);
  51         my $self = bless {
  52                 inboxdir => $inboxdir,
  53                 -inbox => $ibx,
  54                 git => $ibx->git,
  55                 -altid => $altid,
  56                 ibx_ver => $version,
  57                 indexlevel => $indexlevel,
  58         }, $class;
  59         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  60         $ibx->umask_prepare;
  61         if ($version == 1) {
  62                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  63                 my $dir = $self->xdir;
  64                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  65                 $self->{index_max_size} = $ibx->{index_max_size};
  66         } elsif ($version == 2) {
  67                 defined $shard or die "shard is required for v2\n";
  68                 # shard is a number
  69                 $self->{shard} = $shard;
  70                 $self->{lock_path} = undef;
  71         } else {
  72                 die "unsupported inbox version=$version\n";
  73         }
  74         $self->{creat} = ($creat || 0) == 1;
  75         $self;
  76 }
  77
  78 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  79
  80 sub _xdb_release {
  81         my ($self) = @_;
  82         if (need_xapian($self)) {
  83                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  84                 $xdb->close;
  85         }
  86         $self->lock_release if $self->{creat};
  87         undef;
  88 }
  89
  90 sub load_xapian_writable () {
  91         return 1 if $X->{WritableDatabase};
  92         PublicInbox::Search::load_xapian() or return;
  93         my $xap = $PublicInbox::Search::Xap;
  94         for (qw(Document TermGenerator WritableDatabase)) {
  95                 $X->{$_} = $xap.'::'.$_;
  96         }
  97         eval 'require '.$X->{WritableDatabase} or die;
  98         *sortable_serialise = $xap.'::sortable_serialise';
  99         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 100         $DB_OPEN = eval($xap.'::DB_OPEN()');
 101         1;
 102 }
 103
 104 sub _xdb_acquire {
 105         my ($self) = @_;
 106         my $flag;
 107         my $dir = $self->xdir;
 108         if (need_xapian($self)) {
 109                 croak 'already acquired' if $self->{xdb};
 110                 load_xapian_writable();
 111                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 112         }
 113         if ($self->{creat}) {
 114                 require File::Path;
 115                 $self->lock_acquire;
 116
 117                 # don't create empty Xapian directories if we don't need Xapian
 118                 my $is_shard = defined($self->{shard});
 119                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 120                         File::Path::mkpath($dir);
 121                 }
 122         }
 123         return unless defined $flag;
 124         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 125         if ($@) {
 126                 die "Failed opening $dir: ", $@;
 127         }
 128         $self->{xdb} = $xdb;
 129 }
 130
 131 sub add_val ($$$) {
 132         my ($doc, $col, $num) = @_;
 133         $num = sortable_serialise($num);
 134         $doc->add_value($col, $num);
 135 }
 136
 137 sub term_generator ($) { # write-only
 138         my ($self) = @_;
 139
 140         $self->{term_generator} //= do {
 141                 my $tg = $X->{TermGenerator}->new;
 142                 $tg->set_stemmer($self->stemmer);
 143                 $tg;
 144         }
 145 }
 146
 147 sub index_text ($$$$) {
 148         my ($self, $text, $wdf_inc, $prefix) = @_;
 149         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 150
 151         if ($self->{indexlevel} eq 'full') {
 152                 $tg->index_text($text, $wdf_inc, $prefix);
 153                 $tg->increase_termpos;
 154         } else {
 155                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 156         }
 157 }
 158
 159 sub index_users ($$) {
 160         my ($self, $smsg) = @_;
 161
 162         my $from = $smsg->from;
 163         my $to = $smsg->to;
 164         my $cc = $smsg->cc;
 165
 166         index_text($self, $from, 1, 'A'); # A - author
 167         index_text($self, $to, 1, 'XTO') if $to ne '';
 168         index_text($self, $cc, 1, 'XCC') if $cc ne '';
 169 }
 170
 171 sub index_diff_inc ($$$$) {
 172         my ($self, $text, $pfx, $xnq) = @_;
 173         if (@$xnq) {
 174                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 175                 @$xnq = ();
 176         }
 177         index_text($self, $text, 1, $pfx);
 178 }
 179
 180 sub index_old_diff_fn {
 181         my ($self, $seen, $fa, $fb, $xnq) = @_;
 182
 183         # no renames or space support for traditional diffs,
 184         # find the number of leading common paths to strip:
 185         my @fa = split('/', $fa);
 186         my @fb = split('/', $fb);
 187         while (scalar(@fa) && scalar(@fb)) {
 188                 $fa = join('/', @fa);
 189                 $fb = join('/', @fb);
 190                 if ($fa eq $fb) {
 191                         unless ($seen->{$fa}++) {
 192                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 193                         }
 194                         return 1;
 195                 }
 196                 shift @fa;
 197                 shift @fb;
 198         }
 199         0;
 200 }
 201
 202 sub index_diff ($$$) {
 203         my ($self, $txt, $doc) = @_;
 204         my %seen;
 205         my $in_diff;
 206         my @xnq;
 207         my $xnq = \@xnq;
 208         foreach (split(/\n/, $txt)) {
 209                 if ($in_diff && s/^ //) { # diff context
 210                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 211                 } elsif (/^-- $/) { # email signature begins
 212                         $in_diff = undef;
 213                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 214                         # wait until "---" and "+++" to capture filenames
 215                         $in_diff = 1;
 216                 # traditional diff:
 217                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 218                         my ($opt, $fa, $fb) = ($1, $2, $3);
 219                         push @xnq, $_;
 220                         # only support unified:
 221                         next unless $opt =~ /[uU]/;
 222                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 223                                                         $xnq);
 224                 } elsif (m!^--- ("?[^/]+/.+)!) {
 225                         my $fn = $1;
 226                         $fn = (split('/', git_unquote($fn), 2))[1];
 227                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 228                         $in_diff = 1;
 229                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 230                         my $fn = $1;
 231                         $fn = (split('/', git_unquote($fn), 2))[1];
 232                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 233                         $in_diff = 1;
 234                 } elsif (/^--- (\S+)/) {
 235                         $in_diff = $1;
 236                         push @xnq, $_;
 237                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 238                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 239                                                         $1, $xnq);
 240                 } elsif ($in_diff && s/^\+//) { # diff added
 241                         index_diff_inc($self, $_, 'XDFB', $xnq);
 242                 } elsif ($in_diff && s/^-//) { # diff removed
 243                         index_diff_inc($self, $_, 'XDFA', $xnq);
 244                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 245                         my ($ba, $bb) = ($1, $2);
 246                         index_git_blob_id($doc, 'XDFPRE', $ba);
 247                         index_git_blob_id($doc, 'XDFPOST', $bb);
 248                         $in_diff = 1;
 249                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 250                         # traditional diff w/o -p
 251                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 252                         # hunk header context
 253                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 254                 # ignore the following lines:
 255                 } elsif (/^(?:dis)similarity index/ ||
 256                                 /^(?:old|new) mode/ ||
 257                                 /^(?:deleted|new) file mode/ ||
 258                                 /^(?:copy|rename) (?:from|to) / ||
 259                                 /^(?:dis)?similarity index / ||
 260                                 /^\\ No newline at end of file/ ||
 261                                 /^Binary files .* differ/) {
 262                         push @xnq, $_;
 263                 } elsif ($_ eq '') {
 264                         # possible to be in diff context, some mail may be
 265                         # stripped by MUA or even GNU diff(1).  "git apply"
 266                         # treats a bare "\n" as diff context, too
 267                 } else {
 268                         push @xnq, $_;
 269                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 270                         $in_diff = undef;
 271                 }
 272         }
 273
 274         index_text($self, join("\n", @xnq), 1, 'XNQ');
 275 }
 276
 277 sub index_xapian { # msg_iter callback
 278         my $part = $_[0]->[0]; # ignore $depth and $idx
 279         my ($self, $doc) = @{$_[1]};
 280         my $ct = $part->content_type || 'text/plain';
 281         my $fn = $part->filename;
 282         if (defined $fn && $fn ne '') {
 283                 index_text($self, $fn, 1, 'XFN');
 284         }
 285         if ($part->{is_submsg}) {
 286                 my $mids = mids_for_index($part);
 287                 index_ids($self, $doc, $part, $mids);
 288                 my $smsg = PublicInbox::Smsg->new($part);
 289                 index_users($self, $smsg);
 290                 index_text($self, $smsg->subject, 1, 'S') if $smsg->subject;
 291         }
 292
 293         my ($s, undef) = msg_part_text($part, $ct);
 294         defined $s or return;
 295         $_[0]->[0] = $part = undef; # free memory
 296
 297         # split off quoted and unquoted blocks:
 298         my @sections = PublicInbox::MsgIter::split_quotes($s);
 299         undef $s; # free memory
 300         for my $txt (@sections) {
 301                 if ($txt =~ /\A>/) {
 302                         index_text($self, $txt, 0, 'XQUOT');
 303                 } else {
 304                         # does it look like a diff?
 305                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 306                                 index_diff($self, $txt, $doc);
 307                         } else {
 308                                 index_text($self, $txt, 1, 'XNQ');
 309                         }
 310                 }
 311                 undef $txt; # free memory
 312         }
 313 }
 314
 315 sub index_ids ($$$$) {
 316         my ($self, $doc, $hdr, $mids) = @_;
 317         for my $mid (@$mids) {
 318                 index_text($self, $mid, 1, 'XM');
 319
 320                 # because too many Message-IDs are prefixed with
 321                 # "Pine.LNX."...
 322                 if ($mid =~ /\w{12,}/) {
 323                         my @long = ($mid =~ /(\w{3,}+)/g);
 324                         index_text($self, join(' ', @long), 1, 'XM');
 325                 }
 326         }
 327         $doc->add_boolean_term('Q' . $_) for @$mids;
 328         for my $l ($hdr->header_raw('List-Id')) {
 329                 $l =~ /<([^>]+)>/ or next;
 330                 my $lid = $1;
 331                 $doc->add_boolean_term('G' . $lid);
 332                 index_text($self, $lid, 1, 'XL'); # probabilistic
 333         }
 334 }
 335
 336 sub add_xapian ($$$$) {
 337         my ($self, $mime, $smsg, $mids) = @_;
 338         $smsg->{mime} = $mime; # XXX dangerous
 339         my $hdr = $mime->header_obj;
 340         my $doc = $X->{Document}->new;
 341         my $subj = $smsg->subject;
 342         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 343         my @ds = gmtime($smsg->{ds});
 344         my $yyyymmdd = strftime('%Y%m%d', @ds);
 345         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 346         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 347         add_val($doc, PublicInbox::Search::DT(), $dt);
 348
 349         my $tg = term_generator($self);
 350         $tg->set_document($doc);
 351         index_text($self, $subj, 1, 'S') if $subj;
 352         index_users($self, $smsg);
 353
 354         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 355         index_ids($self, $doc, $hdr, $mids);
 356         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 357         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 358         my $data = $smsg->to_doc_data;
 359         $doc->set_data($data);
 360         if (my $altid = $self->{-altid}) {
 361                 foreach my $alt (@$altid) {
 362                         my $pfx = $alt->{xprefix};
 363                         foreach my $mid (@$mids) {
 364                                 my $id = $alt->mid2alt($mid);
 365                                 next unless defined $id;
 366                                 $doc->add_boolean_term($pfx . $id);
 367                         }
 368                 }
 369         }
 370         $self->{xdb}->replace_document($smsg->{num}, $doc);
 371 }
 372
 373 sub _msgmap_init ($) {
 374         my ($self) = @_;
 375         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 376         $self->{mm} //= eval {
 377                 require PublicInbox::Msgmap;
 378                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 379         };
 380 }
 381
 382 sub add_message {
 383         # mime = PublicInbox::Eml or Email::MIME object
 384         my ($self, $mime, $smsg) = @_;
 385         my $hdr = $mime->header_obj;
 386         my $mids = mids_for_index($hdr);
 387         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 388         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 389         $smsg->{num} //= do { # v1
 390                 _msgmap_init($self);
 391                 index_mm($self, $mime);
 392         };
 393
 394         # v1 and tests only:
 395         $smsg->{ds} //= msg_datestamp($hdr, $self->{autime});
 396         $smsg->{ts} //= msg_timestamp($hdr, $self->{cotime});
 397
 398         eval {
 399                 # order matters, overview stores every possible piece of
 400                 # data in doc_data (deflated).  Xapian only stores a subset
 401                 # of the fields which exist in over.sqlite3.  We may stop
 402                 # storing doc_data in Xapian sometime after we get multi-inbox
 403                 # search working.
 404                 if (my $over = $self->{over}) { # v1 only
 405                         $over->add_overview($mime, $smsg);
 406                 }
 407                 if (need_xapian($self)) {
 408                         add_xapian($self, $mime, $smsg, $mids);
 409                 }
 410         };
 411
 412         if ($@) {
 413                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 414                 return undef;
 415         }
 416         $smsg->{num};
 417 }
 418
 419 # returns begin and end PostingIterator
 420 sub find_doc_ids {
 421         my ($self, $termval) = @_;
 422         my $db = $self->{xdb};
 423
 424         ($db->postlist_begin($termval), $db->postlist_end($termval));
 425 }
 426
 427 # v1 only
 428 sub batch_do {
 429         my ($self, $termval, $cb) = @_;
 430         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 431         while (1) {
 432                 my ($head, $tail) = $self->find_doc_ids($termval);
 433                 return if $head == $tail;
 434                 my @ids;
 435                 for (; $head != $tail && @ids < $batch_size; $head++) {
 436                         push @ids, $head->get_docid;
 437                 }
 438                 $cb->(\@ids);
 439         }
 440 }
 441
 442 # v1 only, where $mid is unique
 443 sub remove_message {
 444         my ($self, $mid) = @_;
 445         $mid = mid_clean($mid);
 446
 447         if (my $over = $self->{over}) {
 448                 my $nr = eval { $over->remove_oid(undef, $mid) };
 449                 if ($@) {
 450                         warn "failed to remove <$mid> from overview: $@\n";
 451                 } elsif ($nr == 0) {
 452                         warn "<$mid> missing for removal from overview\n";
 453                 }
 454         }
 455         return unless need_xapian($self);
 456         my $db = $self->{xdb};
 457         my $nr = 0;
 458         eval {
 459                 batch_do($self, 'Q' . $mid, sub {
 460                         my ($ids) = @_;
 461                         $db->delete_document($_) for @$ids;
 462                         $nr += scalar @$ids;
 463                 });
 464         };
 465         if ($@) {
 466                 warn "failed to remove <$mid> from Xapian: $@\n";
 467         } elsif ($nr == 0) {
 468                 warn "<$mid> missing for removal from Xapian\n";
 469         }
 470 }
 471
 472 # MID is a hint in V2
 473 sub remove_by_oid {
 474         my ($self, $oid, $mid) = @_;
 475
 476         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 477
 478         return unless need_xapian($self);
 479         my $db = $self->{xdb};
 480
 481         # XXX careful, we cannot use batch_do here since we conditionally
 482         # delete documents based on other factors, so we cannot call
 483         # find_doc_ids twice.
 484         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 485         return if $head == $tail;
 486
 487         # there is only ONE element in @delete unless we
 488         # have bugs in our v2writable deduplication check
 489         my @delete;
 490         for (; $head != $tail; $head++) {
 491                 my $docid = $head->get_docid;
 492                 my $doc = $db->get_document($docid);
 493                 my $smsg = PublicInbox::Smsg->wrap($mid);
 494                 $smsg->load_expand($doc);
 495                 if ($smsg->{blob} eq $oid) {
 496                         push(@delete, $docid);
 497                 }
 498         }
 499         $db->delete_document($_) foreach @delete;
 500         scalar(@delete);
 501 }
 502
 503 sub index_git_blob_id {
 504         my ($doc, $pfx, $objid) = @_;
 505
 506         my $len = length($objid);
 507         for (my $len = length($objid); $len >= 7; ) {
 508                 $doc->add_term($pfx.$objid);
 509                 $objid = substr($objid, 0, --$len);
 510         }
 511 }
 512
 513 sub unindex_blob {
 514         my ($self, $mime) = @_;
 515         my $mid = eval { mid_mime($mime) };
 516         $self->remove_message($mid) if defined $mid;
 517 }
 518
 519 sub index_mm {
 520         my ($self, $mime) = @_;
 521         my $mid = mid_mime($mime);
 522         my $mm = $self->{mm};
 523         my $num;
 524
 525         if (defined $self->{regen_down}) {
 526                 $num = $mm->num_for($mid) and return $num;
 527
 528                 while (($num = $self->{regen_down}--) > 0) {
 529                         if ($mm->mid_set($num, $mid) != 0) {
 530                                 return $num;
 531                         }
 532                 }
 533         } elsif (defined $self->{regen_up}) {
 534                 $num = $mm->num_for($mid) and return $num;
 535
 536                 # this is to fixup old bugs due to add-remove-add
 537                 while (($num = ++$self->{regen_up})) {
 538                         if ($mm->mid_set($num, $mid) != 0) {
 539                                 return $num;
 540                         }
 541                 }
 542         }
 543
 544         $num = $mm->mid_insert($mid) and return $num;
 545
 546         # fallback to num_for since filters like RubyLang set the number
 547         $mm->num_for($mid);
 548 }
 549
 550 sub unindex_mm {
 551         my ($self, $mime) = @_;
 552         $self->{mm}->mid_delete(mid_mime($mime));
 553 }
 554
 555 sub index_both {
 556         my ($self, $mime, $smsg) = @_;
 557         my $num = index_mm($self, $mime);
 558         $smsg->{num} = $num;
 559         add_message($self, $mime, $smsg);
 560 }
 561
 562 sub unindex_both {
 563         my ($self, $mime) = @_;
 564         unindex_blob($self, $mime);
 565         unindex_mm($self, $mime);
 566 }
 567
 568 sub do_cat_mail {
 569         my ($git, $blob, $sizeref) = @_;
 570         my $str = $git->cat_file($blob, $sizeref) or
 571                 die "BUG: $blob not found in $git->{git_dir}";
 572         PublicInbox::Eml->new($str);
 573 }
 574
 575 # called by public-inbox-index
 576 sub index_sync {
 577         my ($self, $opts) = @_;
 578         delete $self->{lock_path} if $opts->{-skip_lock};
 579         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 580 }
 581
 582 sub batch_adjust ($$$$$) {
 583         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 584         $$max -= $bytes;
 585         if ($$max <= 0) {
 586                 $$max = $BATCH_BYTES;
 587                 $batch_cb->($nr, $latest);
 588         }
 589 }
 590
 591 sub too_big ($$$) {
 592         my ($self, $git, $oid) = @_;
 593         my $max_size = $self->{index_max_size} or return;
 594         my (undef, undef, $size) = $git->check($oid);
 595         die "E: bad $oid in $git->{git_dir}\n" if !defined($size);
 596         return if $size <= $max_size;
 597         warn "W: skipping $oid ($size > $max_size)\n";
 598         1;
 599 }
 600
 601 # only for v1
 602 sub read_log {
 603         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 604         my $hex = '[a-f0-9]';
 605         my $h40 = $hex .'{40}';
 606         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 607         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 608         my $git = $self->{git};
 609         my $latest;
 610         my $bytes;
 611         my $max = $BATCH_BYTES;
 612         local $/ = "\n";
 613         my %D;
 614         my $line;
 615         my $newest;
 616         my $nr = 0;
 617         while (defined($line = <$log>)) {
 618                 if ($line =~ /$addmsg/o) {
 619                         my $blob = $1;
 620                         if (delete $D{$blob}) {
 621                                 if (defined $self->{regen_down}) {
 622                                         my $num = $self->{regen_down}--;
 623                                         $self->{mm}->num_highwater($num);
 624                                 }
 625                                 next;
 626                         }
 627                         next if too_big($self, $git, $blob);
 628                         my $mime = do_cat_mail($git, $blob, \$bytes);
 629                         my $smsg = bless {}, 'PublicInbox::Smsg';
 630                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 631                         $smsg->{blob} = $blob;
 632                         $smsg->{bytes} = $bytes;
 633                         $add_cb->($self, $mime, $smsg);
 634                 } elsif ($line =~ /$delmsg/o) {
 635                         my $blob = $1;
 636                         $D{$blob} = 1 unless too_big($self, $git, $blob);
 637                 } elsif ($line =~ /^commit ($h40)/o) {
 638                         $latest = $1;
 639                         $newest ||= $latest;
 640                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 641                         $self->{autime} = $1;
 642                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 643                         $self->{cotime} = $1;
 644                 }
 645         }
 646         close($log) or die "git log failed: \$?=$?";
 647         # get the leftovers
 648         foreach my $blob (keys %D) {
 649                 my $mime = do_cat_mail($git, $blob, \$bytes);
 650                 $del_cb->($self, $mime);
 651         }
 652         $batch_cb->($nr, $latest, $newest);
 653 }
 654
 655 sub _git_log {
 656         my ($self, $opts, $range) = @_;
 657         my $git = $self->{git};
 658
 659         if (index($range, '..') < 0) {
 660                 # don't show annoying git errors to users who run -index
 661                 # on empty inboxes
 662                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 663                 if ($?) {
 664                         open my $fh, '<', '/dev/null' or
 665                                 die "failed to open /dev/null: $!\n";
 666                         return $fh;
 667                 }
 668         }
 669
 670         # Count the new files so they can be added newest to oldest
 671         # and still have numbers increasing from oldest to newest
 672         my $fcount = 0;
 673         my $pr = $opts->{-progress};
 674         $pr->("counting changes\n\t$range ... ") if $pr;
 675         # can't use 'rev-list --count' if we use --diff-filter
 676         my $fh = $git->popen(qw(log --pretty=tformat:%h
 677                              --no-notes --no-color --no-renames
 678                              --diff-filter=AM), $range);
 679         ++$fcount while <$fh>;
 680         close $fh or die "git log failed: \$?=$?";
 681         my $high = $self->{mm}->num_highwater;
 682         $pr->("$fcount\n") if $pr; # continue previous line
 683         $self->{ntodo} = $fcount;
 684
 685         if (index($range, '..') < 0) {
 686                 if ($high && $high == $fcount) {
 687                         # fix up old bugs in full indexes which caused messages to
 688                         # not appear in Msgmap
 689                         $self->{regen_up} = $high;
 690                 } else {
 691                         # normal regen is for for fresh data
 692                         $self->{regen_down} = $fcount;
 693                 }
 694         } else {
 695                 # Give oldest messages the smallest numbers
 696                 $self->{regen_down} = $high + $fcount;
 697         }
 698
 699         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 700                                 --raw -r --no-abbrev/, $range);
 701 }
 702
 703 # --is-ancestor requires git 1.8.0+
 704 sub is_ancestor ($$$) {
 705         my ($git, $cur, $tip) = @_;
 706         return 0 unless $git->check($cur);
 707         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 708                 qw(merge-base --is-ancestor), $cur, $tip ];
 709         my $pid = spawn($cmd);
 710         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 711         $? == 0;
 712 }
 713
 714 sub need_update ($$$) {
 715         my ($self, $cur, $new) = @_;
 716         my $git = $self->{git};
 717         return 1 if $cur && !is_ancestor($git, $cur, $new);
 718         my $range = $cur eq '' ? $new : "$cur..$new";
 719         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 720         ($n eq '' || $n > 0);
 721 }
 722
 723 # The last git commit we indexed with Xapian or SQLite (msgmap)
 724 # This needs to account for cases where Xapian or SQLite is
 725 # out-of-date with respect to the other.
 726 sub _last_x_commit {
 727         my ($self, $mm) = @_;
 728         my $lm = $mm->last_commit || '';
 729         my $lx = '';
 730         if (need_xapian($self)) {
 731                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 732         } else {
 733                 $lx = $lm;
 734         }
 735         # Use last_commit from msgmap if it is older or unset
 736         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 737                 $lx = $lm;
 738         }
 739         $lx;
 740 }
 741
 742 sub reindex_from ($$) {
 743         my ($reindex, $last_commit) = @_;
 744         return $last_commit unless $reindex;
 745         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 746 }
 747
 748 # indexes all unindexed messages (v1 only)
 749 sub _index_sync {
 750         my ($self, $opts) = @_;
 751         my $tip = $opts->{ref} || 'HEAD';
 752         my ($last_commit, $lx, $xlog);
 753         my $git = $self->{git};
 754         $git->batch_prepare;
 755         my $pr = $opts->{-progress};
 756
 757         my $xdb = $self->begin_txn_lazy;
 758         my $mm = _msgmap_init($self);
 759         do {
 760                 if ($xlog) {
 761                         close($xlog) or die "git log failed: \$?=$?";
 762                         $xlog = undef;
 763                 }
 764                 $last_commit = _last_x_commit($self, $mm);
 765                 $lx = reindex_from($opts->{reindex}, $last_commit);
 766
 767                 $self->{over}->rollback_lazy;
 768                 $self->{over}->disconnect;
 769                 $git->cleanup;
 770                 delete $self->{txn};
 771                 $xdb->cancel_transaction if $xdb;
 772                 $xdb = _xdb_release($self);
 773
 774                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 775                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 776                 $xlog = _git_log($self, $opts, $range);
 777
 778                 $xdb = $self->begin_txn_lazy;
 779         } while (_last_x_commit($self, $mm) ne $last_commit);
 780
 781         my $dbh = $mm->{dbh} if $mm;
 782         my $cb = sub {
 783                 my ($nr, $commit, $newest) = @_;
 784                 if ($dbh) {
 785                         if ($newest) {
 786                                 my $cur = $mm->last_commit || '';
 787                                 if (need_update($self, $cur, $newest)) {
 788                                         $mm->last_commit($newest);
 789                                 }
 790                         }
 791                         $dbh->commit;
 792                 }
 793                 if ($newest && need_xapian($self)) {
 794                         my $cur = $xdb->get_metadata('last_commit');
 795                         if (need_update($self, $cur, $newest)) {
 796                                 $xdb->set_metadata('last_commit', $newest);
 797                         }
 798                 }
 799                 $self->commit_txn_lazy;
 800                 $git->cleanup;
 801                 $xdb = _xdb_release($self);
 802                 # let another process do some work... <
 803                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 804                 if (!$newest) {
 805                         $xdb = $self->begin_txn_lazy;
 806                         $dbh->begin_work if $dbh;
 807                 }
 808         };
 809
 810         $dbh->begin_work;
 811         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 812 }
 813
 814 sub DESTROY {
 815         # order matters for unlocking
 816         $_[0]->{xdb} = undef;
 817         $_[0]->{lockfh} = undef;
 818 }
 819
 820 # remote_* subs are only used by SearchIdxPart
 821 sub remote_commit {
 822         my ($self) = @_;
 823         if (my $w = $self->{w}) {
 824                 print $w "commit\n" or die "failed to write commit: $!";
 825         } else {
 826                 $self->commit_txn_lazy;
 827         }
 828 }
 829
 830 sub remote_close {
 831         my ($self) = @_;
 832         if (my $w = delete $self->{w}) {
 833                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 834                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 835                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 836                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 837                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 838         } else {
 839                 die "transaction in progress $self\n" if $self->{txn};
 840                 $self->_xdb_release if $self->{xdb};
 841         }
 842 }
 843
 844 sub remote_remove {
 845         my ($self, $oid, $mid) = @_;
 846         if (my $w = $self->{w}) {
 847                 # triggers remove_by_oid in a shard
 848                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 849         } else {
 850                 $self->begin_txn_lazy;
 851                 $self->remove_by_oid($oid, $mid);
 852         }
 853 }
 854
 855 sub begin_txn_lazy {
 856         my ($self) = @_;
 857         return if $self->{txn};
 858
 859         $self->{-inbox}->with_umask(sub {
 860                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 861                 $self->{over}->begin_lazy if $self->{over};
 862                 $xdb->begin_transaction if $xdb;
 863                 $self->{txn} = 1;
 864                 $xdb;
 865         });
 866 }
 867
 868 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 869 # This metadata is read by Admin::detect_indexlevel:
 870 sub set_indexlevel {
 871         my ($self) = @_;
 872
 873         if (!$self->{shard} && # undef or 0, not >0
 874                         delete($self->{-set_indexlevel_once})) {
 875                 my $xdb = $self->{xdb};
 876                 my $level = $xdb->get_metadata('indexlevel');
 877                 if (!$level || $level ne 'medium') {
 878                         $xdb->set_metadata('indexlevel', 'medium');
 879                 }
 880         }
 881 }
 882
 883 sub commit_txn_lazy {
 884         my ($self) = @_;
 885         delete $self->{txn} or return;
 886         $self->{-inbox}->with_umask(sub {
 887                 if (my $xdb = $self->{xdb}) {
 888                         set_indexlevel($self);
 889                         $xdb->commit_transaction;
 890                 }
 891                 $self->{over}->commit_lazy if $self->{over};
 892         });
 893 }
 894
 895 sub worker_done {
 896         my ($self) = @_;
 897         if (need_xapian($self)) {
 898                 die "$$ $0 xdb not released\n" if $self->{xdb};
 899         }
 900         die "$$ $0 still in transaction\n" if $self->{txn};
 901 }
 902
 903 1;